CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2
   3 if(COMMAND cmake_policy)
   4    if(POLICY CMP0054)
   5        cmake_policy(SET CMP0054 NEW)
   6    endif()
   7    if(POLICY CMP0042)
   8        cmake_policy(SET CMP0042 NEW)
   9    endif()
  10 endif()
  11
  12 include (CheckFunctionExists)
  13 include (CheckIncludeFile)
  14 include (CheckLibraryExists)
  15 include (CheckCXXSourceCompiles)
  16 include (CheckCXXCompilerFlag)
  17
  18 # using 10.7 because boost requires libc++ and 10.6 doesn't include it
  19 set(CMAKE_OSX_DEPLOYMENT_TARGET 10.7)
  20 set(CMAKE_OSX_SYSROOT /Applications/Xcode.app/Contents/Developer/Platforms/MacOSX.platform/Developer/SDKs/MacOSX10.9.sdk)
  21
  22 # only relevant for building shared libs but let's set it regardless
  23 set(CMAKE_OSX_RPATH 1)
  24
  25 project(SimGear)
  26
  27 # read 'version' file into a variable (stripping any newlines or spaces)
  28 file(READ version versionFile)
  29 string(STRIP ${versionFile} SIMGEAR_VERSION)
  30
  31 set(FIND_LIBRARY_USE_LIB64_PATHS ON)
  32
  33 # use simgear version also as the SO version (if building SOs)
  34 SET(SIMGEAR_SOVERSION ${SIMGEAR_VERSION})
  35
  36 # Warning when build is not an out-of-source build.
  37 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  38 if(InSourceBuild)
  39     message(WARNING  "Avoid building inside the source tree!")
  40     message(WARNING  "Create a separate build directory instead (i.e. 'sgbuild') and call CMake from there: ")
  41     message(WARNING  "  mkdir ../sgbuild && cd ../sgbuild && cmake ${CMAKE_SOURCE_DIR}")
  42 endif(InSourceBuild)
  43
  44 #packaging
  45 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  46 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  47 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Simulation support libraries for FlightGear and related projects")
  48 SET(CPACK_PACKAGE_VENDOR "The FlightGear project")
  49 SET(CPACK_GENERATOR "TBZ2")
  50 SET(CPACK_INSTALL_CMAKE_PROJECTS  ${CMAKE_CURRENT_BINARY_DIR};SimGear;ALL;/)
  51
  52
  53 # split version string into components, note CMAKE_MATCH_0 is the entire regexp match
  54 string(REGEX MATCH "([0-9]+)\\.([0-9]+)\\.([0-9]+)" CPACK_PACKAGE_VERSION ${SIMGEAR_VERSION} )
  55 set(CPACK_PACKAGE_VERSION_MAJOR ${CMAKE_MATCH_1})
  56 set(CPACK_PACKAGE_VERSION_MINOR ${CMAKE_MATCH_2})
  57 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_3})
  58
  59 message(STATUS "version is ${CPACK_PACKAGE_VERSION_MAJOR} dot ${CPACK_PACKAGE_VERSION_MINOR} dot ${CPACK_PACKAGE_VERSION_PATCH}")
  60
  61 set(CPACK_SOURCE_GENERATOR TBZ2)
  62 set(CPACK_SOURCE_PACKAGE_FILE_NAME "simgear-${SIMGEAR_VERSION}" CACHE INTERNAL "tarball basename")
  63 set(CPACK_SOURCE_IGNORE_FILES
  64   "^${PROJECT_SOURCE_DIR}/.git;\\\\.gitignore;Makefile.am;~$;${CPACK_SOURCE_IGNORE_FILES}")
  65
  66 message(STATUS "ignoring: ${CPACK_SOURCE_IGNORE_FILES}")
  67
  68 include (CPack)
  69
  70 # We have some custom .cmake scripts not in the official distribution.
  71 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  72
  73 # Change the default build type to something fast
  74 if(NOT CMAKE_BUILD_TYPE)
  75   set(CMAKE_BUILD_TYPE Release CACHE STRING
  76       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  77       FORCE)
  78 endif(NOT CMAKE_BUILD_TYPE)
  79
  80 # Determine name of library installation directory, i.e. "lib" vs "lib64", which
  81 # differs between all Debian-based vs all other Linux distros.
  82 # See cmake bug #11964, http://cmake.org/gitweb?p=cmake.git;a=commit;h=126c993d
  83 # GNUInstallDirs requires CMake >= 2.8.5, use own file for older cmake
  84 if(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  85   include(GNUInstallDirs)
  86 else(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  87   include(OldGNUInstallDirs)
  88 endif(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  89 message(STATUS "Library installation directory: ${CMAKE_INSTALL_LIBDIR}")
  90
  91 #####################################################################################
  92 # Configure library search paths
  93 #####################################################################################
  94
  95 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  96     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  97     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  98     # add paths manually
  99     # see http://www.cmake.org/Bug/view.php?id=12049 and
 100     # http://www.cmake.org/Bug/view.php?id=12037
 101     list(APPEND ADDITIONAL_LIBRARY_PATHS
 102          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
 103          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
 104          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
 105     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
 106 endif()
 107
 108 #####################################################################################
 109
 110 if (NOT MSVC)
 111 option(SIMGEAR_SHARED   "Set to ON to build SimGear as a shared library/framework" OFF)
 112 option(SYSTEM_EXPAT     "Set to ON to build SimGear using the system libExpat" OFF)
 113 else()
 114 # Building SimGear DLLs is currently not supported for MSVC.
 115 set(SIMGEAR_SHARED OFF)
 116 # Using a system expat is currently not supported for MSVC - it would require shared simgear (DLL).
 117 set(SYSTEM_EXPAT OFF)
 118 endif()
 119
 120 option(SIMGEAR_HEADLESS "Set to ON to build SimGear without GUI/graphics support" OFF)
 121 option(ENABLE_RTI       "Set to ON to build SimGear with RTI support" OFF)
 122 option(ENABLE_TESTS     "Set to OFF to disable building SimGear's test applications" ON)
 123 option(ENABLE_SOUND     "Set to OFF to disable building SimGear's sound support" ON)
 124 option(ENABLE_PKGUTIL   "Set to ON to build the sg_pkgutil application (default)" ON)
 125
 126 if (MSVC)
 127   GET_FILENAME_COMPONENT(PARENT_DIR ${PROJECT_BINARY_DIR} PATH)
 128   if (CMAKE_CL_64)
 129     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty.x64")
 130   else (CMAKE_CL_64)
 131     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty")
 132   endif (CMAKE_CL_64)
 133   if (EXISTS ${TEST_3RDPARTY_DIR})
 134     set(MSVC_3RDPARTY_ROOT ${PARENT_DIR} CACHE PATH "Location where the third-party dependencies are extracted")
 135   else (EXISTS ${TEST_3RDPARTY_DIR})
 136     set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 137   endif (EXISTS ${TEST_3RDPARTY_DIR})
 138 else (MSVC)
 139   set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 140 endif (MSVC)
 141
 142 if (MSVC AND MSVC_3RDPARTY_ROOT)
 143   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_ROOT}")
 144   set( OSG_MSVC "msvc" )
 145   if (${MSVC_VERSION} EQUAL 1700)
 146       set( OSG_MSVC ${OSG_MSVC}110 )
 147   elseif (${MSVC_VERSION} EQUAL 1600)
 148       set( OSG_MSVC ${OSG_MSVC}100 )
 149   else (${MSVC_VERSION} EQUAL 1700)
 150       set( OSG_MSVC ${OSG_MSVC}90 )
 151   endif (${MSVC_VERSION} EQUAL 1700)
 152   if (CMAKE_CL_64)
 153       set( OSG_MSVC ${OSG_MSVC}-64 )
 154       set( MSVC_3RDPARTY_DIR 3rdParty.x64 )
 155   else (CMAKE_CL_64)
 156       set( MSVC_3RDPARTY_DIR 3rdParty )
 157   endif (CMAKE_CL_64)
 158
 159   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/lib )
 160   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/include)
 161   find_path(BOOST_ROOT boost/version.hpp
 162                         ${MSVC_3RDPARTY_ROOT}/boost
 163                         ${MSVC_3RDPARTY_ROOT}/boost_1_52_0
 164                         ${MSVC_3RDPARTY_ROOT}/boost_1_51_0
 165                         ${MSVC_3RDPARTY_ROOT}/boost_1_50_0
 166                         ${MSVC_3RDPARTY_ROOT}/boost_1_49_0
 167                         ${MSVC_3RDPARTY_ROOT}/boost_1_48_0
 168                         ${MSVC_3RDPARTY_ROOT}/boost_1_47_0
 169                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_1
 170                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_0
 171                         ${MSVC_3RDPARTY_ROOT}/boost_1_45_0
 172                         ${MSVC_3RDPARTY_ROOT}/boost_1_44_0
 173                         )
 174   # set (BOOST_ROOT ${MSVC_3RDPARTY_ROOT}/boost_1_44_0)
 175   message(STATUS "BOOST_ROOT is ${BOOST_ROOT}")
 176   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 177   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib)
 178 endif (MSVC AND MSVC_3RDPARTY_ROOT)
 179
 180 if(APPLE)
 181   find_library(COCOA_LIBRARY Cocoa)
 182 endif()
 183
 184 if(${CMAKE_SYSTEM_NAME} MATCHES "Linux" OR
 185         ${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD")
 186     find_package(Threads REQUIRED)
 187 endif()
 188
 189 # Somehow this only works if included before searching for Boost...
 190 include(BoostTestTargets)
 191
 192 find_package(Boost REQUIRED)
 193 set (BOOST_CXX_FLAGS "-DBOOST_BIMAP_DISABLE_SERIALIZATION")
 194
 195 if(SIMGEAR_HEADLESS)
 196     message(STATUS "SimGear mode: HEADLESS")
 197     set(ENABLE_SOUND 0)
 198 else()
 199     message(STATUS "SimGear mode: NORMAL")
 200     find_package(OpenGL REQUIRED)
 201
 202     if (ENABLE_SOUND)
 203         find_package(OpenAL REQUIRED)
 204         message(STATUS "Sound support: ENABLED")
 205     endif(ENABLE_SOUND)
 206
 207     find_package(OpenSceneGraph 3.2.0 REQUIRED osgText osgSim osgDB osgParticle osgGA osgViewer osgUtil)
 208 endif(SIMGEAR_HEADLESS)
 209
 210 find_package(ZLIB REQUIRED)
 211
 212 if (SYSTEM_EXPAT)
 213     message(STATUS "Requested to use system Expat library, forcing SIMGEAR_SHARED to true")
 214     set(SIMGEAR_SHARED ON)
 215     find_package(EXPAT REQUIRED)
 216
 217 else()
 218     message(STATUS "Using built-in expat code")
 219     # XML_STATIC is important to avoid sg_expat_external.h
 220     # declaring symbols as declspec(import)
 221     add_definitions(-DHAVE_EXPAT_CONFIG_H -DXML_STATIC)
 222     set(EXPAT_INCLUDE_DIRS
 223             ${PROJECT_SOURCE_DIR}/3rdparty/expat
 224             ${PROJECT_BINARY_DIR}/3rdparty/expat)
 225 endif(SYSTEM_EXPAT)
 226
 227 include_directories(${EXPAT_INCLUDE_DIRS})
 228
 229 check_include_file(inttypes.h HAVE_INTTYPES_H)
 230 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 231 check_include_file(sys/timeb.h HAVE_SYS_TIMEB_H)
 232 check_include_file(unistd.h HAVE_UNISTD_H)
 233 check_include_file(windows.h HAVE_WINDOWS_H)
 234
 235 if(HAVE_INTTYPES_H)
 236   # ShivaVG needs inttypes.h
 237   add_definitions(-DHAVE_INTTYPES_H)
 238 endif()
 239
 240 if(ENABLE_RTI)
 241     # See if we have any rti library variant installed
 242     message(STATUS "RTI: ENABLED")
 243     find_package(RTI)
 244 else()
 245     message(STATUS "RTI: DISABLED")
 246 endif(ENABLE_RTI)
 247
 248 check_function_exists(gettimeofday HAVE_GETTIMEOFDAY)
 249 check_function_exists(ftime HAVE_FTIME)
 250 check_function_exists(timegm HAVE_TIMEGM)
 251 check_function_exists(rint HAVE_RINT)
 252 check_function_exists(mkdtemp HAVE_MKDTEMP)
 253 check_function_exists(bcopy HAVE_BCOPY)
 254 check_function_exists(mmap HAVE_MMAP)
 255
 256 if(HAVE_UNISTD_H)
 257     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 258     check_cxx_source_compiles(
 259        "#include <unistd.h>
 260         #if !defined(_POSIX_TIMERS) || (0 >= _POSIX_TIMERS)
 261             #error clock_gettime is not supported
 262         #endif
 263
 264         int main() { return 0; }
 265         "
 266         HAVE_CLOCK_GETTIME)
 267 endif(HAVE_UNISTD_H)
 268
 269 set(RT_LIBRARY "")
 270 if(HAVE_CLOCK_GETTIME)
 271     check_library_exists(rt clock_gettime "" HAVE_RT)
 272     if(HAVE_RT)
 273         set(RT_LIBRARY rt)
 274     endif(HAVE_RT)
 275 endif(HAVE_CLOCK_GETTIME)
 276
 277 set(DL_LIBRARY "")
 278 check_cxx_source_compiles(
 279     "#include <dlfcn.h>
 280     int main(void) {
 281         return 0;
 282     }
 283     "
 284     HAVE_DLFCN_H)
 285
 286 if(HAVE_DLFCN_H)
 287     check_library_exists(dl dlerror "" HAVE_DL)
 288     if(HAVE_DL)
 289         set(DL_LIBRARY "dl")
 290     endif()
 291 endif()
 292
 293 SET(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "add a postfix, usually 'd' on windows")
 294 SET(CMAKE_RELEASE_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 295 SET(CMAKE_RELWITHDEBINFO_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 296 SET(CMAKE_MINSIZEREL_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 297
 298 # isnan might not be real symbol, so can't check using function_exists
 299 check_cxx_source_compiles(
 300     "#include <cmath>
 301     int main() { return isnan(0.0);} "
 302     HAVE_ISNAN)
 303
 304 check_cxx_source_compiles(
 305     "#include <cmath>
 306     int main() { return std::isnan(0.0);} "
 307     HAVE_STD_ISNAN)
 308
 309 if(CMAKE_COMPILER_IS_GNUCXX)
 310     set(WARNING_FLAGS_CXX "-Wall")
 311     set(WARNING_FLAGS_C   "-Wall")
 312
 313     # certain GCC versions don't provide the atomic builds, and hence
 314     # require is to provide them in SGAtomic.cxx
 315     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 316     check_cxx_source_compiles(
 317        "int main() { unsigned mValue; return __sync_add_and_fetch(&mValue, 1); }"
 318         GCC_ATOMIC_BUILTINS_FOUND)
 319 endif(CMAKE_COMPILER_IS_GNUCXX)
 320
 321 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 322     # Boost redeclares class members
 323     set(WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual -Wno-redeclared-class-member")
 324     set(WARNING_FLAGS_C   "-Wall")
 325     set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LIBRARY "libc++")
 326     set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LANGUAGE_STANDARD "c++11")
 327     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -stdlib=libc++")
 328 endif()
 329
 330 if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 331 # boost goes haywire wrt static asserts
 332     check_cxx_compiler_flag(-Wno-unused-local-typedefs HAS_NOWARN_UNUSED_TYPEDEFS)
 333     if(HAS_NOWARN_UNUSED_TYPEDEFS)
 334         set(WARNING_FLAGS_CXX " ${WARNING_FLAGS_CXX} -Wno-unused-local-typedefs")
 335     endif()
 336 endif()
 337
 338 if(WIN32)
 339
 340     if(MINGW)
 341         add_definitions(-D_WIN32_WINNT=0x501)
 342     endif()
 343
 344     if(MSVC)
 345         # turn off various warnings
 346         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 347         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 348         # endforeach(warning)
 349
 350         set(MSVC_FLAGS "-DWIN32 -DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS /wd4996 /wd4250 -Dstrdup=_strdup")
 351         if (${MSVC_VERSION} GREATER 1599)
 352             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 353         endif (${MSVC_VERSION} GREATER 1599)
 354     endif(MSVC)
 355
 356     # assumed on Windows
 357     set(HAVE_GETLOCALTIME 1)
 358
 359     set( WINSOCK_LIBRARY "ws2_32.lib" )
 360     set( RT_LIBRARY "winmm" )
 361 endif(WIN32)
 362
 363 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS}")
 364 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} ${BOOST_CXX_FLAGS}")
 365 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 366
 367 # use BEFORE to ensure local directories are used first,
 368 # ahead of system-installed libs
 369 include_directories(BEFORE ${PROJECT_SOURCE_DIR})
 370 include_directories(BEFORE ${PROJECT_SOURCE_DIR}/simgear/canvas/ShivaVG/include)
 371 include_directories(BEFORE ${PROJECT_BINARY_DIR}/simgear)
 372
 373 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 374     ${Boost_INCLUDE_DIRS}
 375     ${ZLIB_INCLUDE_DIR}
 376     ${OPENAL_INCLUDE_DIR}
 377 )
 378
 379 add_definitions(-DHAVE_CONFIG_H)
 380
 381 # configure a header file to pass some of the CMake settings
 382 # to the source code
 383 configure_file (
 384   "${PROJECT_SOURCE_DIR}/simgear/simgear_config_cmake.h.in"
 385   "${PROJECT_BINARY_DIR}/simgear/simgear_config.h"
 386   )
 387
 388 if(ENABLE_TESTS)
 389     # enable CTest / make test target
 390     message(STATUS "Tests: ENABLED")
 391
 392     include (Dart)
 393     enable_testing()
 394 else()
 395     message(STATUS "Tests: DISABLED")
 396 endif(ENABLE_TESTS)
 397
 398 # always set TEST_LIBS as it is also used by other tools/applications
 399 set(TEST_LIBS_INTERNAL_CORE
 400     ${CMAKE_THREAD_LIBS_INIT}
 401     ${ZLIB_LIBRARY}
 402     ${WINSOCK_LIBRARY}
 403     ${RT_LIBRARY}
 404     ${DL_LIBRARY}
 405     ${COCOA_LIBRARY})
 406 set(TEST_LIBS SimGearCore ${TEST_LIBS_INTERNAL_CORE})
 407
 408 if(NOT SIMGEAR_HEADLESS)
 409     set(TEST_LIBS SimGearScene ${OPENGL_LIBRARIES} ${TEST_LIBS})
 410 endif()
 411
 412 install (FILES ${PROJECT_BINARY_DIR}/simgear/simgear_config.h  DESTINATION include/simgear/)
 413
 414 include_directories(3rdparty/utf8/source)
 415
 416 add_subdirectory(3rdparty)
 417 add_subdirectory(simgear)
 418
 419 #-----------------------------------------------------------------------------
 420 ### uninstall target
 421 #-----------------------------------------------------------------------------
 422 CONFIGURE_FILE(
 423   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 424   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 425   IMMEDIATE @ONLY)
 426 ADD_CUSTOM_TARGET(uninstall
 427   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
 428
 429