CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7
   8 project(FlightGear)
   9
  10 # We have some custom .cmake scripts not in the official distribution.
  11 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  12
  13 if(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  14     # use official include provided by latest CMake
  15     include(GNUInstallDirs)
  16 else(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  17     # backward compatibility: use our own module for older cmake versions
  18     include(OldGNUInstallDirs)
  19 endif(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  20
  21 # Warning when build is not an out-of-source build.
  22 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  23 if(InSourceBuild)
  24     message(WARNING  "Avoid building inside the source tree!")
  25     message(WARNING  "Create a separate build directory instead (i.e. 'fgbuild') and call CMake from there: ")
  26     message(WARNING  "  mkdir ../fgbuild && cd ../fgbuild && cmake ${CMAKE_SOURCE_DIR}")
  27 endif(InSourceBuild)
  28
  29 # System detection/default settings
  30 include( DetectDistro )
  31 include( DetectBrowser )
  32
  33 set(CMAKE_DEBUG_POSTFIX          "d" CACHE STRING "add a postfix, usually d on windows")
  34 set(CMAKE_RELEASE_POSTFIX        ""  CACHE STRING "add a postfix, usually empty on windows")
  35 set(CMAKE_RELWITHDEBINFO_POSTFIX ""  CACHE STRING "add a postfix, usually empty on windows")
  36 set(CMAKE_MINSIZEREL_POSTFIX     ""  CACHE STRING "add a postfix, usually empty on windows")
  37
  38 # read 'version' file into a variable (stripping any newlines or spaces)
  39 file(READ version versionFile)
  40 if (NOT versionFile)
  41     message(FATAL_ERROR "Unable to determine FlightGear version. Version file is missing.")
  42 endif()
  43 string(STRIP "${versionFile}" FLIGHTGEAR_VERSION)
  44
  45 # FlightGear packaging (to build a source tarball)
  46 include( ConfigureCPack )
  47
  48 # FlightGear base package path
  49 if (FG_DATA_DIR)
  50     message(STATUS "Using explicit data directory for base package: ${FG_DATA_DIR}")
  51 else()
  52     set(FG_DATA_DIR "${CMAKE_INSTALL_PREFIX}/lib/FlightGear" CACHE PATH "Default location where data files are located")
  53     message(STATUS "Using default data directory for base package:  ${FG_DATA_DIR}")
  54 endif()
  55
  56 # Change the default build type to something fast
  57 if(NOT CMAKE_BUILD_TYPE)
  58     set(CMAKE_BUILD_TYPE Release CACHE STRING
  59         "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  60         FORCE)
  61 endif(NOT CMAKE_BUILD_TYPE)
  62
  63 if(NOT "$ENV{BUILD_ID}" STREQUAL "")
  64     set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  65     set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  66     message(STATUS "running under Hudson/Jenkins, build-number is ${HUDSON_BUILD_NUMBER}")
  67 else()
  68     set(HUDSON_BUILD_NUMBER 0)
  69     set(HUDSON_BUILD_ID "none")
  70 endif()
  71
  72 #####################################################################################
  73 # Configure library search paths
  74 #####################################################################################
  75
  76 if(APPLE)
  77     # Custom library directories for Mac, which should have precedence over any other
  78     list(APPEND ADDITIONAL_LIBRARY_PATHS
  79          ~/Library/Frameworks
  80          /Library/Frameworks)
  81 endif(APPLE)
  82
  83 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  84     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  85     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  86     # add paths manually
  87     # see http://www.cmake.org/Bug/view.php?id=12049 and
  88     # http://www.cmake.org/Bug/view.php?id=12037
  89     list(APPEND ADDITIONAL_LIBRARY_PATHS
  90          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  91          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  92          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
  93     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
  94 endif()
  95
  96 if(NOT MSVC)
  97     # TBD: are these really necessary? Aren't they considered by cmake automatically?
  98     list(APPEND ADDITIONAL_LIBRARY_PATHS
  99          /opt/local
 100          /usr/local
 101          /usr)
 102 endif()
 103 #####################################################################################
 104
 105 IF(APPLE)
 106     set(EVENT_INPUT_DEFAULT 1)
 107
 108     find_library(CORESERVICES_LIBRARY CoreServices)
 109     find_library(COCOA_LIBRARY Cocoa)
 110     list(APPEND PLATFORM_LIBS ${COCOA_LIBRARY} ${CORESERVICES_LIBRARY})
 111
 112 elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 113     find_package(UDev)
 114
 115     if(UDEV_FOUND)
 116         set(EVENT_INPUT_DEFAULT 1)
 117     endif(UDEV_FOUND)
 118 endif()
 119
 120 find_package(Git)
 121 if (GIT_FOUND)
 122     execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
 123         OUTPUT_VARIABLE REVISION
 124         OUTPUT_STRIP_TRAILING_WHITESPACE)
 125     message(STATUS "Git revision is ${REVISION}")
 126 else()
 127     set(REVISION "none")
 128 endif()
 129
 130 # FlightGear build options
 131 option(SIMGEAR_SHARED    "Set to ON when SimGear was built as a shared library" OFF)
 132 option(LOGGING           "Set to ON to build FlightGear with logging support (default)" ON)
 133 option(SP_FDMS           "Set to ON to build FlightGear with special-purpose FDMs" OFF)
 134 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" OFF)
 135 option(ENABLE_LARCSIM    "Set to ON to build FlightGear with LaRCsim FDM" OFF)
 136 option(ENABLE_YASIM      "Set to ON to build FlightGear with YASIM FDM (default)" ON)
 137 option(ENABLE_JSBSIM     "Set to ON to build FlightGear with JSBSim FDM (default)" ON)
 138 option(EVENT_INPUT       "Set to ON to build FlightGear with event-based Input support" ${EVENT_INPUT_DEFAULT})
 139 option(ENABLE_LIBSVN     "Set to ON to build FlightGear/terrasync with libsvnclient support (default)" ON)
 140 option(ENABLE_RTI        "Set to ON to build FlightGear with RTI support" OFF)
 141 option(ENABLE_PROFILE    "Set to ON to build FlightGear with gperftools profiling support" OFF)
 142 option(JPEG_FACTORY      "Set to ON to build FlightGear with JPEG-factory support" OFF)
 143 option(SYSTEM_SQLITE     "Set to ON to build FlightGear with the system's SQLite3 library" OFF)
 144 option(ENABLE_IAX        "Set to ON to build FlightGear with IAXClient/fgcom built-in (default)" ON)
 145
 146 # additional utilities
 147 option(ENABLE_FGADMIN    "Set to ON to build the FGADMIN application (default)" ON)
 148 option(ENABLE_FGELEV     "Set to ON to build the fgelev application (default)" ON)
 149 option(WITH_FGPANEL      "Set to ON to build the fgpanel application (default)" ON)
 150 option(ENABLE_FGVIEWER   "Set to ON to build the fgviewer application (default)" ON)
 151 option(ENABLE_GPSSMOOTH  "Set to ON to build the GPSsmooth application (default)" ON)
 152 option(ENABLE_TERRASYNC  "Set to ON to build the terrasync application (default)" ON)
 153 option(ENABLE_FGJS       "Set to ON to build the fgjs application (default)" ON)
 154 option(ENABLE_JS_DEMO    "Set to ON to build the js_demo application (default)" ON)
 155 option(ENABLE_METAR      "Set to ON to build the metar application (default)" ON)
 156 option(ENABLE_TESTS      "Set to ON to build test applications (default)" ON)
 157 option(ENABLE_FGCOM      "Set to ON to build the FGCom application (default)" ON)
 158
 159 if(LOGGING)
 160     # nothing
 161 else()
 162     set(FG_NDEBUG 1)
 163 endif()
 164
 165 if(SP_FDMS)
 166     set(ENABLE_SP_FDM 1)
 167 endif()
 168
 169 if(ENABLE_FGCOM)
 170   set(ENABLE_IAX 1)
 171 endif()
 172
 173 # Setup MSVC 3rd party directories
 174 include( ConfigureMsvc3rdParty )
 175
 176 if(EVENT_INPUT)
 177     if(APPLE)
 178     elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 179         if(NOT UDEV_FOUND)
 180             message(WARNING "UDev not found, event input is disabled!")
 181             set(EVENT_INPUT 0)
 182         else()
 183             add_definitions(-DWITH_EVENTINPUT)
 184             set(EVENT_INPUT_LIBRARIES ${UDEV_LIBRARIES})
 185             message(STATUS "event-based input enabled. Using ${UDEV_LIBRARIES}")
 186         endif()
 187     else()
 188         message(WARNING "event-based input is not supported on this platform yet")
 189     endif()
 190
 191     # Keep PLIB INPUT enabled as long as EventInput does not replace current joystick configurations.
 192     set(ENABLE_PLIB_JOYSTICK 1)
 193 else(EVENT_INPUT)
 194     set(ENABLE_PLIB_JOYSTICK 1)
 195 endif(EVENT_INPUT)
 196
 197 # check required dependencies
 198 find_package(Boost   REQUIRED)
 199 find_package(ZLIB    REQUIRED)
 200 find_package(Threads REQUIRED)
 201 find_package(OpenGL  REQUIRED)
 202 find_package(OpenAL  REQUIRED)
 203 find_package(OpenSceneGraph 3.0.0 REQUIRED osgText osgSim osgDB osgParticle osgFX osgUtil osgViewer osgGA)
 204
 205 if(ENABLE_FGADMIN)
 206     find_package(FLTK)
 207
 208     if ( FLTK_FOUND )
 209         if ( X11_Xinerama_FOUND )
 210             message(STATUS "Found X11_Xinerama...")
 211             list(APPEND FLTK_LIBRARIES ${X11_Xinerama_LIB})
 212         endif()
 213
 214         if ( X11_Xft_FOUND )
 215             message(STATUS "Found X11_Xft...")
 216             list(APPEND FLTK_LIBRARIES ${X11_Xft_LIB})
 217         endif()
 218
 219         if ( CMAKE_DL_LIBS )
 220             list(APPEND FLTK_LIBRARIES ${CMAKE_DL_LIBS})
 221         endif()
 222
 223         message(STATUS "Using FLTK_LIBRARIES for fgadmin: ${FLTK_LIBRARIES}")
 224     endif ( FLTK_FOUND )
 225 endif(ENABLE_FGADMIN)
 226
 227 if(ENABLE_LIBSVN)
 228     find_package(SvnClient)
 229
 230     if(LIBSVN_FOUND)
 231         message(STATUS "libsvn found, enabling in terrasync")
 232         set(HAVE_SVN_CLIENT_H 1)
 233         set(HAVE_LIBSVN_CLIENT_1 1)
 234     else()
 235         message(STATUS "libsvn missing. Disabling...")
 236     endif(LIBSVN_FOUND)
 237 endif(ENABLE_LIBSVN)
 238
 239 ##############################################################################
 240 ## Sqlite3 setup
 241
 242 if (SYSTEM_SQLITE)
 243     find_package(SQLite3 REQUIRED)
 244
 245     message(STATUS "Using system SQLite3 library")
 246 else()
 247     set(SQLITE3_INCLUDED_DIR "${CMAKE_SOURCE_DIR}/3rdparty/sqlite3")
 248     # this target is defined in src/Navaids/CMakeLists.txt
 249     list(APPEND SQLITE3_LIBRARY fgsqlite3)
 250 endif (SYSTEM_SQLITE)
 251
 252 # Sqlite always depends on the threading lib
 253 list(APPEND SQLITE3_LIBRARY ${CMAKE_THREAD_LIBS_INIT})
 254
 255 ##############################################################################
 256
 257 find_package(PLIB REQUIRED puaux pu js fnt)
 258
 259 if (EMBEDDED_SIMGEAR)
 260     message(STATUS "Using embedded SimGear")
 261     # create the same variables that FindSimGear would define
 262     set(SIMGEAR_INCLUDE_DIR ${PROJECT_SOURCE_DIR}/simgear)
 263     set(SIMGEAR_CORE_LIBRARIES SimGearCore)
 264     set(SIMGEAR_LIBRARIES SimGearScene)
 265
 266     if (NOT SIMGEAR_SHARED)
 267         set(SIMGEAR_CORE_LIBRARY_DEPENDENCIES
 268             ${CMAKE_THREAD_LIBS_INIT}
 269             ${ZLIB_LIBRARY}
 270             ${LIBSVN_LIBRARIES}
 271             ${WINMM_LIBRARY})
 272
 273         set(SIMGEAR_SCENE_LIBRARY_DEPENDENCIES
 274             ${OPENAL_LIBRARY})
 275     endif()
 276 else(EMBEDDED_SIMGEAR)
 277     # FlightGear and SimGear versions need to match
 278     find_package(SimGear ${FLIGHTGEAR_VERSION} REQUIRED)
 279 endif (EMBEDDED_SIMGEAR)
 280
 281 if (JPEG_FACTORY)
 282     # check simgear was built with JPEG-factory support
 283     find_package(JPEG REQUIRED)
 284     include_directories(${JPEG_INCLUDE_DIR})
 285
 286     set(CMAKE_REQUIRED_INCLUDES
 287         ${SIMGEAR_INCLUDE_DIR}
 288         ${JPEG_INCLUDE_DIR}
 289         ${OPENSCENEGRAPH_INCLUDE_DIRS})
 290
 291     check_cxx_source_compiles(
 292         "#include <simgear/screen/jpgfactory.hxx>
 293         int main()    { return 0; } "
 294         FG_JPEG_SERVER)
 295
 296     if (NOT FG_JPEG_SERVER)
 297         message(STATUS "JPEG server support requested, but SimGear was built without JPEG support")
 298     endif()
 299 endif()
 300
 301 check_include_file(unistd.h   HAVE_UNISTD_H)
 302 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 303 check_include_file(windows.h  HAVE_WINDOWS_H)
 304
 305 if(ENABLE_PROFILE)
 306     find_package(GooglePerfTools REQUIRED)
 307     set(FG_HAVE_GPERFTOOLS 1)
 308     message(STATUS "Built-in profiler using gperftools available")
 309 endif()
 310
 311 if(ENABLE_RTI)
 312     message(STATUS "RTI: ENABLED")
 313     find_package(RTI)
 314     if(RTI_FOUND)
 315         set(FG_HAVE_HLA 1)
 316     endif(RTI_FOUND)
 317 else()
 318     message(STATUS "RTI: DISABLED")
 319 endif(ENABLE_RTI)
 320
 321 if(CMAKE_COMPILER_IS_GNUCXX)
 322     set(WARNING_FLAGS_CXX "-Wall")
 323     set(WARNING_FLAGS_C   "-Wall")
 324 endif(CMAKE_COMPILER_IS_GNUCXX)
 325
 326 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 327    set (WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual")
 328    set (WARNING_FLAGS_C   "-Wall")
 329 endif()
 330
 331 if(WIN32)
 332
 333     if(MSVC)
 334         # turn off various warnings
 335         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 336         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 337         # endforeach(warning)
 338
 339         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS -Dstrdup=_strdup")
 340         if (${MSVC_VERSION} GREATER 1599)
 341             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 342         endif (${MSVC_VERSION} GREATER 1599)
 343     endif(MSVC)
 344
 345     set(NOMINMAX 1)
 346 endif(WIN32)
 347
 348 set (BOOST_CXX_FLAGS "-DBOOST_MULTI_INDEX_DISABLE_SERIALIZATION -DBOOST_BIMAP_DISABLE_SERIALIZATION")
 349
 350 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS} -D_REENTRANT")
 351 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} -D_REENTRANT ${BOOST_CXX_FLAGS}")
 352 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 353
 354 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 355     ${Boost_INCLUDE_DIRS}
 356     ${ZLIB_INCLUDE_DIR}
 357     ${OPENGL_INCLUDE_DIR}
 358     ${OPENAL_INCLUDE_DIR}
 359     ${SIMGEAR_INCLUDE_DIR}
 360     ${PLIB_INCLUDE_DIR}
 361     ${SQLITE3_INCLUDED_DIR} )
 362
 363 include_directories(${PROJECT_SOURCE_DIR})
 364 include_directories(${PROJECT_SOURCE_DIR}/src)
 365 include_directories(${PROJECT_SOURCE_DIR}/3rdparty/iaxclient/lib ) # for iaxclient.h
 366 # following is needed, because config.h is include 'bare', whereas
 367 # version.h is included as <Include/version.h> - this should be cleaned up
 368 include_directories(${PROJECT_BINARY_DIR}/src)
 369 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 370
 371 add_definitions(-DHAVE_CONFIG_H)
 372
 373 check_function_exists(mkfifo HAVE_MKFIFO)
 374
 375 # configure a header file to pass some of the CMake settings
 376 # to the source code
 377 configure_file (
 378     "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 379     "${PROJECT_BINARY_DIR}/src/Include/config.h"
 380 )
 381
 382 #and the same for the version header
 383 configure_file (
 384     "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 385     "${PROJECT_BINARY_DIR}/src/Include/version.h"
 386 )
 387
 388 if (EMBEDDED_SIMGEAR)
 389     add_subdirectory(simgear)
 390     # since we build without SimGear installed, we need to
 391     # search this path directly to find the generated
 392     # simgear_config.h
 393     include_directories(${PROJECT_BINARY_DIR}/simgear)
 394 endif(EMBEDDED_SIMGEAR)
 395
 396 add_subdirectory(3rdparty)
 397 add_subdirectory(utils)
 398 add_subdirectory(src)
 399 add_subdirectory(man)
 400
 401 #-----------------------------------------------------------------------------
 402 ### uninstall target
 403 #-----------------------------------------------------------------------------
 404 CONFIGURE_FILE(
 405     "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 406     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 407     IMMEDIATE @ONLY)
 408 ADD_CUSTOM_TARGET(uninstall
 409     "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")