CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7 include (CPack)
   8
   9 project(FlightGear)
  10
  11 set(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "add a postfix, usually d on windows")
  12 set(CMAKE_RELEASE_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
  13 set(CMAKE_RELWITHDEBINFO_POSTFIX "rd" CACHE STRING "add a postfix, usually empty on windows")
  14 set(CMAKE_MINSIZEREL_POSTFIX "s" CACHE STRING "add a postfix, usually empty on windows")
  15
  16 # read 'version' file into a variable (stripping any newlines or spaces)
  17 file(READ version versionFile)
  18 string(STRIP ${versionFile} FLIGHTGEAR_VERSION)
  19
  20 #packaging
  21 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  22 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  23
  24 # We have some custom .cmake scripts not in the official distribution.
  25 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  26
  27 # autoconf compatibility
  28 set(PKGLIBDIR "foo")
  29
  30 if($ENV{BUILD_ID})
  31         set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  32         set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  33         message(STATUS "running under Hudson, build-number is ${HUDSON_BUILD_NUMBER}")
  34 else()
  35         set(HUDSON_BUILD_NUMBER 0)
  36         set(HUDSON_BUILD_ID "none")
  37 endif()
  38
  39 find_package(Git)
  40 if (GIT_FOUND)
  41         execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
  42                 OUTPUT_VARIABLE REVISION
  43                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  44         message(STATUS "Git revision is ${REVISION}")
  45 else()
  46         set(REVISION "none")
  47 endif()
  48
  49 option(LOGGING "Set to OFF to build FlightGear without logging" ON)
  50
  51 option(SP_FDMS "Set to ON to build FlightGear with special-purpose FDMs" OFF)
  52 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" ON)
  53 option(ENABLE_LARCSIM "Set to ON to build FlightGear with LaRCsim FDM" ON)
  54 option(ENABLE_YASIM "Set to ON to build FlightGear with YASIM FDM" ON)
  55 option(ENABLE_JSBSIM "Set to ON to build FlightGear with JSBSim FDM" ON)
  56 option(ENABLE_FGADMIN "Set to ON to build FlightGear with FGADMIN" ON)
  57 option(EVENT_INPUT "Set to ON to build FlightGear with event-based Input support" OFF)
  58 option(ENABLE_LIBSVN "Set to ON to build FlightGear/terrasync with libsvnclient support" ON)
  59 option(ENABLE_RTI "Set to ON to build SimGear with RTI support" OFF)
  60 option(WITH_FGPANEL "Set to ON to build the fgpanel application" ON)
  61
  62 set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
  63
  64 if(LOGGING)
  65         # nothing
  66 else()
  67         set(FG_NDEBUG 1)
  68 endif()
  69
  70 if(SP_FDMS)
  71         set(ENABLE_SP_FDM 1)
  72 endif()
  73
  74 if(EVENT_INPUT)
  75         message(STATUS "checking event-based Input")
  76         find_package(DBus)
  77         IF(APPLE)
  78
  79         elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
  80
  81         else()
  82                 message(WARNING "event input is not supported on this platform yet")
  83         endif()
  84 else(EVENT_INPUT)
  85         set(ENABLE_PLIB_JOYSTICK 1)
  86 endif(EVENT_INPUT)
  87
  88 if (MSVC AND MSVC_3RDPARTY_ROOT)
  89   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_ROOT}")
  90   set( OSG_MSVC "msvc" )
  91   if (${MSVC_VERSION} EQUAL 1600)
  92       set( OSG_MSVC ${OSG_MSVC}100 )
  93   else (${MSVC_VERSION} EQUAL 1600)
  94       set( OSG_MSVC ${OSG_MSVC}90 )
  95   endif (${MSVC_VERSION} EQUAL 1600)
  96   if (CMAKE_CL_64)
  97       set( OSG_MSVC ${OSG_MSVC}-64 )
  98           set( MSVC_3RDPARTY_DIR 3rdParty.x64 )
  99   else (CMAKE_CL_64)
 100           set( MSVC_3RDPARTY_DIR 3rdParty )
 101   endif (CMAKE_CL_64)
 102
 103   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/SimGear/lib )
 104   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/SimGear/include)
 105   set (BOOST_ROOT ${MSVC_3RDPARTY_ROOT}/boost_1_44_0)
 106   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 107   set (ALUT_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 108   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib)
 109 endif (MSVC AND MSVC_3RDPARTY_ROOT)
 110
 111
 112 # check required dependencies
 113 find_package(Boost REQUIRED)
 114 find_package(ZLIB REQUIRED)
 115 find_package(Threads REQUIRED)
 116 find_package(OpenGL REQUIRED)
 117 find_package(OpenAL REQUIRED)
 118 find_package(ALUT REQUIRED)
 119 find_package(OpenSceneGraph 2.8.1 REQUIRED osgText osgSim osgDB osgParticle osgFX osgUtil osgViewer osgGA)
 120
 121 if(ENABLE_FGADMIN)
 122   find_package(FLTK)
 123 endif(ENABLE_FGADMIN)
 124
 125 if(ENABLE_LIBSVN)
 126         find_package(SvnClient)
 127
 128         if(LIBSVN_FOUND)
 129                 message(STATUS "libsvn found, enabling in terrasync")
 130                 set(HAVE_SVN_CLIENT_H 1)
 131                 set(HAVE_LIBSVN_CLIENT_1 1)
 132         endif(LIBSVN_FOUND)
 133 endif(ENABLE_LIBSVN)
 134
 135 find_package(PLIB REQUIRED puaux pu js fnt)
 136 find_package(SimGear 2.5.0 REQUIRED)
 137
 138 check_include_file(unistd.h HAVE_UNISTD_H)
 139 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 140 check_include_file(windows.h HAVE_WINDOWS_H)
 141
 142 # definition depends on OSG version
 143 set(CMAKE_REQUIRED_INCLUDES ${OPENSCENEGRAPH_INCLUDE_DIRS})
 144
 145 check_cxx_source_compiles(
 146     "#include <osg/CullSettings>
 147     int main()
 148     {
 149        osg::CullSettings::VariablesMask mask = osg::CullSettings::CLEAR_MASK;
 150        return 0;
 151     }
 152     "
 153     HAVE_CULLSETTINGS_CLEAR_MASK)
 154
 155 # library required by simgear
 156 # XXX This should go in a module and only run if simgear is not shared.
 157
 158 if(HAVE_UNISTD_H)
 159 set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 160 check_cxx_source_compiles(
 161    "#include <unistd.h>
 162     #if !defined(_POSIX_TIMERS) || (0 >= _POSIX_TIMERS)
 163     #error clock_gettime is not supported
 164     #endif
 165
 166     int main() { return 0; }
 167     "
 168     HAVE_CLOCK_GETTIME)
 169 endif(HAVE_UNISTD_H)
 170
 171 set(RT_LIBRARY "")
 172 if(HAVE_CLOCK_GETTIME)
 173 check_function_exists(clock_gettime CLOCK_GETTIME_IN_LIBC)
 174 if(NOT CLOCK_GETTIME_IN_LIBC)
 175 check_library_exists(rt clock_gettime "" HAVE_RT)
 176 if(HAVE_RT)
 177 set(RT_LIBRARY rt)
 178 endif(HAVE_RT)
 179 endif(NOT CLOCK_GETTIME_IN_LIBC)
 180 endif(HAVE_CLOCK_GETTIME)
 181
 182 if(ENABLE_RTI)
 183     find_package(RTI)
 184     if(RTI_FOUND)
 185         set(FG_HAVE_HLA 1)
 186     endif(RTI_FOUND)
 187 endif(ENABLE_RTI)
 188
 189 if(CMAKE_COMPILER_IS_GNUCXX)
 190     set(WARNING_FLAGS -Wall)
 191 endif(CMAKE_COMPILER_IS_GNUCXX)
 192
 193 if(WIN32)
 194
 195     if(MSVC)
 196         # turn off various warnings
 197         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 198         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 199         # endforeach(warning)
 200
 201         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS")
 202         if (${MSVC_VERSION} EQUAL 1600)
 203                   set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 204         endif (${MSVC_VERSION} EQUAL 1600)
 205     endif(MSVC)
 206
 207     set(NOMINMAX 1)
 208     set( WINSOCK_LIBRARY "ws2_32.lib" )
 209 endif(WIN32)
 210
 211 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS} -D_REENTRANT")
 212 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS} -D_REENTRANT")
 213 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 214
 215 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 216     ${Boost_INCLUDE_DIRS}
 217         ${ZLIB_INCLUDE_DIR}
 218     ${ALUT_INCLUDE_DIR}
 219         ${OPENAL_INCLUDE_DIR}
 220         ${SIMGEAR_INCLUDE_DIR}
 221         ${PLIB_INCLUDE_DIR} )
 222
 223 include_directories(${PROJECT_SOURCE_DIR}/src)
 224
 225 # following is needed, because config.h is include 'bare', whereas
 226 # version.h is included as <Include/version.h> - this should be cleaned up
 227 include_directories(${PROJECT_BINARY_DIR}/src)
 228 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 229
 230 add_definitions(-DHAVE_CONFIG_H)
 231
 232 check_function_exists(mkfifo HAVE_MKFIFO)
 233
 234 # configure a header file to pass some of the CMake settings
 235 # to the source code
 236 configure_file (
 237   "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 238   "${PROJECT_BINARY_DIR}/src/Include/config.h"
 239   )
 240
 241 #and the same for the version header
 242 configure_file (
 243   "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 244   "${PROJECT_BINARY_DIR}/src/Include/version.h"
 245   )
 246
 247 add_subdirectory(src)
 248 add_subdirectory(utils)
 249
 250 #-----------------------------------------------------------------------------
 251 ### uninstall target
 252 #-----------------------------------------------------------------------------
 253 CONFIGURE_FILE(
 254   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 255   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 256   IMMEDIATE @ONLY)
 257 ADD_CUSTOM_TARGET(uninstall
 258   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
 259