CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8.11)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7
   8 if(COMMAND cmake_policy)
   9    if(POLICY CMP0054)
  10        cmake_policy(SET CMP0054 NEW)
  11    endif()
  12    if(POLICY CMP0042)
  13        cmake_policy(SET CMP0042 NEW)
  14    endif()
  15 endif()
  16
  17 if(APPLE)
  18         # using 10.7 because boost requires libc++ and 10.6 doesn't include it
  19         set(CMAKE_OSX_DEPLOYMENT_TARGET 10.7)
  20
  21         set(CMAKE_INSTALL_RPATH "@loader_path/../Frameworks")
  22         # when building, don't use the install RPATH already
  23         # (but later on when installing)
  24         SET(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
  25 endif()
  26
  27 project(FlightGear)
  28
  29 # We have some custom .cmake scripts not in the official distribution.
  30 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  31
  32 # Warning when build is not an out-of-source build.
  33 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  34 if(InSourceBuild)
  35     message(WARNING  "Avoid building inside the source tree!")
  36     message(WARNING  "Create a separate build directory instead (i.e. 'fgbuild') and call CMake from there: ")
  37     message(WARNING  "  mkdir ../fgbuild && cd ../fgbuild && cmake ${CMAKE_SOURCE_DIR}")
  38 endif(InSourceBuild)
  39
  40 include(GNUInstallDirs)
  41 # System detection/default settings
  42 include( DetectDistro )
  43 include( DetectBrowser )
  44
  45 set(CMAKE_DEBUG_POSTFIX          "d" CACHE STRING "add a postfix, usually d on windows")
  46 set(CMAKE_RELEASE_POSTFIX        ""  CACHE STRING "add a postfix, usually empty on windows")
  47 set(CMAKE_RELWITHDEBINFO_POSTFIX ""  CACHE STRING "add a postfix, usually empty on windows")
  48 set(CMAKE_MINSIZEREL_POSTFIX     ""  CACHE STRING "add a postfix, usually empty on windows")
  49
  50 # read 'version' file into a variable (stripping any newlines or spaces)
  51 file(READ version versionFile)
  52 if (NOT versionFile)
  53     message(FATAL_ERROR "Unable to determine FlightGear version. Version file is missing.")
  54 endif()
  55 string(STRIP "${versionFile}" FLIGHTGEAR_VERSION)
  56
  57 # FlightGear packaging (to build a source tarball)
  58 include( ConfigureCPack )
  59
  60 # FlightGear base package path
  61 if (FG_DATA_DIR)
  62     message(STATUS "Using explicit data directory for base package: ${FG_DATA_DIR}")
  63 else()
  64     set(FG_DATA_DIR "${CMAKE_INSTALL_PREFIX}/lib/FlightGear" CACHE PATH "Default location where data files are located")
  65     message(STATUS "Using default data directory for base package:  ${FG_DATA_DIR}")
  66 endif()
  67
  68 # Change the default build type to something fast
  69 if(NOT CMAKE_BUILD_TYPE)
  70     set(CMAKE_BUILD_TYPE Release CACHE STRING
  71         "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  72         FORCE)
  73 endif(NOT CMAKE_BUILD_TYPE)
  74
  75 if(NOT "$ENV{BUILD_ID}" STREQUAL "")
  76     set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  77     set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  78     message(STATUS "running under Hudson/Jenkins, build-number is ${HUDSON_BUILD_NUMBER}")
  79 else()
  80     set(HUDSON_BUILD_NUMBER 0)
  81     set(HUDSON_BUILD_ID "none")
  82 endif()
  83
  84 #####################################################################################
  85 # Configure library search paths
  86 #####################################################################################
  87
  88
  89 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  90     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  91     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  92     # add paths manually
  93     # see http://www.cmake.org/Bug/view.php?id=12049 and
  94     # http://www.cmake.org/Bug/view.php?id=12037
  95     list(APPEND ADDITIONAL_LIBRARY_PATHS
  96          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  97          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  98          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
  99     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
 100 endif()
 101
 102 #####################################################################################
 103
 104 IF(APPLE)
 105     set(EVENT_INPUT_DEFAULT 1)
 106
 107     find_library(CORESERVICES_LIBRARY CoreServices)
 108     find_library(COCOA_LIBRARY Cocoa)
 109     list(APPEND PLATFORM_LIBS ${COCOA_LIBRARY} ${CORESERVICES_LIBRARY})
 110 elseif(${CMAKE_SYSTEM_NAME} MATCHES "Linux" OR
 111         ${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD")
 112     find_package(Threads REQUIRED)
 113     find_package(X11 REQUIRED)
 114
 115     set(USE_DBUS_DEFAULT 1)
 116
 117     find_package(UDev)
 118     if(UDEV_FOUND)
 119         set(EVENT_INPUT_DEFAULT 1)
 120     endif(UDEV_FOUND)
 121
 122     find_package(Speex)
 123     find_package(Speexdsp)
 124     if(SPEEX_FOUND AND SPEEXDSP_FOUND)
 125         set(SYSTEM_SPEEX_DEFAULT 1)
 126     endif(SPEEX_FOUND AND SPEEXDSP_FOUND)
 127
 128     find_package(Gsm)
 129     if(GSM_FOUND)
 130         set(SYSTEM_GSM_DEFAULT 1)
 131     endif(GSM_FOUND)
 132
 133     find_package(Flite)
 134     if(FLITE_FOUND)
 135         set(SYSTEM_FLITE_DEFAULT 1)
 136     endif()
 137
 138     find_package(HtsEngine)
 139     if(HTS_ENGINE_FOUND)
 140         set(SYSTEM_HTS_ENGINE_DEFAULT 1)
 141     endif()
 142 endif()
 143
 144 find_package(Git)
 145 if (GIT_FOUND)
 146     execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
 147         OUTPUT_VARIABLE REVISION
 148         OUTPUT_STRIP_TRAILING_WHITESPACE)
 149     message(STATUS "Git revision is ${REVISION}")
 150 else()
 151     set(REVISION "none")
 152 endif()
 153
 154 # FlightGear build options
 155 option(SIMGEAR_SHARED    "Set to ON when SimGear was built as a shared library" OFF)
 156 option(LOGGING           "Set to ON to build FlightGear with logging support (default)" ON)
 157 option(JSBSIM_TERRAIN    "Set to ON to build FlightGear with JSBSim terrain handling code" ON)
 158 option(SP_FDMS           "Set to ON to build FlightGear with special-purpose FDMs" OFF)
 159 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" OFF)
 160 option(ENABLE_LARCSIM    "Set to ON to build FlightGear with LaRCsim FDM" OFF)
 161 option(ENABLE_YASIM      "Set to ON to build FlightGear with YASIM FDM (default)" ON)
 162 option(ENABLE_JSBSIM     "Set to ON to build FlightGear with JSBSim FDM (default)" ON)
 163 option(EVENT_INPUT       "Set to ON to build FlightGear with event-based Input support" ${EVENT_INPUT_DEFAULT})
 164 option(ENABLE_RTI        "Set to ON to build FlightGear with RTI support" OFF)
 165 option(ENABLE_PROFILE    "Set to ON to build FlightGear with gperftools profiling support" OFF)
 166 option(SYSTEM_SQLITE     "Set to ON to build FlightGear with the system's SQLite3 library" OFF)
 167 option(ENABLE_IAX        "Set to ON to build FlightGear with IAXClient/fgcom built-in (default)" ON)
 168 option(USE_DBUS          "Set to ON to build FlightGear with DBus screensaver interaction (default on Linux)" ${USE_DBUS_DEFAULT})
 169 option(SYSTEM_SPEEX      "Set to ON to build IAXClient with the system's speex and speexdsp library" ${SYSTEM_SPEEX_DEFAULT})
 170 option(SYSTEM_GSM        "Set to ON to build IAXClient with the system's GSM library" ${SYSTEM_GSM_DEFAULT})
 171 option(SYSTEM_FLITE      "Set to ON to build Flightgear with the system's Flite library" ${SYSTEM_FLITE_DEFAULT})
 172 option(SYSTEM_HTS_ENGINE "Set to ON to build Flightgear with the system's HTS Engine library" ${SYSTEM_HTS_ENGINE_DEFAULT})
 173 option(FG_NIGHTLY        "Set to ON to mark this as a nightly build" OFF)
 174
 175 # additional utilities
 176 option(ENABLE_FGADMIN    "Set to ON to build the FGADMIN application (default)" ON)
 177 option(ENABLE_FGELEV     "Set to ON to build the fgelev application (default)" ON)
 178 option(WITH_FGPANEL      "Set to ON to build the fgpanel application (default)" ON)
 179 option(ENABLE_FGVIEWER   "Set to ON to build the fgviewer application (default)" ON)
 180 option(ENABLE_GPSSMOOTH  "Set to ON to build the GPSsmooth application (default)" ON)
 181 option(ENABLE_TERRASYNC  "Set to ON to build the terrasync application (default)" ON)
 182 option(ENABLE_FGJS       "Set to ON to build the fgjs application (default)" ON)
 183 option(ENABLE_JS_DEMO    "Set to ON to build the js_demo application (default)" ON)
 184 option(ENABLE_METAR      "Set to ON to build the metar application (default)" ON)
 185 option(ENABLE_TESTS      "Set to ON to build test applications (default)" ON)
 186 option(ENABLE_FGCOM      "Set to ON to build the FGCom application (default)" ON)
 187 option(ENABLE_FLITE      "Set to ON to build the Flite text-to-speech module" ON)
 188 option(ENABLE_QT         "Set to ON to build the internal Qt launcher" ON)
 189
 190 if(LOGGING)
 191     # nothing
 192 else()
 193     set(FG_NDEBUG 1)
 194 endif()
 195
 196 if(JSBSIM_TERRAIN)
 197    set(JSBSIM_USE_GROUNDREACTIONS 1)
 198 endif()
 199
 200 if(SP_FDMS)
 201     set(ENABLE_SP_FDM 1)
 202 endif()
 203
 204 if(ENABLE_FGCOM)
 205   set(ENABLE_IAX 1)
 206   include_directories(${PROJECT_SOURCE_DIR}/3rdparty/iaxclient/lib ) # for iaxclient.h
 207 endif()
 208
 209 # Setup MSVC 3rd party directories
 210 include( ConfigureMsvc3rdParty )
 211
 212 if(EVENT_INPUT)
 213     if(APPLE)
 214     elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 215         if(NOT UDEV_FOUND)
 216             message(WARNING "UDev not found, event input is disabled!")
 217             set(EVENT_INPUT 0)
 218         else()
 219             add_definitions(-DWITH_EVENTINPUT)
 220             set(EVENT_INPUT_LIBRARIES ${UDEV_LIBRARIES})
 221             message(STATUS "event-based input enabled. Using ${UDEV_LIBRARIES}")
 222         endif()
 223     else()
 224         message(WARNING "event-based input is not supported on this platform yet")
 225     endif()
 226
 227     # Keep PLIB INPUT enabled as long as EventInput does not replace current joystick configurations.
 228     set(ENABLE_PLIB_JOYSTICK 1)
 229 else(EVENT_INPUT)
 230     set(ENABLE_PLIB_JOYSTICK 1)
 231 endif(EVENT_INPUT)
 232
 233 # check required dependencies
 234 find_package(Boost   REQUIRED)
 235 find_package(ZLIB    REQUIRED)
 236 find_package(OpenGL  REQUIRED)
 237 find_package(OpenAL  REQUIRED)
 238 find_package(OpenSceneGraph 3.2.0 REQUIRED
 239   osgText
 240   osgSim
 241   osgDB
 242   osgParticle
 243   osgFX
 244   osgUtil
 245   osgViewer
 246   osgGA
 247 )
 248
 249 if (MSVC)
 250         find_package(CrashRpt)
 251         if (CRASHRPT_FOUND)
 252                 set(HAVE_CRASHRPT 1)
 253                 message(STATUS "Using CrashRpt")
 254         include_directories( ${CRASHRPT_INCLUDE_DIR})
 255         endif()
 256 endif()
 257
 258 ##############################################################################
 259 ## Sqlite3 setup
 260
 261 if (SYSTEM_SQLITE)
 262     find_package(SQLite3 REQUIRED)
 263
 264     message(STATUS "Using system SQLite3 library")
 265 else()
 266     set(SQLITE3_INCLUDED_DIR "${CMAKE_SOURCE_DIR}/3rdparty/sqlite3")
 267     # this target is defined in src/Navaids/CMakeLists.txt
 268     list(APPEND SQLITE3_LIBRARY fgsqlite3)
 269 endif (SYSTEM_SQLITE)
 270
 271 # Sqlite always depends on the threading lib
 272 list(APPEND SQLITE3_LIBRARY ${CMAKE_THREAD_LIBS_INIT})
 273
 274 ##############################################################################
 275 ## DBus setup
 276
 277 if (USE_DBUS)
 278     include(FindPkgConfig)
 279     if (PKG_CONFIG_FOUND)
 280         pkg_check_modules(DBUS dbus-1)
 281     endif (PKG_CONFIG_FOUND) #if we don't have pkg-config, assume we don't have libdbus-1-dev either http://packages.debian.org/sid/libdbus-1-dev
 282     if (DBUS_FOUND)
 283         set(HAVE_DBUS 1)
 284         message(STATUS "Using DBus")
 285         include_directories( ${DBUS_INCLUDE_DIRS})
 286     else()
 287         message(STATUS "DBus not found, screensaver control disabled")
 288     endif (DBUS_FOUND)
 289 else()
 290 endif (USE_DBUS)
 291
 292 ##############################################################################
 293 ## Qt5 setup setup
 294 if (ENABLE_QT)
 295         message(STATUS "Qt launcher enabled, checking for Qt 5.1 / qmake")
 296         find_package(Qt5 5.1 COMPONENTS Widgets)
 297         if (Qt5Widgets_FOUND)
 298                 message(STATUS "Will enable Qt launcher GUI")
 299                 message(STATUS "  Qt5Widgets version: ${Qt5Widgets_VERSION_STRING}")
 300                 message(STATUS "  Qt5Widgets include dir: ${Qt5Widgets_INCLUDE_DIRS}")
 301                 set(HAVE_QT 1)
 302         endif()
 303 endif (ENABLE_QT)
 304 ##############################################################################
 305
 306 find_package(PLIB REQUIRED puaux pu js fnt)
 307
 308 # FlightGear and SimGear versions need to match
 309 find_package(SimGear ${FLIGHTGEAR_VERSION} REQUIRED)
 310
 311 ##############################################################################
 312
 313 check_include_file(unistd.h   HAVE_UNISTD_H)
 314 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 315 check_include_file(windows.h  HAVE_WINDOWS_H)
 316
 317 if(ENABLE_PROFILE)
 318     find_package(GooglePerfTools REQUIRED)
 319     set(FG_HAVE_GPERFTOOLS 1)
 320     message(STATUS "Built-in profiler using gperftools available")
 321 endif()
 322
 323 if(ENABLE_RTI)
 324     message(STATUS "RTI: ENABLED")
 325     find_package(RTI)
 326     if(RTI_FOUND)
 327         set(FG_HAVE_HLA 1)
 328     endif(RTI_FOUND)
 329 else()
 330     message(STATUS "RTI: DISABLED")
 331 endif(ENABLE_RTI)
 332
 333 if(CMAKE_COMPILER_IS_GNUCXX)
 334     set(WARNING_FLAGS_CXX "-Wall")
 335     set(WARNING_FLAGS_C   "-Wall")
 336 endif(CMAKE_COMPILER_IS_GNUCXX)
 337
 338 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 339    set(WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual \
 340      -Wno-redeclared-class-member \
 341      -Wno-inconsistent-missing-override \
 342      -Wno-unused-local-typedef")
 343
 344    set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LIBRARY "libc++")
 345    set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LANGUAGE_STANDARD "c++11")
 346    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -stdlib=libc++")
 347    set(WARNING_FLAGS_C "-Wall")
 348 endif()
 349
 350 if(WIN32)
 351
 352     if(MSVC)
 353         # turn off various warnings
 354         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 355         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 356         # endforeach(warning)
 357
 358         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS -Dstrdup=_strdup")
 359         if (${MSVC_VERSION} GREATER 1599)
 360             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 361         endif (${MSVC_VERSION} GREATER 1599)
 362     endif(MSVC)
 363
 364     set(NOMINMAX 1)
 365 endif(WIN32)
 366
 367 set (BOOST_CXX_FLAGS "-DBOOST_BIMAP_DISABLE_SERIALIZATION")
 368
 369 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS} -D_REENTRANT")
 370 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} -D_REENTRANT ${BOOST_CXX_FLAGS}")
 371 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 372
 373 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 374     ${Boost_INCLUDE_DIRS}
 375     ${ZLIB_INCLUDE_DIR}
 376     ${OPENGL_INCLUDE_DIR}
 377     ${OPENAL_INCLUDE_DIR}
 378     ${SIMGEAR_INCLUDE_DIRS}
 379     ${PLIB_INCLUDE_DIR}
 380     ${SQLITE3_INCLUDED_DIR} )
 381
 382 include_directories(${PROJECT_SOURCE_DIR})
 383 include_directories(${PROJECT_SOURCE_DIR}/src)
 384 # following is needed, because config.h is include 'bare', whereas
 385 # version.h is included as <Include/version.h> - this should be cleaned up
 386 include_directories(${PROJECT_BINARY_DIR}/src)
 387 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 388
 389 if (ENABLE_FLITE)
 390     include_directories(${PROJECT_SOURCE_DIR}/3rdparty/hts_engine_API/include )
 391     include_directories(${PROJECT_SOURCE_DIR}/3rdparty/flite_hts_engine/include )
 392 endif()
 393
 394 add_definitions(-DHAVE_CONFIG_H)
 395
 396 check_function_exists(mkfifo HAVE_MKFIFO)
 397
 398 # configure a header file to pass some of the CMake settings
 399 # to the source code
 400 configure_file (
 401     "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 402     "${PROJECT_BINARY_DIR}/src/Include/config.h"
 403 )
 404
 405 #and the same for the version header
 406 configure_file (
 407     "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 408     "${PROJECT_BINARY_DIR}/src/Include/version.h"
 409 )
 410
 411 add_subdirectory(3rdparty)
 412 add_subdirectory(utils)
 413 add_subdirectory(src)
 414 add_subdirectory(man)
 415
 416 #-----------------------------------------------------------------------------
 417 ### uninstall target
 418 #-----------------------------------------------------------------------------
 419 CONFIGURE_FILE(
 420     "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 421     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 422     IMMEDIATE @ONLY)
 423 ADD_CUSTOM_TARGET(uninstall
 424     "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")