CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8.11)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7
   8 if(COMMAND cmake_policy)
   9    if(POLICY CMP0054)
  10        cmake_policy(SET CMP0054 NEW)
  11    endif()
  12    # Mac RPATH policy
  13    if(POLICY CMP0042)
  14        cmake_policy(SET CMP0042 NEW)
  15    endif()
  16 endif()
  17
  18 if(APPLE)
  19         # using 10.7 because boost requires libc++ and 10.6 doesn't include it
  20         set(CMAKE_OSX_DEPLOYMENT_TARGET 10.7)
  21
  22         set(CMAKE_INSTALL_RPATH "@loader_path/../Frameworks")
  23         # when building, don't use the install RPATH already
  24         # (but later on when installing)
  25         SET(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
  26 endif()
  27
  28 project(FlightGear)
  29
  30 # We have some custom .cmake scripts not in the official distribution.
  31 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  32
  33 # Warning when build is not an out-of-source build.
  34 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  35 if(InSourceBuild)
  36     message(WARNING  "Avoid building inside the source tree!")
  37     message(WARNING  "Create a separate build directory instead (i.e. 'fgbuild') and call CMake from there: ")
  38     message(WARNING  "  mkdir ../fgbuild && cd ../fgbuild && cmake ${CMAKE_SOURCE_DIR}")
  39 endif(InSourceBuild)
  40
  41 include(GNUInstallDirs)
  42 # System detection/default settings
  43 include( DetectDistro )
  44 include( DetectBrowser )
  45
  46 set(CMAKE_DEBUG_POSTFIX          "d" CACHE STRING "add a postfix, usually d on windows")
  47 set(CMAKE_RELEASE_POSTFIX        ""  CACHE STRING "add a postfix, usually empty on windows")
  48 set(CMAKE_RELWITHDEBINFO_POSTFIX ""  CACHE STRING "add a postfix, usually empty on windows")
  49 set(CMAKE_MINSIZEREL_POSTFIX     ""  CACHE STRING "add a postfix, usually empty on windows")
  50
  51 # read 'version' file into a variable (stripping any newlines or spaces)
  52 file(READ version versionFile)
  53 if (NOT versionFile)
  54     message(FATAL_ERROR "Unable to determine FlightGear version. Version file is missing.")
  55 endif()
  56 string(STRIP "${versionFile}" FLIGHTGEAR_VERSION)
  57 # add a dependency on the versino file
  58 set_property(DIRECTORY APPEND PROPERTY CMAKE_CONFIGURE_DEPENDS version)
  59
  60 # FlightGear packaging (to build a source tarball)
  61 include( ConfigureCPack )
  62
  63 # FlightGear base package path
  64 if (FG_DATA_DIR)
  65     message(STATUS "Using explicit data directory for base package: ${FG_DATA_DIR}")
  66 else()
  67     set(FG_DATA_DIR "${CMAKE_INSTALL_PREFIX}/lib/FlightGear" CACHE PATH "Default location where data files are located")
  68     message(STATUS "Using default data directory for base package:  ${FG_DATA_DIR}")
  69 endif()
  70
  71 # Change the default build type to something fast
  72 if(NOT CMAKE_BUILD_TYPE)
  73     set(CMAKE_BUILD_TYPE Release CACHE STRING
  74         "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  75         FORCE)
  76 endif(NOT CMAKE_BUILD_TYPE)
  77
  78 if(NOT "$ENV{BUILD_ID}" STREQUAL "")
  79     set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  80     set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  81     message(STATUS "running under Hudson/Jenkins, build-number is ${HUDSON_BUILD_NUMBER}")
  82 else()
  83     set(HUDSON_BUILD_NUMBER 0)
  84     set(HUDSON_BUILD_ID "none")
  85 endif()
  86
  87 #####################################################################################
  88 # Configure library search paths
  89 #####################################################################################
  90
  91
  92 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  93     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  94     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  95     # add paths manually
  96     # see http://www.cmake.org/Bug/view.php?id=12049 and
  97     # http://www.cmake.org/Bug/view.php?id=12037
  98     list(APPEND ADDITIONAL_LIBRARY_PATHS
  99          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
 100          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
 101          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
 102     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
 103 endif()
 104
 105 #####################################################################################
 106
 107 IF(APPLE)
 108     set(EVENT_INPUT_DEFAULT 1)
 109
 110     find_library(CORESERVICES_LIBRARY CoreServices)
 111     find_library(COCOA_LIBRARY Cocoa)
 112     list(APPEND PLATFORM_LIBS ${COCOA_LIBRARY} ${CORESERVICES_LIBRARY})
 113
 114     # using 10.7 because boost requires libc++ and 10.6 doesn't include it
 115     SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.7")
 116 elseif(${CMAKE_SYSTEM_NAME} MATCHES "Linux" OR
 117         ${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD")
 118     find_package(Threads REQUIRED)
 119     find_package(X11 REQUIRED)
 120
 121     set(USE_DBUS_DEFAULT 1)
 122
 123     find_package(UDev)
 124     if(UDEV_FOUND)
 125         set(EVENT_INPUT_DEFAULT 1)
 126     endif(UDEV_FOUND)
 127
 128     find_package(Speex)
 129     find_package(Speexdsp)
 130     if(SPEEX_FOUND AND SPEEXDSP_FOUND)
 131         set(SYSTEM_SPEEX_DEFAULT 1)
 132     endif(SPEEX_FOUND AND SPEEXDSP_FOUND)
 133
 134     find_package(Gsm)
 135     if(GSM_FOUND)
 136         set(SYSTEM_GSM_DEFAULT 1)
 137     endif(GSM_FOUND)
 138
 139     find_package(Flite)
 140     if(FLITE_FOUND)
 141         set(SYSTEM_FLITE_DEFAULT 1)
 142     endif()
 143
 144     find_package(HtsEngine)
 145     if(HTS_ENGINE_FOUND)
 146         set(SYSTEM_HTS_ENGINE_DEFAULT 1)
 147     endif()
 148 endif()
 149
 150 find_package(Git)
 151 if (GIT_FOUND)
 152     execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
 153         OUTPUT_VARIABLE REVISION
 154         OUTPUT_STRIP_TRAILING_WHITESPACE)
 155     message(STATUS "Git revision is ${REVISION}")
 156 else()
 157     set(REVISION "none")
 158 endif()
 159
 160 # FlightGear build options
 161 option(SIMGEAR_SHARED    "Set to ON when SimGear was built as a shared library" OFF)
 162 option(LOGGING           "Set to ON to build FlightGear with logging support (default)" ON)
 163 option(JSBSIM_TERRAIN    "Set to ON to build FlightGear with JSBSim terrain handling code" ON)
 164 option(SP_FDMS           "Set to ON to build FlightGear with special-purpose FDMs" ON)
 165 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" ON)
 166 option(ENABLE_LARCSIM    "Set to ON to build FlightGear with LaRCsim FDM" ON)
 167 option(ENABLE_YASIM      "Set to ON to build FlightGear with YASIM FDM (default)" ON)
 168 option(ENABLE_JSBSIM     "Set to ON to build FlightGear with JSBSim FDM (default)" ON)
 169 option(EVENT_INPUT       "Set to ON to build FlightGear with event-based Input support" ${EVENT_INPUT_DEFAULT})
 170 option(ENABLE_RTI        "Set to ON to build FlightGear with RTI support" OFF)
 171 option(ENABLE_PROFILE    "Set to ON to build FlightGear with gperftools profiling support" OFF)
 172 option(SYSTEM_SQLITE     "Set to ON to build FlightGear with the system's SQLite3 library" OFF)
 173 option(ENABLE_IAX        "Set to ON to build FlightGear with IAXClient/fgcom built-in (default)" ON)
 174 option(USE_DBUS          "Set to ON to build FlightGear with DBus screensaver interaction (default on Linux)" ${USE_DBUS_DEFAULT})
 175 option(SYSTEM_SPEEX      "Set to ON to build IAXClient with the system's speex and speexdsp library" ${SYSTEM_SPEEX_DEFAULT})
 176 option(SYSTEM_GSM        "Set to ON to build IAXClient with the system's GSM library" ${SYSTEM_GSM_DEFAULT})
 177 option(SYSTEM_FLITE      "Set to ON to build Flightgear with the system's Flite library" ${SYSTEM_FLITE_DEFAULT})
 178 option(SYSTEM_HTS_ENGINE "Set to ON to build Flightgear with the system's HTS Engine library" ${SYSTEM_HTS_ENGINE_DEFAULT})
 179 option(FG_NIGHTLY        "Set to ON to mark this as a nightly build" OFF)
 180 option(ENABLE_DEV_WARNINGS "Set to ON to include developer-warnings" OFF)
 181
 182 # additional utilities
 183 option(ENABLE_FGELEV     "Set to ON to build the fgelev application (default)" ON)
 184 option(WITH_FGPANEL      "Set to ON to build the fgpanel application (default)" ON)
 185 option(ENABLE_FGVIEWER   "Set to ON to build the fgviewer application (default)" ON)
 186 option(ENABLE_GPSSMOOTH  "Set to ON to build the GPSsmooth application (default)" ON)
 187 option(ENABLE_TERRASYNC  "Set to ON to build the terrasync application (default)" ON)
 188 option(ENABLE_FGJS       "Set to ON to build the fgjs application (default)" ON)
 189 option(ENABLE_JS_DEMO    "Set to ON to build the js_demo application (default)" ON)
 190 option(ENABLE_METAR      "Set to ON to build the metar application (default)" ON)
 191 option(ENABLE_TESTS      "Set to ON to build test applications (default)" ON)
 192 option(ENABLE_FGCOM      "Set to ON to build the FGCom application (default)" ON)
 193 option(ENABLE_FLITE      "Set to ON to build the Flite text-to-speech module" ON)
 194 option(ENABLE_QT         "Set to ON to build the internal Qt launcher" ON)
 195
 196 if(LOGGING)
 197     # nothing
 198 else()
 199     set(FG_NDEBUG 1)
 200 endif()
 201
 202 if(JSBSIM_TERRAIN)
 203    set(JSBSIM_USE_GROUNDREACTIONS 1)
 204 endif()
 205
 206 if(SP_FDMS)
 207     set(ENABLE_SP_FDM 1)
 208 endif()
 209
 210 if(ENABLE_FGCOM)
 211   set(ENABLE_IAX 1)
 212   include_directories(${PROJECT_SOURCE_DIR}/3rdparty/iaxclient/lib ) # for iaxclient.h
 213 endif()
 214
 215 # Setup MSVC 3rd party directories
 216 include( ConfigureMsvc3rdParty )
 217
 218 if(EVENT_INPUT)
 219     if(APPLE)
 220     elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 221         if(NOT UDEV_FOUND)
 222             message(WARNING "UDev not found, event input is disabled!")
 223             set(EVENT_INPUT 0)
 224         else()
 225             add_definitions(-DWITH_EVENTINPUT)
 226             set(EVENT_INPUT_LIBRARIES ${UDEV_LIBRARIES})
 227             message(STATUS "event-based input enabled. Using ${UDEV_LIBRARIES}")
 228         endif()
 229     else()
 230         message(WARNING "event-based input is not supported on this platform yet")
 231     endif()
 232
 233     # Keep PLIB INPUT enabled as long as EventInput does not replace current joystick configurations.
 234     set(ENABLE_PLIB_JOYSTICK 1)
 235 else(EVENT_INPUT)
 236     set(ENABLE_PLIB_JOYSTICK 1)
 237 endif(EVENT_INPUT)
 238
 239 # check required dependencies
 240 find_package(Boost   REQUIRED)
 241 find_package(ZLIB    REQUIRED)
 242 find_package(OpenGL  REQUIRED)
 243 find_package(OpenAL  REQUIRED)
 244 find_package(OpenSceneGraph 3.2.0 REQUIRED
 245   osgText
 246   osgSim
 247   osgDB
 248   osgParticle
 249   osgFX
 250   osgUtil
 251   osgViewer
 252   osgGA
 253 )
 254
 255 if (MSVC)
 256         find_package(CrashRpt)
 257         if (CRASHRPT_FOUND)
 258                 set(HAVE_CRASHRPT 1)
 259                 message(STATUS "Using CrashRpt")
 260         include_directories( ${CRASHRPT_INCLUDE_DIR})
 261         endif()
 262 endif()
 263
 264 ##############################################################################
 265 ## Sqlite3 setup
 266
 267 if (SYSTEM_SQLITE)
 268     find_package(SQLite3 REQUIRED)
 269
 270     message(STATUS "Using system SQLite3 library")
 271 else()
 272     set(SQLITE3_INCLUDED_DIR "${CMAKE_SOURCE_DIR}/3rdparty/sqlite3")
 273     # this target is defined in src/Navaids/CMakeLists.txt
 274     list(APPEND SQLITE3_LIBRARY fgsqlite3)
 275 endif (SYSTEM_SQLITE)
 276
 277 # Sqlite always depends on the threading lib
 278 list(APPEND SQLITE3_LIBRARY ${CMAKE_THREAD_LIBS_INIT})
 279
 280 ##############################################################################
 281 ## DBus setup
 282
 283 if (USE_DBUS)
 284     include(FindPkgConfig)
 285     if (PKG_CONFIG_FOUND)
 286         pkg_check_modules(DBUS dbus-1)
 287     endif (PKG_CONFIG_FOUND) #if we don't have pkg-config, assume we don't have libdbus-1-dev either http://packages.debian.org/sid/libdbus-1-dev
 288     if (DBUS_FOUND)
 289         set(HAVE_DBUS 1)
 290         message(STATUS "Using DBus")
 291         include_directories( ${DBUS_INCLUDE_DIRS})
 292     else()
 293         message(STATUS "DBus not found, screensaver control disabled")
 294     endif (DBUS_FOUND)
 295 else()
 296 endif (USE_DBUS)
 297
 298 ##############################################################################
 299 ## Qt5 setup setup
 300 if (ENABLE_QT)
 301         message(STATUS "Qt launcher enabled, checking for Qt 5.1 / qmake")
 302         find_package(Qt5 5.1 COMPONENTS Widgets)
 303         if (Qt5Widgets_FOUND)
 304                 message(STATUS "Will enable Qt launcher GUI")
 305                 message(STATUS "  Qt5Widgets version: ${Qt5Widgets_VERSION_STRING}")
 306                 message(STATUS "  Qt5Widgets include dir: ${Qt5Widgets_INCLUDE_DIRS}")
 307                 set(HAVE_QT 1)
 308         endif()
 309 endif (ENABLE_QT)
 310 ##############################################################################
 311
 312 find_package(PLIB REQUIRED puaux pu js fnt)
 313
 314 # FlightGear and SimGear versions need to match
 315 find_package(SimGear ${FLIGHTGEAR_VERSION} REQUIRED)
 316
 317 ##############################################################################
 318
 319 check_include_file(unistd.h   HAVE_UNISTD_H)
 320 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 321 check_include_file(windows.h  HAVE_WINDOWS_H)
 322
 323 if(ENABLE_PROFILE)
 324     find_package(GooglePerfTools REQUIRED)
 325     set(FG_HAVE_GPERFTOOLS 1)
 326     message(STATUS "Built-in profiler using gperftools available")
 327 endif()
 328
 329 if(ENABLE_RTI)
 330     message(STATUS "RTI: ENABLED")
 331     find_package(RTI)
 332     if(RTI_FOUND)
 333         set(FG_HAVE_HLA 1)
 334     endif(RTI_FOUND)
 335 else()
 336     message(STATUS "RTI: DISABLED")
 337 endif(ENABLE_RTI)
 338
 339 if(CMAKE_COMPILER_IS_GNUCXX)
 340     set(WARNING_FLAGS_CXX "-Wall")
 341     set(WARNING_FLAGS_C   "-Wall")
 342 endif(CMAKE_COMPILER_IS_GNUCXX)
 343
 344 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 345    set(WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual \
 346      -Wno-redeclared-class-member \
 347      -Wno-inconsistent-missing-override \
 348      -Wno-unused-local-typedef")
 349
 350    set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LIBRARY "libc++")
 351    set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LANGUAGE_STANDARD "c++11")
 352    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -stdlib=libc++")
 353    set(WARNING_FLAGS_C "-Wall")
 354 endif()
 355
 356 if(WIN32)
 357
 358     if(MSVC)
 359         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS /MP")
 360         if (${MSVC_VERSION} GREATER 1599)
 361             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 362         endif (${MSVC_VERSION} GREATER 1599)
 363
 364         if (${MSVC_VERSION} GREATER 1899)
 365             # needed for debug builds with VS2015
 366             set( MSVC_FLAGS "${MSVC_FLAGS} /bigobj" )
 367         endif()
 368     endif(MSVC)
 369
 370     set(NOMINMAX 1)
 371 endif(WIN32)
 372
 373 set (BOOST_CXX_FLAGS "-DBOOST_BIMAP_DISABLE_SERIALIZATION")
 374
 375 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS} -D_REENTRANT")
 376 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} -D_REENTRANT ${BOOST_CXX_FLAGS}")
 377 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 378
 379 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 380     ${Boost_INCLUDE_DIRS}
 381     ${ZLIB_INCLUDE_DIR}
 382     ${OPENGL_INCLUDE_DIR}
 383     ${OPENAL_INCLUDE_DIR}
 384     ${SIMGEAR_INCLUDE_DIRS}
 385     ${PLIB_INCLUDE_DIR}
 386     ${SQLITE3_INCLUDED_DIR} )
 387
 388 include_directories(${PROJECT_SOURCE_DIR})
 389 include_directories(${PROJECT_SOURCE_DIR}/src)
 390 # following is needed, because config.h is include 'bare', whereas
 391 # version.h is included as <Include/version.h> - this should be cleaned up
 392 include_directories(${PROJECT_BINARY_DIR}/src)
 393 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 394
 395 if (ENABLE_FLITE)
 396     include_directories(${PROJECT_SOURCE_DIR}/3rdparty/hts_engine_API/include )
 397     include_directories(${PROJECT_SOURCE_DIR}/3rdparty/flite_hts_engine/include )
 398 endif()
 399
 400 add_definitions(-DHAVE_CONFIG_H)
 401
 402 check_function_exists(mkfifo HAVE_MKFIFO)
 403
 404 # configure a header file to pass some of the CMake settings
 405 # to the source code
 406 configure_file (
 407     "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 408     "${PROJECT_BINARY_DIR}/src/Include/config.h"
 409 )
 410
 411 #and the same for the version header
 412 configure_file (
 413     "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 414     "${PROJECT_BINARY_DIR}/src/Include/version.h"
 415 )
 416
 417 add_subdirectory(3rdparty)
 418 add_subdirectory(utils)
 419 add_subdirectory(src)
 420 add_subdirectory(man)
 421
 422 #-----------------------------------------------------------------------------
 423 ### uninstall target
 424 #-----------------------------------------------------------------------------
 425 CONFIGURE_FILE(
 426     "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 427     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 428     IMMEDIATE @ONLY)
 429 ADD_CUSTOM_TARGET(uninstall
 430     "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")