CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8.11)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7
   8 if(COMMAND cmake_policy)
   9    if(POLICY CMP0054)
  10        cmake_policy(SET CMP0054 NEW)
  11    endif()
  12    # Mac RPATH policy
  13    if(POLICY CMP0042)
  14        cmake_policy(SET CMP0042 NEW)
  15    endif()
  16 endif()
  17
  18 if(APPLE)
  19         # using 10.7 because boost requires libc++ and 10.6 doesn't include it
  20         set(CMAKE_OSX_DEPLOYMENT_TARGET 10.7)
  21
  22         set(CMAKE_INSTALL_RPATH "@loader_path/../Frameworks")
  23         # when building, don't use the install RPATH already
  24         # (but later on when installing)
  25         SET(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
  26 endif()
  27
  28 project(FlightGear)
  29
  30 # We have some custom .cmake scripts not in the official distribution.
  31 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  32
  33 # Warning when build is not an out-of-source build.
  34 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  35 if(InSourceBuild)
  36     message(WARNING  "Avoid building inside the source tree!")
  37     message(WARNING  "Create a separate build directory instead (i.e. 'fgbuild') and call CMake from there: ")
  38     message(WARNING  "  mkdir ../fgbuild && cd ../fgbuild && cmake ${CMAKE_SOURCE_DIR}")
  39 endif(InSourceBuild)
  40
  41 include(GNUInstallDirs)
  42 # System detection/default settings
  43 include( DetectDistro )
  44 include( DetectBrowser )
  45
  46 set(CMAKE_DEBUG_POSTFIX          "d" CACHE STRING "add a postfix, usually d on windows")
  47 set(CMAKE_RELEASE_POSTFIX        ""  CACHE STRING "add a postfix, usually empty on windows")
  48 set(CMAKE_RELWITHDEBINFO_POSTFIX ""  CACHE STRING "add a postfix, usually empty on windows")
  49 set(CMAKE_MINSIZEREL_POSTFIX     ""  CACHE STRING "add a postfix, usually empty on windows")
  50
  51 # read 'version' file into a variable (stripping any newlines or spaces)
  52 file(READ version versionFile)
  53 if (NOT versionFile)
  54     message(FATAL_ERROR "Unable to determine FlightGear version. Version file is missing.")
  55 endif()
  56 string(STRIP "${versionFile}" FLIGHTGEAR_VERSION)
  57 # add a dependency on the versino file
  58 set_property(DIRECTORY APPEND PROPERTY CMAKE_CONFIGURE_DEPENDS version)
  59
  60 # FlightGear packaging (to build a source tarball)
  61 include( ConfigureCPack )
  62
  63 # FlightGear base package path
  64 if (FG_DATA_DIR)
  65     message(STATUS "Using explicit data directory for base package: ${FG_DATA_DIR}")
  66 else()
  67     set(FG_DATA_DIR "${CMAKE_INSTALL_PREFIX}/lib/FlightGear" CACHE PATH "Default location where data files are located")
  68     message(STATUS "Using default data directory for base package:  ${FG_DATA_DIR}")
  69 endif()
  70
  71 # Change the default build type to something fast
  72 if(NOT CMAKE_BUILD_TYPE)
  73     set(CMAKE_BUILD_TYPE Release CACHE STRING
  74         "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  75         FORCE)
  76 endif(NOT CMAKE_BUILD_TYPE)
  77
  78 if(NOT "$ENV{BUILD_ID}" STREQUAL "")
  79     set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  80     set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  81     message(STATUS "running under Hudson/Jenkins, build-number is ${HUDSON_BUILD_NUMBER}")
  82 else()
  83     set(HUDSON_BUILD_NUMBER 0)
  84     set(HUDSON_BUILD_ID "none")
  85 endif()
  86
  87 #####################################################################################
  88 # Configure library search paths
  89 #####################################################################################
  90
  91
  92 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  93     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  94     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  95     # add paths manually
  96     # see http://www.cmake.org/Bug/view.php?id=12049 and
  97     # http://www.cmake.org/Bug/view.php?id=12037
  98     list(APPEND ADDITIONAL_LIBRARY_PATHS
  99          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
 100          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
 101          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
 102     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
 103 endif()
 104
 105 #####################################################################################
 106
 107 IF(APPLE)
 108     set(EVENT_INPUT_DEFAULT 1)
 109
 110     find_library(CORESERVICES_LIBRARY CoreServices)
 111     find_library(COCOA_LIBRARY Cocoa)
 112     list(APPEND PLATFORM_LIBS ${COCOA_LIBRARY} ${CORESERVICES_LIBRARY})
 113
 114     # using 10.7 because boost requires libc++ and 10.6 doesn't include it
 115     SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.7")
 116     SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.7")
 117 elseif(WIN32)
 118     list(APPEND PLATFORM_LIBS "Shlwapi.lib")
 119 elseif(${CMAKE_SYSTEM_NAME} MATCHES "Linux" OR
 120         ${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD")
 121     find_package(Threads REQUIRED)
 122     find_package(X11 REQUIRED)
 123
 124     set(USE_DBUS_DEFAULT 1)
 125
 126     find_package(UDev)
 127     if(UDEV_FOUND)
 128         set(EVENT_INPUT_DEFAULT 1)
 129     endif(UDEV_FOUND)
 130
 131     find_package(Speex)
 132     find_package(Speexdsp)
 133     if(SPEEX_FOUND AND SPEEXDSP_FOUND)
 134         set(SYSTEM_SPEEX_DEFAULT 1)
 135     endif(SPEEX_FOUND AND SPEEXDSP_FOUND)
 136
 137     find_package(Gsm)
 138     if(GSM_FOUND)
 139         set(SYSTEM_GSM_DEFAULT 1)
 140     endif(GSM_FOUND)
 141
 142     find_package(Flite)
 143     if(FLITE_FOUND)
 144         set(SYSTEM_FLITE_DEFAULT 1)
 145     endif()
 146
 147     find_package(HtsEngine)
 148     if(HTS_ENGINE_FOUND)
 149         set(SYSTEM_HTS_ENGINE_DEFAULT 1)
 150     endif()
 151 endif()
 152
 153 find_package(Git)
 154 if (GIT_FOUND)
 155     execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
 156         OUTPUT_VARIABLE REVISION
 157         OUTPUT_STRIP_TRAILING_WHITESPACE)
 158     message(STATUS "Git revision is ${REVISION}")
 159 else()
 160     set(REVISION "none")
 161 endif()
 162
 163 # FlightGear build options
 164 option(SIMGEAR_SHARED    "Set to ON when SimGear was built as a shared library" OFF)
 165 option(LOGGING           "Set to ON to build FlightGear with logging support (default)" ON)
 166 option(JSBSIM_TERRAIN    "Set to ON to build FlightGear with JSBSim terrain handling code" ON)
 167 option(SP_FDMS           "Set to ON to build FlightGear with special-purpose FDMs" ON)
 168 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" ON)
 169 option(ENABLE_LARCSIM    "Set to ON to build FlightGear with LaRCsim FDM" ON)
 170 option(ENABLE_YASIM      "Set to ON to build FlightGear with YASIM FDM (default)" ON)
 171 option(ENABLE_JSBSIM     "Set to ON to build FlightGear with JSBSim FDM (default)" ON)
 172 option(EVENT_INPUT       "Set to ON to build FlightGear with event-based Input support" ${EVENT_INPUT_DEFAULT})
 173 option(ENABLE_RTI        "Set to ON to build FlightGear with RTI support" OFF)
 174 option(ENABLE_PROFILE    "Set to ON to build FlightGear with gperftools profiling support" OFF)
 175 option(SYSTEM_SQLITE     "Set to ON to build FlightGear with the system's SQLite3 library" OFF)
 176 option(ENABLE_IAX        "Set to ON to build FlightGear with IAXClient/fgcom built-in (default)" ON)
 177 option(USE_DBUS          "Set to ON to build FlightGear with DBus screensaver interaction (default on Linux)" ${USE_DBUS_DEFAULT})
 178 option(USE_AEONWAVE      "Set to ON to use AeonWave instead of OpenAL" OFF)
 179 option(SYSTEM_SPEEX      "Set to ON to build IAXClient with the system's speex and speexdsp library" ${SYSTEM_SPEEX_DEFAULT})
 180 option(SYSTEM_GSM        "Set to ON to build IAXClient with the system's GSM library" ${SYSTEM_GSM_DEFAULT})
 181 option(SYSTEM_FLITE      "Set to ON to build Flightgear with the system's Flite library" ${SYSTEM_FLITE_DEFAULT})
 182 option(SYSTEM_HTS_ENGINE "Set to ON to build Flightgear with the system's HTS Engine library" ${SYSTEM_HTS_ENGINE_DEFAULT})
 183 option(FG_NIGHTLY        "Set to ON to mark this as a nightly build" OFF)
 184 option(ENABLE_DEV_WARNINGS "Set to ON to include developer-warnings" OFF)
 185
 186 # additional utilities
 187 option(ENABLE_FGELEV     "Set to ON to build the fgelev application (default)" ON)
 188 option(WITH_FGPANEL      "Set to ON to build the fgpanel application (default)" ON)
 189 option(ENABLE_FGVIEWER   "Set to ON to build the fgviewer application (default)" ON)
 190 option(ENABLE_GPSSMOOTH  "Set to ON to build the GPSsmooth application (default)" ON)
 191 option(ENABLE_TERRASYNC  "Set to ON to build the terrasync application (default)" ON)
 192 option(ENABLE_FGJS       "Set to ON to build the fgjs application (default)" ON)
 193 option(ENABLE_JS_DEMO    "Set to ON to build the js_demo application (default)" ON)
 194 option(ENABLE_METAR      "Set to ON to build the metar application (default)" ON)
 195 option(ENABLE_TESTS      "Set to ON to build test applications (default)" ON)
 196 option(ENABLE_FGCOM      "Set to ON to build the FGCom application (default)" ON)
 197 option(ENABLE_FLITE      "Set to ON to build the Flite text-to-speech module" ON)
 198 option(ENABLE_QT         "Set to ON to build the internal Qt launcher" ON)
 199
 200 # when building an OSG with commit 15ec7e2ae7a8b983ecc44e1ce7363a9a9fa7da95
 201 # applied, we can use better link options
 202 option(OSG_FSTREAM_EXPORT_FIXED "Set to ON if the osgDB fstream export patch is applied" OFF)
 203
 204 if(LOGGING)
 205     # nothing
 206 else()
 207     set(FG_NDEBUG 1)
 208 endif()
 209
 210 if(JSBSIM_TERRAIN)
 211    set(JSBSIM_USE_GROUNDREACTIONS 1)
 212 endif()
 213
 214 if(SP_FDMS)
 215     set(ENABLE_SP_FDM 1)
 216 endif()
 217
 218 if(ENABLE_FGCOM)
 219   set(ENABLE_IAX 1)
 220   include_directories(${PROJECT_SOURCE_DIR}/3rdparty/iaxclient/lib ) # for iaxclient.h
 221 endif()
 222
 223 # Setup MSVC 3rd party directories
 224 include( ConfigureMsvc3rdParty )
 225
 226 if(EVENT_INPUT)
 227     if(APPLE)
 228     elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 229         if(NOT UDEV_FOUND)
 230             message(WARNING "UDev not found, event input is disabled!")
 231             set(EVENT_INPUT 0)
 232         else()
 233             add_definitions(-DWITH_EVENTINPUT)
 234             set(EVENT_INPUT_LIBRARIES ${UDEV_LIBRARIES})
 235             message(STATUS "event-based input enabled. Using ${UDEV_LIBRARIES}")
 236         endif()
 237     else()
 238         message(WARNING "event-based input is not supported on this platform yet")
 239     endif()
 240
 241     # Keep PLIB INPUT enabled as long as EventInput does not replace current joystick configurations.
 242     set(ENABLE_PLIB_JOYSTICK 1)
 243 else(EVENT_INPUT)
 244     set(ENABLE_PLIB_JOYSTICK 1)
 245 endif(EVENT_INPUT)
 246
 247 # check required dependencies
 248 find_package(Boost   REQUIRED)
 249 find_package(ZLIB    REQUIRED)
 250 find_package(OpenGL  REQUIRED)
 251 find_package(OpenAL  REQUIRED)
 252 find_package(OpenSceneGraph 3.2.0 REQUIRED
 253   osgText
 254   osgSim
 255   osgDB
 256   osgParticle
 257   osgFX
 258   osgUtil
 259   osgViewer
 260   osgGA
 261 )
 262
 263 if (MSVC)
 264         find_package(CrashRpt)
 265         if (CRASHRPT_FOUND)
 266                 set(HAVE_CRASHRPT 1)
 267                 message(STATUS "Using CrashRpt")
 268         include_directories( ${CRASHRPT_INCLUDE_DIR})
 269         endif()
 270 endif()
 271
 272 ##############################################################################
 273 ## Sqlite3 setup
 274
 275 if (SYSTEM_SQLITE)
 276     find_package(SQLite3 REQUIRED)
 277
 278     message(STATUS "Using system SQLite3 library")
 279 else()
 280     set(SQLITE3_INCLUDED_DIR "${CMAKE_SOURCE_DIR}/3rdparty/sqlite3")
 281     # this target is defined in src/Navaids/CMakeLists.txt
 282     list(APPEND SQLITE3_LIBRARY fgsqlite3)
 283 endif (SYSTEM_SQLITE)
 284
 285 # Sqlite always depends on the threading lib
 286 list(APPEND SQLITE3_LIBRARY ${CMAKE_THREAD_LIBS_INIT})
 287
 288 ##############################################################################
 289 ## DBus setup
 290
 291 if (USE_DBUS)
 292     include(FindPkgConfig)
 293     if (PKG_CONFIG_FOUND)
 294         pkg_check_modules(DBUS dbus-1)
 295     endif (PKG_CONFIG_FOUND) #if we don't have pkg-config, assume we don't have libdbus-1-dev either http://packages.debian.org/sid/libdbus-1-dev
 296     if (DBUS_FOUND)
 297         set(HAVE_DBUS 1)
 298         message(STATUS "Using DBus")
 299         include_directories( ${DBUS_INCLUDE_DIRS})
 300     else()
 301         message(STATUS "DBus not found, screensaver control disabled")
 302     endif (DBUS_FOUND)
 303 else()
 304 endif (USE_DBUS)
 305
 306 ##############################################################################
 307 ## Qt5 setup setup
 308 if (ENABLE_QT)
 309         message(STATUS "Qt launcher enabled, checking for Qt 5.1 / qmake")
 310         find_package(Qt5 5.1 COMPONENTS Widgets)
 311         if (Qt5Widgets_FOUND)
 312                 message(STATUS "Will enable Qt launcher GUI")
 313                 message(STATUS "  Qt5Widgets version: ${Qt5Widgets_VERSION_STRING}")
 314                 message(STATUS "  Qt5Widgets include dir: ${Qt5Widgets_INCLUDE_DIRS}")
 315                 set(HAVE_QT 1)
 316         endif()
 317 endif (ENABLE_QT)
 318 ##############################################################################
 319
 320 find_package(PLIB REQUIRED puaux pu js fnt)
 321
 322 # FlightGear and SimGear versions need to match
 323 find_package(SimGear ${FLIGHTGEAR_VERSION} REQUIRED)
 324
 325 ##############################################################################
 326
 327 check_include_file(unistd.h   HAVE_UNISTD_H)
 328 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 329 check_include_file(windows.h  HAVE_WINDOWS_H)
 330
 331 if(ENABLE_PROFILE)
 332     find_package(GooglePerfTools REQUIRED)
 333     set(FG_HAVE_GPERFTOOLS 1)
 334     message(STATUS "Built-in profiler using gperftools available")
 335 endif()
 336
 337 if(ENABLE_RTI)
 338     message(STATUS "RTI: ENABLED")
 339     find_package(RTI)
 340     if(RTI_FOUND)
 341         set(FG_HAVE_HLA 1)
 342     endif(RTI_FOUND)
 343 else()
 344     message(STATUS "RTI: DISABLED")
 345 endif(ENABLE_RTI)
 346
 347 if(CMAKE_COMPILER_IS_GNUCXX)
 348     set(WARNING_FLAGS_CXX "-Wall")
 349     set(WARNING_FLAGS_C   "-Wall")
 350 endif(CMAKE_COMPILER_IS_GNUCXX)
 351
 352 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 353    set(WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual \
 354      -Wno-redeclared-class-member \
 355      -Wno-inconsistent-missing-override \
 356      -Wno-unused-local-typedef")
 357
 358    set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LIBRARY "libc++")
 359    set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LANGUAGE_STANDARD "c++11")
 360    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -stdlib=libc++")
 361    set(WARNING_FLAGS_C "-Wall")
 362 endif()
 363
 364 if(WIN32)
 365
 366     if(MSVC)
 367         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS /MP")
 368         if (NOT OSG_FSTREAM_EXPORT_FIXED AND ${MSVC_VERSION} GREATER 1599)
 369           message(STATUS "For better linking performance, use OSG with fixed fstream header")
 370           # needed to avoid link errors on multiply-defined standard C++
 371           # symbols. This issue was fixed in OSG commit 15ec7e2ae7a8b983ecc44e1ce7363a9a9fa7da95
 372           set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 373         endif ()
 374
 375         if (${MSVC_VERSION} GREATER 1899)
 376             # needed for debug builds with VS2015
 377             set( MSVC_FLAGS "${MSVC_FLAGS} /bigobj" )
 378         endif()
 379     endif(MSVC)
 380
 381     set(NOMINMAX 1)
 382 endif(WIN32)
 383
 384 set (BOOST_CXX_FLAGS "-DBOOST_BIMAP_DISABLE_SERIALIZATION")
 385
 386 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS} -D_REENTRANT")
 387 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} -D_REENTRANT ${BOOST_CXX_FLAGS}")
 388 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 389
 390 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 391     ${Boost_INCLUDE_DIRS}
 392     ${ZLIB_INCLUDE_DIR}
 393     ${OPENGL_INCLUDE_DIR}
 394     ${SIMGEAR_INCLUDE_DIRS}
 395     ${PLIB_INCLUDE_DIR}
 396     ${SQLITE3_INCLUDED_DIR} )
 397
 398 if (USE_AEONWAVE)
 399     find_package(AAX COMPONENTS aax REQUIRED)
 400     include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 401         ${AAX_INCLUDE_DIR}
 402     )
 403 else()
 404     include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 405         ${OPENAL_INCLUDE_DIR}
 406     )
 407 endif()
 408
 409 include_directories(${PROJECT_SOURCE_DIR})
 410 include_directories(${PROJECT_SOURCE_DIR}/src)
 411 # following is needed, because config.h is include 'bare', whereas
 412 # version.h is included as <Include/version.h> - this should be cleaned up
 413 include_directories(${PROJECT_BINARY_DIR}/src)
 414 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 415
 416 if (ENABLE_FLITE)
 417     include_directories(${PROJECT_SOURCE_DIR}/3rdparty/hts_engine_API/include )
 418     include_directories(${PROJECT_SOURCE_DIR}/3rdparty/flite_hts_engine/include )
 419 endif()
 420
 421 add_definitions(-DHAVE_CONFIG_H)
 422
 423 check_function_exists(mkfifo HAVE_MKFIFO)
 424
 425 # configure a header file to pass some of the CMake settings
 426 # to the source code
 427 configure_file (
 428     "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 429     "${PROJECT_BINARY_DIR}/src/Include/config.h"
 430 )
 431
 432 #and the same for the version header
 433 configure_file (
 434     "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 435     "${PROJECT_BINARY_DIR}/src/Include/version.h"
 436 )
 437
 438 add_subdirectory(3rdparty)
 439 add_subdirectory(utils)
 440 add_subdirectory(src)
 441 add_subdirectory(man)
 442
 443 #-----------------------------------------------------------------------------
 444 ### uninstall target
 445 #-----------------------------------------------------------------------------
 446 CONFIGURE_FILE(
 447     "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 448     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 449     IMMEDIATE @ONLY)
 450 ADD_CUSTOM_TARGET(uninstall
 451     "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")