CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7
   8 project(FlightGear)
   9
  10 # We have some custom .cmake scripts not in the official distribution.
  11 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  12
  13 if(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  14     # use official include provided by latest CMake
  15     include(GNUInstallDirs)
  16 else(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  17     # backward compatibility: use our own module for older cmake versions
  18     include(OldGNUInstallDirs)
  19 endif(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  20
  21 # Warning when build is not an out-of-source build.
  22 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  23 if(InSourceBuild)
  24     message(WARNING  "Avoid building inside the source tree!")
  25     message(WARNING  "Create a separate build directory instead (i.e. 'fgbuild') and call CMake from there: ")
  26     message(WARNING  "  mkdir ../fgbuild && cd ../fgbuild && cmake ${CMAKE_SOURCE_DIR}")
  27 endif(InSourceBuild)
  28
  29 # System detection/default settings
  30 include( DetectDistro )
  31 include( DetectBrowser )
  32
  33 set(CMAKE_DEBUG_POSTFIX          "d" CACHE STRING "add a postfix, usually d on windows")
  34 set(CMAKE_RELEASE_POSTFIX        ""  CACHE STRING "add a postfix, usually empty on windows")
  35 set(CMAKE_RELWITHDEBINFO_POSTFIX ""  CACHE STRING "add a postfix, usually empty on windows")
  36 set(CMAKE_MINSIZEREL_POSTFIX     ""  CACHE STRING "add a postfix, usually empty on windows")
  37
  38 # read 'version' file into a variable (stripping any newlines or spaces)
  39 file(READ version versionFile)
  40 if (NOT versionFile)
  41     message(FATAL_ERROR "Unable to determine FlightGear version. Version file is missing.")
  42 endif()
  43 string(STRIP "${versionFile}" FLIGHTGEAR_VERSION)
  44
  45 # FlightGear packaging (to build a source tarball)
  46 include( ConfigureCPack )
  47
  48 # FlightGear base package path
  49 if (FG_DATA_DIR)
  50     message(STATUS "Using explicit data directory for base package: ${FG_DATA_DIR}")
  51 else()
  52     set(FG_DATA_DIR "${CMAKE_INSTALL_PREFIX}/lib/FlightGear" CACHE PATH "Default location where data files are located")
  53     message(STATUS "Using default data directory for base package:  ${FG_DATA_DIR}")
  54 endif()
  55
  56 # Change the default build type to something fast
  57 if(NOT CMAKE_BUILD_TYPE)
  58     set(CMAKE_BUILD_TYPE Release CACHE STRING
  59         "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  60         FORCE)
  61 endif(NOT CMAKE_BUILD_TYPE)
  62
  63 if(NOT "$ENV{BUILD_ID}" STREQUAL "")
  64     set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  65     set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  66     message(STATUS "running under Hudson/Jenkins, build-number is ${HUDSON_BUILD_NUMBER}")
  67 else()
  68     set(HUDSON_BUILD_NUMBER 0)
  69     set(HUDSON_BUILD_ID "none")
  70 endif()
  71
  72 #####################################################################################
  73 # Configure library search paths
  74 #####################################################################################
  75
  76
  77 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  78     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  79     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  80     # add paths manually
  81     # see http://www.cmake.org/Bug/view.php?id=12049 and
  82     # http://www.cmake.org/Bug/view.php?id=12037
  83     list(APPEND ADDITIONAL_LIBRARY_PATHS
  84          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  85          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  86          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
  87     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
  88 endif()
  89
  90 #####################################################################################
  91
  92 IF(APPLE)
  93     set(EVENT_INPUT_DEFAULT 1)
  94
  95     find_library(CORESERVICES_LIBRARY CoreServices)
  96     find_library(COCOA_LIBRARY Cocoa)
  97     list(APPEND PLATFORM_LIBS ${COCOA_LIBRARY} ${CORESERVICES_LIBRARY})
  98
  99 elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 100     set(USE_DBUS_DEFAULT 1)
 101     find_package(UDev)
 102
 103     if(UDEV_FOUND)
 104         set(EVENT_INPUT_DEFAULT 1)
 105     endif(UDEV_FOUND)
 106
 107     find_package(Speex)
 108     find_package(Speexdsp)
 109     if(SPEEX_FOUND AND SPEEXDSP_FOUND)
 110         set(SYSTEM_SPEEX_DEFAULT 1)
 111     endif(SPEEX_FOUND AND SPEEXDSP_FOUND)
 112
 113     find_package(Gsm)
 114     if(GSM_FOUND)
 115         set(SYSTEM_GSM_DEFAULT 1)
 116     endif(GSM_FOUND)
 117
 118     find_package(Flite)
 119     if(FLITE_FOUND)
 120         set(SYSTEM_FLITE_DEFAULT 1)
 121     endif()
 122
 123     find_package(HtsEngine)
 124     if(HTS_ENGINE_FOUND)
 125         set(SYSTEM_HTS_ENGINE_DEFAULT 1)
 126     endif()
 127 endif()
 128
 129 find_package(Git)
 130 if (GIT_FOUND)
 131     execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
 132         OUTPUT_VARIABLE REVISION
 133         OUTPUT_STRIP_TRAILING_WHITESPACE)
 134     message(STATUS "Git revision is ${REVISION}")
 135 else()
 136     set(REVISION "none")
 137 endif()
 138
 139 # FlightGear build options
 140 option(SIMGEAR_SHARED    "Set to ON when SimGear was built as a shared library" OFF)
 141 option(LOGGING           "Set to ON to build FlightGear with logging support (default)" ON)
 142 option(JSBSIM_TERRAIN    "Set to ON to build FlightGear with JSBSim terrain handling code" ON)
 143 option(SP_FDMS           "Set to ON to build FlightGear with special-purpose FDMs" OFF)
 144 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" OFF)
 145 option(ENABLE_LARCSIM    "Set to ON to build FlightGear with LaRCsim FDM" OFF)
 146 option(ENABLE_YASIM      "Set to ON to build FlightGear with YASIM FDM (default)" ON)
 147 option(ENABLE_JSBSIM     "Set to ON to build FlightGear with JSBSim FDM (default)" ON)
 148 option(EVENT_INPUT       "Set to ON to build FlightGear with event-based Input support" ${EVENT_INPUT_DEFAULT})
 149 option(ENABLE_RTI        "Set to ON to build FlightGear with RTI support" OFF)
 150 option(ENABLE_PROFILE    "Set to ON to build FlightGear with gperftools profiling support" OFF)
 151 option(SYSTEM_SQLITE     "Set to ON to build FlightGear with the system's SQLite3 library" OFF)
 152 option(ENABLE_IAX        "Set to ON to build FlightGear with IAXClient/fgcom built-in (default)" ON)
 153 option(USE_DBUS          "Set to ON to build FlightGear with DBus screensaver interaction (default on Linux)" ${USE_DBUS_DEFAULT})
 154 option(SYSTEM_SPEEX      "Set to ON to build IAXClient with the system's speex and speexdsp library" ${SYSTEM_SPEEX_DEFAULT})
 155 option(SYSTEM_GSM        "Set to ON to build IAXClient with the system's GSM library" ${SYSTEM_GSM_DEFAULT})
 156 option(SYSTEM_FLITE      "Set to ON to build Flightgear with the system's Flite library" ${SYSTEM_FLITE_DEFAULT})
 157 option(SYSTEM_HTS_ENGINE "Set to ON to build Flightgear with the system's HTS Engine library" ${SYSTEM_HTS_ENGINE_DEFAULT})
 158
 159 # additional utilities
 160 option(ENABLE_FGADMIN    "Set to ON to build the FGADMIN application (default)" ON)
 161 option(ENABLE_FGELEV     "Set to ON to build the fgelev application (default)" ON)
 162 option(WITH_FGPANEL      "Set to ON to build the fgpanel application (default)" ON)
 163 option(ENABLE_FGVIEWER   "Set to ON to build the fgviewer application (default)" ON)
 164 option(ENABLE_GPSSMOOTH  "Set to ON to build the GPSsmooth application (default)" ON)
 165 option(ENABLE_TERRASYNC  "Set to ON to build the terrasync application (default)" ON)
 166 option(ENABLE_FGJS       "Set to ON to build the fgjs application (default)" ON)
 167 option(ENABLE_JS_DEMO    "Set to ON to build the js_demo application (default)" ON)
 168 option(ENABLE_METAR      "Set to ON to build the metar application (default)" ON)
 169 option(ENABLE_TESTS      "Set to ON to build test applications (default)" ON)
 170 option(ENABLE_FGCOM      "Set to ON to build the FGCom application (default)" ON)
 171 option(ENABLE_FLITE      "Set to ON to build the Flite text-to-speech module" ON)
 172
 173 if(LOGGING)
 174     # nothing
 175 else()
 176     set(FG_NDEBUG 1)
 177 endif()
 178
 179 if(JSBSIM_TERRAIN)
 180    set(JSBSIM_USE_GROUNDREACTIONS 1)
 181 endif()
 182
 183 if(SP_FDMS)
 184     set(ENABLE_SP_FDM 1)
 185 endif()
 186
 187 if(ENABLE_FGCOM)
 188   set(ENABLE_IAX 1)
 189 endif()
 190
 191 # Setup MSVC 3rd party directories
 192 include( ConfigureMsvc3rdParty )
 193
 194 if(EVENT_INPUT)
 195     if(APPLE)
 196     elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 197         if(NOT UDEV_FOUND)
 198             message(WARNING "UDev not found, event input is disabled!")
 199             set(EVENT_INPUT 0)
 200         else()
 201             add_definitions(-DWITH_EVENTINPUT)
 202             set(EVENT_INPUT_LIBRARIES ${UDEV_LIBRARIES})
 203             message(STATUS "event-based input enabled. Using ${UDEV_LIBRARIES}")
 204         endif()
 205     else()
 206         message(WARNING "event-based input is not supported on this platform yet")
 207     endif()
 208
 209     # Keep PLIB INPUT enabled as long as EventInput does not replace current joystick configurations.
 210     set(ENABLE_PLIB_JOYSTICK 1)
 211 else(EVENT_INPUT)
 212     set(ENABLE_PLIB_JOYSTICK 1)
 213 endif(EVENT_INPUT)
 214
 215 # check required dependencies
 216 find_package(Boost   REQUIRED)
 217 find_package(ZLIB    REQUIRED)
 218 find_package(Threads REQUIRED)
 219 find_package(OpenGL  REQUIRED)
 220 find_package(OpenAL  REQUIRED)
 221 find_package(OpenSceneGraph 3.2.0 REQUIRED osgText osgSim osgDB osgParticle osgFX osgUtil osgViewer osgGA)
 222
 223 if (MSVC)
 224         find_package(CrashRpt)
 225         if (CRASHRPT_FOUND)
 226                 set(HAVE_CRASHRPT 1)
 227                 message(STATUS "Using CrashRpt")
 228         include_directories( ${CRASHRPT_INCLUDE_DIR})
 229         endif()
 230 endif()
 231
 232 ##############################################################################
 233 ## Sqlite3 setup
 234
 235 if (SYSTEM_SQLITE)
 236     find_package(SQLite3 REQUIRED)
 237
 238     message(STATUS "Using system SQLite3 library")
 239 else()
 240     set(SQLITE3_INCLUDED_DIR "${CMAKE_SOURCE_DIR}/3rdparty/sqlite3")
 241     # this target is defined in src/Navaids/CMakeLists.txt
 242     list(APPEND SQLITE3_LIBRARY fgsqlite3)
 243 endif (SYSTEM_SQLITE)
 244
 245 # Sqlite always depends on the threading lib
 246 list(APPEND SQLITE3_LIBRARY ${CMAKE_THREAD_LIBS_INIT})
 247
 248 ##############################################################################
 249 ## DBus setup
 250
 251 if (USE_DBUS)
 252     include(FindPkgConfig)
 253     if (PKG_CONFIG_FOUND)
 254         pkg_check_modules(DBUS dbus-1)
 255     endif (PKG_CONFIG_FOUND) #if we don't have pkg-config, assume we don't have libdbus-1-dev either http://packages.debian.org/sid/libdbus-1-dev
 256     if (DBUS_FOUND)
 257         set(HAVE_DBUS 1)
 258         message(STATUS "Using DBus")
 259         include_directories( ${DBUS_INCLUDE_DIRS})
 260     else()
 261         message(STATUS "DBus not found, screensaver control disabled")
 262     endif (DBUS_FOUND)
 263 else()
 264 endif (USE_DBUS)
 265
 266 # Sqlite always depends on the threading lib
 267 list(APPEND SQLITE3_LIBRARY ${CMAKE_THREAD_LIBS_INIT})
 268
 269 ##############################################################################
 270
 271 find_package(PLIB REQUIRED puaux pu js fnt)
 272
 273 # FlightGear and SimGear versions need to match
 274 find_package(SimGear ${FLIGHTGEAR_VERSION} REQUIRED)
 275
 276 ##############################################################################
 277
 278 check_include_file(unistd.h   HAVE_UNISTD_H)
 279 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 280 check_include_file(windows.h  HAVE_WINDOWS_H)
 281
 282 if(ENABLE_PROFILE)
 283     find_package(GooglePerfTools REQUIRED)
 284     set(FG_HAVE_GPERFTOOLS 1)
 285     message(STATUS "Built-in profiler using gperftools available")
 286 endif()
 287
 288 if(ENABLE_RTI)
 289     message(STATUS "RTI: ENABLED")
 290     find_package(RTI)
 291     if(RTI_FOUND)
 292         set(FG_HAVE_HLA 1)
 293     endif(RTI_FOUND)
 294 else()
 295     message(STATUS "RTI: DISABLED")
 296 endif(ENABLE_RTI)
 297
 298 if(CMAKE_COMPILER_IS_GNUCXX)
 299     set(WARNING_FLAGS_CXX "-Wall")
 300     set(WARNING_FLAGS_C   "-Wall")
 301 endif(CMAKE_COMPILER_IS_GNUCXX)
 302
 303 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 304    set (WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual")
 305    set (WARNING_FLAGS_C   "-Wall")
 306 endif()
 307
 308 if(WIN32)
 309
 310     if(MSVC)
 311         # turn off various warnings
 312         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 313         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 314         # endforeach(warning)
 315
 316         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS -Dstrdup=_strdup")
 317         if (${MSVC_VERSION} GREATER 1599)
 318             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 319         endif (${MSVC_VERSION} GREATER 1599)
 320     endif(MSVC)
 321
 322     set(NOMINMAX 1)
 323 endif(WIN32)
 324
 325 set (BOOST_CXX_FLAGS "-DBOOST_MULTI_INDEX_DISABLE_SERIALIZATION -DBOOST_BIMAP_DISABLE_SERIALIZATION")
 326
 327 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS} -D_REENTRANT")
 328 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} -D_REENTRANT ${BOOST_CXX_FLAGS}")
 329 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 330
 331 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 332     ${Boost_INCLUDE_DIRS}
 333     ${ZLIB_INCLUDE_DIR}
 334     ${OPENGL_INCLUDE_DIR}
 335     ${OPENAL_INCLUDE_DIR}
 336     ${SIMGEAR_INCLUDE_DIR}
 337     ${PLIB_INCLUDE_DIR}
 338     ${SQLITE3_INCLUDED_DIR} )
 339
 340 include_directories(${PROJECT_SOURCE_DIR})
 341 include_directories(${PROJECT_SOURCE_DIR}/src)
 342 include_directories(${PROJECT_SOURCE_DIR}/3rdparty/iaxclient/lib ) # for iaxclient.h
 343 # following is needed, because config.h is include 'bare', whereas
 344 # version.h is included as <Include/version.h> - this should be cleaned up
 345 include_directories(${PROJECT_BINARY_DIR}/src)
 346 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 347
 348 if (ENABLE_FLITE)
 349     include_directories(${PROJECT_SOURCE_DIR}/3rdparty/hts_engine_API/include )
 350     include_directories(${PROJECT_SOURCE_DIR}/3rdparty/flite_hts_engine/include )
 351 endif()
 352
 353 add_definitions(-DHAVE_CONFIG_H)
 354
 355 check_function_exists(mkfifo HAVE_MKFIFO)
 356
 357 # configure a header file to pass some of the CMake settings
 358 # to the source code
 359 configure_file (
 360     "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 361     "${PROJECT_BINARY_DIR}/src/Include/config.h"
 362 )
 363
 364 #and the same for the version header
 365 configure_file (
 366     "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 367     "${PROJECT_BINARY_DIR}/src/Include/version.h"
 368 )
 369
 370 add_subdirectory(3rdparty)
 371 add_subdirectory(utils)
 372 add_subdirectory(src)
 373 add_subdirectory(man)
 374
 375 #-----------------------------------------------------------------------------
 376 ### uninstall target
 377 #-----------------------------------------------------------------------------
 378 CONFIGURE_FILE(
 379     "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 380     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 381     IMMEDIATE @ONLY)
 382 ADD_CUSTOM_TARGET(uninstall
 383     "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")