CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7
   8 project(FlightGear)
   9
  10 # We have some custom .cmake scripts not in the official distribution.
  11 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  12
  13 if(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  14     # use official include provided by latest CMake
  15     include(GNUInstallDirs)
  16 else(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  17     # backward compatibility: use our own module for older cmake versions
  18     include(OldGNUInstallDirs)
  19 endif(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  20
  21 # Warning when build is not an out-of-source build.
  22 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  23 if(InSourceBuild)
  24     message(WARNING  "Avoid building inside the source tree!")
  25     message(WARNING  "Create a separate build directory instead (i.e. 'fgbuild') and call CMake from there: ")
  26     message(WARNING  "  mkdir ../fgbuild && cd ../fgbuild && cmake ${CMAKE_SOURCE_DIR}")
  27 endif(InSourceBuild)
  28
  29 # System detection/default settings
  30 include( DetectDistro )
  31
  32 set(CMAKE_DEBUG_POSTFIX          "d" CACHE STRING "add a postfix, usually d on windows")
  33 set(CMAKE_RELEASE_POSTFIX        ""  CACHE STRING "add a postfix, usually empty on windows")
  34 set(CMAKE_RELWITHDEBINFO_POSTFIX ""  CACHE STRING "add a postfix, usually empty on windows")
  35 set(CMAKE_MINSIZEREL_POSTFIX     ""  CACHE STRING "add a postfix, usually empty on windows")
  36
  37 # read 'version' file into a variable (stripping any newlines or spaces)
  38 file(READ version versionFile)
  39 string(STRIP ${versionFile} FLIGHTGEAR_VERSION)
  40
  41 # FlightGear packaging (to build a source tarball)
  42 include( ConfigureCPack )
  43
  44 # FlightGear base package path
  45 if (FG_DATA_DIR)
  46     message(STATUS "Using explicit data directory for base package: ${FG_DATA_DIR}")
  47 else()
  48     set(FG_DATA_DIR "${CMAKE_INSTALL_PREFIX}/lib/FlightGear" CACHE PATH "Default location where data files are located")
  49     message(STATUS "Using default data directory for base package:  ${FG_DATA_DIR}")
  50 endif()
  51
  52 # Change the default build type to something fast
  53 if(NOT CMAKE_BUILD_TYPE)
  54     set(CMAKE_BUILD_TYPE Release CACHE STRING
  55         "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  56         FORCE)
  57 endif(NOT CMAKE_BUILD_TYPE)
  58
  59 if(NOT "$ENV{BUILD_ID}" STREQUAL "")
  60     set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  61     set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  62     message(STATUS "running under Hudson, build-number is ${HUDSON_BUILD_NUMBER}")
  63 else()
  64     set(HUDSON_BUILD_NUMBER 0)
  65     set(HUDSON_BUILD_ID "none")
  66 endif()
  67
  68 IF(APPLE)
  69     set(EVENT_INPUT_DEFAULT 1)
  70
  71     find_library(CORESERVICES_LIBRARY CoreServices)
  72     find_library(COCOA_LIBRARY Cocoa)
  73     list(APPEND PLATFORM_LIBS ${COCOA_LIBRARY} ${CORESERVICES_LIBRARY})
  74
  75 elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
  76     find_package(UDev)
  77
  78     if(UDEV_FOUND)
  79         set(EVENT_INPUT_DEFAULT 1)
  80     endif(UDEV_FOUND)
  81 endif()
  82
  83 find_package(Git)
  84 if (GIT_FOUND)
  85     execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
  86         OUTPUT_VARIABLE REVISION
  87         OUTPUT_STRIP_TRAILING_WHITESPACE)
  88     message(STATUS "Git revision is ${REVISION}")
  89 else()
  90     set(REVISION "none")
  91 endif()
  92
  93 option(LOGGING           "Set to OFF to build FlightGear without logging" ON)
  94 option(SP_FDMS           "Set to ON to build FlightGear with special-purpose FDMs" OFF)
  95 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" OFF)
  96 option(ENABLE_LARCSIM    "Set to ON to build FlightGear with LaRCsim FDM" OFF)
  97 option(ENABLE_YASIM      "Set to ON to build FlightGear with YASIM FDM" ON)
  98 option(ENABLE_JSBSIM     "Set to ON to build FlightGear with JSBSim FDM" ON)
  99 option(ENABLE_FGADMIN    "Set to ON to build FlightGear with FGADMIN" ON)
 100 option(EVENT_INPUT       "Set to ON to build FlightGear with event-based Input support" ${EVENT_INPUT_DEFAULT})
 101 option(ENABLE_LIBSVN     "Set to ON to build FlightGear/terrasync with libsvnclient support" ON)
 102 option(ENABLE_RTI        "Set to ON to build SimGear with RTI support" OFF)
 103 option(WITH_FGPANEL      "Set to ON to build the fgpanel application" ON)
 104 option(JPEG_FACTORY      "Enable JPEG-factory support" OFF)
 105 option(ENABLE_TESTS      "Set to OFF to disable building test applications" ON)
 106
 107 if(LOGGING)
 108     # nothing
 109 else()
 110     set(FG_NDEBUG 1)
 111 endif()
 112
 113 if(SP_FDMS)
 114     set(ENABLE_SP_FDM 1)
 115 endif()
 116
 117 # Setup MSVC 3rd party directories
 118 include( ConfigureMsvc3rdParty )
 119
 120 if(EVENT_INPUT)
 121     if(APPLE)
 122     elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 123         if(NOT UDEV_FOUND)
 124             message(WARNING "UDev not found, event input is disabled!")
 125             set(EVENT_INPUT 0)
 126         else()
 127             set(EVENT_INPUT_LIBRARIES ${UDEV_LIBRARIES})
 128             message(STATUS "event-based input enabled. Using ${UDEV_LIBRARIES}")
 129         endif()
 130     else()
 131         message(WARNING "event-based input is not supported on this platform yet")
 132     endif()
 133
 134     # Keep PLIB INPUT enabled as long as EventInput does not replace current joystick configurations.
 135     set(ENABLE_PLIB_JOYSTICK 1)
 136 else(EVENT_INPUT)
 137     set(ENABLE_PLIB_JOYSTICK 1)
 138 endif(EVENT_INPUT)
 139
 140 # check required dependencies
 141 find_package(Boost   REQUIRED)
 142 find_package(ZLIB    REQUIRED)
 143 find_package(Threads REQUIRED)
 144 find_package(OpenGL  REQUIRED)
 145 find_package(OpenAL  REQUIRED)
 146 find_package(ALUT    REQUIRED)
 147 find_package(OpenSceneGraph 3.0.0 REQUIRED osgText osgSim osgDB osgParticle osgFX osgUtil osgViewer osgGA)
 148
 149 if(ENABLE_FGADMIN)
 150     find_package(FLTK)
 151
 152     if ( FLTK_FOUND )
 153         if ( X11_Xinerama_FOUND )
 154             message(STATUS "Found X11_Xinerama...")
 155             list(APPEND FLTK_LIBRARIES ${X11_Xinerama_LIB})
 156         endif()
 157
 158         if ( X11_Xft_FOUND )
 159             message(STATUS "Found X11_Xft...")
 160             list(APPEND FLTK_LIBRARIES ${X11_Xft_LIB})
 161         endif()
 162
 163         message(STATUS "Using FLTK_LIBRARIES for fgadmin: ${FLTK_LIBRARIES}")
 164     endif ( FLTK_FOUND )
 165 endif(ENABLE_FGADMIN)
 166
 167 if(ENABLE_LIBSVN)
 168     find_package(SvnClient)
 169
 170     if(LIBSVN_FOUND)
 171         message(STATUS "libsvn found, enabling in terrasync")
 172         set(HAVE_SVN_CLIENT_H 1)
 173         set(HAVE_LIBSVN_CLIENT_1 1)
 174     else()
 175         message(STATUS "libsvn missing. Disabling...")
 176     endif(LIBSVN_FOUND)
 177 endif(ENABLE_LIBSVN)
 178
 179 find_package(PLIB REQUIRED puaux pu js fnt)
 180
 181 # FlightGear and SimGear versions need to match
 182 find_package(SimGear ${FLIGHTGEAR_VERSION} REQUIRED)
 183
 184 if (JPEG_FACTORY)
 185     # check simgear was built with JPEG-factory support
 186     find_package(JPEG REQUIRED)
 187     include_directories(${JPEG_INCLUDE_DIR})
 188
 189     set(CMAKE_REQUIRED_INCLUDES
 190         ${SIMGEAR_INCLUDE_DIR}
 191         ${JPEG_INCLUDE_DIR}
 192         ${OPENSCENEGRAPH_INCLUDE_DIRS})
 193
 194     check_cxx_source_compiles(
 195         "#include <simgear/screen/jpgfactory.hxx>
 196         int main()    { return 0; } "
 197         FG_JPEG_SERVER)
 198
 199     if (NOT FG_JPEG_SERVER)
 200         message(STATUS "JPEG server support requested, but SimGear was built without JPEG support")
 201     endif()
 202 endif()
 203
 204 check_include_file(unistd.h   HAVE_UNISTD_H)
 205 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 206 check_include_file(windows.h  HAVE_WINDOWS_H)
 207
 208 if(ENABLE_RTI)
 209     find_package(RTI)
 210     if(RTI_FOUND)
 211         set(FG_HAVE_HLA 1)
 212     endif(RTI_FOUND)
 213 endif(ENABLE_RTI)
 214
 215 if(CMAKE_COMPILER_IS_GNUCXX)
 216     set(WARNING_FLAGS_CXX "-Wall")
 217     set(WARNING_FLAGS_C   "-Wall")
 218 endif(CMAKE_COMPILER_IS_GNUCXX)
 219
 220 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 221    set (WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual")
 222    set (WARNING_FLAGS_C   "-Wall")
 223 endif()
 224
 225 if(WIN32)
 226
 227     if(MSVC)
 228         # turn off various warnings
 229         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 230         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 231         # endforeach(warning)
 232
 233         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS")
 234         if (${MSVC_VERSION} EQUAL 1600)
 235             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 236         endif (${MSVC_VERSION} EQUAL 1600)
 237     endif(MSVC)
 238
 239     set(NOMINMAX 1)
 240 endif(WIN32)
 241
 242 set (BOOST_CXX_FLAGS "-DBOOST_MULTI_INDEX_DISABLE_SERIALIZATION -DBOOST_BIMAP_DISABLE_SERIALIZATION")
 243
 244 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS} -D_REENTRANT")
 245 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} -D_REENTRANT ${BOOST_CXX_FLAGS}")
 246 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 247
 248 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 249     ${Boost_INCLUDE_DIRS}
 250     ${ZLIB_INCLUDE_DIR}
 251     ${ALUT_INCLUDE_DIR}
 252     ${OPENGL_INCLUDE_DIR}
 253     ${OPENAL_INCLUDE_DIR}
 254     ${SIMGEAR_INCLUDE_DIR}
 255     ${PLIB_INCLUDE_DIR} )
 256
 257 include_directories(${PROJECT_SOURCE_DIR}/src)
 258
 259 # following is needed, because config.h is include 'bare', whereas
 260 # version.h is included as <Include/version.h> - this should be cleaned up
 261 include_directories(${PROJECT_BINARY_DIR}/src)
 262 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 263
 264 add_definitions(-DHAVE_CONFIG_H)
 265
 266 check_function_exists(mkfifo HAVE_MKFIFO)
 267
 268 # configure a header file to pass some of the CMake settings
 269 # to the source code
 270 configure_file (
 271     "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 272     "${PROJECT_BINARY_DIR}/src/Include/config.h"
 273 )
 274
 275 #and the same for the version header
 276 configure_file (
 277     "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 278     "${PROJECT_BINARY_DIR}/src/Include/version.h"
 279 )
 280
 281 add_subdirectory(src)
 282 add_subdirectory(utils)
 283 add_subdirectory(man)
 284
 285 #-----------------------------------------------------------------------------
 286 ### uninstall target
 287 #-----------------------------------------------------------------------------
 288 CONFIGURE_FILE(
 289     "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 290     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 291     IMMEDIATE @ONLY)
 292 ADD_CUSTOM_TARGET(uninstall
 293     "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")