CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2
   3 if(COMMAND cmake_policy)
   4    if(POLICY CMP0054)
   5        cmake_policy(SET CMP0054 NEW)
   6    endif()
   7    if(POLICY CMP0042)
   8        cmake_policy(SET CMP0042 NEW)
   9    endif()
  10 endif()
  11
  12 include (CheckFunctionExists)
  13 include (CheckIncludeFile)
  14 include (CheckLibraryExists)
  15 include (CheckCXXSourceCompiles)
  16 include (CheckCXXCompilerFlag)
  17
  18 # using 10.7 because boost requires libc++ and 10.6 doesn't include it
  19 set(CMAKE_OSX_DEPLOYMENT_TARGET 10.7)
  20
  21 # only relevant for building shared libs but let's set it regardless
  22 set(CMAKE_OSX_RPATH 1)
  23
  24 project(SimGear)
  25
  26 # read 'version' file into a variable (stripping any newlines or spaces)
  27 file(READ version versionFile)
  28 string(STRIP ${versionFile} SIMGEAR_VERSION)
  29
  30 set(FIND_LIBRARY_USE_LIB64_PATHS ON)
  31
  32 # use simgear version also as the SO version (if building SOs)
  33 SET(SIMGEAR_SOVERSION ${SIMGEAR_VERSION})
  34
  35 # Warning when build is not an out-of-source build.
  36 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  37 if(InSourceBuild)
  38     message(WARNING  "Avoid building inside the source tree!")
  39     message(WARNING  "Create a separate build directory instead (i.e. 'sgbuild') and call CMake from there: ")
  40     message(WARNING  "  mkdir ../sgbuild && cd ../sgbuild && cmake ${CMAKE_SOURCE_DIR}")
  41 endif(InSourceBuild)
  42
  43 #packaging
  44 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  45 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  46 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Simulation support libraries for FlightGear and related projects")
  47 SET(CPACK_PACKAGE_VENDOR "The FlightGear project")
  48 SET(CPACK_GENERATOR "TBZ2")
  49 SET(CPACK_INSTALL_CMAKE_PROJECTS  ${CMAKE_CURRENT_BINARY_DIR};SimGear;ALL;/)
  50
  51
  52 # split version string into components, note CMAKE_MATCH_0 is the entire regexp match
  53 string(REGEX MATCH "([0-9]+)\\.([0-9]+)\\.([0-9]+)" CPACK_PACKAGE_VERSION ${SIMGEAR_VERSION} )
  54 set(CPACK_PACKAGE_VERSION_MAJOR ${CMAKE_MATCH_1})
  55 set(CPACK_PACKAGE_VERSION_MINOR ${CMAKE_MATCH_2})
  56 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_3})
  57
  58 message(STATUS "version is ${CPACK_PACKAGE_VERSION_MAJOR} dot ${CPACK_PACKAGE_VERSION_MINOR} dot ${CPACK_PACKAGE_VERSION_PATCH}")
  59
  60 set(CPACK_SOURCE_GENERATOR TBZ2)
  61 set(CPACK_SOURCE_PACKAGE_FILE_NAME "simgear-${SIMGEAR_VERSION}" CACHE INTERNAL "tarball basename")
  62 set(CPACK_SOURCE_IGNORE_FILES
  63   "^${PROJECT_SOURCE_DIR}/.git;\\\\.gitignore;Makefile.am;~$;${CPACK_SOURCE_IGNORE_FILES}")
  64
  65 message(STATUS "ignoring: ${CPACK_SOURCE_IGNORE_FILES}")
  66
  67 include (CPack)
  68
  69 # We have some custom .cmake scripts not in the official distribution.
  70 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  71
  72 # Change the default build type to something fast
  73 if(NOT CMAKE_BUILD_TYPE)
  74   set(CMAKE_BUILD_TYPE Release CACHE STRING
  75       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  76       FORCE)
  77 endif(NOT CMAKE_BUILD_TYPE)
  78
  79 # Determine name of library installation directory, i.e. "lib" vs "lib64", which
  80 # differs between all Debian-based vs all other Linux distros.
  81 # See cmake bug #11964, http://cmake.org/gitweb?p=cmake.git;a=commit;h=126c993d
  82 # GNUInstallDirs requires CMake >= 2.8.5, use own file for older cmake
  83 if(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  84   include(GNUInstallDirs)
  85 else(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  86   include(OldGNUInstallDirs)
  87 endif(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  88 message(STATUS "Library installation directory: ${CMAKE_INSTALL_LIBDIR}")
  89
  90 #####################################################################################
  91 # Configure library search paths
  92 #####################################################################################
  93
  94 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  95     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  96     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  97     # add paths manually
  98     # see http://www.cmake.org/Bug/view.php?id=12049 and
  99     # http://www.cmake.org/Bug/view.php?id=12037
 100     list(APPEND ADDITIONAL_LIBRARY_PATHS
 101          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
 102          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
 103          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
 104     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
 105 endif()
 106
 107 #####################################################################################
 108
 109 if (NOT MSVC)
 110 option(SIMGEAR_SHARED   "Set to ON to build SimGear as a shared library/framework" OFF)
 111 option(SYSTEM_EXPAT     "Set to ON to build SimGear using the system libExpat" OFF)
 112 else()
 113 # Building SimGear DLLs is currently not supported for MSVC.
 114 set(SIMGEAR_SHARED OFF)
 115 # Using a system expat is currently not supported for MSVC - it would require shared simgear (DLL).
 116 set(SYSTEM_EXPAT OFF)
 117 endif()
 118
 119 option(SIMGEAR_HEADLESS "Set to ON to build SimGear without GUI/graphics support" OFF)
 120 option(ENABLE_RTI       "Set to ON to build SimGear with RTI support" OFF)
 121 option(ENABLE_TESTS     "Set to OFF to disable building SimGear's test applications" ON)
 122 option(ENABLE_SOUND     "Set to OFF to disable building SimGear's sound support" ON)
 123 option(ENABLE_PKGUTIL   "Set to ON to build the sg_pkgutil application (default)" ON)
 124
 125 if (MSVC)
 126   GET_FILENAME_COMPONENT(PARENT_DIR ${PROJECT_BINARY_DIR} PATH)
 127   if (CMAKE_CL_64)
 128     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty.x64")
 129   else (CMAKE_CL_64)
 130     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty")
 131   endif (CMAKE_CL_64)
 132   if (EXISTS ${TEST_3RDPARTY_DIR})
 133     set(MSVC_3RDPARTY_ROOT ${PARENT_DIR} CACHE PATH "Location where the third-party dependencies are extracted")
 134   else (EXISTS ${TEST_3RDPARTY_DIR})
 135     set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 136   endif (EXISTS ${TEST_3RDPARTY_DIR})
 137 else (MSVC)
 138   set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 139 endif (MSVC)
 140
 141 if (MSVC AND MSVC_3RDPARTY_ROOT)
 142   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_ROOT}")
 143   set( OSG_MSVC "msvc" )
 144   if (${MSVC_VERSION} EQUAL 1700)
 145       set( OSG_MSVC ${OSG_MSVC}110 )
 146   elseif (${MSVC_VERSION} EQUAL 1600)
 147       set( OSG_MSVC ${OSG_MSVC}100 )
 148   else (${MSVC_VERSION} EQUAL 1700)
 149       set( OSG_MSVC ${OSG_MSVC}90 )
 150   endif (${MSVC_VERSION} EQUAL 1700)
 151   if (CMAKE_CL_64)
 152       set( OSG_MSVC ${OSG_MSVC}-64 )
 153       set( MSVC_3RDPARTY_DIR 3rdParty.x64 )
 154   else (CMAKE_CL_64)
 155       set( MSVC_3RDPARTY_DIR 3rdParty )
 156   endif (CMAKE_CL_64)
 157
 158   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/lib )
 159   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/include)
 160   find_path(BOOST_ROOT boost/version.hpp
 161                         ${MSVC_3RDPARTY_ROOT}/boost
 162                         ${MSVC_3RDPARTY_ROOT}/boost_1_52_0
 163                         ${MSVC_3RDPARTY_ROOT}/boost_1_51_0
 164                         ${MSVC_3RDPARTY_ROOT}/boost_1_50_0
 165                         ${MSVC_3RDPARTY_ROOT}/boost_1_49_0
 166                         ${MSVC_3RDPARTY_ROOT}/boost_1_48_0
 167                         ${MSVC_3RDPARTY_ROOT}/boost_1_47_0
 168                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_1
 169                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_0
 170                         ${MSVC_3RDPARTY_ROOT}/boost_1_45_0
 171                         ${MSVC_3RDPARTY_ROOT}/boost_1_44_0
 172                         )
 173   # set (BOOST_ROOT ${MSVC_3RDPARTY_ROOT}/boost_1_44_0)
 174   message(STATUS "BOOST_ROOT is ${BOOST_ROOT}")
 175   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 176   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib)
 177 endif (MSVC AND MSVC_3RDPARTY_ROOT)
 178
 179 if(APPLE)
 180   find_library(COCOA_LIBRARY Cocoa)
 181 endif()
 182
 183 if(${CMAKE_SYSTEM_NAME} MATCHES "Linux" OR
 184         ${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD")
 185     find_package(Threads REQUIRED)
 186 endif()
 187
 188 # Somehow this only works if included before searching for Boost...
 189 include(BoostTestTargets)
 190
 191 find_package(Boost REQUIRED)
 192 set (BOOST_CXX_FLAGS "-DBOOST_BIMAP_DISABLE_SERIALIZATION")
 193
 194 if(SIMGEAR_HEADLESS)
 195     message(STATUS "SimGear mode: HEADLESS")
 196     set(ENABLE_SOUND 0)
 197 else()
 198     message(STATUS "SimGear mode: NORMAL")
 199     find_package(OpenGL REQUIRED)
 200
 201     if (ENABLE_SOUND)
 202         find_package(OpenAL REQUIRED)
 203         message(STATUS "Sound support: ENABLED")
 204     endif(ENABLE_SOUND)
 205
 206     find_package(OpenSceneGraph 3.2.0 REQUIRED osgText osgSim osgDB osgParticle osgGA osgViewer osgUtil)
 207 endif(SIMGEAR_HEADLESS)
 208
 209 find_package(ZLIB REQUIRED)
 210
 211 if (SYSTEM_EXPAT)
 212     message(STATUS "Requested to use system Expat library, forcing SIMGEAR_SHARED to true")
 213     set(SIMGEAR_SHARED ON)
 214     find_package(EXPAT REQUIRED)
 215
 216 else()
 217     message(STATUS "Using built-in expat code")
 218     # XML_STATIC is important to avoid sg_expat_external.h
 219     # declaring symbols as declspec(import)
 220     add_definitions(-DHAVE_EXPAT_CONFIG_H -DXML_STATIC)
 221     set(EXPAT_INCLUDE_DIRS
 222             ${PROJECT_SOURCE_DIR}/3rdparty/expat
 223             ${PROJECT_BINARY_DIR}/3rdparty/expat)
 224 endif(SYSTEM_EXPAT)
 225
 226 include_directories(${EXPAT_INCLUDE_DIRS})
 227
 228 check_include_file(inttypes.h HAVE_INTTYPES_H)
 229 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 230 check_include_file(sys/timeb.h HAVE_SYS_TIMEB_H)
 231 check_include_file(unistd.h HAVE_UNISTD_H)
 232 check_include_file(windows.h HAVE_WINDOWS_H)
 233
 234 if(HAVE_INTTYPES_H)
 235   # ShivaVG needs inttypes.h
 236   add_definitions(-DHAVE_INTTYPES_H)
 237 endif()
 238
 239 if(ENABLE_RTI)
 240     # See if we have any rti library variant installed
 241     message(STATUS "RTI: ENABLED")
 242     find_package(RTI)
 243 else()
 244     message(STATUS "RTI: DISABLED")
 245 endif(ENABLE_RTI)
 246
 247 check_function_exists(gettimeofday HAVE_GETTIMEOFDAY)
 248 check_function_exists(ftime HAVE_FTIME)
 249 check_function_exists(timegm HAVE_TIMEGM)
 250 check_function_exists(rint HAVE_RINT)
 251 check_function_exists(mkdtemp HAVE_MKDTEMP)
 252 check_function_exists(bcopy HAVE_BCOPY)
 253 check_function_exists(mmap HAVE_MMAP)
 254
 255 if(HAVE_UNISTD_H)
 256     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 257     check_cxx_source_compiles(
 258        "#include <unistd.h>
 259         #if !defined(_POSIX_TIMERS) || (0 >= _POSIX_TIMERS)
 260             #error clock_gettime is not supported
 261         #endif
 262
 263         int main() { return 0; }
 264         "
 265         HAVE_CLOCK_GETTIME)
 266 endif(HAVE_UNISTD_H)
 267
 268 set(RT_LIBRARY "")
 269 if(HAVE_CLOCK_GETTIME)
 270     check_library_exists(rt clock_gettime "" HAVE_RT)
 271     if(HAVE_RT)
 272         set(RT_LIBRARY rt)
 273     endif(HAVE_RT)
 274 endif(HAVE_CLOCK_GETTIME)
 275
 276 set(DL_LIBRARY "")
 277 check_cxx_source_compiles(
 278     "#include <dlfcn.h>
 279     int main(void) {
 280         return 0;
 281     }
 282     "
 283     HAVE_DLFCN_H)
 284
 285 if(HAVE_DLFCN_H)
 286     check_library_exists(dl dlerror "" HAVE_DL)
 287     if(HAVE_DL)
 288         set(DL_LIBRARY "dl")
 289     endif()
 290 endif()
 291
 292 SET(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "add a postfix, usually 'd' on windows")
 293 SET(CMAKE_RELEASE_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 294 SET(CMAKE_RELWITHDEBINFO_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 295 SET(CMAKE_MINSIZEREL_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 296
 297 # isnan might not be real symbol, so can't check using function_exists
 298 check_cxx_source_compiles(
 299     "#include <cmath>
 300     int main() { return isnan(0.0);} "
 301     HAVE_ISNAN)
 302
 303 check_cxx_source_compiles(
 304     "#include <cmath>
 305     int main() { return std::isnan(0.0);} "
 306     HAVE_STD_ISNAN)
 307
 308 if(CMAKE_COMPILER_IS_GNUCXX)
 309     set(WARNING_FLAGS_CXX "-Wall")
 310     set(WARNING_FLAGS_C   "-Wall")
 311
 312     # certain GCC versions don't provide the atomic builds, and hence
 313     # require is to provide them in SGAtomic.cxx
 314     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 315     check_cxx_source_compiles(
 316        "int main() { unsigned mValue; return __sync_add_and_fetch(&mValue, 1); }"
 317         GCC_ATOMIC_BUILTINS_FOUND)
 318 endif(CMAKE_COMPILER_IS_GNUCXX)
 319
 320 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 321     # Boost redeclares class members
 322     set(WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual -Wno-redeclared-class-member")
 323     set(WARNING_FLAGS_C   "-Wall")
 324     set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LIBRARY "libc++")
 325     set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LANGUAGE_STANDARD "c++11")
 326     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -stdlib=libc++")
 327 endif()
 328
 329 if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 330 # boost goes haywire wrt static asserts
 331     check_cxx_compiler_flag(-Wno-unused-local-typedefs HAS_NOWARN_UNUSED_TYPEDEFS)
 332     if(HAS_NOWARN_UNUSED_TYPEDEFS)
 333         set(WARNING_FLAGS_CXX " ${WARNING_FLAGS_CXX} -Wno-unused-local-typedefs")
 334     endif()
 335 endif()
 336
 337 if(WIN32)
 338
 339     if(MINGW)
 340         add_definitions(-D_WIN32_WINNT=0x501)
 341     endif()
 342
 343     if(MSVC)
 344         # turn off various warnings
 345         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 346         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 347         # endforeach(warning)
 348
 349         set(MSVC_FLAGS "-DWIN32 -DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS /wd4996 /wd4250 -Dstrdup=_strdup")
 350         if (${MSVC_VERSION} GREATER 1599)
 351             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 352         endif (${MSVC_VERSION} GREATER 1599)
 353     endif(MSVC)
 354
 355     # assumed on Windows
 356     set(HAVE_GETLOCALTIME 1)
 357
 358     set( WINSOCK_LIBRARY "ws2_32.lib" )
 359     set( RT_LIBRARY "winmm" )
 360 endif(WIN32)
 361
 362 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS}")
 363 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} ${BOOST_CXX_FLAGS}")
 364 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 365
 366 # use BEFORE to ensure local directories are used first,
 367 # ahead of system-installed libs
 368 include_directories(BEFORE ${PROJECT_SOURCE_DIR})
 369 include_directories(BEFORE ${PROJECT_SOURCE_DIR}/simgear/canvas/ShivaVG/include)
 370 include_directories(BEFORE ${PROJECT_BINARY_DIR}/simgear)
 371
 372 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 373     ${Boost_INCLUDE_DIRS}
 374     ${ZLIB_INCLUDE_DIR}
 375     ${OPENAL_INCLUDE_DIR}
 376 )
 377
 378 add_definitions(-DHAVE_CONFIG_H)
 379
 380 # configure a header file to pass some of the CMake settings
 381 # to the source code
 382 configure_file (
 383   "${PROJECT_SOURCE_DIR}/simgear/simgear_config_cmake.h.in"
 384   "${PROJECT_BINARY_DIR}/simgear/simgear_config.h"
 385   )
 386
 387 if(ENABLE_TESTS)
 388     # enable CTest / make test target
 389     message(STATUS "Tests: ENABLED")
 390
 391     include (Dart)
 392     enable_testing()
 393 else()
 394     message(STATUS "Tests: DISABLED")
 395 endif(ENABLE_TESTS)
 396
 397 # always set TEST_LIBS as it is also used by other tools/applications
 398 set(TEST_LIBS_INTERNAL_CORE
 399     ${CMAKE_THREAD_LIBS_INIT}
 400     ${ZLIB_LIBRARY}
 401     ${WINSOCK_LIBRARY}
 402     ${RT_LIBRARY}
 403     ${DL_LIBRARY}
 404     ${COCOA_LIBRARY})
 405 set(TEST_LIBS SimGearCore ${TEST_LIBS_INTERNAL_CORE})
 406
 407 if(NOT SIMGEAR_HEADLESS)
 408     set(TEST_LIBS SimGearScene ${OPENGL_LIBRARIES} ${TEST_LIBS})
 409 endif()
 410
 411 install (FILES ${PROJECT_BINARY_DIR}/simgear/simgear_config.h  DESTINATION include/simgear/)
 412
 413 include_directories(3rdparty/utf8/source)
 414
 415 add_subdirectory(3rdparty)
 416 add_subdirectory(simgear)
 417
 418 #-----------------------------------------------------------------------------
 419 ### uninstall target
 420 #-----------------------------------------------------------------------------
 421 CONFIGURE_FILE(
 422   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 423   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 424   IMMEDIATE @ONLY)
 425 ADD_CUSTOM_TARGET(uninstall
 426   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
 427
 428