CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8.11)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7
   8 if(COMMAND cmake_policy)
   9    if(POLICY CMP0054)
  10        cmake_policy(SET CMP0054 NEW)
  11    endif()
  12    # Mac RPATH policy
  13    if(POLICY CMP0042)
  14        cmake_policy(SET CMP0042 NEW)
  15    endif()
  16 endif()
  17
  18 if(APPLE)
  19         # using 10.7 because boost requires libc++ and 10.6 doesn't include it
  20         set(CMAKE_OSX_DEPLOYMENT_TARGET 10.7)
  21
  22         set(CMAKE_INSTALL_RPATH "@loader_path/../Frameworks")
  23         # when building, don't use the install RPATH already
  24         # (but later on when installing)
  25         SET(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
  26 endif()
  27
  28 project(FlightGear)
  29
  30 # We have some custom .cmake scripts not in the official distribution.
  31 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  32
  33 # Warning when build is not an out-of-source build.
  34 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  35 if(InSourceBuild)
  36     message(WARNING  "Avoid building inside the source tree!")
  37     message(WARNING  "Create a separate build directory instead (i.e. 'fgbuild') and call CMake from there: ")
  38     message(WARNING  "  mkdir ../fgbuild && cd ../fgbuild && cmake ${CMAKE_SOURCE_DIR}")
  39 endif(InSourceBuild)
  40
  41 include(GNUInstallDirs)
  42 # System detection/default settings
  43 include( DetectDistro )
  44 include( DetectBrowser )
  45
  46 set(CMAKE_DEBUG_POSTFIX          "d" CACHE STRING "add a postfix, usually d on windows")
  47 set(CMAKE_RELEASE_POSTFIX        ""  CACHE STRING "add a postfix, usually empty on windows")
  48 set(CMAKE_RELWITHDEBINFO_POSTFIX ""  CACHE STRING "add a postfix, usually empty on windows")
  49 set(CMAKE_MINSIZEREL_POSTFIX     ""  CACHE STRING "add a postfix, usually empty on windows")
  50
  51 # read 'version' file into a variable (stripping any newlines or spaces)
  52 file(READ version versionFile)
  53 if (NOT versionFile)
  54     message(FATAL_ERROR "Unable to determine FlightGear version. Version file is missing.")
  55 endif()
  56 string(STRIP "${versionFile}" FLIGHTGEAR_VERSION)
  57
  58 # FlightGear packaging (to build a source tarball)
  59 include( ConfigureCPack )
  60
  61 # FlightGear base package path
  62 if (FG_DATA_DIR)
  63     message(STATUS "Using explicit data directory for base package: ${FG_DATA_DIR}")
  64 else()
  65     set(FG_DATA_DIR "${CMAKE_INSTALL_PREFIX}/lib/FlightGear" CACHE PATH "Default location where data files are located")
  66     message(STATUS "Using default data directory for base package:  ${FG_DATA_DIR}")
  67 endif()
  68
  69 # Change the default build type to something fast
  70 if(NOT CMAKE_BUILD_TYPE)
  71     set(CMAKE_BUILD_TYPE Release CACHE STRING
  72         "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  73         FORCE)
  74 endif(NOT CMAKE_BUILD_TYPE)
  75
  76 if(NOT "$ENV{BUILD_ID}" STREQUAL "")
  77     set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  78     set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  79     message(STATUS "running under Hudson/Jenkins, build-number is ${HUDSON_BUILD_NUMBER}")
  80 else()
  81     set(HUDSON_BUILD_NUMBER 0)
  82     set(HUDSON_BUILD_ID "none")
  83 endif()
  84
  85 #####################################################################################
  86 # Configure library search paths
  87 #####################################################################################
  88
  89
  90 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  91     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  92     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  93     # add paths manually
  94     # see http://www.cmake.org/Bug/view.php?id=12049 and
  95     # http://www.cmake.org/Bug/view.php?id=12037
  96     list(APPEND ADDITIONAL_LIBRARY_PATHS
  97          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  98          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  99          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
 100     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
 101 endif()
 102
 103 #####################################################################################
 104
 105 IF(APPLE)
 106     set(EVENT_INPUT_DEFAULT 1)
 107
 108     find_library(CORESERVICES_LIBRARY CoreServices)
 109     find_library(COCOA_LIBRARY Cocoa)
 110     list(APPEND PLATFORM_LIBS ${COCOA_LIBRARY} ${CORESERVICES_LIBRARY})
 111 elseif(${CMAKE_SYSTEM_NAME} MATCHES "Linux" OR
 112         ${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD")
 113     find_package(Threads REQUIRED)
 114     find_package(X11 REQUIRED)
 115
 116     set(USE_DBUS_DEFAULT 1)
 117
 118     find_package(UDev)
 119     if(UDEV_FOUND)
 120         set(EVENT_INPUT_DEFAULT 1)
 121     endif(UDEV_FOUND)
 122
 123     find_package(Speex)
 124     find_package(Speexdsp)
 125     if(SPEEX_FOUND AND SPEEXDSP_FOUND)
 126         set(SYSTEM_SPEEX_DEFAULT 1)
 127     endif(SPEEX_FOUND AND SPEEXDSP_FOUND)
 128
 129     find_package(Gsm)
 130     if(GSM_FOUND)
 131         set(SYSTEM_GSM_DEFAULT 1)
 132     endif(GSM_FOUND)
 133
 134     find_package(Flite)
 135     if(FLITE_FOUND)
 136         set(SYSTEM_FLITE_DEFAULT 1)
 137     endif()
 138
 139     find_package(HtsEngine)
 140     if(HTS_ENGINE_FOUND)
 141         set(SYSTEM_HTS_ENGINE_DEFAULT 1)
 142     endif()
 143 endif()
 144
 145 find_package(Git)
 146 if (GIT_FOUND)
 147     execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
 148         OUTPUT_VARIABLE REVISION
 149         OUTPUT_STRIP_TRAILING_WHITESPACE)
 150     message(STATUS "Git revision is ${REVISION}")
 151 else()
 152     set(REVISION "none")
 153 endif()
 154
 155 # FlightGear build options
 156 option(SIMGEAR_SHARED    "Set to ON when SimGear was built as a shared library" OFF)
 157 option(LOGGING           "Set to ON to build FlightGear with logging support (default)" ON)
 158 option(JSBSIM_TERRAIN    "Set to ON to build FlightGear with JSBSim terrain handling code" ON)
 159 option(SP_FDMS           "Set to ON to build FlightGear with special-purpose FDMs" OFF)
 160 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" OFF)
 161 option(ENABLE_LARCSIM    "Set to ON to build FlightGear with LaRCsim FDM" OFF)
 162 option(ENABLE_YASIM      "Set to ON to build FlightGear with YASIM FDM (default)" ON)
 163 option(ENABLE_JSBSIM     "Set to ON to build FlightGear with JSBSim FDM (default)" ON)
 164 option(EVENT_INPUT       "Set to ON to build FlightGear with event-based Input support" ${EVENT_INPUT_DEFAULT})
 165 option(ENABLE_RTI        "Set to ON to build FlightGear with RTI support" OFF)
 166 option(ENABLE_PROFILE    "Set to ON to build FlightGear with gperftools profiling support" OFF)
 167 option(SYSTEM_SQLITE     "Set to ON to build FlightGear with the system's SQLite3 library" OFF)
 168 option(ENABLE_IAX        "Set to ON to build FlightGear with IAXClient/fgcom built-in (default)" ON)
 169 option(USE_DBUS          "Set to ON to build FlightGear with DBus screensaver interaction (default on Linux)" ${USE_DBUS_DEFAULT})
 170 option(SYSTEM_SPEEX      "Set to ON to build IAXClient with the system's speex and speexdsp library" ${SYSTEM_SPEEX_DEFAULT})
 171 option(SYSTEM_GSM        "Set to ON to build IAXClient with the system's GSM library" ${SYSTEM_GSM_DEFAULT})
 172 option(SYSTEM_FLITE      "Set to ON to build Flightgear with the system's Flite library" ${SYSTEM_FLITE_DEFAULT})
 173 option(SYSTEM_HTS_ENGINE "Set to ON to build Flightgear with the system's HTS Engine library" ${SYSTEM_HTS_ENGINE_DEFAULT})
 174 option(FG_NIGHTLY        "Set to ON to mark this as a nightly build" OFF)
 175 option(ENABLE_DEV_WARNINGS "Set to ON to include developer-warnings" OFF)
 176
 177 # additional utilities
 178 option(ENABLE_FGADMIN    "Set to ON to build the FGADMIN application (default)" ON)
 179 option(ENABLE_FGELEV     "Set to ON to build the fgelev application (default)" ON)
 180 option(WITH_FGPANEL      "Set to ON to build the fgpanel application (default)" ON)
 181 option(ENABLE_FGVIEWER   "Set to ON to build the fgviewer application (default)" ON)
 182 option(ENABLE_GPSSMOOTH  "Set to ON to build the GPSsmooth application (default)" ON)
 183 option(ENABLE_TERRASYNC  "Set to ON to build the terrasync application (default)" ON)
 184 option(ENABLE_FGJS       "Set to ON to build the fgjs application (default)" ON)
 185 option(ENABLE_JS_DEMO    "Set to ON to build the js_demo application (default)" ON)
 186 option(ENABLE_METAR      "Set to ON to build the metar application (default)" ON)
 187 option(ENABLE_TESTS      "Set to ON to build test applications (default)" ON)
 188 option(ENABLE_FGCOM      "Set to ON to build the FGCom application (default)" ON)
 189 option(ENABLE_FLITE      "Set to ON to build the Flite text-to-speech module" ON)
 190 option(ENABLE_QT         "Set to ON to build the internal Qt launcher" ON)
 191
 192 if(LOGGING)
 193     # nothing
 194 else()
 195     set(FG_NDEBUG 1)
 196 endif()
 197
 198 if(JSBSIM_TERRAIN)
 199    set(JSBSIM_USE_GROUNDREACTIONS 1)
 200 endif()
 201
 202 if(SP_FDMS)
 203     set(ENABLE_SP_FDM 1)
 204 endif()
 205
 206 if(ENABLE_FGCOM)
 207   set(ENABLE_IAX 1)
 208   include_directories(${PROJECT_SOURCE_DIR}/3rdparty/iaxclient/lib ) # for iaxclient.h
 209 endif()
 210
 211 # Setup MSVC 3rd party directories
 212 include( ConfigureMsvc3rdParty )
 213
 214 if(EVENT_INPUT)
 215     if(APPLE)
 216     elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 217         if(NOT UDEV_FOUND)
 218             message(WARNING "UDev not found, event input is disabled!")
 219             set(EVENT_INPUT 0)
 220         else()
 221             add_definitions(-DWITH_EVENTINPUT)
 222             set(EVENT_INPUT_LIBRARIES ${UDEV_LIBRARIES})
 223             message(STATUS "event-based input enabled. Using ${UDEV_LIBRARIES}")
 224         endif()
 225     else()
 226         message(WARNING "event-based input is not supported on this platform yet")
 227     endif()
 228
 229     # Keep PLIB INPUT enabled as long as EventInput does not replace current joystick configurations.
 230     set(ENABLE_PLIB_JOYSTICK 1)
 231 else(EVENT_INPUT)
 232     set(ENABLE_PLIB_JOYSTICK 1)
 233 endif(EVENT_INPUT)
 234
 235 # check required dependencies
 236 find_package(Boost   REQUIRED)
 237 find_package(ZLIB    REQUIRED)
 238 find_package(OpenGL  REQUIRED)
 239 find_package(OpenAL  REQUIRED)
 240 find_package(OpenSceneGraph 3.2.0 REQUIRED
 241   osgText
 242   osgSim
 243   osgDB
 244   osgParticle
 245   osgFX
 246   osgUtil
 247   osgViewer
 248   osgGA
 249 )
 250
 251 if (MSVC)
 252         find_package(CrashRpt)
 253         if (CRASHRPT_FOUND)
 254                 set(HAVE_CRASHRPT 1)
 255                 message(STATUS "Using CrashRpt")
 256         include_directories( ${CRASHRPT_INCLUDE_DIR})
 257         endif()
 258 endif()
 259
 260 ##############################################################################
 261 ## Sqlite3 setup
 262
 263 if (SYSTEM_SQLITE)
 264     find_package(SQLite3 REQUIRED)
 265
 266     message(STATUS "Using system SQLite3 library")
 267 else()
 268     set(SQLITE3_INCLUDED_DIR "${CMAKE_SOURCE_DIR}/3rdparty/sqlite3")
 269     # this target is defined in src/Navaids/CMakeLists.txt
 270     list(APPEND SQLITE3_LIBRARY fgsqlite3)
 271 endif (SYSTEM_SQLITE)
 272
 273 # Sqlite always depends on the threading lib
 274 list(APPEND SQLITE3_LIBRARY ${CMAKE_THREAD_LIBS_INIT})
 275
 276 ##############################################################################
 277 ## DBus setup
 278
 279 if (USE_DBUS)
 280     include(FindPkgConfig)
 281     if (PKG_CONFIG_FOUND)
 282         pkg_check_modules(DBUS dbus-1)
 283     endif (PKG_CONFIG_FOUND) #if we don't have pkg-config, assume we don't have libdbus-1-dev either http://packages.debian.org/sid/libdbus-1-dev
 284     if (DBUS_FOUND)
 285         set(HAVE_DBUS 1)
 286         message(STATUS "Using DBus")
 287         include_directories( ${DBUS_INCLUDE_DIRS})
 288     else()
 289         message(STATUS "DBus not found, screensaver control disabled")
 290     endif (DBUS_FOUND)
 291 else()
 292 endif (USE_DBUS)
 293
 294 ##############################################################################
 295 ## Qt5 setup setup
 296 if (ENABLE_QT)
 297         message(STATUS "Qt launcher enabled, checking for Qt 5.1 / qmake")
 298         find_package(Qt5 5.1 COMPONENTS Widgets)
 299         if (Qt5Widgets_FOUND)
 300                 message(STATUS "Will enable Qt launcher GUI")
 301                 message(STATUS "  Qt5Widgets version: ${Qt5Widgets_VERSION_STRING}")
 302                 message(STATUS "  Qt5Widgets include dir: ${Qt5Widgets_INCLUDE_DIRS}")
 303                 set(HAVE_QT 1)
 304         endif()
 305 endif (ENABLE_QT)
 306 ##############################################################################
 307
 308 find_package(PLIB REQUIRED puaux pu js fnt)
 309
 310 # FlightGear and SimGear versions need to match
 311 find_package(SimGear ${FLIGHTGEAR_VERSION} REQUIRED)
 312
 313 ##############################################################################
 314
 315 check_include_file(unistd.h   HAVE_UNISTD_H)
 316 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 317 check_include_file(windows.h  HAVE_WINDOWS_H)
 318
 319 if(ENABLE_PROFILE)
 320     find_package(GooglePerfTools REQUIRED)
 321     set(FG_HAVE_GPERFTOOLS 1)
 322     message(STATUS "Built-in profiler using gperftools available")
 323 endif()
 324
 325 if(ENABLE_RTI)
 326     message(STATUS "RTI: ENABLED")
 327     find_package(RTI)
 328     if(RTI_FOUND)
 329         set(FG_HAVE_HLA 1)
 330     endif(RTI_FOUND)
 331 else()
 332     message(STATUS "RTI: DISABLED")
 333 endif(ENABLE_RTI)
 334
 335 if(CMAKE_COMPILER_IS_GNUCXX)
 336     set(WARNING_FLAGS_CXX "-Wall")
 337     set(WARNING_FLAGS_C   "-Wall")
 338 endif(CMAKE_COMPILER_IS_GNUCXX)
 339
 340 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 341    set(WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual \
 342      -Wno-redeclared-class-member \
 343      -Wno-inconsistent-missing-override \
 344      -Wno-unused-local-typedef")
 345
 346    set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LIBRARY "libc++")
 347    set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LANGUAGE_STANDARD "c++11")
 348    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -stdlib=libc++")
 349    set(WARNING_FLAGS_C "-Wall")
 350 endif()
 351
 352 if(WIN32)
 353
 354     if(MSVC)
 355         # turn off various warnings
 356         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 357         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 358         # endforeach(warning)
 359
 360         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS -Dstrdup=_strdup")
 361         if (${MSVC_VERSION} GREATER 1599)
 362             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 363         endif (${MSVC_VERSION} GREATER 1599)
 364     endif(MSVC)
 365
 366     set(NOMINMAX 1)
 367 endif(WIN32)
 368
 369 set (BOOST_CXX_FLAGS "-DBOOST_BIMAP_DISABLE_SERIALIZATION")
 370
 371 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS} -D_REENTRANT")
 372 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} -D_REENTRANT ${BOOST_CXX_FLAGS}")
 373 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 374
 375 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 376     ${Boost_INCLUDE_DIRS}
 377     ${ZLIB_INCLUDE_DIR}
 378     ${OPENGL_INCLUDE_DIR}
 379     ${OPENAL_INCLUDE_DIR}
 380     ${SIMGEAR_INCLUDE_DIRS}
 381     ${PLIB_INCLUDE_DIR}
 382     ${SQLITE3_INCLUDED_DIR} )
 383
 384 include_directories(${PROJECT_SOURCE_DIR})
 385 include_directories(${PROJECT_SOURCE_DIR}/src)
 386 # following is needed, because config.h is include 'bare', whereas
 387 # version.h is included as <Include/version.h> - this should be cleaned up
 388 include_directories(${PROJECT_BINARY_DIR}/src)
 389 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 390
 391 if (ENABLE_FLITE)
 392     include_directories(${PROJECT_SOURCE_DIR}/3rdparty/hts_engine_API/include )
 393     include_directories(${PROJECT_SOURCE_DIR}/3rdparty/flite_hts_engine/include )
 394 endif()
 395
 396 add_definitions(-DHAVE_CONFIG_H)
 397
 398 check_function_exists(mkfifo HAVE_MKFIFO)
 399
 400 # configure a header file to pass some of the CMake settings
 401 # to the source code
 402 configure_file (
 403     "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 404     "${PROJECT_BINARY_DIR}/src/Include/config.h"
 405 )
 406
 407 #and the same for the version header
 408 configure_file (
 409     "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 410     "${PROJECT_BINARY_DIR}/src/Include/version.h"
 411 )
 412
 413 add_subdirectory(3rdparty)
 414 add_subdirectory(utils)
 415 add_subdirectory(src)
 416 add_subdirectory(man)
 417
 418 #-----------------------------------------------------------------------------
 419 ### uninstall target
 420 #-----------------------------------------------------------------------------
 421 CONFIGURE_FILE(
 422     "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 423     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 424     IMMEDIATE @ONLY)
 425 ADD_CUSTOM_TARGET(uninstall
 426     "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")