CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2 include (CheckFunctionExists)
   3 include (CheckIncludeFile)
   4 include (CheckCXXSourceCompiles)
   5 include (CPack)
   6
   7 project(SimGear)
   8
   9 # read 'version' file into a variable (stripping any newlines or spaces)
  10 file(READ version versionFile)
  11 string(STRIP ${versionFile} SIMGEAR_VERSION)
  12
  13 #packaging
  14 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  15 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  16 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Simulation support libraries for FlightGear and related projects")
  17 SET(CPACK_PACKAGE_VENDOR "The FlightGear project")
  18 SET(CPACK_GENERATOR "TBZ2")
  19 SET(CPACK_INSTALL_CMAKE_PROJECTS  ${CMAKE_CURRENT_BINARY_DIR};SimGear;ALL;/)
  20
  21 # split version string into components, note CMAKE_MATCH_0 is the entire regexp match
  22 string(REGEX MATCH "([0-9]+)\\.([0-9]+)\\.([0-9]+)" CPACK_PACKAGE_VERSION ${SIMGEAR_VERSION} )
  23 set(CPACK_PACKAGE_VERSION_MAJOR ${CMAKE_MATCH_1})
  24 set(CPACK_PACKAGE_VERSION_MINOR ${CMAKE_MATCH_2})
  25 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_3})
  26
  27 message(STATUS "version is ${CPACK_PACKAGE_VERSION_MAJOR} dot ${CPACK_PACKAGE_VERSION_MINOR} dot ${CPACK_PACKAGE_VERSION_PATCH}")
  28
  29 # We have some custom .cmake scripts not in the official distribution.
  30 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  31
  32 # Change the default build type to something fast
  33 if(NOT CMAKE_BUILD_TYPE)
  34   set(CMAKE_BUILD_TYPE Release CACHE STRING
  35       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  36       FORCE)
  37 endif(NOT CMAKE_BUILD_TYPE)
  38
  39 option(SIMGEAR_SHARED "Set to ON to build SimGear as a shared library/framework" OFF)
  40 option(SIMGEAR_HEADLESS "Set to ON to build SimGear without GUI/graphics support" OFF)
  41 option(JPEG_FACTORY "Enable JPEG-factory support" OFF)
  42 option(ENABLE_LIBSVN "Set to ON to build SimGear with libsvnclient support" ON)
  43 option(ENABLE_RTI "Set to ON to build SimGear with RTI support" OFF)
  44
  45 set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
  46
  47 if (MSVC AND MSVC_3RDPARTY_ROOT)
  48   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_ROOT}")
  49   set( OSG_MSVC "msvc" )
  50   if (${MSVC_VERSION} EQUAL 1600)
  51       set( OSG_MSVC ${OSG_MSVC}100 )
  52   else (${MSVC_VERSION} EQUAL 1600)
  53       set( OSG_MSVC ${OSG_MSVC}90 )
  54   endif (${MSVC_VERSION} EQUAL 1600)
  55   if (CMAKE_CL_64)
  56       set( OSG_MSVC ${OSG_MSVC}-64 )
  57       set( MSVC_3RDPARTY_DIR 3rdParty.x64 )
  58   else (CMAKE_CL_64)
  59       set( MSVC_3RDPARTY_DIR 3rdParty )
  60   endif (CMAKE_CL_64)
  61
  62   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/lib )
  63   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/include)
  64   set (BOOST_ROOT ${MSVC_3RDPARTY_ROOT}/boost_1_44_0)
  65   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
  66   set (ALUT_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
  67   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib)
  68 endif (MSVC AND MSVC_3RDPARTY_ROOT)
  69
  70 find_package(Boost REQUIRED)
  71 set (BOOST_CXX_FLAGS "-DBOOST_MULTI_INDEX_DISABLE_SERIALIZATION -DBOOST_BIMAP_DISABLE_SERIALIZATION")
  72
  73 find_package(ZLIB REQUIRED)
  74 find_package(Threads REQUIRED)
  75
  76 if(SIMGEAR_HEADLESS)
  77     message(STATUS "headlesss mode")
  78     set(NO_OPENSCENEGRAPH_INTERFACE 1)
  79 else()
  80     find_package(OpenGL REQUIRED)
  81     find_package(OpenAL REQUIRED)
  82     find_package(ALUT REQUIRED)
  83     find_package(OpenSceneGraph 2.8.1 REQUIRED osgText osgSim osgDB osgParticle osgUtil)
  84 endif(SIMGEAR_HEADLESS)
  85
  86 if(JPEG_FACTORY)
  87     message(STATUS "JPEG-factory enabled")
  88     find_package(JPEG REQUIRED)
  89     include_directories(${JPEG_INCLUDE_DIR})
  90 endif(JPEG_FACTORY)
  91
  92 if(ENABLE_LIBSVN)
  93         find_package(SvnClient)
  94
  95         if(LIBSVN_FOUND)
  96                 message(STATUS "libsvn found, enabling in SimGear")
  97                 set(HAVE_SVN_CLIENT_H 1)
  98                 set(HAVE_LIBSVN_CLIENT_1 1)
  99         else()
 100                 message(STATUS "Missing libsvn, unable to enable SVN in SimGear")
 101         endif(LIBSVN_FOUND)
 102 endif(ENABLE_LIBSVN)
 103
 104 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 105 check_include_file(sys/timeb.h HAVE_SYS_TIMEB_H)
 106 check_include_file(unistd.h HAVE_UNISTD_H)
 107 check_include_file(windows.h HAVE_WINDOWS_H)
 108
 109 if(ENABLE_RTI)
 110 # See if we have any rti library variant installed
 111 find_package(RTI)
 112 endif(ENABLE_RTI)
 113
 114 check_function_exists(gettimeofday HAVE_GETTIMEOFDAY)
 115 check_function_exists(ftime HAVE_FTIME)
 116 check_function_exists(timegm HAVE_TIMEGM)
 117 check_function_exists(rint HAVE_RINT)
 118
 119
 120 if(HAVE_UNISTD_H)
 121     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 122     check_cxx_source_compiles(
 123        "#include <unistd.h>
 124         #if !defined(_POSIX_TIMERS) || (0 >= _POSIX_TIMERS)
 125             #error clock_gettime is not supported
 126         #endif
 127
 128         int main() { return 0; }
 129         "
 130         HAVE_CLOCK_GETTIME)
 131 endif(HAVE_UNISTD_H)
 132
 133 set(RT_LIBRARY "")
 134 if(HAVE_CLOCK_GETTIME)
 135     check_function_exists(clock_gettime CLOCK_GETTIME_IN_LIBC)
 136     if(NOT CLOCK_GETTIME_IN_LIBC)
 137         check_library_exists(rt clock_gettime "" HAVE_RT)
 138         if(HAVE_RT)
 139             set(RT_LIBRARY rt)
 140         endif(HAVE_RT)
 141         endif(NOT CLOCK_GETTIME_IN_LIBC)
 142 endif(HAVE_CLOCK_GETTIME)
 143
 144 SET(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "add a postfix, usually d on windows")
 145 SET(CMAKE_RELEASE_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 146 SET(CMAKE_RELWITHDEBINFO_POSTFIX "rd" CACHE STRING "add a postfix, usually empty on windows")
 147 SET(CMAKE_MINSIZEREL_POSTFIX "s" CACHE STRING "add a postfix, usually empty on windows")
 148
 149 # isnan might not be real symbol, so can't check using function_exists
 150 check_cxx_source_compiles(
 151     "#include <cmath>
 152     void f() { isnan(0.0);} "
 153     HAVE_ISNAN)
 154
 155 if(CMAKE_COMPILER_IS_GNUCXX)
 156     set(WARNING_FLAGS -Wall)
 157 endif(CMAKE_COMPILER_IS_GNUCXX)
 158
 159 if(WIN32)
 160
 161     if(MSVC)
 162         # turn off various warnings
 163         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 164         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 165         # endforeach(warning)
 166
 167         set(MSVC_FLAGS "-DWIN32 -DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS /wd4996")
 168     endif(MSVC)
 169
 170     # assumed on Windows
 171     set(HAVE_GETLOCALTIME 1)
 172
 173     set( WINSOCK_LIBRARY "ws2_32.lib" )
 174     set( RT_LIBRARY "winmm" )
 175 endif(WIN32)
 176
 177 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS}")
 178 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS} ${BOOST_CXX_FLAGS}")
 179
 180 include_directories(${PROJECT_SOURCE_DIR})
 181 include_directories(${PROJECT_BINARY_DIR}/simgear)
 182
 183 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 184     ${Boost_INCLUDE_DIRS} ${ZLIB_INCLUDE_DIR}
 185     ${ALUT_INCLUDE_DIR} ${OPENAL_INCLUDE_DIR} )
 186
 187
 188 add_definitions(-DHAVE_CONFIG_H)
 189
 190 # configure a header file to pass some of the CMake settings
 191 # to the source code
 192 configure_file (
 193   "${PROJECT_SOURCE_DIR}/simgear/simgear_config_cmake.h.in"
 194   "${PROJECT_BINARY_DIR}/simgear/simgear_config.h"
 195   )
 196
 197 # enable CTest / make test target
 198
 199 include (Dart)
 200 enable_testing()
 201
 202 install (FILES ${PROJECT_BINARY_DIR}/simgear/simgear_config.h  DESTINATION include/simgear/)
 203 add_subdirectory(simgear)
 204
 205 #-----------------------------------------------------------------------------
 206 ### uninstall target
 207 #-----------------------------------------------------------------------------
 208 CONFIGURE_FILE(
 209   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 210   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 211   IMMEDIATE @ONLY)
 212 ADD_CUSTOM_TARGET(uninstall
 213   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
 214
 215
 216