CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2 include (CheckFunctionExists)
   3 include (CheckIncludeFile)
   4 include (CheckCXXSourceCompiles)
   5 include (CheckCXXCompilerFlag)
   6
   7 project(SimGear)
   8
   9 # read 'version' file into a variable (stripping any newlines or spaces)
  10 file(READ version versionFile)
  11 string(STRIP ${versionFile} SIMGEAR_VERSION)
  12
  13 set(FIND_LIBRARY_USE_LIB64_PATHS ON)
  14
  15 # use simgear version also as the SO version (if building SOs)
  16 SET(SIMGEAR_SOVERSION ${SIMGEAR_VERSION})
  17
  18 # Warning when build is not an out-of-source build.
  19 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  20 if(InSourceBuild)
  21     message(WARNING  "Avoid building inside the source tree!")
  22     message(WARNING  "Create a separate build directory instead (i.e. 'sgbuild') and call CMake from there: ")
  23     message(WARNING  "  mkdir ../sgbuild && cd ../sgbuild && cmake ${CMAKE_SOURCE_DIR}")
  24 endif(InSourceBuild)
  25
  26 #packaging
  27 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  28 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  29 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Simulation support libraries for FlightGear and related projects")
  30 SET(CPACK_PACKAGE_VENDOR "The FlightGear project")
  31 SET(CPACK_GENERATOR "TBZ2")
  32 SET(CPACK_INSTALL_CMAKE_PROJECTS  ${CMAKE_CURRENT_BINARY_DIR};SimGear;ALL;/)
  33
  34
  35 # split version string into components, note CMAKE_MATCH_0 is the entire regexp match
  36 string(REGEX MATCH "([0-9]+)\\.([0-9]+)\\.([0-9]+)" CPACK_PACKAGE_VERSION ${SIMGEAR_VERSION} )
  37 set(CPACK_PACKAGE_VERSION_MAJOR ${CMAKE_MATCH_1})
  38 set(CPACK_PACKAGE_VERSION_MINOR ${CMAKE_MATCH_2})
  39 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_3})
  40
  41 message(STATUS "version is ${CPACK_PACKAGE_VERSION_MAJOR} dot ${CPACK_PACKAGE_VERSION_MINOR} dot ${CPACK_PACKAGE_VERSION_PATCH}")
  42
  43 set(CPACK_SOURCE_GENERATOR TBZ2)
  44 set(CPACK_SOURCE_PACKAGE_FILE_NAME "simgear-${SIMGEAR_VERSION}" CACHE INTERNAL "tarball basename")
  45 set(CPACK_SOURCE_IGNORE_FILES
  46   "^${PROJECT_SOURCE_DIR}/.git;\\\\.gitignore;Makefile.am;~$;${CPACK_SOURCE_IGNORE_FILES}")
  47
  48 message(STATUS "ignoring: ${CPACK_SOURCE_IGNORE_FILES}")
  49
  50 include (CPack)
  51
  52 # We have some custom .cmake scripts not in the official distribution.
  53 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  54
  55 # Change the default build type to something fast
  56 if(NOT CMAKE_BUILD_TYPE)
  57   set(CMAKE_BUILD_TYPE Release CACHE STRING
  58       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  59       FORCE)
  60 endif(NOT CMAKE_BUILD_TYPE)
  61
  62 # Determine name of library installation directory, i.e. "lib" vs "lib64", which
  63 # differs between all Debian-based vs all other Linux distros.
  64 # See cmake bug #11964, http://cmake.org/gitweb?p=cmake.git;a=commit;h=126c993d
  65 # GNUInstallDirs requires CMake >= 2.8.5, use own file for older cmake
  66 if(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  67   include(GNUInstallDirs)
  68 else(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  69   include(OldGNUInstallDirs)
  70 endif(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  71 message(STATUS "Library installation directory: ${CMAKE_INSTALL_LIBDIR}")
  72
  73 #####################################################################################
  74 # Configure library search paths
  75 #####################################################################################
  76
  77 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  78     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  79     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  80     # add paths manually
  81     # see http://www.cmake.org/Bug/view.php?id=12049 and
  82     # http://www.cmake.org/Bug/view.php?id=12037
  83     list(APPEND ADDITIONAL_LIBRARY_PATHS
  84          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  85          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  86          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
  87     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
  88 endif()
  89
  90 #####################################################################################
  91
  92 if (NOT MSVC)
  93 option(SIMGEAR_SHARED   "Set to ON to build SimGear as a shared library/framework" OFF)
  94 option(SYSTEM_EXPAT     "Set to ON to build SimGear using the system libExpat" OFF)
  95 else()
  96 # Building SimGear DLLs is currently not supported for MSVC.
  97 set(SIMGEAR_SHARED OFF)
  98 # Using a system expat is currently not supported for MSVC - it would require shared simgear (DLL).
  99 set(SYSTEM_EXPAT OFF)
 100 endif()
 101
 102 option(SIMGEAR_HEADLESS "Set to ON to build SimGear without GUI/graphics support" OFF)
 103 option(ENABLE_RTI       "Set to ON to build SimGear with RTI support" OFF)
 104 option(ENABLE_TESTS     "Set to OFF to disable building SimGear's test applications" ON)
 105 option(ENABLE_SOUND     "Set to OFF to disable building SimGear's sound support" ON)
 106 option(ENABLE_PKGUTIL   "Set to ON to build the sg_pkgutil application (default)" ON)
 107
 108 if (MSVC)
 109   GET_FILENAME_COMPONENT(PARENT_DIR ${PROJECT_BINARY_DIR} PATH)
 110   if (CMAKE_CL_64)
 111     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty.x64")
 112   else (CMAKE_CL_64)
 113     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty")
 114   endif (CMAKE_CL_64)
 115   if (EXISTS ${TEST_3RDPARTY_DIR})
 116     set(MSVC_3RDPARTY_ROOT ${PARENT_DIR} CACHE PATH "Location where the third-party dependencies are extracted")
 117   else (EXISTS ${TEST_3RDPARTY_DIR})
 118     set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 119   endif (EXISTS ${TEST_3RDPARTY_DIR})
 120 else (MSVC)
 121   set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 122 endif (MSVC)
 123
 124 if (MSVC AND MSVC_3RDPARTY_ROOT)
 125   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_ROOT}")
 126   set( OSG_MSVC "msvc" )
 127   if (${MSVC_VERSION} EQUAL 1700)
 128       set( OSG_MSVC ${OSG_MSVC}110 )
 129   elseif (${MSVC_VERSION} EQUAL 1600)
 130       set( OSG_MSVC ${OSG_MSVC}100 )
 131   else (${MSVC_VERSION} EQUAL 1700)
 132       set( OSG_MSVC ${OSG_MSVC}90 )
 133   endif (${MSVC_VERSION} EQUAL 1700)
 134   if (CMAKE_CL_64)
 135       set( OSG_MSVC ${OSG_MSVC}-64 )
 136       set( MSVC_3RDPARTY_DIR 3rdParty.x64 )
 137   else (CMAKE_CL_64)
 138       set( MSVC_3RDPARTY_DIR 3rdParty )
 139   endif (CMAKE_CL_64)
 140
 141   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/lib )
 142   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/include)
 143   find_path(BOOST_ROOT boost/version.hpp
 144                         ${MSVC_3RDPARTY_ROOT}/boost
 145                         ${MSVC_3RDPARTY_ROOT}/boost_1_52_0
 146                         ${MSVC_3RDPARTY_ROOT}/boost_1_51_0
 147                         ${MSVC_3RDPARTY_ROOT}/boost_1_50_0
 148                         ${MSVC_3RDPARTY_ROOT}/boost_1_49_0
 149                         ${MSVC_3RDPARTY_ROOT}/boost_1_48_0
 150                         ${MSVC_3RDPARTY_ROOT}/boost_1_47_0
 151                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_1
 152                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_0
 153                         ${MSVC_3RDPARTY_ROOT}/boost_1_45_0
 154                         ${MSVC_3RDPARTY_ROOT}/boost_1_44_0
 155                         )
 156   # set (BOOST_ROOT ${MSVC_3RDPARTY_ROOT}/boost_1_44_0)
 157   message(STATUS "BOOST_ROOT is ${BOOST_ROOT}")
 158   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 159   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib)
 160 endif (MSVC AND MSVC_3RDPARTY_ROOT)
 161
 162 if(APPLE)
 163   find_library(COCOA_LIBRARY Cocoa)
 164 endif()
 165
 166 # Somehow this only works if included before searching for Boost...
 167 include(BoostTestTargets)
 168
 169 find_package(Boost REQUIRED)
 170 set (BOOST_CXX_FLAGS "-DBOOST_MULTI_INDEX_DISABLE_SERIALIZATION -DBOOST_BIMAP_DISABLE_SERIALIZATION")
 171
 172 if(SIMGEAR_HEADLESS)
 173     message(STATUS "SimGear mode: HEADLESS")
 174     set(ENABLE_SOUND 0)
 175 else()
 176     message(STATUS "SimGear mode: NORMAL")
 177     find_package(OpenGL REQUIRED)
 178
 179     if (ENABLE_SOUND)
 180         find_package(OpenAL REQUIRED)
 181         message(STATUS "Sound support: ENABLED")
 182     endif(ENABLE_SOUND)
 183
 184     find_package(OpenSceneGraph 3.2.0 REQUIRED osgText osgSim osgDB osgParticle osgGA osgUtil)
 185 endif(SIMGEAR_HEADLESS)
 186
 187 find_package(ZLIB REQUIRED)
 188 find_package(Threads REQUIRED)
 189
 190 if (SYSTEM_EXPAT)
 191     message(STATUS "Requested to use system Expat library, forcing SIMGEAR_SHARED to true")
 192     set(SIMGEAR_SHARED ON)
 193     find_package(EXPAT REQUIRED)
 194
 195 else()
 196     message(STATUS "Using built-in expat code")
 197     # XML_STATIC is important to avoid sg_expat_external.h
 198     # declaring symbols as declspec(import)
 199     add_definitions(-DHAVE_EXPAT_CONFIG_H -DXML_STATIC)
 200     set(EXPAT_INCLUDE_DIRS
 201             ${PROJECT_SOURCE_DIR}/3rdparty/expat
 202             ${PROJECT_BINARY_DIR}/3rdparty/expat)
 203 endif(SYSTEM_EXPAT)
 204
 205 include_directories(${EXPAT_INCLUDE_DIRS})
 206
 207 check_include_file(inttypes.h HAVE_INTTYPES_H)
 208 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 209 check_include_file(sys/timeb.h HAVE_SYS_TIMEB_H)
 210 check_include_file(unistd.h HAVE_UNISTD_H)
 211 check_include_file(windows.h HAVE_WINDOWS_H)
 212
 213 if(HAVE_INTTYPES_H)
 214   # ShivaVG needs inttypes.h
 215   add_definitions(-DHAVE_INTTYPES_H)
 216 endif()
 217
 218 if(ENABLE_RTI)
 219     # See if we have any rti library variant installed
 220     message(STATUS "RTI: ENABLED")
 221     find_package(RTI)
 222 else()
 223     message(STATUS "RTI: DISABLED")
 224 endif(ENABLE_RTI)
 225
 226 check_function_exists(gettimeofday HAVE_GETTIMEOFDAY)
 227 check_function_exists(ftime HAVE_FTIME)
 228 check_function_exists(timegm HAVE_TIMEGM)
 229 check_function_exists(rint HAVE_RINT)
 230 check_function_exists(mkdtemp HAVE_MKDTEMP)
 231 check_function_exists(bcopy HAVE_BCOPY)
 232 check_function_exists(mmap HAVE_MMAP)
 233
 234 if(HAVE_UNISTD_H)
 235     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 236     check_cxx_source_compiles(
 237        "#include <unistd.h>
 238         #if !defined(_POSIX_TIMERS) || (0 >= _POSIX_TIMERS)
 239             #error clock_gettime is not supported
 240         #endif
 241
 242         int main() { return 0; }
 243         "
 244         HAVE_CLOCK_GETTIME)
 245 endif(HAVE_UNISTD_H)
 246
 247 set(RT_LIBRARY "")
 248 if(HAVE_CLOCK_GETTIME)
 249     check_library_exists(rt clock_gettime "" HAVE_RT)
 250     if(HAVE_RT)
 251         set(RT_LIBRARY rt)
 252     endif(HAVE_RT)
 253 endif(HAVE_CLOCK_GETTIME)
 254
 255 set(DL_LIBRARY "")
 256 check_cxx_source_compiles(
 257     "#include <dlfcn.h>
 258     int main(void) {
 259         return 0;
 260     }
 261     "
 262     HAVE_DLFCN_H)
 263
 264 if(HAVE_DLFCN_H)
 265     check_library_exists(dl dlerror "" HAVE_DL)
 266     if(HAVE_DL)
 267         set(DL_LIBRARY "dl")
 268     endif()
 269 endif()
 270
 271 SET(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "add a postfix, usually 'd' on windows")
 272 SET(CMAKE_RELEASE_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 273 SET(CMAKE_RELWITHDEBINFO_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 274 SET(CMAKE_MINSIZEREL_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 275
 276 # isnan might not be real symbol, so can't check using function_exists
 277 check_cxx_source_compiles(
 278     "#include <cmath>
 279     void f() { isnan(0.0);} "
 280     HAVE_ISNAN)
 281
 282 check_cxx_source_compiles(
 283     "#include <cmath>
 284     void f() { std::isnan(0.0);} "
 285     HAVE_STD_ISNAN)
 286
 287 if(CMAKE_COMPILER_IS_GNUCXX)
 288     set(WARNING_FLAGS_CXX "-Wall")
 289     set(WARNING_FLAGS_C   "-Wall")
 290
 291     # certain GCC versions don't provide the atomic builds, and hence
 292     # require is to provide them in SGAtomic.cxx
 293     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 294     check_cxx_source_compiles(
 295        "int main() { unsigned mValue; return __sync_add_and_fetch(&mValue, 1); }"
 296         GCC_ATOMIC_BUILTINS_FOUND)
 297 endif(CMAKE_COMPILER_IS_GNUCXX)
 298
 299 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 300    set(WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual")
 301    set(WARNING_FLAGS_C   "-Wall")
 302 endif()
 303
 304 if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 305 # boost goes haywire wrt static asserts
 306     check_cxx_compiler_flag(-Wno-unused-local-typedefs HAS_NOWARN_UNUSED_TYPEDEFS)
 307     if(HAS_NOWARN_UNUSED_TYPEDEFS)
 308         set(WARNING_FLAGS_CXX " ${WARNING_FLAGS_CXX} -Wno-unused-local-typedefs")
 309     endif()
 310 endif()
 311
 312 if(WIN32)
 313
 314     if(MINGW)
 315         add_definitions(-D_WIN32_WINNT=0x501)
 316     endif()
 317
 318     if(MSVC)
 319         # turn off various warnings
 320         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 321         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 322         # endforeach(warning)
 323
 324         set(MSVC_FLAGS "-DWIN32 -DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS /wd4996 /wd4250 -Dstrdup=_strdup")
 325         if (${MSVC_VERSION} GREATER 1599)
 326             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 327         endif (${MSVC_VERSION} GREATER 1599)
 328     endif(MSVC)
 329
 330     # assumed on Windows
 331     set(HAVE_GETLOCALTIME 1)
 332
 333     set( WINSOCK_LIBRARY "ws2_32.lib" )
 334     set( RT_LIBRARY "winmm" )
 335 endif(WIN32)
 336
 337 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS}")
 338 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} ${BOOST_CXX_FLAGS}")
 339 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 340
 341 # use BEFORE to ensure local directories are used first,
 342 # ahead of system-installed libs
 343 include_directories(BEFORE ${PROJECT_SOURCE_DIR})
 344 include_directories(BEFORE ${PROJECT_SOURCE_DIR}/simgear/canvas/ShivaVG/include)
 345 include_directories(BEFORE ${PROJECT_BINARY_DIR}/simgear)
 346
 347 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 348     ${Boost_INCLUDE_DIRS}
 349     ${ZLIB_INCLUDE_DIR}
 350     ${OPENAL_INCLUDE_DIR}
 351 )
 352
 353 add_definitions(-DHAVE_CONFIG_H)
 354
 355 # configure a header file to pass some of the CMake settings
 356 # to the source code
 357 configure_file (
 358   "${PROJECT_SOURCE_DIR}/simgear/simgear_config_cmake.h.in"
 359   "${PROJECT_BINARY_DIR}/simgear/simgear_config.h"
 360   )
 361
 362 if(ENABLE_TESTS)
 363     # enable CTest / make test target
 364     message(STATUS "Tests: ENABLED")
 365
 366     include (Dart)
 367     enable_testing()
 368 else()
 369     message(STATUS "Tests: DISABLED")
 370 endif(ENABLE_TESTS)
 371
 372 # always set TEST_LIBS as it is also used by other tools/applications
 373 set(TEST_LIBS_INTERNAL_CORE
 374     ${CMAKE_THREAD_LIBS_INIT}
 375     ${ZLIB_LIBRARY}
 376     ${WINSOCK_LIBRARY}
 377     ${RT_LIBRARY}
 378     ${DL_LIBRARY}
 379     ${COCOA_LIBRARY})
 380 set(TEST_LIBS SimGearCore ${TEST_LIBS_INTERNAL_CORE})
 381
 382 if(NOT SIMGEAR_HEADLESS)
 383     set(TEST_LIBS SimGearScene ${OPENGL_LIBRARIES} ${TEST_LIBS})
 384 endif()
 385
 386 install (FILES ${PROJECT_BINARY_DIR}/simgear/simgear_config.h  DESTINATION include/simgear/)
 387
 388 add_subdirectory(3rdparty)
 389 add_subdirectory(simgear)
 390
 391 #-----------------------------------------------------------------------------
 392 ### uninstall target
 393 #-----------------------------------------------------------------------------
 394 CONFIGURE_FILE(
 395   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 396   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 397   IMMEDIATE @ONLY)
 398 ADD_CUSTOM_TARGET(uninstall
 399   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
 400
 401