CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7
   8 project(FlightGear)
   9
  10 # We have some custom .cmake scripts not in the official distribution.
  11 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  12
  13 if(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  14     # use official include provided by latest CMake
  15     include(GNUInstallDirs)
  16 else(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  17     # backward compatibility: use our own module for older cmake versions
  18     include(OldGNUInstallDirs)
  19 endif(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  20
  21 # Warning when build is not an out-of-source build.
  22 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  23 if(InSourceBuild)
  24     message(WARNING  "Avoid building inside the source tree!")
  25     message(WARNING  "Create a separate build directory instead (i.e. 'fgbuild') and call CMake from there: ")
  26     message(WARNING  "  mkdir ../fgbuild && cd ../fgbuild && cmake ${CMAKE_SOURCE_DIR}")
  27 endif(InSourceBuild)
  28
  29 set(CMAKE_DEBUG_POSTFIX          "d" CACHE STRING "add a postfix, usually d on windows")
  30 set(CMAKE_RELEASE_POSTFIX        ""  CACHE STRING "add a postfix, usually empty on windows")
  31 set(CMAKE_RELWITHDEBINFO_POSTFIX ""  CACHE STRING "add a postfix, usually empty on windows")
  32 set(CMAKE_MINSIZEREL_POSTFIX     ""  CACHE STRING "add a postfix, usually empty on windows")
  33
  34 # read 'version' file into a variable (stripping any newlines or spaces)
  35 file(READ version versionFile)
  36 string(STRIP ${versionFile} FLIGHTGEAR_VERSION)
  37
  38 #packaging
  39 if(EXISTS ${PROJECT_SOURCE_DIR}/.gitignore)
  40     file(READ .gitignore CPACK_SOURCE_IGNORE_FILES)
  41 else()
  42     # clean tar-balls do not contain SCM (.git/.gitignore/...) files.
  43     set(CPACK_SOURCE_IGNORE_FILES
  44         "Makefile.am;~$;${CPACK_SOURCE_IGNORE_FILES}")
  45 endif()
  46
  47 list (APPEND CPACK_SOURCE_IGNORE_FILES "${PROJECT_SOURCE_DIR}/.git;\\\\.gitignore")
  48
  49 # split version string into components, note CMAKE_MATCH_0 is the entire regexp match
  50 string(REGEX MATCH "([0-9]+)\\.([0-9]+)\\.([0-9]+)" CPACK_PACKAGE_VERSION ${FLIGHTGEAR_VERSION} )
  51 set(CPACK_PACKAGE_VERSION_MAJOR ${CMAKE_MATCH_1})
  52 set(CPACK_PACKAGE_VERSION_MINOR ${CMAKE_MATCH_2})
  53 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_3})
  54 set(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  55 set(CPACK_RESOURCE_FILE_README  "${PROJECT_SOURCE_DIR}/README")
  56
  57 set(CPACK_SOURCE_GENERATOR TBZ2)
  58 set(CPACK_SOURCE_PACKAGE_FILE_NAME "flightgear-${FLIGHTGEAR_VERSION}" CACHE INTERNAL "tarball basename")
  59
  60 include (CPack)
  61
  62 if (FG_DATA_DIR)
  63     message(STATUS "Using explicit data-dir: ${FG_DATA_DIR}")
  64 else()
  65     set(FG_DATA_DIR "${CMAKE_INSTALL_PREFIX}/lib/FlightGear" CACHE PATH "Default location where data files are located")
  66     message(STATUS "Using default data-dir:  ${FG_DATA_DIR}")
  67 endif()
  68
  69 # Change the default build type to something fast
  70 if(NOT CMAKE_BUILD_TYPE)
  71     set(CMAKE_BUILD_TYPE Release CACHE STRING
  72         "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  73         FORCE)
  74 endif(NOT CMAKE_BUILD_TYPE)
  75
  76 if(NOT "$ENV{BUILD_ID}" STREQUAL "")
  77     set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  78     set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  79     message(STATUS "running under Hudson, build-number is ${HUDSON_BUILD_NUMBER}")
  80 else()
  81     set(HUDSON_BUILD_NUMBER 0)
  82     set(HUDSON_BUILD_ID "none")
  83 endif()
  84
  85 IF(APPLE)
  86     set(EVENT_INPUT_DEFAULT 1)
  87
  88     find_library(CORESERVICES_LIBRARY CoreServices)
  89     find_library(COCOA_LIBRARY Cocoa)
  90     list(APPEND PLATFORM_LIBS ${COCOA_LIBRARY} ${CORESERVICES_LIBRARY})
  91
  92 elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
  93     find_package(UDev)
  94
  95     if(UDEV_FOUND)
  96         set(EVENT_INPUT_DEFAULT 1)
  97     endif(UDEV_FOUND)
  98 endif()
  99
 100 find_package(Git)
 101 if (GIT_FOUND)
 102     execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
 103         OUTPUT_VARIABLE REVISION
 104         OUTPUT_STRIP_TRAILING_WHITESPACE)
 105     message(STATUS "Git revision is ${REVISION}")
 106 else()
 107     set(REVISION "none")
 108 endif()
 109
 110 option(LOGGING           "Set to OFF to build FlightGear without logging" ON)
 111 option(SP_FDMS           "Set to ON to build FlightGear with special-purpose FDMs" OFF)
 112 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" OFF)
 113 option(ENABLE_LARCSIM    "Set to ON to build FlightGear with LaRCsim FDM" OFF)
 114 option(ENABLE_YASIM      "Set to ON to build FlightGear with YASIM FDM" ON)
 115 option(ENABLE_JSBSIM     "Set to ON to build FlightGear with JSBSim FDM" ON)
 116 option(ENABLE_FGADMIN    "Set to ON to build FlightGear with FGADMIN" ON)
 117 option(EVENT_INPUT       "Set to ON to build FlightGear with event-based Input support" ${EVENT_INPUT_DEFAULT})
 118 option(ENABLE_LIBSVN     "Set to ON to build FlightGear/terrasync with libsvnclient support" ON)
 119 option(ENABLE_RTI        "Set to ON to build SimGear with RTI support" OFF)
 120 option(WITH_FGPANEL      "Set to ON to build the fgpanel application" ON)
 121 option(JPEG_FACTORY      "Enable JPEG-factory support" OFF)
 122 option(ENABLE_TESTS      "Set to OFF to disable building test applications" ON)
 123
 124 if (MSVC)
 125     GET_FILENAME_COMPONENT(PARENT_DIR ${PROJECT_SOURCE_DIR} PATH)
 126     if (CMAKE_CL_64)
 127         SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty.x64")
 128     else (CMAKE_CL_64)
 129         SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty")
 130     endif (CMAKE_CL_64)
 131     if (EXISTS ${TEST_3RDPARTY_DIR})
 132         set(MSVC_3RDPARTY_ROOT ${PARENT_DIR} CACHE PATH "Location where the third-party dependencies are extracted")
 133     else (EXISTS ${TEST_3RDPARTY_DIR})
 134         set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 135     endif (EXISTS ${TEST_3RDPARTY_DIR})
 136         list(APPEND PLATFORM_LIBS "winmm.lib")
 137 else (MSVC)
 138     set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 139 endif (MSVC)
 140
 141 if(LOGGING)
 142     # nothing
 143 else()
 144     set(FG_NDEBUG 1)
 145 endif()
 146
 147 if(SP_FDMS)
 148     set(ENABLE_SP_FDM 1)
 149 endif()
 150
 151 if (MSVC AND MSVC_3RDPARTY_ROOT)
 152     message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_ROOT}")
 153     set( OSG_MSVC "msvc" )
 154     if (${MSVC_VERSION} EQUAL 1600)
 155         set( OSG_MSVC ${OSG_MSVC}100 )
 156     else (${MSVC_VERSION} EQUAL 1600)
 157         set( OSG_MSVC ${OSG_MSVC}90 )
 158     endif (${MSVC_VERSION} EQUAL 1600)
 159     if (CMAKE_CL_64)
 160         set( OSG_MSVC ${OSG_MSVC}-64 )
 161         set( MSVC_3RDPARTY_DIR 3rdParty.x64 )
 162                 set( BOOST_LIB lib64 )
 163     else (CMAKE_CL_64)
 164         set( MSVC_3RDPARTY_DIR 3rdParty )
 165                 set( BOOST_LIB lib )
 166     endif (CMAKE_CL_64)
 167
 168     set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/SimGear/lib $(BOOST_ROOT)/$(BOOST_LIB) )
 169     set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/SimGear/include)
 170     set (BOOST_ROOT         ${MSVC_3RDPARTY_ROOT}/boost_1_44_0)
 171     set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 172     set (ALUT_INCLUDE_DIR   ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 173     set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib)
 174 endif (MSVC AND MSVC_3RDPARTY_ROOT)
 175
 176 if(EVENT_INPUT)
 177     message(STATUS "checking event-based Input")
 178
 179     IF(APPLE)
 180
 181     elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 182         if(NOT UDEV_FOUND)
 183             message(WARNING "UDev not found, event input is disabled!")
 184             set(EVENT_INPUT 0)
 185         else()
 186             set(EVENT_INPUT_LIBRARIES ${UDEV_LIBRARIES})
 187         endif()
 188
 189     else()
 190         message(WARNING "event input is not supported on this platform yet")
 191     endif()
 192
 193     # Keep PLIB INPUT enabled as long as EventInput does not replace current joystick configurations.
 194     set(ENABLE_PLIB_JOYSTICK 1)
 195 else(EVENT_INPUT)
 196     set(ENABLE_PLIB_JOYSTICK 1)
 197 endif(EVENT_INPUT)
 198
 199 # check required dependencies
 200 find_package(Boost   REQUIRED)
 201 find_package(ZLIB    REQUIRED)
 202 find_package(Threads REQUIRED)
 203 find_package(OpenGL  REQUIRED)
 204 find_package(OpenAL  REQUIRED)
 205 find_package(ALUT    REQUIRED)
 206 find_package(OpenSceneGraph 3.0.0 REQUIRED osgText osgSim osgDB osgParticle osgFX osgUtil osgViewer osgGA)
 207
 208 if(ENABLE_FGADMIN)
 209     find_package(FLTK)
 210
 211     if ( FLTK_FOUND )
 212         if ( X11_Xinerama_FOUND )
 213             message(STATUS "Found X11_Xinerama...")
 214             list(APPEND FLTK_LIBRARIES ${X11_Xinerama_LIB})
 215         endif()
 216
 217         if ( X11_Xft_FOUND )
 218             message(STATUS "Found X11_Xft...")
 219             list(APPEND FLTK_LIBRARIES ${X11_Xft_LIB})
 220         endif()
 221
 222         message(STATUS "Using FLTK_LIBRARIES for fgadmin: ${FLTK_LIBRARIES}")
 223     endif ( FLTK_FOUND )
 224 endif(ENABLE_FGADMIN)
 225
 226 if(ENABLE_LIBSVN)
 227     find_package(SvnClient)
 228
 229     if(LIBSVN_FOUND)
 230         message(STATUS "libsvn found, enabling in terrasync")
 231         set(HAVE_SVN_CLIENT_H 1)
 232         set(HAVE_LIBSVN_CLIENT_1 1)
 233     endif(LIBSVN_FOUND)
 234 endif(ENABLE_LIBSVN)
 235
 236 find_package(PLIB REQUIRED puaux pu js fnt)
 237
 238 # FlightGear and SimGear versions need to match
 239 find_package(SimGear ${FLIGHTGEAR_VERSION} REQUIRED)
 240
 241 if (JPEG_FACTORY)
 242     # check simgear was built with JPEG-factory support
 243     find_package(JPEG REQUIRED)
 244     include_directories(${JPEG_INCLUDE_DIR})
 245
 246     set(CMAKE_REQUIRED_INCLUDES
 247         ${SIMGEAR_INCLUDE_DIR}
 248         ${JPEG_INCLUDE_DIR}
 249         ${OPENSCENEGRAPH_INCLUDE_DIRS})
 250
 251     check_cxx_source_compiles(
 252         "#include <simgear/screen/jpgfactory.hxx>
 253         int main()    { return 0; } "
 254         FG_JPEG_SERVER)
 255
 256     if (NOT FG_JPEG_SERVER)
 257         message(STATUS "JPEG server support requested, but SimGear was built without JPEG support")
 258     endif()
 259 endif()
 260
 261 check_include_file(unistd.h   HAVE_UNISTD_H)
 262 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 263 check_include_file(windows.h  HAVE_WINDOWS_H)
 264
 265 if(ENABLE_RTI)
 266     find_package(RTI)
 267     if(RTI_FOUND)
 268         set(FG_HAVE_HLA 1)
 269     endif(RTI_FOUND)
 270 endif(ENABLE_RTI)
 271
 272 if(CMAKE_COMPILER_IS_GNUCXX)
 273     set(WARNING_FLAGS_CXX "-Wall")
 274     set(WARNING_FLAGS_C   "-Wall")
 275 endif(CMAKE_COMPILER_IS_GNUCXX)
 276
 277 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 278    set (WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual")
 279    set (WARNING_FLAGS_C   "-Wall")
 280 endif()
 281
 282 if(WIN32)
 283
 284     if(MSVC)
 285         # turn off various warnings
 286         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 287         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 288         # endforeach(warning)
 289
 290         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS")
 291         if (${MSVC_VERSION} EQUAL 1600)
 292             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 293         endif (${MSVC_VERSION} EQUAL 1600)
 294     endif(MSVC)
 295
 296     set(NOMINMAX 1)
 297 endif(WIN32)
 298
 299 set (BOOST_CXX_FLAGS "-DBOOST_MULTI_INDEX_DISABLE_SERIALIZATION -DBOOST_BIMAP_DISABLE_SERIALIZATION")
 300
 301 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS} -D_REENTRANT")
 302 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} -D_REENTRANT ${BOOST_CXX_FLAGS}")
 303 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 304
 305 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 306     ${Boost_INCLUDE_DIRS}
 307     ${ZLIB_INCLUDE_DIR}
 308     ${ALUT_INCLUDE_DIR}
 309     ${OPENGL_INCLUDE_DIR}
 310     ${OPENAL_INCLUDE_DIR}
 311     ${SIMGEAR_INCLUDE_DIR}
 312     ${PLIB_INCLUDE_DIR} )
 313
 314 include_directories(${PROJECT_SOURCE_DIR}/src)
 315
 316 # following is needed, because config.h is include 'bare', whereas
 317 # version.h is included as <Include/version.h> - this should be cleaned up
 318 include_directories(${PROJECT_BINARY_DIR}/src)
 319 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 320
 321 add_definitions(-DHAVE_CONFIG_H)
 322
 323 check_function_exists(mkfifo HAVE_MKFIFO)
 324
 325 # configure a header file to pass some of the CMake settings
 326 # to the source code
 327 configure_file (
 328     "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 329     "${PROJECT_BINARY_DIR}/src/Include/config.h"
 330 )
 331
 332 #and the same for the version header
 333 configure_file (
 334     "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 335     "${PROJECT_BINARY_DIR}/src/Include/version.h"
 336 )
 337
 338 add_subdirectory(src)
 339 add_subdirectory(utils)
 340 add_subdirectory(man)
 341
 342 #-----------------------------------------------------------------------------
 343 ### uninstall target
 344 #-----------------------------------------------------------------------------
 345 CONFIGURE_FILE(
 346     "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 347     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 348     IMMEDIATE @ONLY)
 349 ADD_CUSTOM_TARGET(uninstall
 350     "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")