CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6)
   2 include (CheckFunctionExists)
   3 include (CheckIncludeFile)
   4 include (CheckCXXSourceCompiles)
   5 include (CPack)
   6
   7 project(SimGear)
   8
   9 # read 'version' file into a variable (stripping any newlines or spaces)
  10 file(READ version versionFile)
  11 string(STRIP ${versionFile} SIMGEAR_VERSION)
  12
  13 #packaging
  14 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  15 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  16
  17 # We have some custom .cmake scripts not in the official distribution.
  18 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  19
  20 option(SIMGEAR_SHARED "Set to ON to build SimGear as a shared library/framework" OFF)
  21 option(SIMGEAR_HEADLESS "Set to ON to build SimGear with GUI/graphics support" OFF)
  22 option(JPEG_FACTORY "Enable JPEG-factory support" OFF)
  23 option(ENABLE_LIBSVN "Set to ON to build SimGear with libsvnclient support" OFF)
  24
  25 set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
  26
  27 if (MSVC AND MSVC_3RDPARTY_ROOT)
  28   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_ROOT}")
  29   set( OSG_MSVC "msvc" )
  30   if (${MSVC_VERSION} EQUAL 1600)
  31       set( OSG_MSVC ${OSG_MSVC}100 )
  32   else (${MSVC_VERSION} EQUAL 1600)
  33       set( OSG_MSVC ${OSG_MSVC}90 )
  34   endif (${MSVC_VERSION} EQUAL 1600)
  35   if (CMAKE_CL_64)
  36       set( OSG_MSVC ${OSG_MSVC}-64 )
  37       set( MSVC_3RDPARTY_DIR 3rdParty.x64 )
  38   else (CMAKE_CL_64)
  39       set( MSVC_3RDPARTY_DIR 3rdParty )
  40   endif (CMAKE_CL_64)
  41
  42   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/lib )
  43   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/include)
  44   set (BOOST_ROOT ${MSVC_3RDPARTY_ROOT}/boost_1_44_0)
  45   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
  46   set (ALUT_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
  47   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib)
  48 endif (MSVC AND MSVC_3RDPARTY_ROOT)
  49
  50 find_package(Boost REQUIRED)
  51 set (BOOST_CXX_FLAGS "-DBOOST_MULTI_INDEX_DISABLE_SERIALIZATION -DBOOST_BIMAP_DISABLE_SERIALIZATION")
  52
  53 find_package(ZLIB REQUIRED)
  54 find_package(Threads REQUIRED)
  55
  56 if (${SIMGEAR_HEADLESS})
  57     message(STATUS "headlesss mode")
  58     set(NO_OPENSCENEGRAPH_INTERFACE 1)
  59 else()
  60     find_package(OpenGL REQUIRED)
  61     find_package(OpenAL REQUIRED)
  62     find_package(ALUT REQUIRED)
  63     find_package(OpenSceneGraph 2.8.1 REQUIRED osgText osgSim osgDB osgParticle osgUtil)
  64 endif()
  65
  66 if(JPEG_FACTORY)
  67     message(STATUS "JPEG-factory enabled")
  68     find_package(JPEG REQUIRED)
  69     include_directories(${JPEG_INCLUDE_DIR})
  70 endif()
  71
  72 if(ENABLE_LIBSVN)
  73         find_package(SvnClient)
  74
  75         if(LIBSVN_FOUND)
  76                 message(STATUS "libsvn found, enabling in SimGear")
  77                 set(HAVE_SVN_CLIENT_H 1)
  78                 set(HAVE_LIBSVN_CLIENT_1 1)
  79         endif(LIBSVN_FOUND)
  80 endif(ENABLE_LIBSVN)
  81
  82 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  83 check_include_file(sys/timeb.h HAVE_SYS_TIMEB_H)
  84 check_include_file(unistd.h HAVE_UNISTD_H)
  85 check_include_file(windows.h HAVE_WINDOWS_H)
  86
  87 # See if we have any rti library variant installed
  88 find_package(RTI)
  89
  90 check_function_exists(gettimeofday HAVE_GETTIMEOFDAY)
  91 check_function_exists(ftime HAVE_FTIME)
  92 check_function_exists(timegm HAVE_TIMEGM)
  93 check_function_exists(rint HAVE_RINT)
  94
  95
  96 if(HAVE_UNISTD_H)
  97     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
  98     check_cxx_source_compiles(
  99        "#include <unistd.h>
 100         #if !defined(_POSIX_TIMERS) || (0 >= _POSIX_TIMERS)
 101             #error clock_gettime is not supported
 102         #endif
 103
 104         int main() { return 0; }
 105         "
 106         HAVE_CLOCK_GETTIME)
 107 endif(HAVE_UNISTD_H)
 108
 109 set(RT_LIBRARY "")
 110 if(HAVE_CLOCK_GETTIME)
 111     check_function_exists(clock_gettime CLOCK_GETTIME_IN_LIBC)
 112     if(NOT CLOCK_GETTIME_IN_LIBC)
 113         check_library_exists(rt clock_gettime "" HAVE_RT)
 114         if(HAVE_RT)
 115             set(RT_LIBRARY rt)
 116         endif(HAVE_RT)
 117         endif(NOT CLOCK_GETTIME_IN_LIBC)
 118 endif(HAVE_CLOCK_GETTIME)
 119
 120 SET(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "add a postfix, usually d on windows")
 121 SET(CMAKE_RELEASE_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 122 SET(CMAKE_RELWITHDEBINFO_POSTFIX "rd" CACHE STRING "add a postfix, usually empty on windows")
 123 SET(CMAKE_MINSIZEREL_POSTFIX "s" CACHE STRING "add a postfix, usually empty on windows")
 124
 125 # isnan might not be real symbol, so can't check using function_exists
 126 check_cxx_source_compiles(
 127     "#include <cmath>
 128     void f() { isnan(0.0);} "
 129     HAVE_ISNAN)
 130
 131 if(CMAKE_COMPILER_IS_GNUCXX)
 132     set(WARNING_FLAGS -Wall)
 133 endif(CMAKE_COMPILER_IS_GNUCXX)
 134
 135 if(WIN32)
 136
 137     if(MSVC)
 138         # turn off various warnings
 139         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 140         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 141         # endforeach(warning)
 142
 143         set(MSVC_FLAGS "-DWIN32 -DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS")
 144     endif(MSVC)
 145
 146     # assumed on Windows
 147     set(HAVE_GETLOCALTIME 1)
 148 endif(WIN32)
 149
 150 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS}")
 151 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS} ${BOOST_CXX_FLAGS}")
 152
 153 include_directories(${PROJECT_SOURCE_DIR})
 154 include_directories(${PROJECT_BINARY_DIR}/simgear)
 155
 156 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 157     ${Boost_INCLUDE_DIRS} ${ZLIB_INCLUDE_DIR}
 158     ${ALUT_INCLUDE_DIR} ${OPENAL_INCLUDE_DIR} )
 159
 160
 161 add_definitions(-DHAVE_CONFIG_H)
 162
 163 # configure a header file to pass some of the CMake settings
 164 # to the source code
 165 configure_file (
 166   "${PROJECT_SOURCE_DIR}/simgear/simgear_config_cmake.h.in"
 167   "${PROJECT_BINARY_DIR}/simgear/simgear_config.h"
 168   )
 169
 170 # enable CTest / make test target
 171
 172 include (Dart)
 173 enable_testing()
 174
 175 install (FILES ${PROJECT_BINARY_DIR}/simgear/simgear_config.h  DESTINATION include/simgear/)
 176 add_subdirectory(simgear)
 177
 178 #-----------------------------------------------------------------------------
 179 ### uninstall target
 180 #-----------------------------------------------------------------------------
 181 CONFIGURE_FILE(
 182   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 183   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 184   IMMEDIATE @ONLY)
 185 ADD_CUSTOM_TARGET(uninstall
 186   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
 187
 188
 189