CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7
   8 project(FlightGear)
   9
  10 # We have some custom .cmake scripts not in the official distribution.
  11 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  12
  13 if(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  14     # use official include provided by latest CMake
  15     include(GNUInstallDirs)
  16 else(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  17     # backward compatibility: use our own module for older cmake versions
  18     include(OldGNUInstallDirs)
  19 endif(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  20
  21 set(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "add a postfix, usually d on windows")
  22 set(CMAKE_RELEASE_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
  23 set(CMAKE_RELWITHDEBINFO_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
  24 set(CMAKE_MINSIZEREL_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
  25
  26 # read 'version' file into a variable (stripping any newlines or spaces)
  27 file(READ version versionFile)
  28 string(STRIP ${versionFile} FLIGHTGEAR_VERSION)
  29
  30 #packaging
  31 if(EXISTS ${PROJECT_SOURCE_DIR}/.gitignore)
  32     file(READ .gitignore CPACK_SOURCE_IGNORE_FILES)
  33 else()
  34     # clean tar-balls do not contain SCM (.git/.gitignore/...) files.
  35     set(CPACK_SOURCE_IGNORE_FILES
  36       "^${PROJECT_SOURCE_DIR}/.git;\\\\.gitignore;Makefile.am;~$;${CPACK_SOURCE_IGNORE_FILES}")
  37 endif()
  38
  39 # split version string into components, note CMAKE_MATCH_0 is the entire regexp match
  40 string(REGEX MATCH "([0-9]+)\\.([0-9]+)\\.([0-9]+)" CPACK_PACKAGE_VERSION ${FLIGHTGEAR_VERSION} )
  41 set(CPACK_PACKAGE_VERSION_MAJOR ${CMAKE_MATCH_1})
  42 set(CPACK_PACKAGE_VERSION_MINOR ${CMAKE_MATCH_2})
  43 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_3})
  44 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  45 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  46
  47 set(CPACK_SOURCE_GENERATOR TBZ2 ZIP)
  48 set(CPACK_SOURCE_PACKAGE_FILE_NAME "flightgear-${FLIGHTGEAR_VERSION}" CACHE INTERNAL "tarball basename")
  49
  50 include (CPack)
  51
  52 if (FG_DATA_DIR)
  53     message(STATUS "Using explicit data-dir: ${FG_DATA_DIR}")
  54 else()
  55     set(FG_DATA_DIR "${CMAKE_INSTALL_PREFIX}/lib/FlightGear" CACHE PATH "Default location where data files are located")
  56     message(STATUS "Using default data-dir:  ${FG_DATA_DIR}")
  57 endif()
  58
  59 # Change the default build type to something fast
  60 if(NOT CMAKE_BUILD_TYPE)
  61   set(CMAKE_BUILD_TYPE Release CACHE STRING
  62       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  63       FORCE)
  64 endif(NOT CMAKE_BUILD_TYPE)
  65
  66 if($ENV{BUILD_ID})
  67         set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  68         set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  69         message(STATUS "running under Hudson, build-number is ${HUDSON_BUILD_NUMBER}")
  70 else()
  71         set(HUDSON_BUILD_NUMBER 0)
  72         set(HUDSON_BUILD_ID "none")
  73 endif()
  74
  75 IF(APPLE)
  76     set(EVENT_INPUT_DEFAULT 1)
  77
  78     find_library(CORESERVICES_LIBRARY CoreServices)
  79     find_library(COCOA_LIBRARY Cocoa)
  80     list(APPEND PLATFORM_LIBS ${COCOA_LIBRARY} ${CORESERVICES_LIBRARY})
  81
  82 elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
  83         find_package(UDev)
  84
  85         if(UDEV_FOUND)
  86                 set(EVENT_INPUT_DEFAULT 1)
  87         endif(UDEV_FOUND)
  88 endif()
  89
  90 find_package(Git)
  91 if (GIT_FOUND)
  92         execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
  93                 OUTPUT_VARIABLE REVISION
  94                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  95         message(STATUS "Git revision is ${REVISION}")
  96 else()
  97         set(REVISION "none")
  98 endif()
  99
 100 option(LOGGING "Set to OFF to build FlightGear without logging" ON)
 101
 102 option(SP_FDMS "Set to ON to build FlightGear with special-purpose FDMs" OFF)
 103 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" OFF)
 104 option(ENABLE_LARCSIM "Set to ON to build FlightGear with LaRCsim FDM" OFF)
 105 option(ENABLE_YASIM "Set to ON to build FlightGear with YASIM FDM" ON)
 106 option(ENABLE_JSBSIM "Set to ON to build FlightGear with JSBSim FDM" ON)
 107 option(ENABLE_FGADMIN "Set to ON to build FlightGear with FGADMIN" ON)
 108 option(EVENT_INPUT "Set to ON to build FlightGear with event-based Input support" ${EVENT_INPUT_DEFAULT})
 109 option(ENABLE_LIBSVN "Set to ON to build FlightGear/terrasync with libsvnclient support" ON)
 110 option(ENABLE_RTI "Set to ON to build SimGear with RTI support" OFF)
 111 option(WITH_FGPANEL "Set to ON to build the fgpanel application" ON)
 112 option(JPEG_FACTORY "Enable JPEG-factory support" OFF)
 113
 114 if (MSVC)
 115   GET_FILENAME_COMPONENT(PARENT_DIR ${PROJECT_SOURCE_DIR} PATH)
 116   if (CMAKE_CL_64)
 117     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty.x64")
 118   else (CMAKE_CL_64)
 119     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty")
 120   endif (CMAKE_CL_64)
 121   if (EXISTS ${TEST_3RDPARTY_DIR})
 122     set(MSVC_3RDPARTY_ROOT ${PARENT_DIR} CACHE PATH "Location where the third-party dependencies are extracted")
 123   else (EXISTS ${TEST_3RDPARTY_DIR})
 124     set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 125   endif (EXISTS ${TEST_3RDPARTY_DIR})
 126   list(APPEND PLATFORM_LIBS "winmm.lib")
 127 else (MSVC)
 128   set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 129 endif (MSVC)
 130
 131 if(LOGGING)
 132         # nothing
 133 else()
 134         set(FG_NDEBUG 1)
 135 endif()
 136
 137 if(SP_FDMS)
 138         set(ENABLE_SP_FDM 1)
 139 endif()
 140
 141 if (MSVC AND MSVC_3RDPARTY_ROOT)
 142   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_ROOT}")
 143   set( OSG_MSVC "msvc" )
 144   if (${MSVC_VERSION} EQUAL 1600)
 145       set( OSG_MSVC ${OSG_MSVC}100 )
 146   else (${MSVC_VERSION} EQUAL 1600)
 147       set( OSG_MSVC ${OSG_MSVC}90 )
 148   endif (${MSVC_VERSION} EQUAL 1600)
 149   if (CMAKE_CL_64)
 150       set( OSG_MSVC ${OSG_MSVC}-64 )
 151           set( MSVC_3RDPARTY_DIR 3rdParty.x64 )
 152   else (CMAKE_CL_64)
 153           set( MSVC_3RDPARTY_DIR 3rdParty )
 154   endif (CMAKE_CL_64)
 155
 156   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/SimGear/lib )
 157   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/SimGear/include)
 158   set (BOOST_ROOT ${MSVC_3RDPARTY_ROOT}/boost_1_44_0)
 159   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 160   set (ALUT_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 161   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib)
 162 endif (MSVC AND MSVC_3RDPARTY_ROOT)
 163
 164 if(EVENT_INPUT)
 165         message(STATUS "checking event-based Input")
 166
 167         IF(APPLE)
 168
 169         elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 170                 if(NOT UDEV_FOUND)
 171                         message(WARNING "UDev not found, event input is disabled!")
 172                         set(EVENT_INPUT 0)
 173                 else()
 174                         set(EVENT_INPUT_LIBRARIES ${UDEV_LIBRARIES})
 175                 endif()
 176
 177         else()
 178                 message(WARNING "event input is not supported on this platform yet")
 179         endif()
 180
 181         # Keep PLIB INPUT enabled as long as EventInput does not replace current joystick configurations.
 182         set(ENABLE_PLIB_JOYSTICK 1)
 183 else(EVENT_INPUT)
 184         set(ENABLE_PLIB_JOYSTICK 1)
 185 endif(EVENT_INPUT)
 186
 187 # check required dependencies
 188 find_package(Boost REQUIRED)
 189 find_package(ZLIB REQUIRED)
 190 find_package(Threads REQUIRED)
 191 find_package(OpenGL REQUIRED)
 192 find_package(OpenAL REQUIRED)
 193 find_package(ALUT REQUIRED)
 194 find_package(OpenSceneGraph 3.0.0 REQUIRED osgText osgSim osgDB osgParticle osgFX osgUtil osgViewer osgGA)
 195
 196 if(ENABLE_FGADMIN)
 197   find_package(FLTK)
 198 endif(ENABLE_FGADMIN)
 199
 200 if(ENABLE_LIBSVN)
 201         find_package(SvnClient)
 202
 203         if(LIBSVN_FOUND)
 204                 message(STATUS "libsvn found, enabling in terrasync")
 205                 set(HAVE_SVN_CLIENT_H 1)
 206                 set(HAVE_LIBSVN_CLIENT_1 1)
 207         endif(LIBSVN_FOUND)
 208 endif(ENABLE_LIBSVN)
 209
 210 find_package(PLIB REQUIRED puaux pu js fnt)
 211 find_package(SimGear 2.5.0 REQUIRED)
 212
 213 if (JPEG_FACTORY)
 214     # check simgear was built with JPEG-factory support
 215     find_package(JPEG REQUIRED)
 216     include_directories(${JPEG_INCLUDE_DIR})
 217
 218     set(CMAKE_REQUIRED_INCLUDES
 219         ${SIMGEAR_INCLUDE_DIR}
 220         ${JPEG_INCLUDE_DIR}
 221         ${OPENSCENEGRAPH_INCLUDE_DIRS})
 222
 223     check_cxx_source_compiles(
 224         "#include <simgear/screen/jpgfactory.hxx>
 225         int main()    { return 0; } "
 226         FG_JPEG_SERVER)
 227
 228     if (NOT FG_JPEG_SERVER)
 229         message(STATUS "JPEG server support requested, but SimGear was built without JPEG support")
 230     endif()
 231 endif()
 232
 233 check_include_file(unistd.h HAVE_UNISTD_H)
 234 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 235 check_include_file(windows.h HAVE_WINDOWS_H)
 236
 237 # definition depends on OSG version
 238 set(CMAKE_REQUIRED_INCLUDES ${OPENSCENEGRAPH_INCLUDE_DIRS})
 239
 240 check_cxx_source_compiles(
 241     "#include <osg/CullSettings>
 242     int main()
 243     {
 244        osg::CullSettings::VariablesMask mask = osg::CullSettings::CLEAR_MASK;
 245        return 0;
 246     }
 247     "
 248     HAVE_CULLSETTINGS_CLEAR_MASK)
 249
 250 if(ENABLE_RTI)
 251     find_package(RTI)
 252     if(RTI_FOUND)
 253         set(FG_HAVE_HLA 1)
 254     endif(RTI_FOUND)
 255 endif(ENABLE_RTI)
 256
 257 if(CMAKE_COMPILER_IS_GNUCXX)
 258     set(WARNING_FLAGS -Wall)
 259 endif(CMAKE_COMPILER_IS_GNUCXX)
 260
 261 if(WIN32)
 262
 263     if(MSVC)
 264         # turn off various warnings
 265         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 266         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 267         # endforeach(warning)
 268
 269         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS")
 270         if (${MSVC_VERSION} EQUAL 1600)
 271                   set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 272         endif (${MSVC_VERSION} EQUAL 1600)
 273     endif(MSVC)
 274
 275     set(NOMINMAX 1)
 276 endif(WIN32)
 277
 278 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS} -D_REENTRANT")
 279 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS} -D_REENTRANT")
 280 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 281
 282 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 283         ${Boost_INCLUDE_DIRS}
 284         ${ZLIB_INCLUDE_DIR}
 285         ${ALUT_INCLUDE_DIR}
 286         ${OPENAL_INCLUDE_DIR}
 287         ${SIMGEAR_INCLUDE_DIR}
 288         ${PLIB_INCLUDE_DIR} )
 289
 290 include_directories(${PROJECT_SOURCE_DIR}/src)
 291
 292 # following is needed, because config.h is include 'bare', whereas
 293 # version.h is included as <Include/version.h> - this should be cleaned up
 294 include_directories(${PROJECT_BINARY_DIR}/src)
 295 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 296
 297 add_definitions(-DHAVE_CONFIG_H)
 298
 299 check_function_exists(mkfifo HAVE_MKFIFO)
 300
 301 # configure a header file to pass some of the CMake settings
 302 # to the source code
 303 configure_file (
 304   "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 305   "${PROJECT_BINARY_DIR}/src/Include/config.h"
 306   )
 307
 308 #and the same for the version header
 309 configure_file (
 310   "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 311   "${PROJECT_BINARY_DIR}/src/Include/version.h"
 312   )
 313
 314 add_subdirectory(src)
 315 add_subdirectory(utils)
 316 add_subdirectory(man)
 317
 318 set (INSTALL_DOCS
 319         README
 320         README.OpenAL
 321         README.plib
 322         README.OSG
 323         README.SimGear)
 324
 325 INSTALL(FILES ${INSTALL_DOCS} DESTINATION ${CMAKE_INSTALL_DOCDIR} OPTIONAL)
 326
 327 #-----------------------------------------------------------------------------
 328 ### uninstall target
 329 #-----------------------------------------------------------------------------
 330 CONFIGURE_FILE(
 331   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 332   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 333   IMMEDIATE @ONLY)
 334 ADD_CUSTOM_TARGET(uninstall
 335   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
 336