CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7
   8 project(FlightGear)
   9
  10 # We have some custom .cmake scripts not in the official distribution.
  11 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  12
  13 if(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  14     # use official include provided by latest CMake
  15     include(GNUInstallDirs)
  16 else(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  17     # backward compatibility: use our own module for older cmake versions
  18     include(OldGNUInstallDirs)
  19 endif(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  20
  21 # Warning when build is not an out-of-source build.
  22 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  23 if(InSourceBuild)
  24     message(WARNING  "Avoid building inside the source tree!")
  25     message(WARNING  "Create a separate build directory instead (i.e. 'fgbuild') and call CMake from there: ")
  26     message(WARNING  "  mkdir ../fgbuild && cd ../fgbuild && cmake ${CMAKE_SOURCE_DIR}")
  27 endif(InSourceBuild)
  28
  29 # System detection/default settings
  30 include( DetectDistro )
  31 include( DetectBrowser )
  32
  33 set(CMAKE_DEBUG_POSTFIX          "d" CACHE STRING "add a postfix, usually d on windows")
  34 set(CMAKE_RELEASE_POSTFIX        ""  CACHE STRING "add a postfix, usually empty on windows")
  35 set(CMAKE_RELWITHDEBINFO_POSTFIX ""  CACHE STRING "add a postfix, usually empty on windows")
  36 set(CMAKE_MINSIZEREL_POSTFIX     ""  CACHE STRING "add a postfix, usually empty on windows")
  37
  38 # read 'version' file into a variable (stripping any newlines or spaces)
  39 file(READ version versionFile)
  40 if (NOT versionFile)
  41     message(FATAL_ERROR "Unable to determine FlightGear version. Version file is missing.")
  42 endif()
  43 string(STRIP "${versionFile}" FLIGHTGEAR_VERSION)
  44
  45 # FlightGear packaging (to build a source tarball)
  46 include( ConfigureCPack )
  47
  48 # FlightGear base package path
  49 if (FG_DATA_DIR)
  50     message(STATUS "Using explicit data directory for base package: ${FG_DATA_DIR}")
  51 else()
  52     set(FG_DATA_DIR "${CMAKE_INSTALL_PREFIX}/lib/FlightGear" CACHE PATH "Default location where data files are located")
  53     message(STATUS "Using default data directory for base package:  ${FG_DATA_DIR}")
  54 endif()
  55
  56 # Change the default build type to something fast
  57 if(NOT CMAKE_BUILD_TYPE)
  58     set(CMAKE_BUILD_TYPE Release CACHE STRING
  59         "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  60         FORCE)
  61 endif(NOT CMAKE_BUILD_TYPE)
  62
  63 if(NOT "$ENV{BUILD_ID}" STREQUAL "")
  64     set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  65     set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  66     message(STATUS "running under Hudson/Jenkins, build-number is ${HUDSON_BUILD_NUMBER}")
  67 else()
  68     set(HUDSON_BUILD_NUMBER 0)
  69     set(HUDSON_BUILD_ID "none")
  70 endif()
  71
  72 IF(APPLE)
  73     set(EVENT_INPUT_DEFAULT 1)
  74
  75     find_library(CORESERVICES_LIBRARY CoreServices)
  76     find_library(COCOA_LIBRARY Cocoa)
  77     list(APPEND PLATFORM_LIBS ${COCOA_LIBRARY} ${CORESERVICES_LIBRARY})
  78
  79 elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
  80     find_package(UDev)
  81
  82     if(UDEV_FOUND)
  83         set(EVENT_INPUT_DEFAULT 1)
  84     endif(UDEV_FOUND)
  85 endif()
  86
  87 find_package(Git)
  88 if (GIT_FOUND)
  89     execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
  90         OUTPUT_VARIABLE REVISION
  91         OUTPUT_STRIP_TRAILING_WHITESPACE)
  92     message(STATUS "Git revision is ${REVISION}")
  93 else()
  94     set(REVISION "none")
  95 endif()
  96
  97 # FlightGear build options
  98 option(LOGGING           "Set to ON to build FlightGear with logging support (default)" ON)
  99 option(SP_FDMS           "Set to ON to build FlightGear with special-purpose FDMs" OFF)
 100 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" OFF)
 101 option(ENABLE_LARCSIM    "Set to ON to build FlightGear with LaRCsim FDM" OFF)
 102 option(ENABLE_YASIM      "Set to ON to build FlightGear with YASIM FDM (default)" ON)
 103 option(ENABLE_JSBSIM     "Set to ON to build FlightGear with JSBSim FDM (default)" ON)
 104 option(EVENT_INPUT       "Set to ON to build FlightGear with event-based Input support" ${EVENT_INPUT_DEFAULT})
 105 option(ENABLE_LIBSVN     "Set to ON to build FlightGear/terrasync with libsvnclient support (default)" ON)
 106 option(ENABLE_RTI        "Set to ON to build FlightGear with RTI support" OFF)
 107 option(JPEG_FACTORY      "Set to ON to build FlightGear with JPEG-factory support" OFF)
 108 option(SYSTEM_SQLITE     "Set to ON to build FlightGear with the system's SQLite3 library" OFF)
 109
 110 # additional utilities
 111 option(ENABLE_FGADMIN    "Set to ON to build the FGADMIN application (default)" ON)
 112 option(WITH_FGPANEL      "Set to ON to build the fgpanel application (default)" ON)
 113 option(ENABLE_TESTS      "Set to ON to build test applications (default)" ON)
 114
 115 if(LOGGING)
 116     # nothing
 117 else()
 118     set(FG_NDEBUG 1)
 119 endif()
 120
 121 if(SP_FDMS)
 122     set(ENABLE_SP_FDM 1)
 123 endif()
 124
 125 # Setup MSVC 3rd party directories
 126 include( ConfigureMsvc3rdParty )
 127
 128 if(EVENT_INPUT)
 129     if(APPLE)
 130     elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 131         if(NOT UDEV_FOUND)
 132             message(WARNING "UDev not found, event input is disabled!")
 133             set(EVENT_INPUT 0)
 134         else()
 135             set(EVENT_INPUT_LIBRARIES ${UDEV_LIBRARIES})
 136             message(STATUS "event-based input enabled. Using ${UDEV_LIBRARIES}")
 137         endif()
 138     else()
 139         message(WARNING "event-based input is not supported on this platform yet")
 140     endif()
 141
 142     # Keep PLIB INPUT enabled as long as EventInput does not replace current joystick configurations.
 143     set(ENABLE_PLIB_JOYSTICK 1)
 144 else(EVENT_INPUT)
 145     set(ENABLE_PLIB_JOYSTICK 1)
 146 endif(EVENT_INPUT)
 147
 148 # check required dependencies
 149 find_package(Boost   REQUIRED)
 150 find_package(ZLIB    REQUIRED)
 151 find_package(Threads REQUIRED)
 152 find_package(OpenGL  REQUIRED)
 153 find_package(OpenAL  REQUIRED)
 154 find_package(OpenSceneGraph 3.0.0 REQUIRED osgText osgSim osgDB osgParticle osgFX osgUtil osgViewer osgGA)
 155
 156 if(ENABLE_FGADMIN)
 157     find_package(FLTK)
 158
 159     if ( FLTK_FOUND )
 160         if ( X11_Xinerama_FOUND )
 161             message(STATUS "Found X11_Xinerama...")
 162             list(APPEND FLTK_LIBRARIES ${X11_Xinerama_LIB})
 163         endif()
 164
 165         if ( X11_Xft_FOUND )
 166             message(STATUS "Found X11_Xft...")
 167             list(APPEND FLTK_LIBRARIES ${X11_Xft_LIB})
 168         endif()
 169
 170         message(STATUS "Using FLTK_LIBRARIES for fgadmin: ${FLTK_LIBRARIES}")
 171     endif ( FLTK_FOUND )
 172 endif(ENABLE_FGADMIN)
 173
 174 if(ENABLE_LIBSVN)
 175     find_package(SvnClient)
 176
 177     if(LIBSVN_FOUND)
 178         message(STATUS "libsvn found, enabling in terrasync")
 179         set(HAVE_SVN_CLIENT_H 1)
 180         set(HAVE_LIBSVN_CLIENT_1 1)
 181     else()
 182         message(STATUS "libsvn missing. Disabling...")
 183     endif(LIBSVN_FOUND)
 184 endif(ENABLE_LIBSVN)
 185
 186 if (SYSTEM_SQLITE)
 187     find_package(SQLite3 REQUIRED)
 188     set(CMAKE_REQUIRED_INCLUDES ${SQLITE3_INCLUDED_DIR})
 189     message(STATUS "Using system SQLite3 library")
 190 endif (SYSTEM_SQLITE)
 191
 192 find_package(PLIB REQUIRED puaux pu js fnt)
 193
 194 # FlightGear and SimGear versions need to match
 195 find_package(SimGear ${FLIGHTGEAR_VERSION} REQUIRED)
 196
 197 if (JPEG_FACTORY)
 198     # check simgear was built with JPEG-factory support
 199     find_package(JPEG REQUIRED)
 200     include_directories(${JPEG_INCLUDE_DIR})
 201
 202     set(CMAKE_REQUIRED_INCLUDES
 203         ${SIMGEAR_INCLUDE_DIR}
 204         ${JPEG_INCLUDE_DIR}
 205         ${OPENSCENEGRAPH_INCLUDE_DIRS})
 206
 207     check_cxx_source_compiles(
 208         "#include <simgear/screen/jpgfactory.hxx>
 209         int main()    { return 0; } "
 210         FG_JPEG_SERVER)
 211
 212     if (NOT FG_JPEG_SERVER)
 213         message(STATUS "JPEG server support requested, but SimGear was built without JPEG support")
 214     endif()
 215 endif()
 216
 217 check_include_file(unistd.h   HAVE_UNISTD_H)
 218 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 219 check_include_file(windows.h  HAVE_WINDOWS_H)
 220
 221 if(ENABLE_RTI)
 222     find_package(RTI)
 223     if(RTI_FOUND)
 224         set(FG_HAVE_HLA 1)
 225     endif(RTI_FOUND)
 226 endif(ENABLE_RTI)
 227
 228 if(CMAKE_COMPILER_IS_GNUCXX)
 229     set(WARNING_FLAGS_CXX "-Wall")
 230     set(WARNING_FLAGS_C   "-Wall")
 231 endif(CMAKE_COMPILER_IS_GNUCXX)
 232
 233 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 234    set (WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual")
 235    set (WARNING_FLAGS_C   "-Wall")
 236 endif()
 237
 238 if(WIN32)
 239
 240     if(MSVC)
 241         # turn off various warnings
 242         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 243         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 244         # endforeach(warning)
 245
 246         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS")
 247         if (${MSVC_VERSION} GREATER 1599)
 248             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 249         endif (${MSVC_VERSION} GREATER 1599)
 250     endif(MSVC)
 251
 252     set(NOMINMAX 1)
 253 endif(WIN32)
 254
 255 set (BOOST_CXX_FLAGS "-DBOOST_MULTI_INDEX_DISABLE_SERIALIZATION -DBOOST_BIMAP_DISABLE_SERIALIZATION")
 256
 257 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS} -D_REENTRANT")
 258 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} -D_REENTRANT ${BOOST_CXX_FLAGS}")
 259 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 260
 261 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 262     ${Boost_INCLUDE_DIRS}
 263     ${ZLIB_INCLUDE_DIR}
 264     ${OPENGL_INCLUDE_DIR}
 265     ${OPENAL_INCLUDE_DIR}
 266     ${SIMGEAR_INCLUDE_DIR}
 267     ${PLIB_INCLUDE_DIR} )
 268
 269 include_directories(${PROJECT_SOURCE_DIR}/src)
 270
 271 # following is needed, because config.h is include 'bare', whereas
 272 # version.h is included as <Include/version.h> - this should be cleaned up
 273 include_directories(${PROJECT_BINARY_DIR}/src)
 274 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 275
 276 add_definitions(-DHAVE_CONFIG_H)
 277
 278 check_function_exists(mkfifo HAVE_MKFIFO)
 279
 280 # configure a header file to pass some of the CMake settings
 281 # to the source code
 282 configure_file (
 283     "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 284     "${PROJECT_BINARY_DIR}/src/Include/config.h"
 285 )
 286
 287 #and the same for the version header
 288 configure_file (
 289     "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 290     "${PROJECT_BINARY_DIR}/src/Include/version.h"
 291 )
 292
 293 add_subdirectory(src)
 294 add_subdirectory(utils)
 295 add_subdirectory(man)
 296
 297 #-----------------------------------------------------------------------------
 298 ### uninstall target
 299 #-----------------------------------------------------------------------------
 300 CONFIGURE_FILE(
 301     "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 302     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 303     IMMEDIATE @ONLY)
 304 ADD_CUSTOM_TARGET(uninstall
 305     "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")