CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7
   8
   9 project(FlightGear)
  10
  11 set(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "add a postfix, usually d on windows")
  12 set(CMAKE_RELEASE_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
  13 set(CMAKE_RELWITHDEBINFO_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
  14 set(CMAKE_MINSIZEREL_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
  15
  16 # read 'version' file into a variable (stripping any newlines or spaces)
  17 file(READ version versionFile)
  18 string(STRIP ${versionFile} FLIGHTGEAR_VERSION)
  19
  20 #packaging
  21
  22 # split version string into components, note CMAKE_MATCH_0 is the entire regexp match
  23 string(REGEX MATCH "([0-9]+)\\.([0-9]+)\\.([0-9]+)" CPACK_PACKAGE_VERSION ${FLIGHTGEAR_VERSION} )
  24 set(CPACK_PACKAGE_VERSION_MAJOR ${CMAKE_MATCH_1})
  25 set(CPACK_PACKAGE_VERSION_MINOR ${CMAKE_MATCH_2})
  26 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_3})
  27 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  28 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  29
  30 set(CPACK_SOURCE_GENERATOR TBZ2 ZIP)
  31 set(CPACK_SOURCE_PACKAGE_FILE_NAME "flightgear-${FLIGHTGEAR_VERSION}" CACHE INTERNAL "tarball basename")
  32 set(CPACK_SOURCE_IGNORE_FILES
  33   "^${PROJECT_SOURCE_DIR}/.git;\\\\.gitignore;Makefile.am;~$;${CPACK_SOURCE_IGNORE_FILES}")
  34
  35 include (CPack)
  36
  37 # We have some custom .cmake scripts not in the official distribution.
  38 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  39
  40 # autoconf compatibility
  41 set(PKGLIBDIR "foo")
  42
  43 # Change the default build type to something fast
  44 if(NOT CMAKE_BUILD_TYPE)
  45   set(CMAKE_BUILD_TYPE Release CACHE STRING
  46       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  47       FORCE)
  48 endif(NOT CMAKE_BUILD_TYPE)
  49
  50 if($ENV{BUILD_ID})
  51         set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  52         set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  53         message(STATUS "running under Hudson, build-number is ${HUDSON_BUILD_NUMBER}")
  54 else()
  55         set(HUDSON_BUILD_NUMBER 0)
  56         set(HUDSON_BUILD_ID "none")
  57 endif()
  58
  59 IF(APPLE)
  60     set(EVENT_INPUT_DEFAULT 1)
  61
  62     find_library(CORESERVICES_LIBRARY CoreServices)
  63     list(APPEND PLATFORM_LIBS ${CORESERVICES_LIBRARY})
  64
  65 elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
  66     # disabled while DBus / HAL / udev issues are decided
  67     #set(EVENT_INPUT_DEFAULT 1)
  68 endif()
  69
  70 find_package(Git)
  71 if (GIT_FOUND)
  72         execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
  73                 OUTPUT_VARIABLE REVISION
  74                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  75         message(STATUS "Git revision is ${REVISION}")
  76 else()
  77         set(REVISION "none")
  78 endif()
  79
  80 option(LOGGING "Set to OFF to build FlightGear without logging" ON)
  81
  82 option(SP_FDMS "Set to ON to build FlightGear with special-purpose FDMs" OFF)
  83 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" ON)
  84 option(ENABLE_LARCSIM "Set to ON to build FlightGear with LaRCsim FDM" ON)
  85 option(ENABLE_YASIM "Set to ON to build FlightGear with YASIM FDM" ON)
  86 option(ENABLE_JSBSIM "Set to ON to build FlightGear with JSBSim FDM" ON)
  87 option(ENABLE_FGADMIN "Set to ON to build FlightGear with FGADMIN" ON)
  88 option(EVENT_INPUT "Set to ON to build FlightGear with event-based Input support" ${EVENT_INPUT_DEFAULT})
  89 option(ENABLE_LIBSVN "Set to ON to build FlightGear/terrasync with libsvnclient support" ON)
  90 option(ENABLE_RTI "Set to ON to build SimGear with RTI support" OFF)
  91 option(WITH_FGPANEL "Set to ON to build the fgpanel application" ON)
  92
  93
  94 if (MSVC)
  95   GET_FILENAME_COMPONENT(PARENT_DIR ${PROJECT_SOURCE_DIR} PATH)
  96   if (CMAKE_CL_64)
  97     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty.x64")
  98   else (CMAKE_CL_64)
  99     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty")
 100   endif (CMAKE_CL_64)
 101   if (EXISTS ${TEST_3RDPARTY_DIR})
 102     set(MSVC_3RDPARTY_ROOT ${PARENT_DIR} CACHE PATH "Location where the third-party dependencies are extracted")
 103   else (EXISTS ${TEST_3RDPARTY_DIR})
 104     set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 105   endif (EXISTS ${TEST_3RDPARTY_DIR})
 106   list(APPEND PLATFORM_LIBS "winmm.lib")
 107 else (MSVC)
 108   set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 109 endif (MSVC)
 110
 111 if(LOGGING)
 112         # nothing
 113 else()
 114         set(FG_NDEBUG 1)
 115 endif()
 116
 117 if(SP_FDMS)
 118         set(ENABLE_SP_FDM 1)
 119 endif()
 120
 121 if (MSVC AND MSVC_3RDPARTY_ROOT)
 122   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_ROOT}")
 123   set( OSG_MSVC "msvc" )
 124   if (${MSVC_VERSION} EQUAL 1600)
 125       set( OSG_MSVC ${OSG_MSVC}100 )
 126   else (${MSVC_VERSION} EQUAL 1600)
 127       set( OSG_MSVC ${OSG_MSVC}90 )
 128   endif (${MSVC_VERSION} EQUAL 1600)
 129   if (CMAKE_CL_64)
 130       set( OSG_MSVC ${OSG_MSVC}-64 )
 131           set( MSVC_3RDPARTY_DIR 3rdParty.x64 )
 132   else (CMAKE_CL_64)
 133           set( MSVC_3RDPARTY_DIR 3rdParty )
 134   endif (CMAKE_CL_64)
 135
 136   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/SimGear/lib )
 137   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/SimGear/include)
 138   set (BOOST_ROOT ${MSVC_3RDPARTY_ROOT}/boost_1_44_0)
 139   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 140   set (ALUT_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 141   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib)
 142 endif (MSVC AND MSVC_3RDPARTY_ROOT)
 143
 144 if(EVENT_INPUT)
 145         message(STATUS "checking event-based Input")
 146
 147         IF(APPLE)
 148
 149         elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 150         find_package(DBus)
 151         if(NOT DBUS_FOUND)
 152             message(WARNING "DBus not found, event input will be disabled")
 153             set(EVENT_INPUT 0)
 154         endif()
 155
 156         else()
 157                 message(WARNING "event input is not supported on this platform yet")
 158         endif()
 159 else(EVENT_INPUT)
 160         set(ENABLE_PLIB_JOYSTICK 1)
 161 endif(EVENT_INPUT)
 162
 163 # check required dependencies
 164 find_package(Boost REQUIRED)
 165 find_package(ZLIB REQUIRED)
 166 find_package(Threads REQUIRED)
 167 find_package(OpenGL REQUIRED)
 168 find_package(OpenAL REQUIRED)
 169 find_package(ALUT REQUIRED)
 170 find_package(OpenSceneGraph 2.8.1 REQUIRED osgText osgSim osgDB osgParticle osgFX osgUtil osgViewer osgGA)
 171
 172 if(ENABLE_FGADMIN)
 173   find_package(FLTK)
 174 endif(ENABLE_FGADMIN)
 175
 176 if(ENABLE_LIBSVN)
 177         find_package(SvnClient)
 178
 179         if(LIBSVN_FOUND)
 180                 message(STATUS "libsvn found, enabling in terrasync")
 181                 set(HAVE_SVN_CLIENT_H 1)
 182                 set(HAVE_LIBSVN_CLIENT_1 1)
 183         endif(LIBSVN_FOUND)
 184 endif(ENABLE_LIBSVN)
 185
 186 find_package(PLIB REQUIRED puaux pu js fnt)
 187 find_package(SimGear 2.5.0 REQUIRED)
 188
 189 check_include_file(unistd.h HAVE_UNISTD_H)
 190 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 191 check_include_file(windows.h HAVE_WINDOWS_H)
 192
 193 # definition depends on OSG version
 194 set(CMAKE_REQUIRED_INCLUDES ${OPENSCENEGRAPH_INCLUDE_DIRS})
 195
 196 check_cxx_source_compiles(
 197     "#include <osg/CullSettings>
 198     int main()
 199     {
 200        osg::CullSettings::VariablesMask mask = osg::CullSettings::CLEAR_MASK;
 201        return 0;
 202     }
 203     "
 204     HAVE_CULLSETTINGS_CLEAR_MASK)
 205
 206 if(ENABLE_RTI)
 207     find_package(RTI)
 208     if(RTI_FOUND)
 209         set(FG_HAVE_HLA 1)
 210     endif(RTI_FOUND)
 211 endif(ENABLE_RTI)
 212
 213 if(CMAKE_COMPILER_IS_GNUCXX)
 214     set(WARNING_FLAGS -Wall)
 215 endif(CMAKE_COMPILER_IS_GNUCXX)
 216
 217 if(WIN32)
 218
 219     if(MSVC)
 220         # turn off various warnings
 221         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 222         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 223         # endforeach(warning)
 224
 225         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS")
 226         if (${MSVC_VERSION} EQUAL 1600)
 227                   set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 228         endif (${MSVC_VERSION} EQUAL 1600)
 229     endif(MSVC)
 230
 231     set(NOMINMAX 1)
 232 endif(WIN32)
 233
 234 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS} -D_REENTRANT")
 235 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS} -D_REENTRANT")
 236 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 237
 238 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 239         ${Boost_INCLUDE_DIRS}
 240         ${ZLIB_INCLUDE_DIR}
 241         ${ALUT_INCLUDE_DIR}
 242         ${OPENAL_INCLUDE_DIR}
 243         ${SIMGEAR_INCLUDE_DIR}
 244         ${PLIB_INCLUDE_DIR} )
 245
 246 include_directories(${PROJECT_SOURCE_DIR}/src)
 247
 248 # following is needed, because config.h is include 'bare', whereas
 249 # version.h is included as <Include/version.h> - this should be cleaned up
 250 include_directories(${PROJECT_BINARY_DIR}/src)
 251 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 252
 253 add_definitions(-DHAVE_CONFIG_H)
 254
 255 check_function_exists(mkfifo HAVE_MKFIFO)
 256
 257 # configure a header file to pass some of the CMake settings
 258 # to the source code
 259 configure_file (
 260   "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 261   "${PROJECT_BINARY_DIR}/src/Include/config.h"
 262   )
 263
 264 #and the same for the version header
 265 configure_file (
 266   "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 267   "${PROJECT_BINARY_DIR}/src/Include/version.h"
 268   )
 269
 270 add_subdirectory(src)
 271 add_subdirectory(utils)
 272
 273 set (INSTALL_DOCS
 274     README
 275         README.OpenAL
 276         README.plib
 277         README.OSG
 278         README.SimGear)
 279
 280 INSTALL(FILES ${INSTALL_DOCS} DESTINATION doc OPTIONAL)
 281
 282 #-----------------------------------------------------------------------------
 283 ### uninstall target
 284 #-----------------------------------------------------------------------------
 285 CONFIGURE_FILE(
 286   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 287   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 288   IMMEDIATE @ONLY)
 289 ADD_CUSTOM_TARGET(uninstall
 290   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
 291