CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2 include (CheckFunctionExists)
   3 include (CheckIncludeFile)
   4 include (CheckCXXSourceCompiles)
   5 include (CheckCXXCompilerFlag)
   6
   7 # set this before project()
   8 set(CMAKE_OSX_DEPLOYMENT_TARGET 10.6)
   9
  10 project(SimGear)
  11
  12 # read 'version' file into a variable (stripping any newlines or spaces)
  13 file(READ version versionFile)
  14 string(STRIP ${versionFile} SIMGEAR_VERSION)
  15
  16 set(FIND_LIBRARY_USE_LIB64_PATHS ON)
  17
  18 # use simgear version also as the SO version (if building SOs)
  19 SET(SIMGEAR_SOVERSION ${SIMGEAR_VERSION})
  20
  21 # Warning when build is not an out-of-source build.
  22 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  23 if(InSourceBuild)
  24     message(WARNING  "Avoid building inside the source tree!")
  25     message(WARNING  "Create a separate build directory instead (i.e. 'sgbuild') and call CMake from there: ")
  26     message(WARNING  "  mkdir ../sgbuild && cd ../sgbuild && cmake ${CMAKE_SOURCE_DIR}")
  27 endif(InSourceBuild)
  28
  29 #packaging
  30 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  31 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  32 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Simulation support libraries for FlightGear and related projects")
  33 SET(CPACK_PACKAGE_VENDOR "The FlightGear project")
  34 SET(CPACK_GENERATOR "TBZ2")
  35 SET(CPACK_INSTALL_CMAKE_PROJECTS  ${CMAKE_CURRENT_BINARY_DIR};SimGear;ALL;/)
  36
  37
  38 # split version string into components, note CMAKE_MATCH_0 is the entire regexp match
  39 string(REGEX MATCH "([0-9]+)\\.([0-9]+)\\.([0-9]+)" CPACK_PACKAGE_VERSION ${SIMGEAR_VERSION} )
  40 set(CPACK_PACKAGE_VERSION_MAJOR ${CMAKE_MATCH_1})
  41 set(CPACK_PACKAGE_VERSION_MINOR ${CMAKE_MATCH_2})
  42 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_3})
  43
  44 message(STATUS "version is ${CPACK_PACKAGE_VERSION_MAJOR} dot ${CPACK_PACKAGE_VERSION_MINOR} dot ${CPACK_PACKAGE_VERSION_PATCH}")
  45
  46 set(CPACK_SOURCE_GENERATOR TBZ2)
  47 set(CPACK_SOURCE_PACKAGE_FILE_NAME "simgear-${SIMGEAR_VERSION}" CACHE INTERNAL "tarball basename")
  48 set(CPACK_SOURCE_IGNORE_FILES
  49   "^${PROJECT_SOURCE_DIR}/.git;\\\\.gitignore;Makefile.am;~$;${CPACK_SOURCE_IGNORE_FILES}")
  50
  51 message(STATUS "ignoring: ${CPACK_SOURCE_IGNORE_FILES}")
  52
  53 include (CPack)
  54
  55 # We have some custom .cmake scripts not in the official distribution.
  56 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  57
  58 # Change the default build type to something fast
  59 if(NOT CMAKE_BUILD_TYPE)
  60   set(CMAKE_BUILD_TYPE Release CACHE STRING
  61       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  62       FORCE)
  63 endif(NOT CMAKE_BUILD_TYPE)
  64
  65 # Determine name of library installation directory, i.e. "lib" vs "lib64", which
  66 # differs between all Debian-based vs all other Linux distros.
  67 # See cmake bug #11964, http://cmake.org/gitweb?p=cmake.git;a=commit;h=126c993d
  68 # GNUInstallDirs requires CMake >= 2.8.5, use own file for older cmake
  69 if(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  70   include(GNUInstallDirs)
  71 else(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  72   include(OldGNUInstallDirs)
  73 endif(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  74 message(STATUS "Library installation directory: ${CMAKE_INSTALL_LIBDIR}")
  75
  76 #####################################################################################
  77 # Configure library search paths
  78 #####################################################################################
  79
  80 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  81     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  82     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  83     # add paths manually
  84     # see http://www.cmake.org/Bug/view.php?id=12049 and
  85     # http://www.cmake.org/Bug/view.php?id=12037
  86     list(APPEND ADDITIONAL_LIBRARY_PATHS
  87          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  88          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  89          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
  90     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
  91 endif()
  92
  93 #####################################################################################
  94
  95 if (NOT MSVC)
  96 option(SIMGEAR_SHARED   "Set to ON to build SimGear as a shared library/framework" OFF)
  97 option(SYSTEM_EXPAT     "Set to ON to build SimGear using the system libExpat" OFF)
  98 else()
  99 # Building SimGear DLLs is currently not supported for MSVC.
 100 set(SIMGEAR_SHARED OFF)
 101 # Using a system expat is currently not supported for MSVC - it would require shared simgear (DLL).
 102 set(SYSTEM_EXPAT OFF)
 103 endif()
 104
 105 option(SIMGEAR_HEADLESS "Set to ON to build SimGear without GUI/graphics support" OFF)
 106 option(ENABLE_RTI       "Set to ON to build SimGear with RTI support" OFF)
 107 option(ENABLE_TESTS     "Set to OFF to disable building SimGear's test applications" ON)
 108 option(ENABLE_SOUND     "Set to OFF to disable building SimGear's sound support" ON)
 109 option(ENABLE_PKGUTIL   "Set to ON to build the sg_pkgutil application (default)" ON)
 110
 111 if (MSVC)
 112   GET_FILENAME_COMPONENT(PARENT_DIR ${PROJECT_BINARY_DIR} PATH)
 113   if (CMAKE_CL_64)
 114     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty.x64")
 115   else (CMAKE_CL_64)
 116     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty")
 117   endif (CMAKE_CL_64)
 118   if (EXISTS ${TEST_3RDPARTY_DIR})
 119     set(MSVC_3RDPARTY_ROOT ${PARENT_DIR} CACHE PATH "Location where the third-party dependencies are extracted")
 120   else (EXISTS ${TEST_3RDPARTY_DIR})
 121     set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 122   endif (EXISTS ${TEST_3RDPARTY_DIR})
 123 else (MSVC)
 124   set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 125 endif (MSVC)
 126
 127 if (MSVC AND MSVC_3RDPARTY_ROOT)
 128   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_ROOT}")
 129   set( OSG_MSVC "msvc" )
 130   if (${MSVC_VERSION} EQUAL 1700)
 131       set( OSG_MSVC ${OSG_MSVC}110 )
 132   elseif (${MSVC_VERSION} EQUAL 1600)
 133       set( OSG_MSVC ${OSG_MSVC}100 )
 134   else (${MSVC_VERSION} EQUAL 1700)
 135       set( OSG_MSVC ${OSG_MSVC}90 )
 136   endif (${MSVC_VERSION} EQUAL 1700)
 137   if (CMAKE_CL_64)
 138       set( OSG_MSVC ${OSG_MSVC}-64 )
 139       set( MSVC_3RDPARTY_DIR 3rdParty.x64 )
 140   else (CMAKE_CL_64)
 141       set( MSVC_3RDPARTY_DIR 3rdParty )
 142   endif (CMAKE_CL_64)
 143
 144   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/lib )
 145   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/include)
 146   find_path(BOOST_ROOT boost/version.hpp
 147                         ${MSVC_3RDPARTY_ROOT}/boost
 148                         ${MSVC_3RDPARTY_ROOT}/boost_1_52_0
 149                         ${MSVC_3RDPARTY_ROOT}/boost_1_51_0
 150                         ${MSVC_3RDPARTY_ROOT}/boost_1_50_0
 151                         ${MSVC_3RDPARTY_ROOT}/boost_1_49_0
 152                         ${MSVC_3RDPARTY_ROOT}/boost_1_48_0
 153                         ${MSVC_3RDPARTY_ROOT}/boost_1_47_0
 154                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_1
 155                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_0
 156                         ${MSVC_3RDPARTY_ROOT}/boost_1_45_0
 157                         ${MSVC_3RDPARTY_ROOT}/boost_1_44_0
 158                         )
 159   # set (BOOST_ROOT ${MSVC_3RDPARTY_ROOT}/boost_1_44_0)
 160   message(STATUS "BOOST_ROOT is ${BOOST_ROOT}")
 161   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 162   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib)
 163 endif (MSVC AND MSVC_3RDPARTY_ROOT)
 164
 165 if(APPLE)
 166   find_library(COCOA_LIBRARY Cocoa)
 167
 168   # force libstdc++, not libc++
 169   set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LIBRARY "libstdc++")
 170   list(APPEND CMAKE_CXX_FLAGS "-stdlib=libstdc++")
 171   list(APPEND CMAKE_EXE_LINKER_FLAGS "-stdlib=libstdc++")
 172   list(APPEND CMAKE_SHARED_LINKER_FLAGS "-stdlib=libstdc++")
 173 endif()
 174
 175 # Somehow this only works if included before searching for Boost...
 176 include(BoostTestTargets)
 177
 178 find_package(Boost REQUIRED)
 179 set (BOOST_CXX_FLAGS "-DBOOST_MULTI_INDEX_DISABLE_SERIALIZATION -DBOOST_BIMAP_DISABLE_SERIALIZATION")
 180
 181 if(SIMGEAR_HEADLESS)
 182     message(STATUS "SimGear mode: HEADLESS")
 183     set(ENABLE_SOUND 0)
 184 else()
 185     message(STATUS "SimGear mode: NORMAL")
 186     find_package(OpenGL REQUIRED)
 187
 188     if (ENABLE_SOUND)
 189         find_package(OpenAL REQUIRED)
 190         message(STATUS "Sound support: ENABLED")
 191     endif(ENABLE_SOUND)
 192
 193     find_package(OpenSceneGraph 3.2.0 REQUIRED osgText osgSim osgDB osgParticle osgGA osgViewer osgUtil)
 194 endif(SIMGEAR_HEADLESS)
 195
 196 find_package(ZLIB REQUIRED)
 197 find_package(Threads REQUIRED)
 198
 199 if (SYSTEM_EXPAT)
 200     message(STATUS "Requested to use system Expat library, forcing SIMGEAR_SHARED to true")
 201     set(SIMGEAR_SHARED ON)
 202     find_package(EXPAT REQUIRED)
 203
 204 else()
 205     message(STATUS "Using built-in expat code")
 206     # XML_STATIC is important to avoid sg_expat_external.h
 207     # declaring symbols as declspec(import)
 208     add_definitions(-DHAVE_EXPAT_CONFIG_H -DXML_STATIC)
 209     set(EXPAT_INCLUDE_DIRS
 210             ${PROJECT_SOURCE_DIR}/3rdparty/expat
 211             ${PROJECT_BINARY_DIR}/3rdparty/expat)
 212 endif(SYSTEM_EXPAT)
 213
 214 include_directories(${EXPAT_INCLUDE_DIRS})
 215
 216 check_include_file(inttypes.h HAVE_INTTYPES_H)
 217 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 218 check_include_file(sys/timeb.h HAVE_SYS_TIMEB_H)
 219 check_include_file(unistd.h HAVE_UNISTD_H)
 220 check_include_file(windows.h HAVE_WINDOWS_H)
 221
 222 if(HAVE_INTTYPES_H)
 223   # ShivaVG needs inttypes.h
 224   add_definitions(-DHAVE_INTTYPES_H)
 225 endif()
 226
 227 if(ENABLE_RTI)
 228     # See if we have any rti library variant installed
 229     message(STATUS "RTI: ENABLED")
 230     find_package(RTI)
 231 else()
 232     message(STATUS "RTI: DISABLED")
 233 endif(ENABLE_RTI)
 234
 235 check_function_exists(gettimeofday HAVE_GETTIMEOFDAY)
 236 check_function_exists(ftime HAVE_FTIME)
 237 check_function_exists(timegm HAVE_TIMEGM)
 238 check_function_exists(rint HAVE_RINT)
 239 check_function_exists(mkdtemp HAVE_MKDTEMP)
 240 check_function_exists(bcopy HAVE_BCOPY)
 241 check_function_exists(mmap HAVE_MMAP)
 242
 243 if(HAVE_UNISTD_H)
 244     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 245     check_cxx_source_compiles(
 246        "#include <unistd.h>
 247         #if !defined(_POSIX_TIMERS) || (0 >= _POSIX_TIMERS)
 248             #error clock_gettime is not supported
 249         #endif
 250
 251         int main() { return 0; }
 252         "
 253         HAVE_CLOCK_GETTIME)
 254 endif(HAVE_UNISTD_H)
 255
 256 set(RT_LIBRARY "")
 257 if(HAVE_CLOCK_GETTIME)
 258     check_library_exists(rt clock_gettime "" HAVE_RT)
 259     if(HAVE_RT)
 260         set(RT_LIBRARY rt)
 261     endif(HAVE_RT)
 262 endif(HAVE_CLOCK_GETTIME)
 263
 264 set(DL_LIBRARY "")
 265 check_cxx_source_compiles(
 266     "#include <dlfcn.h>
 267     int main(void) {
 268         return 0;
 269     }
 270     "
 271     HAVE_DLFCN_H)
 272
 273 if(HAVE_DLFCN_H)
 274     check_library_exists(dl dlerror "" HAVE_DL)
 275     if(HAVE_DL)
 276         set(DL_LIBRARY "dl")
 277     endif()
 278 endif()
 279
 280 SET(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "add a postfix, usually 'd' on windows")
 281 SET(CMAKE_RELEASE_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 282 SET(CMAKE_RELWITHDEBINFO_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 283 SET(CMAKE_MINSIZEREL_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 284
 285 # isnan might not be real symbol, so can't check using function_exists
 286 check_cxx_source_compiles(
 287     "#include <cmath>
 288     int main() { return isnan(0.0);} "
 289     HAVE_ISNAN)
 290
 291 check_cxx_source_compiles(
 292     "#include <cmath>
 293     int main() { return std::isnan(0.0);} "
 294     HAVE_STD_ISNAN)
 295
 296 if(CMAKE_COMPILER_IS_GNUCXX)
 297     set(WARNING_FLAGS_CXX "-Wall")
 298     set(WARNING_FLAGS_C   "-Wall")
 299
 300     # certain GCC versions don't provide the atomic builds, and hence
 301     # require is to provide them in SGAtomic.cxx
 302     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 303     check_cxx_source_compiles(
 304        "int main() { unsigned mValue; return __sync_add_and_fetch(&mValue, 1); }"
 305         GCC_ATOMIC_BUILTINS_FOUND)
 306 endif(CMAKE_COMPILER_IS_GNUCXX)
 307
 308 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 309    set(WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual")
 310    set(WARNING_FLAGS_C   "-Wall")
 311 endif()
 312
 313 if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 314 # boost goes haywire wrt static asserts
 315     check_cxx_compiler_flag(-Wno-unused-local-typedefs HAS_NOWARN_UNUSED_TYPEDEFS)
 316     if(HAS_NOWARN_UNUSED_TYPEDEFS)
 317         set(WARNING_FLAGS_CXX " ${WARNING_FLAGS_CXX} -Wno-unused-local-typedefs")
 318     endif()
 319 endif()
 320
 321 if(WIN32)
 322
 323     if(MINGW)
 324         add_definitions(-D_WIN32_WINNT=0x501)
 325     endif()
 326
 327     if(MSVC)
 328         # turn off various warnings
 329         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 330         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 331         # endforeach(warning)
 332
 333         set(MSVC_FLAGS "-DWIN32 -DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS /wd4996 /wd4250 -Dstrdup=_strdup")
 334         if (${MSVC_VERSION} GREATER 1599)
 335             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 336         endif (${MSVC_VERSION} GREATER 1599)
 337     endif(MSVC)
 338
 339     # assumed on Windows
 340     set(HAVE_GETLOCALTIME 1)
 341
 342     set( WINSOCK_LIBRARY "ws2_32.lib" )
 343     set( RT_LIBRARY "winmm" )
 344 endif(WIN32)
 345
 346 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS}")
 347 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} ${BOOST_CXX_FLAGS}")
 348 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 349
 350 # use BEFORE to ensure local directories are used first,
 351 # ahead of system-installed libs
 352 include_directories(BEFORE ${PROJECT_SOURCE_DIR})
 353 include_directories(BEFORE ${PROJECT_SOURCE_DIR}/simgear/canvas/ShivaVG/include)
 354 include_directories(BEFORE ${PROJECT_BINARY_DIR}/simgear)
 355
 356 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 357     ${Boost_INCLUDE_DIRS}
 358     ${ZLIB_INCLUDE_DIR}
 359     ${OPENAL_INCLUDE_DIR}
 360 )
 361
 362 add_definitions(-DHAVE_CONFIG_H)
 363
 364 # configure a header file to pass some of the CMake settings
 365 # to the source code
 366 configure_file (
 367   "${PROJECT_SOURCE_DIR}/simgear/simgear_config_cmake.h.in"
 368   "${PROJECT_BINARY_DIR}/simgear/simgear_config.h"
 369   )
 370
 371 if(ENABLE_TESTS)
 372     # enable CTest / make test target
 373     message(STATUS "Tests: ENABLED")
 374
 375     include (Dart)
 376     enable_testing()
 377 else()
 378     message(STATUS "Tests: DISABLED")
 379 endif(ENABLE_TESTS)
 380
 381 # always set TEST_LIBS as it is also used by other tools/applications
 382 set(TEST_LIBS_INTERNAL_CORE
 383     ${CMAKE_THREAD_LIBS_INIT}
 384     ${ZLIB_LIBRARY}
 385     ${WINSOCK_LIBRARY}
 386     ${RT_LIBRARY}
 387     ${DL_LIBRARY}
 388     ${COCOA_LIBRARY})
 389 set(TEST_LIBS SimGearCore ${TEST_LIBS_INTERNAL_CORE})
 390
 391 if(NOT SIMGEAR_HEADLESS)
 392     set(TEST_LIBS SimGearScene ${OPENGL_LIBRARIES} ${TEST_LIBS})
 393 endif()
 394
 395 install (FILES ${PROJECT_BINARY_DIR}/simgear/simgear_config.h  DESTINATION include/simgear/)
 396
 397 include_directories(3rdparty/utf8/source)
 398
 399 add_subdirectory(3rdparty)
 400 add_subdirectory(simgear)
 401
 402 #-----------------------------------------------------------------------------
 403 ### uninstall target
 404 #-----------------------------------------------------------------------------
 405 CONFIGURE_FILE(
 406   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 407   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 408   IMMEDIATE @ONLY)
 409 ADD_CUSTOM_TARGET(uninstall
 410   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
 411
 412