CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8.11)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7
   8 if(COMMAND cmake_policy)
   9    if(POLICY CMP0054)
  10        cmake_policy(SET CMP0054 NEW)
  11    endif()
  12    if(POLICY CMP0042)
  13        cmake_policy(SET CMP0042 NEW)
  14    endif()
  15 endif()
  16
  17 if(APPLE)
  18         # using 10.7 because boost requires libc++ and 10.6 doesn't include it
  19         set(CMAKE_OSX_DEPLOYMENT_TARGET 10.7)
  20         set(CMAKE_OSX_SYSROOT /Applications/Xcode.app/Contents/Developer/Platforms/MacOSX.platform/Developer/SDKs/MacOSX10.9.sdk)
  21
  22         set(CMAKE_INSTALL_RPATH "@loader_path/../Frameworks")
  23         # when building, don't use the install RPATH already
  24         # (but later on when installing)
  25         SET(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
  26 endif()
  27
  28 project(FlightGear)
  29
  30 # We have some custom .cmake scripts not in the official distribution.
  31 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  32
  33 if(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  34     # use official include provided by latest CMake
  35     include(GNUInstallDirs)
  36 else(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  37     # backward compatibility: use our own module for older cmake versions
  38     include(OldGNUInstallDirs)
  39 endif(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  40
  41 # Warning when build is not an out-of-source build.
  42 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  43 if(InSourceBuild)
  44     message(WARNING  "Avoid building inside the source tree!")
  45     message(WARNING  "Create a separate build directory instead (i.e. 'fgbuild') and call CMake from there: ")
  46     message(WARNING  "  mkdir ../fgbuild && cd ../fgbuild && cmake ${CMAKE_SOURCE_DIR}")
  47 endif(InSourceBuild)
  48
  49 # System detection/default settings
  50 include( DetectDistro )
  51 include( DetectBrowser )
  52
  53 set(CMAKE_DEBUG_POSTFIX          "d" CACHE STRING "add a postfix, usually d on windows")
  54 set(CMAKE_RELEASE_POSTFIX        ""  CACHE STRING "add a postfix, usually empty on windows")
  55 set(CMAKE_RELWITHDEBINFO_POSTFIX ""  CACHE STRING "add a postfix, usually empty on windows")
  56 set(CMAKE_MINSIZEREL_POSTFIX     ""  CACHE STRING "add a postfix, usually empty on windows")
  57
  58 # read 'version' file into a variable (stripping any newlines or spaces)
  59 file(READ version versionFile)
  60 if (NOT versionFile)
  61     message(FATAL_ERROR "Unable to determine FlightGear version. Version file is missing.")
  62 endif()
  63 string(STRIP "${versionFile}" FLIGHTGEAR_VERSION)
  64
  65 # FlightGear packaging (to build a source tarball)
  66 include( ConfigureCPack )
  67
  68 # FlightGear base package path
  69 if (FG_DATA_DIR)
  70     message(STATUS "Using explicit data directory for base package: ${FG_DATA_DIR}")
  71 else()
  72     set(FG_DATA_DIR "${CMAKE_INSTALL_PREFIX}/lib/FlightGear" CACHE PATH "Default location where data files are located")
  73     message(STATUS "Using default data directory for base package:  ${FG_DATA_DIR}")
  74 endif()
  75
  76 # Change the default build type to something fast
  77 if(NOT CMAKE_BUILD_TYPE)
  78     set(CMAKE_BUILD_TYPE Release CACHE STRING
  79         "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  80         FORCE)
  81 endif(NOT CMAKE_BUILD_TYPE)
  82
  83 if(NOT "$ENV{BUILD_ID}" STREQUAL "")
  84     set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  85     set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  86     message(STATUS "running under Hudson/Jenkins, build-number is ${HUDSON_BUILD_NUMBER}")
  87 else()
  88     set(HUDSON_BUILD_NUMBER 0)
  89     set(HUDSON_BUILD_ID "none")
  90 endif()
  91
  92 #####################################################################################
  93 # Configure library search paths
  94 #####################################################################################
  95
  96
  97 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  98     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  99     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
 100     # add paths manually
 101     # see http://www.cmake.org/Bug/view.php?id=12049 and
 102     # http://www.cmake.org/Bug/view.php?id=12037
 103     list(APPEND ADDITIONAL_LIBRARY_PATHS
 104          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
 105          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
 106          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
 107     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
 108 endif()
 109
 110 #####################################################################################
 111
 112 IF(APPLE)
 113     set(EVENT_INPUT_DEFAULT 1)
 114
 115     find_library(CORESERVICES_LIBRARY CoreServices)
 116     find_library(COCOA_LIBRARY Cocoa)
 117     list(APPEND PLATFORM_LIBS ${COCOA_LIBRARY} ${CORESERVICES_LIBRARY})
 118 elseif(${CMAKE_SYSTEM_NAME} MATCHES "Linux" OR
 119         ${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD")
 120     find_package(Threads REQUIRED)
 121     find_package(X11 REQUIRED)
 122
 123     set(USE_DBUS_DEFAULT 1)
 124
 125     find_package(UDev)
 126     if(UDEV_FOUND)
 127         set(EVENT_INPUT_DEFAULT 1)
 128     endif(UDEV_FOUND)
 129
 130     find_package(Speex)
 131     find_package(Speexdsp)
 132     if(SPEEX_FOUND AND SPEEXDSP_FOUND)
 133         set(SYSTEM_SPEEX_DEFAULT 1)
 134     endif(SPEEX_FOUND AND SPEEXDSP_FOUND)
 135
 136     find_package(Gsm)
 137     if(GSM_FOUND)
 138         set(SYSTEM_GSM_DEFAULT 1)
 139     endif(GSM_FOUND)
 140
 141     find_package(Flite)
 142     if(FLITE_FOUND)
 143         set(SYSTEM_FLITE_DEFAULT 1)
 144     endif()
 145
 146     find_package(HtsEngine)
 147     if(HTS_ENGINE_FOUND)
 148         set(SYSTEM_HTS_ENGINE_DEFAULT 1)
 149     endif()
 150 endif()
 151
 152 find_package(Git)
 153 if (GIT_FOUND)
 154     execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
 155         OUTPUT_VARIABLE REVISION
 156         OUTPUT_STRIP_TRAILING_WHITESPACE)
 157     message(STATUS "Git revision is ${REVISION}")
 158 else()
 159     set(REVISION "none")
 160 endif()
 161
 162 # FlightGear build options
 163 option(SIMGEAR_SHARED    "Set to ON when SimGear was built as a shared library" OFF)
 164 option(LOGGING           "Set to ON to build FlightGear with logging support (default)" ON)
 165 option(JSBSIM_TERRAIN    "Set to ON to build FlightGear with JSBSim terrain handling code" ON)
 166 option(SP_FDMS           "Set to ON to build FlightGear with special-purpose FDMs" OFF)
 167 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" OFF)
 168 option(ENABLE_LARCSIM    "Set to ON to build FlightGear with LaRCsim FDM" OFF)
 169 option(ENABLE_YASIM      "Set to ON to build FlightGear with YASIM FDM (default)" ON)
 170 option(ENABLE_JSBSIM     "Set to ON to build FlightGear with JSBSim FDM (default)" ON)
 171 option(EVENT_INPUT       "Set to ON to build FlightGear with event-based Input support" ${EVENT_INPUT_DEFAULT})
 172 option(ENABLE_RTI        "Set to ON to build FlightGear with RTI support" OFF)
 173 option(ENABLE_PROFILE    "Set to ON to build FlightGear with gperftools profiling support" OFF)
 174 option(SYSTEM_SQLITE     "Set to ON to build FlightGear with the system's SQLite3 library" OFF)
 175 option(ENABLE_IAX        "Set to ON to build FlightGear with IAXClient/fgcom built-in (default)" ON)
 176 option(USE_DBUS          "Set to ON to build FlightGear with DBus screensaver interaction (default on Linux)" ${USE_DBUS_DEFAULT})
 177 option(SYSTEM_SPEEX      "Set to ON to build IAXClient with the system's speex and speexdsp library" ${SYSTEM_SPEEX_DEFAULT})
 178 option(SYSTEM_GSM        "Set to ON to build IAXClient with the system's GSM library" ${SYSTEM_GSM_DEFAULT})
 179 option(SYSTEM_FLITE      "Set to ON to build Flightgear with the system's Flite library" ${SYSTEM_FLITE_DEFAULT})
 180 option(SYSTEM_HTS_ENGINE "Set to ON to build Flightgear with the system's HTS Engine library" ${SYSTEM_HTS_ENGINE_DEFAULT})
 181 option(FG_NIGHTLY        "Set to ON to mark this as a nightly build" OFF)
 182
 183 # additional utilities
 184 option(ENABLE_FGADMIN    "Set to ON to build the FGADMIN application (default)" ON)
 185 option(ENABLE_FGELEV     "Set to ON to build the fgelev application (default)" ON)
 186 option(WITH_FGPANEL      "Set to ON to build the fgpanel application (default)" ON)
 187 option(ENABLE_FGVIEWER   "Set to ON to build the fgviewer application (default)" ON)
 188 option(ENABLE_GPSSMOOTH  "Set to ON to build the GPSsmooth application (default)" ON)
 189 option(ENABLE_TERRASYNC  "Set to ON to build the terrasync application (default)" ON)
 190 option(ENABLE_FGJS       "Set to ON to build the fgjs application (default)" ON)
 191 option(ENABLE_JS_DEMO    "Set to ON to build the js_demo application (default)" ON)
 192 option(ENABLE_METAR      "Set to ON to build the metar application (default)" ON)
 193 option(ENABLE_TESTS      "Set to ON to build test applications (default)" ON)
 194 option(ENABLE_FGCOM      "Set to ON to build the FGCom application (default)" ON)
 195 option(ENABLE_FLITE      "Set to ON to build the Flite text-to-speech module" ON)
 196 option(ENABLE_QT         "Set to ON to build the internal Qt launcher" ON)
 197
 198 if(LOGGING)
 199     # nothing
 200 else()
 201     set(FG_NDEBUG 1)
 202 endif()
 203
 204 if(JSBSIM_TERRAIN)
 205    set(JSBSIM_USE_GROUNDREACTIONS 1)
 206 endif()
 207
 208 if(SP_FDMS)
 209     set(ENABLE_SP_FDM 1)
 210 endif()
 211
 212 if(ENABLE_FGCOM)
 213   set(ENABLE_IAX 1)
 214   include_directories(${PROJECT_SOURCE_DIR}/3rdparty/iaxclient/lib ) # for iaxclient.h
 215 endif()
 216
 217 # Setup MSVC 3rd party directories
 218 include( ConfigureMsvc3rdParty )
 219
 220 if(EVENT_INPUT)
 221     if(APPLE)
 222     elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 223         if(NOT UDEV_FOUND)
 224             message(WARNING "UDev not found, event input is disabled!")
 225             set(EVENT_INPUT 0)
 226         else()
 227             add_definitions(-DWITH_EVENTINPUT)
 228             set(EVENT_INPUT_LIBRARIES ${UDEV_LIBRARIES})
 229             message(STATUS "event-based input enabled. Using ${UDEV_LIBRARIES}")
 230         endif()
 231     else()
 232         message(WARNING "event-based input is not supported on this platform yet")
 233     endif()
 234
 235     # Keep PLIB INPUT enabled as long as EventInput does not replace current joystick configurations.
 236     set(ENABLE_PLIB_JOYSTICK 1)
 237 else(EVENT_INPUT)
 238     set(ENABLE_PLIB_JOYSTICK 1)
 239 endif(EVENT_INPUT)
 240
 241 # check required dependencies
 242 find_package(Boost   REQUIRED)
 243 find_package(ZLIB    REQUIRED)
 244 find_package(OpenGL  REQUIRED)
 245 find_package(OpenAL  REQUIRED)
 246 find_package(OpenSceneGraph 3.2.0 REQUIRED
 247   osgText
 248   osgSim
 249   osgDB
 250   osgParticle
 251   osgFX
 252   osgUtil
 253   osgViewer
 254   osgGA
 255 )
 256
 257 if (MSVC)
 258         find_package(CrashRpt)
 259         if (CRASHRPT_FOUND)
 260                 set(HAVE_CRASHRPT 1)
 261                 message(STATUS "Using CrashRpt")
 262         include_directories( ${CRASHRPT_INCLUDE_DIR})
 263         endif()
 264 endif()
 265
 266 ##############################################################################
 267 ## Sqlite3 setup
 268
 269 if (SYSTEM_SQLITE)
 270     find_package(SQLite3 REQUIRED)
 271
 272     message(STATUS "Using system SQLite3 library")
 273 else()
 274     set(SQLITE3_INCLUDED_DIR "${CMAKE_SOURCE_DIR}/3rdparty/sqlite3")
 275     # this target is defined in src/Navaids/CMakeLists.txt
 276     list(APPEND SQLITE3_LIBRARY fgsqlite3)
 277 endif (SYSTEM_SQLITE)
 278
 279 # Sqlite always depends on the threading lib
 280 list(APPEND SQLITE3_LIBRARY ${CMAKE_THREAD_LIBS_INIT})
 281
 282 ##############################################################################
 283 ## DBus setup
 284
 285 if (USE_DBUS)
 286     include(FindPkgConfig)
 287     if (PKG_CONFIG_FOUND)
 288         pkg_check_modules(DBUS dbus-1)
 289     endif (PKG_CONFIG_FOUND) #if we don't have pkg-config, assume we don't have libdbus-1-dev either http://packages.debian.org/sid/libdbus-1-dev
 290     if (DBUS_FOUND)
 291         set(HAVE_DBUS 1)
 292         message(STATUS "Using DBus")
 293         include_directories( ${DBUS_INCLUDE_DIRS})
 294     else()
 295         message(STATUS "DBus not found, screensaver control disabled")
 296     endif (DBUS_FOUND)
 297 else()
 298 endif (USE_DBUS)
 299
 300 ##############################################################################
 301 ## Qt5 setup setup
 302 if (ENABLE_QT)
 303         message(STATUS "Qt launcher enabled, checking for Qt 5.1 / qmake")
 304         find_package(Qt5 5.1 COMPONENTS Widgets)
 305         if (Qt5Widgets_FOUND)
 306                 message(STATUS "Will enable Qt launcher GUI")
 307                 message(STATUS "  Qt5Widgets version: ${Qt5Widgets_VERSION_STRING}")
 308                 message(STATUS "  Qt5Widgets include dir: ${Qt5Widgets_INCLUDE_DIRS}")
 309                 set(HAVE_QT 1)
 310         endif()
 311 endif (ENABLE_QT)
 312 ##############################################################################
 313
 314 find_package(PLIB REQUIRED puaux pu js fnt)
 315
 316 # FlightGear and SimGear versions need to match
 317 find_package(SimGear ${FLIGHTGEAR_VERSION} REQUIRED)
 318
 319 ##############################################################################
 320
 321 check_include_file(unistd.h   HAVE_UNISTD_H)
 322 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 323 check_include_file(windows.h  HAVE_WINDOWS_H)
 324
 325 if(ENABLE_PROFILE)
 326     find_package(GooglePerfTools REQUIRED)
 327     set(FG_HAVE_GPERFTOOLS 1)
 328     message(STATUS "Built-in profiler using gperftools available")
 329 endif()
 330
 331 if(ENABLE_RTI)
 332     message(STATUS "RTI: ENABLED")
 333     find_package(RTI)
 334     if(RTI_FOUND)
 335         set(FG_HAVE_HLA 1)
 336     endif(RTI_FOUND)
 337 else()
 338     message(STATUS "RTI: DISABLED")
 339 endif(ENABLE_RTI)
 340
 341 if(CMAKE_COMPILER_IS_GNUCXX)
 342     set(WARNING_FLAGS_CXX "-Wall")
 343     set(WARNING_FLAGS_C   "-Wall")
 344 endif(CMAKE_COMPILER_IS_GNUCXX)
 345
 346 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 347    set (WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual -Wno-redeclared-class-member")
 348    set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LIBRARY "libc++")
 349    set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LANGUAGE_STANDARD "c++11")
 350    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -stdlib=libc++")
 351    set (WARNING_FLAGS_C "-Wall")
 352 endif()
 353
 354 if(WIN32)
 355
 356     if(MSVC)
 357         # turn off various warnings
 358         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 359         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 360         # endforeach(warning)
 361
 362         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS -Dstrdup=_strdup")
 363         if (${MSVC_VERSION} GREATER 1599)
 364             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 365         endif (${MSVC_VERSION} GREATER 1599)
 366     endif(MSVC)
 367
 368     set(NOMINMAX 1)
 369 endif(WIN32)
 370
 371 set (BOOST_CXX_FLAGS "-DBOOST_BIMAP_DISABLE_SERIALIZATION")
 372
 373 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS} -D_REENTRANT")
 374 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} -D_REENTRANT ${BOOST_CXX_FLAGS}")
 375 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 376
 377 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 378     ${Boost_INCLUDE_DIRS}
 379     ${ZLIB_INCLUDE_DIR}
 380     ${OPENGL_INCLUDE_DIR}
 381     ${OPENAL_INCLUDE_DIR}
 382     ${SIMGEAR_INCLUDE_DIRS}
 383     ${PLIB_INCLUDE_DIR}
 384     ${SQLITE3_INCLUDED_DIR} )
 385
 386 include_directories(${PROJECT_SOURCE_DIR})
 387 include_directories(${PROJECT_SOURCE_DIR}/src)
 388 # following is needed, because config.h is include 'bare', whereas
 389 # version.h is included as <Include/version.h> - this should be cleaned up
 390 include_directories(${PROJECT_BINARY_DIR}/src)
 391 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 392
 393 if (ENABLE_FLITE)
 394     include_directories(${PROJECT_SOURCE_DIR}/3rdparty/hts_engine_API/include )
 395     include_directories(${PROJECT_SOURCE_DIR}/3rdparty/flite_hts_engine/include )
 396 endif()
 397
 398 add_definitions(-DHAVE_CONFIG_H)
 399
 400 check_function_exists(mkfifo HAVE_MKFIFO)
 401
 402 # configure a header file to pass some of the CMake settings
 403 # to the source code
 404 configure_file (
 405     "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 406     "${PROJECT_BINARY_DIR}/src/Include/config.h"
 407 )
 408
 409 #and the same for the version header
 410 configure_file (
 411     "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 412     "${PROJECT_BINARY_DIR}/src/Include/version.h"
 413 )
 414
 415 add_subdirectory(3rdparty)
 416 add_subdirectory(utils)
 417 add_subdirectory(src)
 418 add_subdirectory(man)
 419
 420 #-----------------------------------------------------------------------------
 421 ### uninstall target
 422 #-----------------------------------------------------------------------------
 423 CONFIGURE_FILE(
 424     "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 425     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 426     IMMEDIATE @ONLY)
 427 ADD_CUSTOM_TARGET(uninstall
 428     "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")