CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2 include (CheckFunctionExists)
   3 include (CheckIncludeFile)
   4 include (CheckCXXSourceCompiles)
   5 include (CheckCXXCompilerFlag)
   6
   7 project(SimGear)
   8
   9 # read 'version' file into a variable (stripping any newlines or spaces)
  10 file(READ version versionFile)
  11 string(STRIP ${versionFile} SIMGEAR_VERSION)
  12
  13 set(FIND_LIBRARY_USE_LIB64_PATHS ON)
  14
  15 # use simgear version also as the SO version (if building SOs)
  16 SET(SIMGEAR_SOVERSION ${SIMGEAR_VERSION})
  17
  18 # Warning when build is not an out-of-source build.
  19 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  20 if(InSourceBuild)
  21     message(WARNING  "Avoid building inside the source tree!")
  22     message(WARNING  "Create a separate build directory instead (i.e. 'sgbuild') and call CMake from there: ")
  23     message(WARNING  "  mkdir ../sgbuild && cd ../sgbuild && cmake ${CMAKE_SOURCE_DIR}")
  24 endif(InSourceBuild)
  25
  26 #packaging
  27 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  28 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  29 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Simulation support libraries for FlightGear and related projects")
  30 SET(CPACK_PACKAGE_VENDOR "The FlightGear project")
  31 SET(CPACK_GENERATOR "TBZ2")
  32 SET(CPACK_INSTALL_CMAKE_PROJECTS  ${CMAKE_CURRENT_BINARY_DIR};SimGear;ALL;/)
  33
  34
  35 # split version string into components, note CMAKE_MATCH_0 is the entire regexp match
  36 string(REGEX MATCH "([0-9]+)\\.([0-9]+)\\.([0-9]+)" CPACK_PACKAGE_VERSION ${SIMGEAR_VERSION} )
  37 set(CPACK_PACKAGE_VERSION_MAJOR ${CMAKE_MATCH_1})
  38 set(CPACK_PACKAGE_VERSION_MINOR ${CMAKE_MATCH_2})
  39 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_3})
  40
  41 message(STATUS "version is ${CPACK_PACKAGE_VERSION_MAJOR} dot ${CPACK_PACKAGE_VERSION_MINOR} dot ${CPACK_PACKAGE_VERSION_PATCH}")
  42
  43 set(CPACK_SOURCE_GENERATOR TBZ2)
  44 set(CPACK_SOURCE_PACKAGE_FILE_NAME "simgear-${SIMGEAR_VERSION}" CACHE INTERNAL "tarball basename")
  45 set(CPACK_SOURCE_IGNORE_FILES
  46   "^${PROJECT_SOURCE_DIR}/.git;\\\\.gitignore;Makefile.am;~$;${CPACK_SOURCE_IGNORE_FILES}")
  47
  48 message(STATUS "ignoring: ${CPACK_SOURCE_IGNORE_FILES}")
  49
  50 include (CPack)
  51
  52 # We have some custom .cmake scripts not in the official distribution.
  53 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  54
  55 # Change the default build type to something fast
  56 if(NOT CMAKE_BUILD_TYPE)
  57   set(CMAKE_BUILD_TYPE Release CACHE STRING
  58       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  59       FORCE)
  60 endif(NOT CMAKE_BUILD_TYPE)
  61
  62 # Determine name of library installation directory, i.e. "lib" vs "lib64", which
  63 # differs between all Debian-based vs all other Linux distros.
  64 # See cmake bug #11964, http://cmake.org/gitweb?p=cmake.git;a=commit;h=126c993d
  65 # GNUInstallDirs requires CMake >= 2.8.5, use own file for older cmake
  66 if(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  67   include(GNUInstallDirs)
  68 else(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  69   include(OldGNUInstallDirs)
  70 endif(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  71 message(STATUS "Library installation directory: ${CMAKE_INSTALL_LIBDIR}")
  72
  73 #####################################################################################
  74 # Configure library search paths
  75 #####################################################################################
  76
  77 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  78     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  79     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  80     # add paths manually
  81     # see http://www.cmake.org/Bug/view.php?id=12049 and
  82     # http://www.cmake.org/Bug/view.php?id=12037
  83     list(APPEND ADDITIONAL_LIBRARY_PATHS
  84          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  85          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  86          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
  87     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
  88 endif()
  89
  90 #####################################################################################
  91
  92 if (NOT MSVC)
  93 option(SIMGEAR_SHARED   "Set to ON to build SimGear as a shared library/framework" OFF)
  94 option(SYSTEM_EXPAT     "Set to ON to build SimGear using the system libExpat" OFF)
  95 else()
  96 # Building SimGear DLLs is currently not supported for MSVC.
  97 set(SIMGEAR_SHARED OFF)
  98 # Using a system expat is currently not supported for MSVC - it would require shared simgear (DLL).
  99 set(SYSTEM_EXPAT OFF)
 100 endif()
 101
 102 option(SIMGEAR_HEADLESS "Set to ON to build SimGear without GUI/graphics support" OFF)
 103 option(JPEG_FACTORY     "Enable JPEG-factory support" OFF)
 104 option(ENABLE_RTI       "Set to ON to build SimGear with RTI support" OFF)
 105 option(ENABLE_TESTS     "Set to OFF to disable building SimGear's test applications" ON)
 106 option(ENABLE_SOUND     "Set to OFF to disable building SimGear's sound support" ON)
 107 option(ENABLE_PKGUTIL   "Set to ON to build the sg_pkgutil application (default)" ON)
 108
 109 if (MSVC)
 110   GET_FILENAME_COMPONENT(PARENT_DIR ${PROJECT_BINARY_DIR} PATH)
 111   if (CMAKE_CL_64)
 112     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty.x64")
 113   else (CMAKE_CL_64)
 114     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty")
 115   endif (CMAKE_CL_64)
 116   if (EXISTS ${TEST_3RDPARTY_DIR})
 117     set(MSVC_3RDPARTY_ROOT ${PARENT_DIR} CACHE PATH "Location where the third-party dependencies are extracted")
 118   else (EXISTS ${TEST_3RDPARTY_DIR})
 119     set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 120   endif (EXISTS ${TEST_3RDPARTY_DIR})
 121 else (MSVC)
 122   set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 123 endif (MSVC)
 124
 125 if (MSVC AND MSVC_3RDPARTY_ROOT)
 126   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_ROOT}")
 127   set( OSG_MSVC "msvc" )
 128   if (${MSVC_VERSION} EQUAL 1700)
 129       set( OSG_MSVC ${OSG_MSVC}110 )
 130   elseif (${MSVC_VERSION} EQUAL 1600)
 131       set( OSG_MSVC ${OSG_MSVC}100 )
 132   else (${MSVC_VERSION} EQUAL 1700)
 133       set( OSG_MSVC ${OSG_MSVC}90 )
 134   endif (${MSVC_VERSION} EQUAL 1700)
 135   if (CMAKE_CL_64)
 136       set( OSG_MSVC ${OSG_MSVC}-64 )
 137       set( MSVC_3RDPARTY_DIR 3rdParty.x64 )
 138   else (CMAKE_CL_64)
 139       set( MSVC_3RDPARTY_DIR 3rdParty )
 140   endif (CMAKE_CL_64)
 141
 142   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/lib )
 143   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/include)
 144   find_path(BOOST_ROOT boost/version.hpp
 145                         ${MSVC_3RDPARTY_ROOT}/boost
 146                         ${MSVC_3RDPARTY_ROOT}/boost_1_52_0
 147                         ${MSVC_3RDPARTY_ROOT}/boost_1_51_0
 148                         ${MSVC_3RDPARTY_ROOT}/boost_1_50_0
 149                         ${MSVC_3RDPARTY_ROOT}/boost_1_49_0
 150                         ${MSVC_3RDPARTY_ROOT}/boost_1_48_0
 151                         ${MSVC_3RDPARTY_ROOT}/boost_1_47_0
 152                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_1
 153                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_0
 154                         ${MSVC_3RDPARTY_ROOT}/boost_1_45_0
 155                         ${MSVC_3RDPARTY_ROOT}/boost_1_44_0
 156                         )
 157   # set (BOOST_ROOT ${MSVC_3RDPARTY_ROOT}/boost_1_44_0)
 158   message(STATUS "BOOST_ROOT is ${BOOST_ROOT}")
 159   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 160   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib)
 161 endif (MSVC AND MSVC_3RDPARTY_ROOT)
 162
 163 if(APPLE)
 164   find_library(CORE_SERVICES_LIBRARY CoreServices)
 165 endif()
 166
 167 find_package(Boost REQUIRED)
 168 set (BOOST_CXX_FLAGS "-DBOOST_MULTI_INDEX_DISABLE_SERIALIZATION -DBOOST_BIMAP_DISABLE_SERIALIZATION")
 169
 170 if(SIMGEAR_HEADLESS)
 171     message(STATUS "SimGear mode: HEADLESS")
 172     set(ENABLE_SOUND 0)
 173 else()
 174     message(STATUS "SimGear mode: NORMAL")
 175     find_package(OpenGL REQUIRED)
 176
 177     if (ENABLE_SOUND)
 178         find_package(OpenAL REQUIRED)
 179         message(STATUS "Sound support: ENABLED")
 180     endif(ENABLE_SOUND)
 181
 182     find_package(OpenSceneGraph 3.0.0 REQUIRED osgText osgSim osgDB osgParticle osgGA osgUtil)
 183 endif(SIMGEAR_HEADLESS)
 184
 185 if(JPEG_FACTORY)
 186     message(STATUS "JPEG-factory: ENABLED")
 187     find_package(JPEG REQUIRED)
 188     include_directories(${JPEG_INCLUDE_DIR})
 189 else()
 190     message(STATUS "JPEG-factory: DISABLED")
 191 endif(JPEG_FACTORY)
 192
 193 find_package(ZLIB REQUIRED)
 194 find_package(Threads REQUIRED)
 195
 196 if (SYSTEM_EXPAT)
 197     message(STATUS "Requested to use system Expat library, forcing SIMGEAR_SHARED to true")
 198     set(SIMGEAR_SHARED ON)
 199     find_package(EXPAT REQUIRED)
 200
 201 else()
 202     message(STATUS "Using built-in expat code")
 203     # XML_STATIC is important to avoid sg_expat_external.h
 204     # declaring symbols as declspec(import)
 205     add_definitions(-DHAVE_EXPAT_CONFIG_H -DXML_STATIC)
 206     set(EXPAT_INCLUDE_DIRS
 207             ${PROJECT_SOURCE_DIR}/3rdparty/expat
 208             ${PROJECT_BINARY_DIR}/3rdparty/expat)
 209 endif(SYSTEM_EXPAT)
 210
 211 include_directories(${EXPAT_INCLUDE_DIRS})
 212
 213 check_include_file(inttypes.h HAVE_INTTYPES_H)
 214 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 215 check_include_file(sys/timeb.h HAVE_SYS_TIMEB_H)
 216 check_include_file(unistd.h HAVE_UNISTD_H)
 217 check_include_file(windows.h HAVE_WINDOWS_H)
 218
 219 if(HAVE_INTTYPES_H)
 220   # ShivaVG needs inttypes.h
 221   add_definitions(-DHAVE_INTTYPES_H)
 222 endif()
 223
 224 if(ENABLE_RTI)
 225     # See if we have any rti library variant installed
 226     message(STATUS "RTI: ENABLED")
 227     find_package(RTI)
 228 else()
 229     message(STATUS "RTI: DISABLED")
 230 endif(ENABLE_RTI)
 231
 232 check_function_exists(gettimeofday HAVE_GETTIMEOFDAY)
 233 check_function_exists(ftime HAVE_FTIME)
 234 check_function_exists(timegm HAVE_TIMEGM)
 235 check_function_exists(rint HAVE_RINT)
 236 check_function_exists(mkdtemp HAVE_MKDTEMP)
 237 check_function_exists(bcopy HAVE_BCOPY)
 238 check_function_exists(mmap HAVE_MMAP)
 239
 240 if(HAVE_UNISTD_H)
 241     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 242     check_cxx_source_compiles(
 243        "#include <unistd.h>
 244         #if !defined(_POSIX_TIMERS) || (0 >= _POSIX_TIMERS)
 245             #error clock_gettime is not supported
 246         #endif
 247
 248         int main() { return 0; }
 249         "
 250         HAVE_CLOCK_GETTIME)
 251 endif(HAVE_UNISTD_H)
 252
 253 set(RT_LIBRARY "")
 254 if(HAVE_CLOCK_GETTIME)
 255     check_library_exists(rt clock_gettime "" HAVE_RT)
 256     if(HAVE_RT)
 257         set(RT_LIBRARY rt)
 258     endif(HAVE_RT)
 259 endif(HAVE_CLOCK_GETTIME)
 260
 261 set(DL_LIBRARY "")
 262 check_cxx_source_compiles(
 263     "#include <dlfcn.h>
 264     int main(void) {
 265         return 0;
 266     }
 267     "
 268     HAVE_DLFCN_H)
 269
 270 if(HAVE_DLFCN_H)
 271     check_library_exists(dl dlerror "" HAVE_DL)
 272     set(DL_LIBRARY "dl")
 273 endif()
 274
 275 SET(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "add a postfix, usually 'd' on windows")
 276 SET(CMAKE_RELEASE_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 277 SET(CMAKE_RELWITHDEBINFO_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 278 SET(CMAKE_MINSIZEREL_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 279
 280 # isnan might not be real symbol, so can't check using function_exists
 281 check_cxx_source_compiles(
 282     "#include <cmath>
 283     void f() { isnan(0.0);} "
 284     HAVE_ISNAN)
 285
 286 check_cxx_source_compiles(
 287     "#include <cmath>
 288     void f() { std::isnan(0.0);} "
 289     HAVE_STD_ISNAN)
 290
 291 if(CMAKE_COMPILER_IS_GNUCXX)
 292     set(WARNING_FLAGS_CXX "-Wall")
 293     set(WARNING_FLAGS_C   "-Wall")
 294
 295     # certain GCC versions don't provide the atomic builds, and hence
 296     # require is to provide them in SGAtomic.cxx
 297     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 298     check_cxx_source_compiles(
 299        "int main() { unsigned mValue; return __sync_add_and_fetch(&mValue, 1); }"
 300         GCC_ATOMIC_BUILTINS_FOUND)
 301 endif(CMAKE_COMPILER_IS_GNUCXX)
 302
 303 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 304    set(WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual")
 305    set(WARNING_FLAGS_C   "-Wall")
 306 endif()
 307
 308 if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 309 # boost goes haywire wrt static asserts
 310     check_cxx_compiler_flag(-Wno-unused-local-typedefs HAS_NOWARN_UNUSED_TYPEDEFS)
 311     if(HAS_NOWARN_UNUSED_TYPEDEFS)
 312         set(WARNING_FLAGS_CXX " ${WARNING_FLAGS_CXX} -Wno-unused-local-typedefs")
 313     endif()
 314 endif()
 315
 316 if(WIN32)
 317
 318     if(MINGW)
 319         add_definitions(-D_WIN32_WINNT=0x501)
 320     endif()
 321
 322     if(MSVC)
 323         # turn off various warnings
 324         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 325         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 326         # endforeach(warning)
 327
 328         set(MSVC_FLAGS "-DWIN32 -DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS /wd4996 /wd4250 -Dstrdup=_strdup")
 329         if (${MSVC_VERSION} GREATER 1599)
 330             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 331         endif (${MSVC_VERSION} GREATER 1599)
 332     endif(MSVC)
 333
 334     # assumed on Windows
 335     set(HAVE_GETLOCALTIME 1)
 336
 337     set( WINSOCK_LIBRARY "ws2_32.lib" )
 338     set( RT_LIBRARY "winmm" )
 339 endif(WIN32)
 340
 341 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS}")
 342 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} ${BOOST_CXX_FLAGS}")
 343 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 344
 345 include_directories(${PROJECT_SOURCE_DIR})
 346 include_directories(${PROJECT_SOURCE_DIR}/simgear/canvas/ShivaVG/include)
 347 include_directories(${PROJECT_BINARY_DIR}/simgear)
 348
 349 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 350     ${Boost_INCLUDE_DIRS}
 351     ${ZLIB_INCLUDE_DIR}
 352     ${OPENAL_INCLUDE_DIR}
 353 )
 354
 355 add_definitions(-DHAVE_CONFIG_H)
 356
 357 # configure a header file to pass some of the CMake settings
 358 # to the source code
 359 configure_file (
 360   "${PROJECT_SOURCE_DIR}/simgear/simgear_config_cmake.h.in"
 361   "${PROJECT_BINARY_DIR}/simgear/simgear_config.h"
 362   )
 363
 364 if(ENABLE_TESTS)
 365     # enable CTest / make test target
 366     message(STATUS "Tests: ENABLED")
 367
 368     include (Dart)
 369     enable_testing()
 370 else()
 371     message(STATUS "Tests: DISABLED")
 372 endif(ENABLE_TESTS)
 373
 374 # always set TEST_LIBS as it is also used by other tools/applications
 375 set(TEST_LIBS_INTERNAL_CORE
 376     ${CMAKE_THREAD_LIBS_INIT}
 377     ${ZLIB_LIBRARY}
 378     ${WINSOCK_LIBRARY}
 379     ${RT_LIBRARY}
 380     ${DL_LIBRARY}
 381     ${CORE_SERVICES_LIBRARY})
 382 set(TEST_LIBS SimGearCore ${TEST_LIBS_INTERNAL_CORE})
 383
 384 if(NOT SIMGEAR_HEADLESS)
 385     set(TEST_LIBS SimGearScene ${OPENGL_LIBRARIES} ${TEST_LIBS})
 386 endif()
 387
 388 install (FILES ${PROJECT_BINARY_DIR}/simgear/simgear_config.h  DESTINATION include/simgear/)
 389
 390 add_subdirectory(3rdparty)
 391 add_subdirectory(simgear)
 392
 393 #-----------------------------------------------------------------------------
 394 ### uninstall target
 395 #-----------------------------------------------------------------------------
 396 CONFIGURE_FILE(
 397   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 398   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 399   IMMEDIATE @ONLY)
 400 ADD_CUSTOM_TARGET(uninstall
 401   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
 402
 403