CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7
   8 if(COMMAND cmake_policy)
   9    if(POLICY CMP0054)
  10        cmake_policy(SET CMP0054 NEW)
  11    endif()
  12    if(POLICY CMP0042)
  13        cmake_policy(SET CMP0042 NEW)
  14    endif()
  15 endif()
  16
  17 # set this before project()
  18 # using 10.7 because boost requires libc++ and 10.6 doesn't include it
  19 set(CMAKE_OSX_DEPLOYMENT_TARGET 10.7)
  20
  21 project(FlightGear)
  22
  23 # We have some custom .cmake scripts not in the official distribution.
  24 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  25
  26 if(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  27     # use official include provided by latest CMake
  28     include(GNUInstallDirs)
  29 else(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  30     # backward compatibility: use our own module for older cmake versions
  31     include(OldGNUInstallDirs)
  32 endif(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  33
  34 # Warning when build is not an out-of-source build.
  35 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  36 if(InSourceBuild)
  37     message(WARNING  "Avoid building inside the source tree!")
  38     message(WARNING  "Create a separate build directory instead (i.e. 'fgbuild') and call CMake from there: ")
  39     message(WARNING  "  mkdir ../fgbuild && cd ../fgbuild && cmake ${CMAKE_SOURCE_DIR}")
  40 endif(InSourceBuild)
  41
  42 # System detection/default settings
  43 include( DetectDistro )
  44 include( DetectBrowser )
  45
  46 set(CMAKE_DEBUG_POSTFIX          "d" CACHE STRING "add a postfix, usually d on windows")
  47 set(CMAKE_RELEASE_POSTFIX        ""  CACHE STRING "add a postfix, usually empty on windows")
  48 set(CMAKE_RELWITHDEBINFO_POSTFIX ""  CACHE STRING "add a postfix, usually empty on windows")
  49 set(CMAKE_MINSIZEREL_POSTFIX     ""  CACHE STRING "add a postfix, usually empty on windows")
  50
  51 # read 'version' file into a variable (stripping any newlines or spaces)
  52 file(READ version versionFile)
  53 if (NOT versionFile)
  54     message(FATAL_ERROR "Unable to determine FlightGear version. Version file is missing.")
  55 endif()
  56 string(STRIP "${versionFile}" FLIGHTGEAR_VERSION)
  57
  58 # FlightGear packaging (to build a source tarball)
  59 include( ConfigureCPack )
  60
  61 # FlightGear base package path
  62 if (FG_DATA_DIR)
  63     message(STATUS "Using explicit data directory for base package: ${FG_DATA_DIR}")
  64 else()
  65     set(FG_DATA_DIR "${CMAKE_INSTALL_PREFIX}/lib/FlightGear" CACHE PATH "Default location where data files are located")
  66     message(STATUS "Using default data directory for base package:  ${FG_DATA_DIR}")
  67 endif()
  68
  69 # Change the default build type to something fast
  70 if(NOT CMAKE_BUILD_TYPE)
  71     set(CMAKE_BUILD_TYPE Release CACHE STRING
  72         "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  73         FORCE)
  74 endif(NOT CMAKE_BUILD_TYPE)
  75
  76 if(NOT "$ENV{BUILD_ID}" STREQUAL "")
  77     set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  78     set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  79     message(STATUS "running under Hudson/Jenkins, build-number is ${HUDSON_BUILD_NUMBER}")
  80 else()
  81     set(HUDSON_BUILD_NUMBER 0)
  82     set(HUDSON_BUILD_ID "none")
  83 endif()
  84
  85 #####################################################################################
  86 # Configure library search paths
  87 #####################################################################################
  88
  89
  90 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  91     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  92     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  93     # add paths manually
  94     # see http://www.cmake.org/Bug/view.php?id=12049 and
  95     # http://www.cmake.org/Bug/view.php?id=12037
  96     list(APPEND ADDITIONAL_LIBRARY_PATHS
  97          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  98          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  99          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
 100     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
 101 endif()
 102
 103 #####################################################################################
 104
 105 IF(APPLE)
 106     set(EVENT_INPUT_DEFAULT 1)
 107
 108     find_library(CORESERVICES_LIBRARY CoreServices)
 109     find_library(COCOA_LIBRARY Cocoa)
 110     list(APPEND PLATFORM_LIBS ${COCOA_LIBRARY} ${CORESERVICES_LIBRARY})
 111
 112 elseif(${CMAKE_SYSTEM_NAME} MATCHES "Linux" OR
 113         ${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD")
 114     set(USE_DBUS_DEFAULT 1)
 115
 116     find_package(UDev)
 117     if(UDEV_FOUND)
 118         set(EVENT_INPUT_DEFAULT 1)
 119     endif(UDEV_FOUND)
 120
 121     find_package(Speex)
 122     find_package(Speexdsp)
 123     if(SPEEX_FOUND AND SPEEXDSP_FOUND)
 124         set(SYSTEM_SPEEX_DEFAULT 1)
 125     endif(SPEEX_FOUND AND SPEEXDSP_FOUND)
 126
 127     find_package(Gsm)
 128     if(GSM_FOUND)
 129         set(SYSTEM_GSM_DEFAULT 1)
 130     endif(GSM_FOUND)
 131
 132     find_package(Flite)
 133     if(FLITE_FOUND)
 134         set(SYSTEM_FLITE_DEFAULT 1)
 135     endif()
 136
 137     find_package(HtsEngine)
 138     if(HTS_ENGINE_FOUND)
 139         set(SYSTEM_HTS_ENGINE_DEFAULT 1)
 140     endif()
 141 endif()
 142
 143 find_package(Git)
 144 if (GIT_FOUND)
 145     execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
 146         OUTPUT_VARIABLE REVISION
 147         OUTPUT_STRIP_TRAILING_WHITESPACE)
 148     message(STATUS "Git revision is ${REVISION}")
 149 else()
 150     set(REVISION "none")
 151 endif()
 152
 153 # FlightGear build options
 154 option(SIMGEAR_SHARED    "Set to ON when SimGear was built as a shared library" OFF)
 155 option(LOGGING           "Set to ON to build FlightGear with logging support (default)" ON)
 156 option(JSBSIM_TERRAIN    "Set to ON to build FlightGear with JSBSim terrain handling code" ON)
 157 option(SP_FDMS           "Set to ON to build FlightGear with special-purpose FDMs" OFF)
 158 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" OFF)
 159 option(ENABLE_LARCSIM    "Set to ON to build FlightGear with LaRCsim FDM" OFF)
 160 option(ENABLE_YASIM      "Set to ON to build FlightGear with YASIM FDM (default)" ON)
 161 option(ENABLE_JSBSIM     "Set to ON to build FlightGear with JSBSim FDM (default)" ON)
 162 option(EVENT_INPUT       "Set to ON to build FlightGear with event-based Input support" ${EVENT_INPUT_DEFAULT})
 163 option(ENABLE_RTI        "Set to ON to build FlightGear with RTI support" OFF)
 164 option(ENABLE_PROFILE    "Set to ON to build FlightGear with gperftools profiling support" OFF)
 165 option(SYSTEM_SQLITE     "Set to ON to build FlightGear with the system's SQLite3 library" OFF)
 166 option(ENABLE_IAX        "Set to ON to build FlightGear with IAXClient/fgcom built-in (default)" ON)
 167 option(USE_DBUS          "Set to ON to build FlightGear with DBus screensaver interaction (default on Linux)" ${USE_DBUS_DEFAULT})
 168 option(SYSTEM_SPEEX      "Set to ON to build IAXClient with the system's speex and speexdsp library" ${SYSTEM_SPEEX_DEFAULT})
 169 option(SYSTEM_GSM        "Set to ON to build IAXClient with the system's GSM library" ${SYSTEM_GSM_DEFAULT})
 170 option(SYSTEM_FLITE      "Set to ON to build Flightgear with the system's Flite library" ${SYSTEM_FLITE_DEFAULT})
 171 option(SYSTEM_HTS_ENGINE "Set to ON to build Flightgear with the system's HTS Engine library" ${SYSTEM_HTS_ENGINE_DEFAULT})
 172
 173 # additional utilities
 174 option(ENABLE_FGADMIN    "Set to ON to build the FGADMIN application (default)" ON)
 175 option(ENABLE_FGELEV     "Set to ON to build the fgelev application (default)" ON)
 176 option(WITH_FGPANEL      "Set to ON to build the fgpanel application (default)" ON)
 177 option(ENABLE_FGVIEWER   "Set to ON to build the fgviewer application (default)" ON)
 178 option(ENABLE_GPSSMOOTH  "Set to ON to build the GPSsmooth application (default)" ON)
 179 option(ENABLE_TERRASYNC  "Set to ON to build the terrasync application (default)" ON)
 180 option(ENABLE_FGJS       "Set to ON to build the fgjs application (default)" ON)
 181 option(ENABLE_JS_DEMO    "Set to ON to build the js_demo application (default)" ON)
 182 option(ENABLE_METAR      "Set to ON to build the metar application (default)" ON)
 183 option(ENABLE_TESTS      "Set to ON to build test applications (default)" ON)
 184 option(ENABLE_FGCOM      "Set to ON to build the FGCom application (default)" ON)
 185 option(ENABLE_FLITE      "Set to ON to build the Flite text-to-speech module" ON)
 186 option(ENABLE_QT         "Set to ON to build the internal Qt launcher" ON)
 187
 188 if(LOGGING)
 189     # nothing
 190 else()
 191     set(FG_NDEBUG 1)
 192 endif()
 193
 194 if(JSBSIM_TERRAIN)
 195    set(JSBSIM_USE_GROUNDREACTIONS 1)
 196 endif()
 197
 198 if(SP_FDMS)
 199     set(ENABLE_SP_FDM 1)
 200 endif()
 201
 202 if(ENABLE_FGCOM)
 203   set(ENABLE_IAX 1)
 204   include_directories(${PROJECT_SOURCE_DIR}/3rdparty/iaxclient/lib ) # for iaxclient.h
 205 endif()
 206
 207 # Setup MSVC 3rd party directories
 208 include( ConfigureMsvc3rdParty )
 209
 210 if(EVENT_INPUT)
 211     if(APPLE)
 212     elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 213         if(NOT UDEV_FOUND)
 214             message(WARNING "UDev not found, event input is disabled!")
 215             set(EVENT_INPUT 0)
 216         else()
 217             add_definitions(-DWITH_EVENTINPUT)
 218             set(EVENT_INPUT_LIBRARIES ${UDEV_LIBRARIES})
 219             message(STATUS "event-based input enabled. Using ${UDEV_LIBRARIES}")
 220         endif()
 221     else()
 222         message(WARNING "event-based input is not supported on this platform yet")
 223     endif()
 224
 225     # Keep PLIB INPUT enabled as long as EventInput does not replace current joystick configurations.
 226     set(ENABLE_PLIB_JOYSTICK 1)
 227 else(EVENT_INPUT)
 228     set(ENABLE_PLIB_JOYSTICK 1)
 229 endif(EVENT_INPUT)
 230
 231 # check required dependencies
 232 find_package(Boost   REQUIRED)
 233 find_package(ZLIB    REQUIRED)
 234 find_package(Threads REQUIRED)
 235 find_package(OpenGL  REQUIRED)
 236 find_package(OpenAL  REQUIRED)
 237 find_package(OpenSceneGraph 3.2.0 REQUIRED
 238   osgText
 239   osgSim
 240   osgDB
 241   osgParticle
 242   osgFX
 243   osgUtil
 244   osgViewer
 245   osgGA
 246 )
 247
 248 if (MSVC)
 249         find_package(CrashRpt)
 250         if (CRASHRPT_FOUND)
 251                 set(HAVE_CRASHRPT 1)
 252                 message(STATUS "Using CrashRpt")
 253         include_directories( ${CRASHRPT_INCLUDE_DIR})
 254         endif()
 255 endif()
 256
 257 ##############################################################################
 258 ## Sqlite3 setup
 259
 260 if (SYSTEM_SQLITE)
 261     find_package(SQLite3 REQUIRED)
 262
 263     message(STATUS "Using system SQLite3 library")
 264 else()
 265     set(SQLITE3_INCLUDED_DIR "${CMAKE_SOURCE_DIR}/3rdparty/sqlite3")
 266     # this target is defined in src/Navaids/CMakeLists.txt
 267     list(APPEND SQLITE3_LIBRARY fgsqlite3)
 268 endif (SYSTEM_SQLITE)
 269
 270 # Sqlite always depends on the threading lib
 271 list(APPEND SQLITE3_LIBRARY ${CMAKE_THREAD_LIBS_INIT})
 272
 273 ##############################################################################
 274 ## DBus setup
 275
 276 if (USE_DBUS)
 277     include(FindPkgConfig)
 278     if (PKG_CONFIG_FOUND)
 279         pkg_check_modules(DBUS dbus-1)
 280     endif (PKG_CONFIG_FOUND) #if we don't have pkg-config, assume we don't have libdbus-1-dev either http://packages.debian.org/sid/libdbus-1-dev
 281     if (DBUS_FOUND)
 282         set(HAVE_DBUS 1)
 283         message(STATUS "Using DBus")
 284         include_directories( ${DBUS_INCLUDE_DIRS})
 285     else()
 286         message(STATUS "DBus not found, screensaver control disabled")
 287     endif (DBUS_FOUND)
 288 else()
 289 endif (USE_DBUS)
 290
 291 # Sqlite always depends on the threading lib
 292 list(APPEND SQLITE3_LIBRARY ${CMAKE_THREAD_LIBS_INIT})
 293
 294 ##############################################################################
 295 ## Qt5 setup setup
 296 if (ENABLE_QT)
 297         message(STATUS "Qt launcher enabled, checking for Qt 5.1 / qmake")
 298         find_package(Qt5 5.1 COMPONENTS Widgets)
 299         if (Qt5Widgets_FOUND)
 300                 message(STATUS "Will enable Qt launcher GUI")
 301                 set(HAVE_QT 1)
 302         endif()
 303 endif (ENABLE_QT)
 304 ##############################################################################
 305
 306 find_package(PLIB REQUIRED puaux pu js fnt)
 307
 308 # FlightGear and SimGear versions need to match
 309 find_package(SimGear ${FLIGHTGEAR_VERSION} REQUIRED)
 310
 311 ##############################################################################
 312
 313 check_include_file(unistd.h   HAVE_UNISTD_H)
 314 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 315 check_include_file(windows.h  HAVE_WINDOWS_H)
 316
 317 if(ENABLE_PROFILE)
 318     find_package(GooglePerfTools REQUIRED)
 319     set(FG_HAVE_GPERFTOOLS 1)
 320     message(STATUS "Built-in profiler using gperftools available")
 321 endif()
 322
 323 if(ENABLE_RTI)
 324     message(STATUS "RTI: ENABLED")
 325     find_package(RTI)
 326     if(RTI_FOUND)
 327         set(FG_HAVE_HLA 1)
 328     endif(RTI_FOUND)
 329 else()
 330     message(STATUS "RTI: DISABLED")
 331 endif(ENABLE_RTI)
 332
 333 if(CMAKE_COMPILER_IS_GNUCXX)
 334     set(WARNING_FLAGS_CXX "-Wall")
 335     set(WARNING_FLAGS_C   "-Wall")
 336 endif(CMAKE_COMPILER_IS_GNUCXX)
 337
 338 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 339    set (WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual")
 340    set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LIBRARY "libc++")
 341    set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LANGUAGE_STANDARD "c++11")
 342    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -stdlib=libc++")
 343    set (WARNING_FLAGS_C   "-Wall")
 344 endif()
 345
 346 if(WIN32)
 347
 348     if(MSVC)
 349         # turn off various warnings
 350         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 351         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 352         # endforeach(warning)
 353
 354         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS -Dstrdup=_strdup")
 355         if (${MSVC_VERSION} GREATER 1599)
 356             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 357         endif (${MSVC_VERSION} GREATER 1599)
 358     endif(MSVC)
 359
 360     set(NOMINMAX 1)
 361 endif(WIN32)
 362
 363 set (BOOST_CXX_FLAGS "-DBOOST_MULTI_INDEX_DISABLE_SERIALIZATION -DBOOST_BIMAP_DISABLE_SERIALIZATION")
 364
 365 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS} -D_REENTRANT")
 366 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} -D_REENTRANT ${BOOST_CXX_FLAGS}")
 367 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 368
 369 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 370     ${Boost_INCLUDE_DIRS}
 371     ${ZLIB_INCLUDE_DIR}
 372     ${OPENGL_INCLUDE_DIR}
 373     ${OPENAL_INCLUDE_DIR}
 374     ${SIMGEAR_INCLUDE_DIRS}
 375     ${PLIB_INCLUDE_DIR}
 376     ${SQLITE3_INCLUDED_DIR} )
 377
 378 include_directories(${PROJECT_SOURCE_DIR})
 379 include_directories(${PROJECT_SOURCE_DIR}/src)
 380 # following is needed, because config.h is include 'bare', whereas
 381 # version.h is included as <Include/version.h> - this should be cleaned up
 382 include_directories(${PROJECT_BINARY_DIR}/src)
 383 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 384
 385 if (ENABLE_FLITE)
 386     include_directories(${PROJECT_SOURCE_DIR}/3rdparty/hts_engine_API/include )
 387     include_directories(${PROJECT_SOURCE_DIR}/3rdparty/flite_hts_engine/include )
 388 endif()
 389
 390 add_definitions(-DHAVE_CONFIG_H)
 391
 392 check_function_exists(mkfifo HAVE_MKFIFO)
 393
 394 # configure a header file to pass some of the CMake settings
 395 # to the source code
 396 configure_file (
 397     "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 398     "${PROJECT_BINARY_DIR}/src/Include/config.h"
 399 )
 400
 401 #and the same for the version header
 402 configure_file (
 403     "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 404     "${PROJECT_BINARY_DIR}/src/Include/version.h"
 405 )
 406
 407 add_subdirectory(3rdparty)
 408 add_subdirectory(utils)
 409 add_subdirectory(src)
 410 add_subdirectory(man)
 411
 412 #-----------------------------------------------------------------------------
 413 ### uninstall target
 414 #-----------------------------------------------------------------------------
 415 CONFIGURE_FILE(
 416     "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 417     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 418     IMMEDIATE @ONLY)
 419 ADD_CUSTOM_TARGET(uninstall
 420     "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")