CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7
   8 project(FlightGear)
   9
  10 # We have some custom .cmake scripts not in the official distribution.
  11 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  12
  13 if(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  14     # use official include provided by latest CMake
  15     include(GNUInstallDirs)
  16 else(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  17     # backward compatibility: use our own module for older cmake versions
  18     include(OldGNUInstallDirs)
  19 endif(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  20
  21 # Warning when build is not an out-of-source build.
  22 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  23 if(InSourceBuild)
  24     message(WARNING  "Avoid building inside the source tree!")
  25     message(WARNING  "Create a separate build directory instead (i.e. 'fgbuild') and call CMake from there: ")
  26     message(WARNING  "  mkdir ../fgbuild && cd ../fgbuild && cmake ${CMAKE_SOURCE_DIR}")
  27 endif(InSourceBuild)
  28
  29 # System detection/default settings
  30 include( DetectDistro )
  31 include( DetectBrowser )
  32
  33 set(CMAKE_DEBUG_POSTFIX          "d" CACHE STRING "add a postfix, usually d on windows")
  34 set(CMAKE_RELEASE_POSTFIX        ""  CACHE STRING "add a postfix, usually empty on windows")
  35 set(CMAKE_RELWITHDEBINFO_POSTFIX ""  CACHE STRING "add a postfix, usually empty on windows")
  36 set(CMAKE_MINSIZEREL_POSTFIX     ""  CACHE STRING "add a postfix, usually empty on windows")
  37
  38 # read 'version' file into a variable (stripping any newlines or spaces)
  39 file(READ version versionFile)
  40 if (NOT versionFile)
  41     message(FATAL_ERROR "Unable to determine FlightGear version. Version file is missing.")
  42 endif()
  43 string(STRIP "${versionFile}" FLIGHTGEAR_VERSION)
  44
  45 # FlightGear packaging (to build a source tarball)
  46 include( ConfigureCPack )
  47
  48 # FlightGear base package path
  49 if (FG_DATA_DIR)
  50     message(STATUS "Using explicit data directory for base package: ${FG_DATA_DIR}")
  51 else()
  52     set(FG_DATA_DIR "${CMAKE_INSTALL_PREFIX}/lib/FlightGear" CACHE PATH "Default location where data files are located")
  53     message(STATUS "Using default data directory for base package:  ${FG_DATA_DIR}")
  54 endif()
  55
  56 # Change the default build type to something fast
  57 if(NOT CMAKE_BUILD_TYPE)
  58     set(CMAKE_BUILD_TYPE Release CACHE STRING
  59         "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  60         FORCE)
  61 endif(NOT CMAKE_BUILD_TYPE)
  62
  63 if(NOT "$ENV{BUILD_ID}" STREQUAL "")
  64     set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  65     set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  66     message(STATUS "running under Hudson/Jenkins, build-number is ${HUDSON_BUILD_NUMBER}")
  67 else()
  68     set(HUDSON_BUILD_NUMBER 0)
  69     set(HUDSON_BUILD_ID "none")
  70 endif()
  71
  72 #####################################################################################
  73 # Configure library search paths
  74 #####################################################################################
  75
  76 if(APPLE)
  77     # Custom library directories for Mac, which should have precedence over any other
  78     list(APPEND ADDITIONAL_LIBRARY_PATHS
  79          ~/Library/Frameworks
  80          /Library/Frameworks)
  81 endif(APPLE)
  82
  83 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  84     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  85     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  86     # add paths manually
  87     # see http://www.cmake.org/Bug/view.php?id=12049 and
  88     # http://www.cmake.org/Bug/view.php?id=12037
  89     list(APPEND ADDITIONAL_LIBRARY_PATHS
  90          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  91          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  92          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
  93     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
  94 endif()
  95
  96 if(NOT MSVC)
  97     # TBD: are these really necessary? Aren't they considered by cmake automatically?
  98     list(APPEND ADDITIONAL_LIBRARY_PATHS
  99          /opt/local
 100          /usr/local
 101          /usr)
 102 endif()
 103 #####################################################################################
 104
 105 IF(APPLE)
 106     set(EVENT_INPUT_DEFAULT 1)
 107
 108     find_library(CORESERVICES_LIBRARY CoreServices)
 109     find_library(COCOA_LIBRARY Cocoa)
 110     list(APPEND PLATFORM_LIBS ${COCOA_LIBRARY} ${CORESERVICES_LIBRARY})
 111
 112 elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 113     find_package(UDev)
 114
 115     if(UDEV_FOUND)
 116         set(EVENT_INPUT_DEFAULT 1)
 117     endif(UDEV_FOUND)
 118 endif()
 119
 120 find_package(Git)
 121 if (GIT_FOUND)
 122     execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
 123         OUTPUT_VARIABLE REVISION
 124         OUTPUT_STRIP_TRAILING_WHITESPACE)
 125     message(STATUS "Git revision is ${REVISION}")
 126 else()
 127     set(REVISION "none")
 128 endif()
 129
 130 # FlightGear build options
 131 option(SIMGEAR_SHARED    "Set to ON when SimGear was built as a shared library" OFF)
 132 option(LOGGING           "Set to ON to build FlightGear with logging support (default)" ON)
 133 option(SP_FDMS           "Set to ON to build FlightGear with special-purpose FDMs" OFF)
 134 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" OFF)
 135 option(ENABLE_LARCSIM    "Set to ON to build FlightGear with LaRCsim FDM" OFF)
 136 option(ENABLE_YASIM      "Set to ON to build FlightGear with YASIM FDM (default)" ON)
 137 option(ENABLE_JSBSIM     "Set to ON to build FlightGear with JSBSim FDM (default)" ON)
 138 option(EVENT_INPUT       "Set to ON to build FlightGear with event-based Input support" ${EVENT_INPUT_DEFAULT})
 139 option(ENABLE_LIBSVN     "Set to ON to build FlightGear/terrasync with libsvnclient support (default)" ON)
 140 option(ENABLE_RTI        "Set to ON to build FlightGear with RTI support" OFF)
 141 option(ENABLE_PROFILE    "Set to ON to build FlightGear with gperftools profiling support" OFF)
 142 option(JPEG_FACTORY      "Set to ON to build FlightGear with JPEG-factory support" OFF)
 143 option(SYSTEM_SQLITE     "Set to ON to build FlightGear with the system's SQLite3 library" OFF)
 144
 145 # additional utilities
 146 option(ENABLE_FGADMIN    "Set to ON to build the FGADMIN application (default)" ON)
 147 option(WITH_FGPANEL      "Set to ON to build the fgpanel application (default)" ON)
 148 option(ENABLE_TESTS      "Set to ON to build test applications (default)" ON)
 149
 150 if(LOGGING)
 151     # nothing
 152 else()
 153     set(FG_NDEBUG 1)
 154 endif()
 155
 156 if(SP_FDMS)
 157     set(ENABLE_SP_FDM 1)
 158 endif()
 159
 160 # Setup MSVC 3rd party directories
 161 include( ConfigureMsvc3rdParty )
 162
 163 if(EVENT_INPUT)
 164     if(APPLE)
 165     elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 166         if(NOT UDEV_FOUND)
 167             message(WARNING "UDev not found, event input is disabled!")
 168             set(EVENT_INPUT 0)
 169         else()
 170             add_definitions(-DWITH_EVENTINPUT)
 171             set(EVENT_INPUT_LIBRARIES ${UDEV_LIBRARIES})
 172             message(STATUS "event-based input enabled. Using ${UDEV_LIBRARIES}")
 173         endif()
 174     else()
 175         message(WARNING "event-based input is not supported on this platform yet")
 176     endif()
 177
 178     # Keep PLIB INPUT enabled as long as EventInput does not replace current joystick configurations.
 179     set(ENABLE_PLIB_JOYSTICK 1)
 180 else(EVENT_INPUT)
 181     set(ENABLE_PLIB_JOYSTICK 1)
 182 endif(EVENT_INPUT)
 183
 184 # check required dependencies
 185 find_package(Boost   REQUIRED)
 186 find_package(ZLIB    REQUIRED)
 187 find_package(Threads REQUIRED)
 188 find_package(OpenGL  REQUIRED)
 189 find_package(OpenAL  REQUIRED)
 190 find_package(OpenSceneGraph 3.0.0 REQUIRED osgText osgSim osgDB osgParticle osgFX osgUtil osgViewer osgGA)
 191
 192 if(ENABLE_FGADMIN)
 193     find_package(FLTK)
 194
 195     if ( FLTK_FOUND )
 196         if ( X11_Xinerama_FOUND )
 197             message(STATUS "Found X11_Xinerama...")
 198             list(APPEND FLTK_LIBRARIES ${X11_Xinerama_LIB})
 199         endif()
 200
 201         if ( X11_Xft_FOUND )
 202             message(STATUS "Found X11_Xft...")
 203             list(APPEND FLTK_LIBRARIES ${X11_Xft_LIB})
 204         endif()
 205
 206         message(STATUS "Using FLTK_LIBRARIES for fgadmin: ${FLTK_LIBRARIES}")
 207     endif ( FLTK_FOUND )
 208 endif(ENABLE_FGADMIN)
 209
 210 if(ENABLE_LIBSVN)
 211     find_package(SvnClient)
 212
 213     if(LIBSVN_FOUND)
 214         message(STATUS "libsvn found, enabling in terrasync")
 215         set(HAVE_SVN_CLIENT_H 1)
 216         set(HAVE_LIBSVN_CLIENT_1 1)
 217     else()
 218         message(STATUS "libsvn missing. Disabling...")
 219     endif(LIBSVN_FOUND)
 220 endif(ENABLE_LIBSVN)
 221
 222 if (SYSTEM_SQLITE)
 223     find_package(SQLite3 REQUIRED)
 224     set(CMAKE_REQUIRED_INCLUDES ${SQLITE3_INCLUDED_DIR})
 225     message(STATUS "Using system SQLite3 library")
 226 endif (SYSTEM_SQLITE)
 227
 228 # Sqlite always depends on the threading lib
 229 list(APPEND SQLITE3_LIBRARY ${CMAKE_THREAD_LIBS_INIT})
 230
 231 find_package(PLIB REQUIRED puaux pu js fnt)
 232
 233 if (EMBEDDED_SIMGEAR)
 234     message(STATUS "Using embedded SimGear")
 235     # create the same variables that FindSimGear would define
 236     set(SIMGEAR_INCLUDE_DIR ${PROJECT_SOURCE_DIR}/simgear)
 237     set(SIMGEAR_CORE_LIBRARIES SimGearCore)
 238     set(SIMGEAR_LIBRARIES SimGearScene)
 239
 240     if (NOT SIMGEAR_SHARED)
 241         set(SIMGEAR_CORE_LIBRARY_DEPENDENCIES
 242             ${CMAKE_THREAD_LIBS_INIT}
 243             ${ZLIB_LIBRARY}
 244             ${LIBSVN_LIBRARIES}
 245             ${WINMM_LIBRARY})
 246
 247         set(SIMGEAR_SCENE_LIBRARY_DEPENDENCIES
 248             ${OPENAL_LIBRARY})
 249     endif()
 250 else(EMBEDDED_SIMGEAR)
 251     # FlightGear and SimGear versions need to match
 252     find_package(SimGear ${FLIGHTGEAR_VERSION} REQUIRED)
 253 endif (EMBEDDED_SIMGEAR)
 254
 255 if (JPEG_FACTORY)
 256     # check simgear was built with JPEG-factory support
 257     find_package(JPEG REQUIRED)
 258     include_directories(${JPEG_INCLUDE_DIR})
 259
 260     set(CMAKE_REQUIRED_INCLUDES
 261         ${SIMGEAR_INCLUDE_DIR}
 262         ${JPEG_INCLUDE_DIR}
 263         ${OPENSCENEGRAPH_INCLUDE_DIRS})
 264
 265     check_cxx_source_compiles(
 266         "#include <simgear/screen/jpgfactory.hxx>
 267         int main()    { return 0; } "
 268         FG_JPEG_SERVER)
 269
 270     if (NOT FG_JPEG_SERVER)
 271         message(STATUS "JPEG server support requested, but SimGear was built without JPEG support")
 272     endif()
 273 endif()
 274
 275 check_include_file(unistd.h   HAVE_UNISTD_H)
 276 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 277 check_include_file(windows.h  HAVE_WINDOWS_H)
 278
 279 if(ENABLE_PROFILE)
 280     find_package(GooglePerfTools REQUIRED)
 281     set(FG_HAVE_GPERFTOOLS 1)
 282     message(STATUS "Built-in profiler using gperftools available")
 283 endif()
 284
 285 if(ENABLE_RTI)
 286     find_package(RTI)
 287     if(RTI_FOUND)
 288         set(FG_HAVE_HLA 1)
 289     endif(RTI_FOUND)
 290 endif(ENABLE_RTI)
 291
 292 if(CMAKE_COMPILER_IS_GNUCXX)
 293     set(WARNING_FLAGS_CXX "-Wall")
 294     set(WARNING_FLAGS_C   "-Wall")
 295 endif(CMAKE_COMPILER_IS_GNUCXX)
 296
 297 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 298    set (WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual")
 299    set (WARNING_FLAGS_C   "-Wall")
 300 endif()
 301
 302 if(WIN32)
 303
 304     if(MSVC)
 305         # turn off various warnings
 306         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 307         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 308         # endforeach(warning)
 309
 310         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS")
 311         if (${MSVC_VERSION} GREATER 1599)
 312             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 313         endif (${MSVC_VERSION} GREATER 1599)
 314     endif(MSVC)
 315
 316     set(NOMINMAX 1)
 317 endif(WIN32)
 318
 319 set (BOOST_CXX_FLAGS "-DBOOST_MULTI_INDEX_DISABLE_SERIALIZATION -DBOOST_BIMAP_DISABLE_SERIALIZATION")
 320
 321 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS} -D_REENTRANT")
 322 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} -D_REENTRANT ${BOOST_CXX_FLAGS}")
 323 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 324
 325 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 326     ${Boost_INCLUDE_DIRS}
 327     ${ZLIB_INCLUDE_DIR}
 328     ${OPENGL_INCLUDE_DIR}
 329     ${OPENAL_INCLUDE_DIR}
 330     ${SIMGEAR_INCLUDE_DIR}
 331     ${PLIB_INCLUDE_DIR} )
 332
 333 include_directories(${PROJECT_SOURCE_DIR}/src)
 334
 335 # following is needed, because config.h is include 'bare', whereas
 336 # version.h is included as <Include/version.h> - this should be cleaned up
 337 include_directories(${PROJECT_BINARY_DIR}/src)
 338 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 339
 340 add_definitions(-DHAVE_CONFIG_H)
 341
 342 check_function_exists(mkfifo HAVE_MKFIFO)
 343
 344 # configure a header file to pass some of the CMake settings
 345 # to the source code
 346 configure_file (
 347     "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 348     "${PROJECT_BINARY_DIR}/src/Include/config.h"
 349 )
 350
 351 #and the same for the version header
 352 configure_file (
 353     "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 354     "${PROJECT_BINARY_DIR}/src/Include/version.h"
 355 )
 356
 357 if (EMBEDDED_SIMGEAR)
 358     add_subdirectory(simgear)
 359     # since we build without SimGear installed, we need to
 360     # search this path directly to find the generated
 361     # simgear_config.h
 362     include_directories(${PROJECT_BINARY_DIR}/simgear)
 363 endif(EMBEDDED_SIMGEAR)
 364
 365 add_subdirectory(src)
 366 add_subdirectory(utils)
 367 add_subdirectory(man)
 368
 369 #-----------------------------------------------------------------------------
 370 ### uninstall target
 371 #-----------------------------------------------------------------------------
 372 CONFIGURE_FILE(
 373     "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 374     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 375     IMMEDIATE @ONLY)
 376 ADD_CUSTOM_TARGET(uninstall
 377     "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")