CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7 include (CPack)
   8
   9 project(FlightGear)
  10
  11 set(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "add a postfix, usually d on windows")
  12 set(CMAKE_RELEASE_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
  13 set(CMAKE_RELWITHDEBINFO_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
  14 set(CMAKE_MINSIZEREL_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
  15
  16 # read 'version' file into a variable (stripping any newlines or spaces)
  17 file(READ version versionFile)
  18 string(STRIP ${versionFile} FLIGHTGEAR_VERSION)
  19
  20 #packaging
  21
  22 # split version string into components, note CMAKE_MATCH_0 is the entire regexp match
  23 string(REGEX MATCH "([0-9]+)\\.([0-9]+)\\.([0-9]+)" CPACK_PACKAGE_VERSION ${FLIGHTGEAR_VERSION} )
  24 set(CPACK_PACKAGE_VERSION_MAJOR ${CMAKE_MATCH_1})
  25 set(CPACK_PACKAGE_VERSION_MINOR ${CMAKE_MATCH_2})
  26 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_3})
  27 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  28 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  29
  30 # We have some custom .cmake scripts not in the official distribution.
  31 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  32
  33 # autoconf compatibility
  34 set(PKGLIBDIR "foo")
  35
  36 # Change the default build type to something fast
  37 if(NOT CMAKE_BUILD_TYPE)
  38   set(CMAKE_BUILD_TYPE Release CACHE STRING
  39       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  40       FORCE)
  41 endif(NOT CMAKE_BUILD_TYPE)
  42
  43 if($ENV{BUILD_ID})
  44         set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  45         set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  46         message(STATUS "running under Hudson, build-number is ${HUDSON_BUILD_NUMBER}")
  47 else()
  48         set(HUDSON_BUILD_NUMBER 0)
  49         set(HUDSON_BUILD_ID "none")
  50 endif()
  51
  52 IF(APPLE)
  53     set(EVENT_INPUT_DEFAULT 1)
  54 elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
  55     # disabled while DBus / HAL / udev issues are decided
  56     #set(EVENT_INPUT_DEFAULT 1)
  57 endif()
  58
  59 find_package(Git)
  60 if (GIT_FOUND)
  61         execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
  62                 OUTPUT_VARIABLE REVISION
  63                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  64         message(STATUS "Git revision is ${REVISION}")
  65 else()
  66         set(REVISION "none")
  67 endif()
  68
  69 option(LOGGING "Set to OFF to build FlightGear without logging" ON)
  70
  71 option(SP_FDMS "Set to ON to build FlightGear with special-purpose FDMs" OFF)
  72 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" ON)
  73 option(ENABLE_LARCSIM "Set to ON to build FlightGear with LaRCsim FDM" ON)
  74 option(ENABLE_YASIM "Set to ON to build FlightGear with YASIM FDM" ON)
  75 option(ENABLE_JSBSIM "Set to ON to build FlightGear with JSBSim FDM" ON)
  76 option(ENABLE_FGADMIN "Set to ON to build FlightGear with FGADMIN" ON)
  77 option(EVENT_INPUT "Set to ON to build FlightGear with event-based Input support" ${EVENT_INPUT_DEFAULT})
  78 option(ENABLE_LIBSVN "Set to ON to build FlightGear/terrasync with libsvnclient support" ON)
  79 option(ENABLE_RTI "Set to ON to build SimGear with RTI support" OFF)
  80 option(WITH_FGPANEL "Set to ON to build the fgpanel application" ON)
  81
  82
  83 if (MSVC)
  84   GET_FILENAME_COMPONENT(PARENT_DIR ${PROJECT_SOURCE_DIR} PATH)
  85   if (CMAKE_CL_64)
  86     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty.x64")
  87   else (CMAKE_CL_64)
  88     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty")
  89   endif (CMAKE_CL_64)
  90   if (EXISTS ${TEST_3RDPARTY_DIR})
  91     set(MSVC_3RDPARTY_ROOT ${PARENT_DIR} CACHE PATH "Location where the third-party dependencies are extracted")
  92   else (EXISTS ${TEST_3RDPARTY_DIR})
  93     set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
  94   endif (EXISTS ${TEST_3RDPARTY_DIR})
  95 else (MSVC)
  96   set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
  97 endif (MSVC)
  98
  99 if(LOGGING)
 100         # nothing
 101 else()
 102         set(FG_NDEBUG 1)
 103 endif()
 104
 105 if(SP_FDMS)
 106         set(ENABLE_SP_FDM 1)
 107 endif()
 108
 109 if (MSVC AND MSVC_3RDPARTY_ROOT)
 110   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_ROOT}")
 111   set( OSG_MSVC "msvc" )
 112   if (${MSVC_VERSION} EQUAL 1600)
 113       set( OSG_MSVC ${OSG_MSVC}100 )
 114   else (${MSVC_VERSION} EQUAL 1600)
 115       set( OSG_MSVC ${OSG_MSVC}90 )
 116   endif (${MSVC_VERSION} EQUAL 1600)
 117   if (CMAKE_CL_64)
 118       set( OSG_MSVC ${OSG_MSVC}-64 )
 119           set( MSVC_3RDPARTY_DIR 3rdParty.x64 )
 120   else (CMAKE_CL_64)
 121           set( MSVC_3RDPARTY_DIR 3rdParty )
 122   endif (CMAKE_CL_64)
 123
 124   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/SimGear/lib )
 125   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/SimGear/include)
 126   set (BOOST_ROOT ${MSVC_3RDPARTY_ROOT}/boost_1_44_0)
 127   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 128   set (ALUT_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 129   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib)
 130 endif (MSVC AND MSVC_3RDPARTY_ROOT)
 131
 132 if(EVENT_INPUT)
 133         message(STATUS "checking event-based Input")
 134
 135         IF(APPLE)
 136
 137         elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 138         find_package(DBus)
 139         if(NOT DBUS_FOUND)
 140             message(WARNING "DBus not found, event input will be disabled")
 141             set(EVENT_INPUT 0)
 142         endif()
 143
 144         else()
 145                 message(WARNING "event input is not supported on this platform yet")
 146         endif()
 147 else(EVENT_INPUT)
 148         set(ENABLE_PLIB_JOYSTICK 1)
 149 endif(EVENT_INPUT)
 150
 151 # check required dependencies
 152 find_package(Boost REQUIRED)
 153 find_package(ZLIB REQUIRED)
 154 find_package(Threads REQUIRED)
 155 find_package(OpenGL REQUIRED)
 156 find_package(OpenAL REQUIRED)
 157 find_package(ALUT REQUIRED)
 158 find_package(OpenSceneGraph 2.8.1 REQUIRED osgText osgSim osgDB osgParticle osgFX osgUtil osgViewer osgGA)
 159
 160 if(ENABLE_FGADMIN)
 161   find_package(FLTK)
 162 endif(ENABLE_FGADMIN)
 163
 164 if(ENABLE_LIBSVN)
 165         find_package(SvnClient)
 166
 167         if(LIBSVN_FOUND)
 168                 message(STATUS "libsvn found, enabling in terrasync")
 169                 set(HAVE_SVN_CLIENT_H 1)
 170                 set(HAVE_LIBSVN_CLIENT_1 1)
 171         endif(LIBSVN_FOUND)
 172 endif(ENABLE_LIBSVN)
 173
 174 find_package(PLIB REQUIRED puaux pu js fnt)
 175 find_package(SimGear 2.5.0 REQUIRED)
 176
 177 check_include_file(unistd.h HAVE_UNISTD_H)
 178 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 179 check_include_file(windows.h HAVE_WINDOWS_H)
 180
 181 # definition depends on OSG version
 182 set(CMAKE_REQUIRED_INCLUDES ${OPENSCENEGRAPH_INCLUDE_DIRS})
 183
 184 check_cxx_source_compiles(
 185     "#include <osg/CullSettings>
 186     int main()
 187     {
 188        osg::CullSettings::VariablesMask mask = osg::CullSettings::CLEAR_MASK;
 189        return 0;
 190     }
 191     "
 192     HAVE_CULLSETTINGS_CLEAR_MASK)
 193
 194 if(ENABLE_RTI)
 195     find_package(RTI)
 196     if(RTI_FOUND)
 197         set(FG_HAVE_HLA 1)
 198     endif(RTI_FOUND)
 199 endif(ENABLE_RTI)
 200
 201 if(CMAKE_COMPILER_IS_GNUCXX)
 202     set(WARNING_FLAGS -Wall)
 203 endif(CMAKE_COMPILER_IS_GNUCXX)
 204
 205 if(WIN32)
 206
 207     if(MSVC)
 208         # turn off various warnings
 209         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 210         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 211         # endforeach(warning)
 212
 213         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS")
 214         if (${MSVC_VERSION} EQUAL 1600)
 215                   set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 216         endif (${MSVC_VERSION} EQUAL 1600)
 217     endif(MSVC)
 218
 219     set(NOMINMAX 1)
 220 endif(WIN32)
 221
 222 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS} -D_REENTRANT")
 223 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS} -D_REENTRANT")
 224 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 225
 226 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 227         ${Boost_INCLUDE_DIRS}
 228         ${ZLIB_INCLUDE_DIR}
 229         ${ALUT_INCLUDE_DIR}
 230         ${OPENAL_INCLUDE_DIR}
 231         ${SIMGEAR_INCLUDE_DIR}
 232         ${PLIB_INCLUDE_DIR} )
 233
 234 include_directories(${PROJECT_SOURCE_DIR}/src)
 235
 236 # following is needed, because config.h is include 'bare', whereas
 237 # version.h is included as <Include/version.h> - this should be cleaned up
 238 include_directories(${PROJECT_BINARY_DIR}/src)
 239 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 240
 241 add_definitions(-DHAVE_CONFIG_H)
 242
 243 check_function_exists(mkfifo HAVE_MKFIFO)
 244
 245 # configure a header file to pass some of the CMake settings
 246 # to the source code
 247 configure_file (
 248   "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 249   "${PROJECT_BINARY_DIR}/src/Include/config.h"
 250   )
 251
 252 #and the same for the version header
 253 configure_file (
 254   "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 255   "${PROJECT_BINARY_DIR}/src/Include/version.h"
 256   )
 257
 258 add_subdirectory(src)
 259 add_subdirectory(utils)
 260
 261 #-----------------------------------------------------------------------------
 262 ### uninstall target
 263 #-----------------------------------------------------------------------------
 264 CONFIGURE_FILE(
 265   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 266   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 267   IMMEDIATE @ONLY)
 268 ADD_CUSTOM_TARGET(uninstall
 269   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
 270