CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7
   8
   9 project(FlightGear)
  10
  11 set(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "add a postfix, usually d on windows")
  12 set(CMAKE_RELEASE_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
  13 set(CMAKE_RELWITHDEBINFO_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
  14 set(CMAKE_MINSIZEREL_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
  15
  16 # read 'version' file into a variable (stripping any newlines or spaces)
  17 file(READ version versionFile)
  18 string(STRIP ${versionFile} FLIGHTGEAR_VERSION)
  19
  20 #packaging
  21
  22 # split version string into components, note CMAKE_MATCH_0 is the entire regexp match
  23 string(REGEX MATCH "([0-9]+)\\.([0-9]+)\\.([0-9]+)" CPACK_PACKAGE_VERSION ${FLIGHTGEAR_VERSION} )
  24 set(CPACK_PACKAGE_VERSION_MAJOR ${CMAKE_MATCH_1})
  25 set(CPACK_PACKAGE_VERSION_MINOR ${CMAKE_MATCH_2})
  26 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_3})
  27 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  28 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  29
  30 set(CPACK_SOURCE_GENERATOR TBZ2 ZIP)
  31 set(CPACK_SOURCE_PACKAGE_FILE_NAME "flightgear-${FLIGHTGEAR_VERSION}" CACHE INTERNAL "tarball basename")
  32 set(CPACK_SOURCE_IGNORE_FILES
  33   "^${PROJECT_SOURCE_DIR}/.git;\\\\.gitignore;Makefile.am;~$;${CPACK_SOURCE_IGNORE_FILES}")
  34
  35 include (CPack)
  36
  37 # We have some custom .cmake scripts not in the official distribution.
  38 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  39
  40 if (FG_DATA_DIR)
  41     message(STATUS "Using explicit data-dir: ${FG_DATA_DIR}")
  42 else()
  43     set(FG_DATA_DIR "${CMAKE_INSTALL_PREFIX}/lib/FlightGear")
  44     message(STATUS "Using default data-dir:  ${FG_DATA_DIR}")
  45 endif()
  46
  47 # Change the default build type to something fast
  48 if(NOT CMAKE_BUILD_TYPE)
  49   set(CMAKE_BUILD_TYPE Release CACHE STRING
  50       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  51       FORCE)
  52 endif(NOT CMAKE_BUILD_TYPE)
  53
  54 if($ENV{BUILD_ID})
  55         set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  56         set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  57         message(STATUS "running under Hudson, build-number is ${HUDSON_BUILD_NUMBER}")
  58 else()
  59         set(HUDSON_BUILD_NUMBER 0)
  60         set(HUDSON_BUILD_ID "none")
  61 endif()
  62
  63 IF(APPLE)
  64     set(EVENT_INPUT_DEFAULT 1)
  65
  66     find_library(CORESERVICES_LIBRARY CoreServices)
  67     list(APPEND PLATFORM_LIBS ${CORESERVICES_LIBRARY})
  68
  69 elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
  70     # disabled while DBus / HAL / udev issues are decided
  71     #set(EVENT_INPUT_DEFAULT 1)
  72 endif()
  73
  74 find_package(Git)
  75 if (GIT_FOUND)
  76         execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
  77                 OUTPUT_VARIABLE REVISION
  78                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  79         message(STATUS "Git revision is ${REVISION}")
  80 else()
  81         set(REVISION "none")
  82 endif()
  83
  84 option(LOGGING "Set to OFF to build FlightGear without logging" ON)
  85
  86 option(SP_FDMS "Set to ON to build FlightGear with special-purpose FDMs" OFF)
  87 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" OFF)
  88 option(ENABLE_LARCSIM "Set to ON to build FlightGear with LaRCsim FDM" OFF)
  89 option(ENABLE_YASIM "Set to ON to build FlightGear with YASIM FDM" ON)
  90 option(ENABLE_JSBSIM "Set to ON to build FlightGear with JSBSim FDM" ON)
  91 option(ENABLE_FGADMIN "Set to ON to build FlightGear with FGADMIN" ON)
  92 option(EVENT_INPUT "Set to ON to build FlightGear with event-based Input support" ${EVENT_INPUT_DEFAULT})
  93 option(ENABLE_LIBSVN "Set to ON to build FlightGear/terrasync with libsvnclient support" ON)
  94 option(ENABLE_RTI "Set to ON to build SimGear with RTI support" OFF)
  95 option(WITH_FGPANEL "Set to ON to build the fgpanel application" ON)
  96
  97
  98 if (MSVC)
  99   GET_FILENAME_COMPONENT(PARENT_DIR ${PROJECT_SOURCE_DIR} PATH)
 100   if (CMAKE_CL_64)
 101     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty.x64")
 102   else (CMAKE_CL_64)
 103     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty")
 104   endif (CMAKE_CL_64)
 105   if (EXISTS ${TEST_3RDPARTY_DIR})
 106     set(MSVC_3RDPARTY_ROOT ${PARENT_DIR} CACHE PATH "Location where the third-party dependencies are extracted")
 107   else (EXISTS ${TEST_3RDPARTY_DIR})
 108     set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 109   endif (EXISTS ${TEST_3RDPARTY_DIR})
 110   list(APPEND PLATFORM_LIBS "winmm.lib")
 111 else (MSVC)
 112   set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 113 endif (MSVC)
 114
 115 if(LOGGING)
 116         # nothing
 117 else()
 118         set(FG_NDEBUG 1)
 119 endif()
 120
 121 if(SP_FDMS)
 122         set(ENABLE_SP_FDM 1)
 123 endif()
 124
 125 if (MSVC AND MSVC_3RDPARTY_ROOT)
 126   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_ROOT}")
 127   set( OSG_MSVC "msvc" )
 128   if (${MSVC_VERSION} EQUAL 1600)
 129       set( OSG_MSVC ${OSG_MSVC}100 )
 130   else (${MSVC_VERSION} EQUAL 1600)
 131       set( OSG_MSVC ${OSG_MSVC}90 )
 132   endif (${MSVC_VERSION} EQUAL 1600)
 133   if (CMAKE_CL_64)
 134       set( OSG_MSVC ${OSG_MSVC}-64 )
 135           set( MSVC_3RDPARTY_DIR 3rdParty.x64 )
 136   else (CMAKE_CL_64)
 137           set( MSVC_3RDPARTY_DIR 3rdParty )
 138   endif (CMAKE_CL_64)
 139
 140   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/SimGear/lib )
 141   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/SimGear/include)
 142   set (BOOST_ROOT ${MSVC_3RDPARTY_ROOT}/boost_1_44_0)
 143   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 144   set (ALUT_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 145   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib)
 146 endif (MSVC AND MSVC_3RDPARTY_ROOT)
 147
 148 if(EVENT_INPUT)
 149         message(STATUS "checking event-based Input")
 150
 151         IF(APPLE)
 152
 153         elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 154         find_package(DBus)
 155         if(NOT DBUS_FOUND)
 156             message(WARNING "DBus not found, event input will be disabled")
 157             set(EVENT_INPUT 0)
 158         endif()
 159
 160         else()
 161                 message(WARNING "event input is not supported on this platform yet")
 162         endif()
 163 else(EVENT_INPUT)
 164         set(ENABLE_PLIB_JOYSTICK 1)
 165 endif(EVENT_INPUT)
 166
 167 # check required dependencies
 168 find_package(Boost REQUIRED)
 169 find_package(ZLIB REQUIRED)
 170 find_package(Threads REQUIRED)
 171 find_package(OpenGL REQUIRED)
 172 find_package(OpenAL REQUIRED)
 173 find_package(ALUT REQUIRED)
 174 find_package(OpenSceneGraph 2.8.1 REQUIRED osgText osgSim osgDB osgParticle osgFX osgUtil osgViewer osgGA)
 175
 176 if(ENABLE_FGADMIN)
 177   find_package(FLTK)
 178 endif(ENABLE_FGADMIN)
 179
 180 if(ENABLE_LIBSVN)
 181         find_package(SvnClient)
 182
 183         if(LIBSVN_FOUND)
 184                 message(STATUS "libsvn found, enabling in terrasync")
 185                 set(HAVE_SVN_CLIENT_H 1)
 186                 set(HAVE_LIBSVN_CLIENT_1 1)
 187         endif(LIBSVN_FOUND)
 188 endif(ENABLE_LIBSVN)
 189
 190 find_package(PLIB REQUIRED puaux pu js fnt)
 191 find_package(SimGear 2.5.0 REQUIRED)
 192
 193 check_include_file(unistd.h HAVE_UNISTD_H)
 194 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 195 check_include_file(windows.h HAVE_WINDOWS_H)
 196
 197 # definition depends on OSG version
 198 set(CMAKE_REQUIRED_INCLUDES ${OPENSCENEGRAPH_INCLUDE_DIRS})
 199
 200 check_cxx_source_compiles(
 201     "#include <osg/CullSettings>
 202     int main()
 203     {
 204        osg::CullSettings::VariablesMask mask = osg::CullSettings::CLEAR_MASK;
 205        return 0;
 206     }
 207     "
 208     HAVE_CULLSETTINGS_CLEAR_MASK)
 209
 210 if(ENABLE_RTI)
 211     find_package(RTI)
 212     if(RTI_FOUND)
 213         set(FG_HAVE_HLA 1)
 214     endif(RTI_FOUND)
 215 endif(ENABLE_RTI)
 216
 217 if(CMAKE_COMPILER_IS_GNUCXX)
 218     set(WARNING_FLAGS -Wall)
 219 endif(CMAKE_COMPILER_IS_GNUCXX)
 220
 221 if(WIN32)
 222
 223     if(MSVC)
 224         # turn off various warnings
 225         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 226         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 227         # endforeach(warning)
 228
 229         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS")
 230         if (${MSVC_VERSION} EQUAL 1600)
 231                   set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 232         endif (${MSVC_VERSION} EQUAL 1600)
 233     endif(MSVC)
 234
 235     set(NOMINMAX 1)
 236 endif(WIN32)
 237
 238 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS} -D_REENTRANT")
 239 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS} -D_REENTRANT")
 240 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 241
 242 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 243         ${Boost_INCLUDE_DIRS}
 244         ${ZLIB_INCLUDE_DIR}
 245         ${ALUT_INCLUDE_DIR}
 246         ${OPENAL_INCLUDE_DIR}
 247         ${SIMGEAR_INCLUDE_DIR}
 248         ${PLIB_INCLUDE_DIR} )
 249
 250 include_directories(${PROJECT_SOURCE_DIR}/src)
 251
 252 # following is needed, because config.h is include 'bare', whereas
 253 # version.h is included as <Include/version.h> - this should be cleaned up
 254 include_directories(${PROJECT_BINARY_DIR}/src)
 255 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 256
 257 add_definitions(-DHAVE_CONFIG_H)
 258
 259 check_function_exists(mkfifo HAVE_MKFIFO)
 260
 261 # configure a header file to pass some of the CMake settings
 262 # to the source code
 263 configure_file (
 264   "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 265   "${PROJECT_BINARY_DIR}/src/Include/config.h"
 266   )
 267
 268 #and the same for the version header
 269 configure_file (
 270   "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 271   "${PROJECT_BINARY_DIR}/src/Include/version.h"
 272   )
 273
 274 add_subdirectory(src)
 275 add_subdirectory(utils)
 276
 277 set (INSTALL_DOCS
 278     README
 279         README.OpenAL
 280         README.plib
 281         README.OSG
 282         README.SimGear)
 283
 284 INSTALL(FILES ${INSTALL_DOCS} DESTINATION doc OPTIONAL)
 285
 286 #-----------------------------------------------------------------------------
 287 ### uninstall target
 288 #-----------------------------------------------------------------------------
 289 CONFIGURE_FILE(
 290   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 291   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 292   IMMEDIATE @ONLY)
 293 ADD_CUSTOM_TARGET(uninstall
 294   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
 295