CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7
   8 if(COMMAND cmake_policy)
   9     if(${CMAKE_MAJOR_VERSION} GREATER 2) # version 3 or higher
  10         cmake_policy(SET CMP0054 NEW)
  11         cmake_policy(SET CMP0042 NEW)
  12     endif()
  13 endif()
  14
  15 # set this before project()
  16 # using 10.7 because boost requires libc++ and 10.6 doesn't include it
  17 set(CMAKE_OSX_DEPLOYMENT_TARGET 10.7)
  18
  19 project(FlightGear)
  20
  21 # We have some custom .cmake scripts not in the official distribution.
  22 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  23
  24 if(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  25     # use official include provided by latest CMake
  26     include(GNUInstallDirs)
  27 else(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  28     # backward compatibility: use our own module for older cmake versions
  29     include(OldGNUInstallDirs)
  30 endif(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  31
  32 # Warning when build is not an out-of-source build.
  33 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  34 if(InSourceBuild)
  35     message(WARNING  "Avoid building inside the source tree!")
  36     message(WARNING  "Create a separate build directory instead (i.e. 'fgbuild') and call CMake from there: ")
  37     message(WARNING  "  mkdir ../fgbuild && cd ../fgbuild && cmake ${CMAKE_SOURCE_DIR}")
  38 endif(InSourceBuild)
  39
  40 # System detection/default settings
  41 include( DetectDistro )
  42 include( DetectBrowser )
  43
  44 set(CMAKE_DEBUG_POSTFIX          "d" CACHE STRING "add a postfix, usually d on windows")
  45 set(CMAKE_RELEASE_POSTFIX        ""  CACHE STRING "add a postfix, usually empty on windows")
  46 set(CMAKE_RELWITHDEBINFO_POSTFIX ""  CACHE STRING "add a postfix, usually empty on windows")
  47 set(CMAKE_MINSIZEREL_POSTFIX     ""  CACHE STRING "add a postfix, usually empty on windows")
  48
  49 # read 'version' file into a variable (stripping any newlines or spaces)
  50 file(READ version versionFile)
  51 if (NOT versionFile)
  52     message(FATAL_ERROR "Unable to determine FlightGear version. Version file is missing.")
  53 endif()
  54 string(STRIP "${versionFile}" FLIGHTGEAR_VERSION)
  55
  56 # FlightGear packaging (to build a source tarball)
  57 include( ConfigureCPack )
  58
  59 # FlightGear base package path
  60 if (FG_DATA_DIR)
  61     message(STATUS "Using explicit data directory for base package: ${FG_DATA_DIR}")
  62 else()
  63     set(FG_DATA_DIR "${CMAKE_INSTALL_PREFIX}/lib/FlightGear" CACHE PATH "Default location where data files are located")
  64     message(STATUS "Using default data directory for base package:  ${FG_DATA_DIR}")
  65 endif()
  66
  67 # Change the default build type to something fast
  68 if(NOT CMAKE_BUILD_TYPE)
  69     set(CMAKE_BUILD_TYPE Release CACHE STRING
  70         "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  71         FORCE)
  72 endif(NOT CMAKE_BUILD_TYPE)
  73
  74 if(NOT "$ENV{BUILD_ID}" STREQUAL "")
  75     set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  76     set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  77     message(STATUS "running under Hudson/Jenkins, build-number is ${HUDSON_BUILD_NUMBER}")
  78 else()
  79     set(HUDSON_BUILD_NUMBER 0)
  80     set(HUDSON_BUILD_ID "none")
  81 endif()
  82
  83 #####################################################################################
  84 # Configure library search paths
  85 #####################################################################################
  86
  87
  88 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  89     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  90     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  91     # add paths manually
  92     # see http://www.cmake.org/Bug/view.php?id=12049 and
  93     # http://www.cmake.org/Bug/view.php?id=12037
  94     list(APPEND ADDITIONAL_LIBRARY_PATHS
  95          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  96          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  97          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
  98     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
  99 endif()
 100
 101 #####################################################################################
 102
 103 IF(APPLE)
 104     set(EVENT_INPUT_DEFAULT 1)
 105
 106     find_library(CORESERVICES_LIBRARY CoreServices)
 107     find_library(COCOA_LIBRARY Cocoa)
 108     list(APPEND PLATFORM_LIBS ${COCOA_LIBRARY} ${CORESERVICES_LIBRARY})
 109
 110 elseif(${CMAKE_SYSTEM_NAME} MATCHES "Linux" OR
 111         ${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD")
 112     set(USE_DBUS_DEFAULT 1)
 113
 114     find_package(UDev)
 115     if(UDEV_FOUND)
 116         set(EVENT_INPUT_DEFAULT 1)
 117     endif(UDEV_FOUND)
 118
 119     find_package(Speex)
 120     find_package(Speexdsp)
 121     if(SPEEX_FOUND AND SPEEXDSP_FOUND)
 122         set(SYSTEM_SPEEX_DEFAULT 1)
 123     endif(SPEEX_FOUND AND SPEEXDSP_FOUND)
 124
 125     find_package(Gsm)
 126     if(GSM_FOUND)
 127         set(SYSTEM_GSM_DEFAULT 1)
 128     endif(GSM_FOUND)
 129
 130     find_package(Flite)
 131     if(FLITE_FOUND)
 132         set(SYSTEM_FLITE_DEFAULT 1)
 133     endif()
 134
 135     find_package(HtsEngine)
 136     if(HTS_ENGINE_FOUND)
 137         set(SYSTEM_HTS_ENGINE_DEFAULT 1)
 138     endif()
 139 endif()
 140
 141 find_package(Git)
 142 if (GIT_FOUND)
 143     execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
 144         OUTPUT_VARIABLE REVISION
 145         OUTPUT_STRIP_TRAILING_WHITESPACE)
 146     message(STATUS "Git revision is ${REVISION}")
 147 else()
 148     set(REVISION "none")
 149 endif()
 150
 151 # FlightGear build options
 152 option(SIMGEAR_SHARED    "Set to ON when SimGear was built as a shared library" OFF)
 153 option(LOGGING           "Set to ON to build FlightGear with logging support (default)" ON)
 154 option(JSBSIM_TERRAIN    "Set to ON to build FlightGear with JSBSim terrain handling code" ON)
 155 option(SP_FDMS           "Set to ON to build FlightGear with special-purpose FDMs" OFF)
 156 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" OFF)
 157 option(ENABLE_LARCSIM    "Set to ON to build FlightGear with LaRCsim FDM" OFF)
 158 option(ENABLE_YASIM      "Set to ON to build FlightGear with YASIM FDM (default)" ON)
 159 option(ENABLE_JSBSIM     "Set to ON to build FlightGear with JSBSim FDM (default)" ON)
 160 option(EVENT_INPUT       "Set to ON to build FlightGear with event-based Input support" ${EVENT_INPUT_DEFAULT})
 161 option(ENABLE_RTI        "Set to ON to build FlightGear with RTI support" OFF)
 162 option(ENABLE_PROFILE    "Set to ON to build FlightGear with gperftools profiling support" OFF)
 163 option(SYSTEM_SQLITE     "Set to ON to build FlightGear with the system's SQLite3 library" OFF)
 164 option(ENABLE_IAX        "Set to ON to build FlightGear with IAXClient/fgcom built-in (default)" ON)
 165 option(USE_DBUS          "Set to ON to build FlightGear with DBus screensaver interaction (default on Linux)" ${USE_DBUS_DEFAULT})
 166 option(SYSTEM_SPEEX      "Set to ON to build IAXClient with the system's speex and speexdsp library" ${SYSTEM_SPEEX_DEFAULT})
 167 option(SYSTEM_GSM        "Set to ON to build IAXClient with the system's GSM library" ${SYSTEM_GSM_DEFAULT})
 168 option(SYSTEM_FLITE      "Set to ON to build Flightgear with the system's Flite library" ${SYSTEM_FLITE_DEFAULT})
 169 option(SYSTEM_HTS_ENGINE "Set to ON to build Flightgear with the system's HTS Engine library" ${SYSTEM_HTS_ENGINE_DEFAULT})
 170
 171 # additional utilities
 172 option(ENABLE_FGADMIN    "Set to ON to build the FGADMIN application (default)" ON)
 173 option(ENABLE_FGELEV     "Set to ON to build the fgelev application (default)" ON)
 174 option(WITH_FGPANEL      "Set to ON to build the fgpanel application (default)" ON)
 175 option(ENABLE_FGVIEWER   "Set to ON to build the fgviewer application (default)" ON)
 176 option(ENABLE_GPSSMOOTH  "Set to ON to build the GPSsmooth application (default)" ON)
 177 option(ENABLE_TERRASYNC  "Set to ON to build the terrasync application (default)" ON)
 178 option(ENABLE_FGJS       "Set to ON to build the fgjs application (default)" ON)
 179 option(ENABLE_JS_DEMO    "Set to ON to build the js_demo application (default)" ON)
 180 option(ENABLE_METAR      "Set to ON to build the metar application (default)" ON)
 181 option(ENABLE_TESTS      "Set to ON to build test applications (default)" ON)
 182 option(ENABLE_FGCOM      "Set to ON to build the FGCom application (default)" ON)
 183 option(ENABLE_FLITE      "Set to ON to build the Flite text-to-speech module" ON)
 184 option(ENABLE_QT         "Set to ON to build the internal Qt launcher" ON)
 185
 186 if(LOGGING)
 187     # nothing
 188 else()
 189     set(FG_NDEBUG 1)
 190 endif()
 191
 192 if(JSBSIM_TERRAIN)
 193    set(JSBSIM_USE_GROUNDREACTIONS 1)
 194 endif()
 195
 196 if(SP_FDMS)
 197     set(ENABLE_SP_FDM 1)
 198 endif()
 199
 200 if(ENABLE_FGCOM)
 201   set(ENABLE_IAX 1)
 202   include_directories(${PROJECT_SOURCE_DIR}/3rdparty/iaxclient/lib ) # for iaxclient.h
 203 endif()
 204
 205 # Setup MSVC 3rd party directories
 206 include( ConfigureMsvc3rdParty )
 207
 208 if(EVENT_INPUT)
 209     if(APPLE)
 210     elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 211         if(NOT UDEV_FOUND)
 212             message(WARNING "UDev not found, event input is disabled!")
 213             set(EVENT_INPUT 0)
 214         else()
 215             add_definitions(-DWITH_EVENTINPUT)
 216             set(EVENT_INPUT_LIBRARIES ${UDEV_LIBRARIES})
 217             message(STATUS "event-based input enabled. Using ${UDEV_LIBRARIES}")
 218         endif()
 219     else()
 220         message(WARNING "event-based input is not supported on this platform yet")
 221     endif()
 222
 223     # Keep PLIB INPUT enabled as long as EventInput does not replace current joystick configurations.
 224     set(ENABLE_PLIB_JOYSTICK 1)
 225 else(EVENT_INPUT)
 226     set(ENABLE_PLIB_JOYSTICK 1)
 227 endif(EVENT_INPUT)
 228
 229 # check required dependencies
 230 find_package(Boost   REQUIRED)
 231 find_package(ZLIB    REQUIRED)
 232 find_package(Threads REQUIRED)
 233 find_package(OpenGL  REQUIRED)
 234 find_package(OpenAL  REQUIRED)
 235 find_package(OpenSceneGraph 3.2.0 REQUIRED
 236   osgText
 237   osgSim
 238   osgDB
 239   osgParticle
 240   osgFX
 241   osgUtil
 242   osgViewer
 243   osgGA
 244 )
 245
 246 if (MSVC)
 247         find_package(CrashRpt)
 248         if (CRASHRPT_FOUND)
 249                 set(HAVE_CRASHRPT 1)
 250                 message(STATUS "Using CrashRpt")
 251         include_directories( ${CRASHRPT_INCLUDE_DIR})
 252         endif()
 253 endif()
 254
 255 ##############################################################################
 256 ## Sqlite3 setup
 257
 258 if (SYSTEM_SQLITE)
 259     find_package(SQLite3 REQUIRED)
 260
 261     message(STATUS "Using system SQLite3 library")
 262 else()
 263     set(SQLITE3_INCLUDED_DIR "${CMAKE_SOURCE_DIR}/3rdparty/sqlite3")
 264     # this target is defined in src/Navaids/CMakeLists.txt
 265     list(APPEND SQLITE3_LIBRARY fgsqlite3)
 266 endif (SYSTEM_SQLITE)
 267
 268 # Sqlite always depends on the threading lib
 269 list(APPEND SQLITE3_LIBRARY ${CMAKE_THREAD_LIBS_INIT})
 270
 271 ##############################################################################
 272 ## DBus setup
 273
 274 if (USE_DBUS)
 275     include(FindPkgConfig)
 276     if (PKG_CONFIG_FOUND)
 277         pkg_check_modules(DBUS dbus-1)
 278     endif (PKG_CONFIG_FOUND) #if we don't have pkg-config, assume we don't have libdbus-1-dev either http://packages.debian.org/sid/libdbus-1-dev
 279     if (DBUS_FOUND)
 280         set(HAVE_DBUS 1)
 281         message(STATUS "Using DBus")
 282         include_directories( ${DBUS_INCLUDE_DIRS})
 283     else()
 284         message(STATUS "DBus not found, screensaver control disabled")
 285     endif (DBUS_FOUND)
 286 else()
 287 endif (USE_DBUS)
 288
 289 # Sqlite always depends on the threading lib
 290 list(APPEND SQLITE3_LIBRARY ${CMAKE_THREAD_LIBS_INIT})
 291
 292 ##############################################################################
 293 ## Qt5 setup setup
 294 if (ENABLE_QT)
 295         message(STATUS "Qt launcher enabled, checking for Qt 5.1 / qmake")
 296         find_package(Qt5 5.1 COMPONENTS Widgets)
 297         if (Qt5Widgets_FOUND)
 298                 message(STATUS "Will enable Qt launcher GUI")
 299                 set(HAVE_QT 1)
 300         endif()
 301 endif (ENABLE_QT)
 302 ##############################################################################
 303
 304 find_package(PLIB REQUIRED puaux pu js fnt)
 305
 306 # FlightGear and SimGear versions need to match
 307 find_package(SimGear ${FLIGHTGEAR_VERSION} REQUIRED)
 308
 309 ##############################################################################
 310
 311 check_include_file(unistd.h   HAVE_UNISTD_H)
 312 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 313 check_include_file(windows.h  HAVE_WINDOWS_H)
 314
 315 if(ENABLE_PROFILE)
 316     find_package(GooglePerfTools REQUIRED)
 317     set(FG_HAVE_GPERFTOOLS 1)
 318     message(STATUS "Built-in profiler using gperftools available")
 319 endif()
 320
 321 if(ENABLE_RTI)
 322     message(STATUS "RTI: ENABLED")
 323     find_package(RTI)
 324     if(RTI_FOUND)
 325         set(FG_HAVE_HLA 1)
 326     endif(RTI_FOUND)
 327 else()
 328     message(STATUS "RTI: DISABLED")
 329 endif(ENABLE_RTI)
 330
 331 if(CMAKE_COMPILER_IS_GNUCXX)
 332     set(WARNING_FLAGS_CXX "-Wall")
 333     set(WARNING_FLAGS_C   "-Wall")
 334 endif(CMAKE_COMPILER_IS_GNUCXX)
 335
 336 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 337    set (WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual")
 338    set (WARNING_FLAGS_C   "-Wall")
 339 endif()
 340
 341 if(WIN32)
 342
 343     if(MSVC)
 344         # turn off various warnings
 345         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 346         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 347         # endforeach(warning)
 348
 349         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS -Dstrdup=_strdup")
 350         if (${MSVC_VERSION} GREATER 1599)
 351             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 352         endif (${MSVC_VERSION} GREATER 1599)
 353     endif(MSVC)
 354
 355     set(NOMINMAX 1)
 356 endif(WIN32)
 357
 358 set (BOOST_CXX_FLAGS "-DBOOST_MULTI_INDEX_DISABLE_SERIALIZATION -DBOOST_BIMAP_DISABLE_SERIALIZATION")
 359
 360 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS} -D_REENTRANT")
 361 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} -D_REENTRANT ${BOOST_CXX_FLAGS}")
 362 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 363
 364 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 365     ${Boost_INCLUDE_DIRS}
 366     ${ZLIB_INCLUDE_DIR}
 367     ${OPENGL_INCLUDE_DIR}
 368     ${OPENAL_INCLUDE_DIR}
 369     ${SIMGEAR_INCLUDE_DIRS}
 370     ${PLIB_INCLUDE_DIR}
 371     ${SQLITE3_INCLUDED_DIR} )
 372
 373 include_directories(${PROJECT_SOURCE_DIR})
 374 include_directories(${PROJECT_SOURCE_DIR}/src)
 375 # following is needed, because config.h is include 'bare', whereas
 376 # version.h is included as <Include/version.h> - this should be cleaned up
 377 include_directories(${PROJECT_BINARY_DIR}/src)
 378 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 379
 380 if (ENABLE_FLITE)
 381     include_directories(${PROJECT_SOURCE_DIR}/3rdparty/hts_engine_API/include )
 382     include_directories(${PROJECT_SOURCE_DIR}/3rdparty/flite_hts_engine/include )
 383 endif()
 384
 385 add_definitions(-DHAVE_CONFIG_H)
 386
 387 check_function_exists(mkfifo HAVE_MKFIFO)
 388
 389 # configure a header file to pass some of the CMake settings
 390 # to the source code
 391 configure_file (
 392     "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 393     "${PROJECT_BINARY_DIR}/src/Include/config.h"
 394 )
 395
 396 #and the same for the version header
 397 configure_file (
 398     "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 399     "${PROJECT_BINARY_DIR}/src/Include/version.h"
 400 )
 401
 402 add_subdirectory(3rdparty)
 403 add_subdirectory(utils)
 404 add_subdirectory(src)
 405 add_subdirectory(man)
 406
 407 #-----------------------------------------------------------------------------
 408 ### uninstall target
 409 #-----------------------------------------------------------------------------
 410 CONFIGURE_FILE(
 411     "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 412     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 413     IMMEDIATE @ONLY)
 414 ADD_CUSTOM_TARGET(uninstall
 415     "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")