CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8.11)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7
   8 if(COMMAND cmake_policy)
   9    if(POLICY CMP0054)
  10        cmake_policy(SET CMP0054 NEW)
  11    endif()
  12    # Mac RPATH policy
  13    if(POLICY CMP0042)
  14        cmake_policy(SET CMP0042 NEW)
  15    endif()
  16 endif()
  17
  18 if(APPLE)
  19         # using 10.7 because boost requires libc++ and 10.6 doesn't include it
  20         set(CMAKE_OSX_DEPLOYMENT_TARGET 10.7)
  21
  22         set(CMAKE_INSTALL_RPATH "@loader_path/../Frameworks")
  23         # when building, don't use the install RPATH already
  24         # (but later on when installing)
  25         SET(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
  26 endif()
  27
  28 project(FlightGear)
  29
  30 # We have some custom .cmake scripts not in the official distribution.
  31 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  32
  33 # Warning when build is not an out-of-source build.
  34 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  35 if(InSourceBuild)
  36     message(WARNING  "Avoid building inside the source tree!")
  37     message(WARNING  "Create a separate build directory instead (i.e. 'fgbuild') and call CMake from there: ")
  38     message(WARNING  "  mkdir ../fgbuild && cd ../fgbuild && cmake ${CMAKE_SOURCE_DIR}")
  39 endif(InSourceBuild)
  40
  41 include(GNUInstallDirs)
  42 # System detection/default settings
  43 include( DetectDistro )
  44 include( DetectBrowser )
  45
  46 set(CMAKE_DEBUG_POSTFIX          "d" CACHE STRING "add a postfix, usually d on windows")
  47 set(CMAKE_RELEASE_POSTFIX        ""  CACHE STRING "add a postfix, usually empty on windows")
  48 set(CMAKE_RELWITHDEBINFO_POSTFIX ""  CACHE STRING "add a postfix, usually empty on windows")
  49 set(CMAKE_MINSIZEREL_POSTFIX     ""  CACHE STRING "add a postfix, usually empty on windows")
  50
  51 # read 'version' file into a variable (stripping any newlines or spaces)
  52 file(READ version versionFile)
  53 if (NOT versionFile)
  54     message(FATAL_ERROR "Unable to determine FlightGear version. Version file is missing.")
  55 endif()
  56 string(STRIP "${versionFile}" FLIGHTGEAR_VERSION)
  57
  58 # FlightGear packaging (to build a source tarball)
  59 include( ConfigureCPack )
  60
  61 # FlightGear base package path
  62 if (FG_DATA_DIR)
  63     message(STATUS "Using explicit data directory for base package: ${FG_DATA_DIR}")
  64 else()
  65     set(FG_DATA_DIR "${CMAKE_INSTALL_PREFIX}/lib/FlightGear" CACHE PATH "Default location where data files are located")
  66     message(STATUS "Using default data directory for base package:  ${FG_DATA_DIR}")
  67 endif()
  68
  69 # Change the default build type to something fast
  70 if(NOT CMAKE_BUILD_TYPE)
  71     set(CMAKE_BUILD_TYPE Release CACHE STRING
  72         "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  73         FORCE)
  74 endif(NOT CMAKE_BUILD_TYPE)
  75
  76 if(NOT "$ENV{BUILD_ID}" STREQUAL "")
  77     set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  78     set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  79     message(STATUS "running under Hudson/Jenkins, build-number is ${HUDSON_BUILD_NUMBER}")
  80 else()
  81     set(HUDSON_BUILD_NUMBER 0)
  82     set(HUDSON_BUILD_ID "none")
  83 endif()
  84
  85 #####################################################################################
  86 # Configure library search paths
  87 #####################################################################################
  88
  89
  90 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  91     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  92     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  93     # add paths manually
  94     # see http://www.cmake.org/Bug/view.php?id=12049 and
  95     # http://www.cmake.org/Bug/view.php?id=12037
  96     list(APPEND ADDITIONAL_LIBRARY_PATHS
  97          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  98          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  99          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
 100     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
 101 endif()
 102
 103 #####################################################################################
 104
 105 IF(APPLE)
 106     set(EVENT_INPUT_DEFAULT 1)
 107
 108     find_library(CORESERVICES_LIBRARY CoreServices)
 109     find_library(COCOA_LIBRARY Cocoa)
 110     list(APPEND PLATFORM_LIBS ${COCOA_LIBRARY} ${CORESERVICES_LIBRARY})
 111
 112     # this should be handled by setting CMAKE_OSX_DEPLOYMENT_TARGET
 113     # but it's not working reliably, so forcing it for now
 114     SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.7")
 115     SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.7")
 116 elseif(${CMAKE_SYSTEM_NAME} MATCHES "Linux" OR
 117         ${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD")
 118     find_package(Threads REQUIRED)
 119     find_package(X11 REQUIRED)
 120
 121     set(USE_DBUS_DEFAULT 1)
 122
 123     find_package(UDev)
 124     if(UDEV_FOUND)
 125         set(EVENT_INPUT_DEFAULT 1)
 126     endif(UDEV_FOUND)
 127
 128     find_package(Speex)
 129     find_package(Speexdsp)
 130     if(SPEEX_FOUND AND SPEEXDSP_FOUND)
 131         set(SYSTEM_SPEEX_DEFAULT 1)
 132     endif(SPEEX_FOUND AND SPEEXDSP_FOUND)
 133
 134     find_package(Gsm)
 135     if(GSM_FOUND)
 136         set(SYSTEM_GSM_DEFAULT 1)
 137     endif(GSM_FOUND)
 138
 139     find_package(Flite)
 140     if(FLITE_FOUND)
 141         set(SYSTEM_FLITE_DEFAULT 1)
 142     endif()
 143
 144     find_package(HtsEngine)
 145     if(HTS_ENGINE_FOUND)
 146         set(SYSTEM_HTS_ENGINE_DEFAULT 1)
 147     endif()
 148 endif()
 149
 150 find_package(Git)
 151 if (GIT_FOUND)
 152     execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
 153         OUTPUT_VARIABLE REVISION
 154         OUTPUT_STRIP_TRAILING_WHITESPACE)
 155     message(STATUS "Git revision is ${REVISION}")
 156 else()
 157     set(REVISION "none")
 158 endif()
 159
 160 # FlightGear build options
 161 option(SIMGEAR_SHARED    "Set to ON when SimGear was built as a shared library" OFF)
 162 option(LOGGING           "Set to ON to build FlightGear with logging support (default)" ON)
 163 option(JSBSIM_TERRAIN    "Set to ON to build FlightGear with JSBSim terrain handling code" ON)
 164 option(SP_FDMS           "Set to ON to build FlightGear with special-purpose FDMs" ON)
 165 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" ON)
 166 option(ENABLE_LARCSIM    "Set to ON to build FlightGear with LaRCsim FDM" ON)
 167 option(ENABLE_YASIM      "Set to ON to build FlightGear with YASIM FDM (default)" ON)
 168 option(ENABLE_JSBSIM     "Set to ON to build FlightGear with JSBSim FDM (default)" ON)
 169 option(EVENT_INPUT       "Set to ON to build FlightGear with event-based Input support" ${EVENT_INPUT_DEFAULT})
 170 option(ENABLE_RTI        "Set to ON to build FlightGear with RTI support" OFF)
 171 option(ENABLE_PROFILE    "Set to ON to build FlightGear with gperftools profiling support" OFF)
 172 option(SYSTEM_SQLITE     "Set to ON to build FlightGear with the system's SQLite3 library" OFF)
 173 option(ENABLE_IAX        "Set to ON to build FlightGear with IAXClient/fgcom built-in (default)" ON)
 174 option(USE_DBUS          "Set to ON to build FlightGear with DBus screensaver interaction (default on Linux)" ${USE_DBUS_DEFAULT})
 175 option(SYSTEM_SPEEX      "Set to ON to build IAXClient with the system's speex and speexdsp library" ${SYSTEM_SPEEX_DEFAULT})
 176 option(SYSTEM_GSM        "Set to ON to build IAXClient with the system's GSM library" ${SYSTEM_GSM_DEFAULT})
 177 option(SYSTEM_FLITE      "Set to ON to build Flightgear with the system's Flite library" ${SYSTEM_FLITE_DEFAULT})
 178 option(SYSTEM_HTS_ENGINE "Set to ON to build Flightgear with the system's HTS Engine library" ${SYSTEM_HTS_ENGINE_DEFAULT})
 179 option(FG_NIGHTLY        "Set to ON to mark this as a nightly build" OFF)
 180 option(ENABLE_DEV_WARNINGS "Set to ON to include developer-warnings" OFF)
 181
 182 # additional utilities
 183 option(ENABLE_FGADMIN    "Set to ON to build the FGADMIN application (default)" ON)
 184 option(ENABLE_FGELEV     "Set to ON to build the fgelev application (default)" ON)
 185 option(WITH_FGPANEL      "Set to ON to build the fgpanel application (default)" ON)
 186 option(ENABLE_FGVIEWER   "Set to ON to build the fgviewer application (default)" ON)
 187 option(ENABLE_GPSSMOOTH  "Set to ON to build the GPSsmooth application (default)" ON)
 188 option(ENABLE_TERRASYNC  "Set to ON to build the terrasync application (default)" ON)
 189 option(ENABLE_FGJS       "Set to ON to build the fgjs application (default)" ON)
 190 option(ENABLE_JS_DEMO    "Set to ON to build the js_demo application (default)" ON)
 191 option(ENABLE_METAR      "Set to ON to build the metar application (default)" ON)
 192 option(ENABLE_TESTS      "Set to ON to build test applications (default)" ON)
 193 option(ENABLE_FGCOM      "Set to ON to build the FGCom application (default)" ON)
 194 option(ENABLE_FLITE      "Set to ON to build the Flite text-to-speech module" ON)
 195 option(ENABLE_QT         "Set to ON to build the internal Qt launcher" ON)
 196
 197 if(LOGGING)
 198     # nothing
 199 else()
 200     set(FG_NDEBUG 1)
 201 endif()
 202
 203 if(JSBSIM_TERRAIN)
 204    set(JSBSIM_USE_GROUNDREACTIONS 1)
 205 endif()
 206
 207 if(SP_FDMS)
 208     set(ENABLE_SP_FDM 1)
 209 endif()
 210
 211 if(ENABLE_FGCOM)
 212   set(ENABLE_IAX 1)
 213   include_directories(${PROJECT_SOURCE_DIR}/3rdparty/iaxclient/lib ) # for iaxclient.h
 214 endif()
 215
 216 # Setup MSVC 3rd party directories
 217 include( ConfigureMsvc3rdParty )
 218
 219 if(EVENT_INPUT)
 220     if(APPLE)
 221     elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 222         if(NOT UDEV_FOUND)
 223             message(WARNING "UDev not found, event input is disabled!")
 224             set(EVENT_INPUT 0)
 225         else()
 226             add_definitions(-DWITH_EVENTINPUT)
 227             set(EVENT_INPUT_LIBRARIES ${UDEV_LIBRARIES})
 228             message(STATUS "event-based input enabled. Using ${UDEV_LIBRARIES}")
 229         endif()
 230     else()
 231         message(WARNING "event-based input is not supported on this platform yet")
 232     endif()
 233
 234     # Keep PLIB INPUT enabled as long as EventInput does not replace current joystick configurations.
 235     set(ENABLE_PLIB_JOYSTICK 1)
 236 else(EVENT_INPUT)
 237     set(ENABLE_PLIB_JOYSTICK 1)
 238 endif(EVENT_INPUT)
 239
 240 # check required dependencies
 241 find_package(Boost   REQUIRED)
 242 find_package(ZLIB    REQUIRED)
 243 find_package(OpenGL  REQUIRED)
 244 find_package(OpenAL  REQUIRED)
 245 find_package(OpenSceneGraph 3.2.0 REQUIRED
 246   osgText
 247   osgSim
 248   osgDB
 249   osgParticle
 250   osgFX
 251   osgUtil
 252   osgViewer
 253   osgGA
 254 )
 255
 256 if (MSVC)
 257         find_package(CrashRpt)
 258         if (CRASHRPT_FOUND)
 259                 set(HAVE_CRASHRPT 1)
 260                 message(STATUS "Using CrashRpt")
 261         include_directories( ${CRASHRPT_INCLUDE_DIR})
 262         endif()
 263 endif()
 264
 265 ##############################################################################
 266 ## Sqlite3 setup
 267
 268 if (SYSTEM_SQLITE)
 269     find_package(SQLite3 REQUIRED)
 270
 271     message(STATUS "Using system SQLite3 library")
 272 else()
 273     set(SQLITE3_INCLUDED_DIR "${CMAKE_SOURCE_DIR}/3rdparty/sqlite3")
 274     # this target is defined in src/Navaids/CMakeLists.txt
 275     list(APPEND SQLITE3_LIBRARY fgsqlite3)
 276 endif (SYSTEM_SQLITE)
 277
 278 # Sqlite always depends on the threading lib
 279 list(APPEND SQLITE3_LIBRARY ${CMAKE_THREAD_LIBS_INIT})
 280
 281 ##############################################################################
 282 ## DBus setup
 283
 284 if (USE_DBUS)
 285     include(FindPkgConfig)
 286     if (PKG_CONFIG_FOUND)
 287         pkg_check_modules(DBUS dbus-1)
 288     endif (PKG_CONFIG_FOUND) #if we don't have pkg-config, assume we don't have libdbus-1-dev either http://packages.debian.org/sid/libdbus-1-dev
 289     if (DBUS_FOUND)
 290         set(HAVE_DBUS 1)
 291         message(STATUS "Using DBus")
 292         include_directories( ${DBUS_INCLUDE_DIRS})
 293     else()
 294         message(STATUS "DBus not found, screensaver control disabled")
 295     endif (DBUS_FOUND)
 296 else()
 297 endif (USE_DBUS)
 298
 299 ##############################################################################
 300 ## Qt5 setup setup
 301 if (ENABLE_QT)
 302         message(STATUS "Qt launcher enabled, checking for Qt 5.1 / qmake")
 303         find_package(Qt5 5.1 COMPONENTS Widgets)
 304         if (Qt5Widgets_FOUND)
 305                 message(STATUS "Will enable Qt launcher GUI")
 306                 message(STATUS "  Qt5Widgets version: ${Qt5Widgets_VERSION_STRING}")
 307                 message(STATUS "  Qt5Widgets include dir: ${Qt5Widgets_INCLUDE_DIRS}")
 308                 set(HAVE_QT 1)
 309         endif()
 310 endif (ENABLE_QT)
 311 ##############################################################################
 312
 313 find_package(PLIB REQUIRED puaux pu js fnt)
 314
 315 # FlightGear and SimGear versions need to match
 316 find_package(SimGear ${FLIGHTGEAR_VERSION} REQUIRED)
 317
 318 ##############################################################################
 319
 320 check_include_file(unistd.h   HAVE_UNISTD_H)
 321 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 322 check_include_file(windows.h  HAVE_WINDOWS_H)
 323
 324 if(ENABLE_PROFILE)
 325     find_package(GooglePerfTools REQUIRED)
 326     set(FG_HAVE_GPERFTOOLS 1)
 327     message(STATUS "Built-in profiler using gperftools available")
 328 endif()
 329
 330 if(ENABLE_RTI)
 331     message(STATUS "RTI: ENABLED")
 332     find_package(RTI)
 333     if(RTI_FOUND)
 334         set(FG_HAVE_HLA 1)
 335     endif(RTI_FOUND)
 336 else()
 337     message(STATUS "RTI: DISABLED")
 338 endif(ENABLE_RTI)
 339
 340 if(CMAKE_COMPILER_IS_GNUCXX)
 341     set(WARNING_FLAGS_CXX "-Wall")
 342     set(WARNING_FLAGS_C   "-Wall")
 343 endif(CMAKE_COMPILER_IS_GNUCXX)
 344
 345 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 346    set(WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual \
 347      -Wno-redeclared-class-member \
 348      -Wno-inconsistent-missing-override \
 349      -Wno-unused-local-typedef")
 350
 351    set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LIBRARY "libc++")
 352    set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LANGUAGE_STANDARD "c++11")
 353    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -stdlib=libc++")
 354    set(WARNING_FLAGS_C "-Wall")
 355 endif()
 356
 357 if(WIN32)
 358
 359     if(MSVC)
 360         # turn off various warnings
 361         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 362         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 363         # endforeach(warning)
 364
 365         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS -Dstrdup=_strdup")
 366         if (${MSVC_VERSION} GREATER 1599)
 367             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 368         endif (${MSVC_VERSION} GREATER 1599)
 369     endif(MSVC)
 370
 371     set(NOMINMAX 1)
 372 endif(WIN32)
 373
 374 set (BOOST_CXX_FLAGS "-DBOOST_BIMAP_DISABLE_SERIALIZATION")
 375
 376 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS} -D_REENTRANT")
 377 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} -D_REENTRANT ${BOOST_CXX_FLAGS}")
 378 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 379
 380 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 381     ${Boost_INCLUDE_DIRS}
 382     ${ZLIB_INCLUDE_DIR}
 383     ${OPENGL_INCLUDE_DIR}
 384     ${OPENAL_INCLUDE_DIR}
 385     ${SIMGEAR_INCLUDE_DIRS}
 386     ${PLIB_INCLUDE_DIR}
 387     ${SQLITE3_INCLUDED_DIR} )
 388
 389 include_directories(${PROJECT_SOURCE_DIR})
 390 include_directories(${PROJECT_SOURCE_DIR}/src)
 391 # following is needed, because config.h is include 'bare', whereas
 392 # version.h is included as <Include/version.h> - this should be cleaned up
 393 include_directories(${PROJECT_BINARY_DIR}/src)
 394 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 395
 396 if (ENABLE_FLITE)
 397     include_directories(${PROJECT_SOURCE_DIR}/3rdparty/hts_engine_API/include )
 398     include_directories(${PROJECT_SOURCE_DIR}/3rdparty/flite_hts_engine/include )
 399 endif()
 400
 401 add_definitions(-DHAVE_CONFIG_H)
 402
 403 check_function_exists(mkfifo HAVE_MKFIFO)
 404
 405 # configure a header file to pass some of the CMake settings
 406 # to the source code
 407 configure_file (
 408     "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 409     "${PROJECT_BINARY_DIR}/src/Include/config.h"
 410 )
 411
 412 #and the same for the version header
 413 configure_file (
 414     "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 415     "${PROJECT_BINARY_DIR}/src/Include/version.h"
 416 )
 417
 418 add_subdirectory(3rdparty)
 419 add_subdirectory(utils)
 420 add_subdirectory(src)
 421 add_subdirectory(man)
 422
 423 #-----------------------------------------------------------------------------
 424 ### uninstall target
 425 #-----------------------------------------------------------------------------
 426 CONFIGURE_FILE(
 427     "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 428     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 429     IMMEDIATE @ONLY)
 430 ADD_CUSTOM_TARGET(uninstall
 431     "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")