CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7
   8 project(FlightGear)
   9
  10 # We have some custom .cmake scripts not in the official distribution.
  11 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  12
  13 if(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  14     # use official include provided by latest CMake
  15     include(GNUInstallDirs)
  16 else(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  17     # backward compatibility: use our own module for older cmake versions
  18     include(OldGNUInstallDirs)
  19 endif(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  20
  21 # Warning when build is not an out-of-source build.
  22 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  23 if(InSourceBuild)
  24     message(WARNING  "Avoid building inside the source tree!")
  25     message(WARNING  "Create a separate build directory instead (i.e. 'fgbuild') and call CMake from there: ")
  26     message(WARNING  "  mkdir ../fgbuild && cd ../fgbuild && cmake ${CMAKE_SOURCE_DIR}")
  27 endif(InSourceBuild)
  28
  29 # System detection/default settings
  30 include( DetectDistro )
  31 include( DetectBrowser )
  32
  33 set(CMAKE_DEBUG_POSTFIX          "d" CACHE STRING "add a postfix, usually d on windows")
  34 set(CMAKE_RELEASE_POSTFIX        ""  CACHE STRING "add a postfix, usually empty on windows")
  35 set(CMAKE_RELWITHDEBINFO_POSTFIX ""  CACHE STRING "add a postfix, usually empty on windows")
  36 set(CMAKE_MINSIZEREL_POSTFIX     ""  CACHE STRING "add a postfix, usually empty on windows")
  37
  38 # read 'version' file into a variable (stripping any newlines or spaces)
  39 file(READ version versionFile)
  40 string(STRIP ${versionFile} FLIGHTGEAR_VERSION)
  41
  42 # FlightGear packaging (to build a source tarball)
  43 include( ConfigureCPack )
  44
  45 # FlightGear base package path
  46 if (FG_DATA_DIR)
  47     message(STATUS "Using explicit data directory for base package: ${FG_DATA_DIR}")
  48 else()
  49     set(FG_DATA_DIR "${CMAKE_INSTALL_PREFIX}/lib/FlightGear" CACHE PATH "Default location where data files are located")
  50     message(STATUS "Using default data directory for base package:  ${FG_DATA_DIR}")
  51 endif()
  52
  53 # Change the default build type to something fast
  54 if(NOT CMAKE_BUILD_TYPE)
  55     set(CMAKE_BUILD_TYPE Release CACHE STRING
  56         "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  57         FORCE)
  58 endif(NOT CMAKE_BUILD_TYPE)
  59
  60 if(NOT "$ENV{BUILD_ID}" STREQUAL "")
  61     set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  62     set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  63     message(STATUS "running under Hudson, build-number is ${HUDSON_BUILD_NUMBER}")
  64 else()
  65     set(HUDSON_BUILD_NUMBER 0)
  66     set(HUDSON_BUILD_ID "none")
  67 endif()
  68
  69 IF(APPLE)
  70     set(EVENT_INPUT_DEFAULT 1)
  71
  72     find_library(CORESERVICES_LIBRARY CoreServices)
  73     find_library(COCOA_LIBRARY Cocoa)
  74     list(APPEND PLATFORM_LIBS ${COCOA_LIBRARY} ${CORESERVICES_LIBRARY})
  75
  76 elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
  77     find_package(UDev)
  78
  79     if(UDEV_FOUND)
  80         set(EVENT_INPUT_DEFAULT 1)
  81     endif(UDEV_FOUND)
  82 endif()
  83
  84 find_package(Git)
  85 if (GIT_FOUND)
  86     execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
  87         OUTPUT_VARIABLE REVISION
  88         OUTPUT_STRIP_TRAILING_WHITESPACE)
  89     message(STATUS "Git revision is ${REVISION}")
  90 else()
  91     set(REVISION "none")
  92 endif()
  93
  94 option(LOGGING           "Set to OFF to build FlightGear without logging" ON)
  95 option(SP_FDMS           "Set to ON to build FlightGear with special-purpose FDMs" OFF)
  96 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" OFF)
  97 option(ENABLE_LARCSIM    "Set to ON to build FlightGear with LaRCsim FDM" OFF)
  98 option(ENABLE_YASIM      "Set to ON to build FlightGear with YASIM FDM" ON)
  99 option(ENABLE_JSBSIM     "Set to ON to build FlightGear with JSBSim FDM" ON)
 100 option(ENABLE_FGADMIN    "Set to ON to build FlightGear with FGADMIN" ON)
 101 option(EVENT_INPUT       "Set to ON to build FlightGear with event-based Input support" ${EVENT_INPUT_DEFAULT})
 102 option(ENABLE_LIBSVN     "Set to ON to build FlightGear/terrasync with libsvnclient support" ON)
 103 option(ENABLE_RTI        "Set to ON to build SimGear with RTI support" OFF)
 104 option(WITH_FGPANEL      "Set to ON to build the fgpanel application" ON)
 105 option(JPEG_FACTORY      "Enable JPEG-factory support" OFF)
 106 option(ENABLE_TESTS      "Set to OFF to disable building test applications" ON)
 107
 108 if(LOGGING)
 109     # nothing
 110 else()
 111     set(FG_NDEBUG 1)
 112 endif()
 113
 114 if(SP_FDMS)
 115     set(ENABLE_SP_FDM 1)
 116 endif()
 117
 118 # Setup MSVC 3rd party directories
 119 include( ConfigureMsvc3rdParty )
 120
 121 if(EVENT_INPUT)
 122     if(APPLE)
 123     elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 124         if(NOT UDEV_FOUND)
 125             message(WARNING "UDev not found, event input is disabled!")
 126             set(EVENT_INPUT 0)
 127         else()
 128             set(EVENT_INPUT_LIBRARIES ${UDEV_LIBRARIES})
 129             message(STATUS "event-based input enabled. Using ${UDEV_LIBRARIES}")
 130         endif()
 131     else()
 132         message(WARNING "event-based input is not supported on this platform yet")
 133     endif()
 134
 135     # Keep PLIB INPUT enabled as long as EventInput does not replace current joystick configurations.
 136     set(ENABLE_PLIB_JOYSTICK 1)
 137 else(EVENT_INPUT)
 138     set(ENABLE_PLIB_JOYSTICK 1)
 139 endif(EVENT_INPUT)
 140
 141 # check required dependencies
 142 find_package(Boost   REQUIRED)
 143 find_package(ZLIB    REQUIRED)
 144 find_package(Threads REQUIRED)
 145 find_package(OpenGL  REQUIRED)
 146 find_package(OpenAL  REQUIRED)
 147 find_package(ALUT    REQUIRED)
 148 find_package(OpenSceneGraph 3.0.0 REQUIRED osgText osgSim osgDB osgParticle osgFX osgUtil osgViewer osgGA)
 149
 150 if(ENABLE_FGADMIN)
 151     find_package(FLTK)
 152
 153     if ( FLTK_FOUND )
 154         if ( X11_Xinerama_FOUND )
 155             message(STATUS "Found X11_Xinerama...")
 156             list(APPEND FLTK_LIBRARIES ${X11_Xinerama_LIB})
 157         endif()
 158
 159         if ( X11_Xft_FOUND )
 160             message(STATUS "Found X11_Xft...")
 161             list(APPEND FLTK_LIBRARIES ${X11_Xft_LIB})
 162         endif()
 163
 164         message(STATUS "Using FLTK_LIBRARIES for fgadmin: ${FLTK_LIBRARIES}")
 165     endif ( FLTK_FOUND )
 166 endif(ENABLE_FGADMIN)
 167
 168 if(ENABLE_LIBSVN)
 169     find_package(SvnClient)
 170
 171     if(LIBSVN_FOUND)
 172         message(STATUS "libsvn found, enabling in terrasync")
 173         set(HAVE_SVN_CLIENT_H 1)
 174         set(HAVE_LIBSVN_CLIENT_1 1)
 175     else()
 176         message(STATUS "libsvn missing. Disabling...")
 177     endif(LIBSVN_FOUND)
 178 endif(ENABLE_LIBSVN)
 179
 180 find_package(PLIB REQUIRED puaux pu js fnt)
 181
 182 # FlightGear and SimGear versions need to match
 183 find_package(SimGear ${FLIGHTGEAR_VERSION} REQUIRED)
 184
 185 if (JPEG_FACTORY)
 186     # check simgear was built with JPEG-factory support
 187     find_package(JPEG REQUIRED)
 188     include_directories(${JPEG_INCLUDE_DIR})
 189
 190     set(CMAKE_REQUIRED_INCLUDES
 191         ${SIMGEAR_INCLUDE_DIR}
 192         ${JPEG_INCLUDE_DIR}
 193         ${OPENSCENEGRAPH_INCLUDE_DIRS})
 194
 195     check_cxx_source_compiles(
 196         "#include <simgear/screen/jpgfactory.hxx>
 197         int main()    { return 0; } "
 198         FG_JPEG_SERVER)
 199
 200     if (NOT FG_JPEG_SERVER)
 201         message(STATUS "JPEG server support requested, but SimGear was built without JPEG support")
 202     endif()
 203 endif()
 204
 205 check_include_file(unistd.h   HAVE_UNISTD_H)
 206 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 207 check_include_file(windows.h  HAVE_WINDOWS_H)
 208
 209 if(ENABLE_RTI)
 210     find_package(RTI)
 211     if(RTI_FOUND)
 212         set(FG_HAVE_HLA 1)
 213     endif(RTI_FOUND)
 214 endif(ENABLE_RTI)
 215
 216 if(CMAKE_COMPILER_IS_GNUCXX)
 217     set(WARNING_FLAGS_CXX "-Wall")
 218     set(WARNING_FLAGS_C   "-Wall")
 219 endif(CMAKE_COMPILER_IS_GNUCXX)
 220
 221 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 222    set (WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual")
 223    set (WARNING_FLAGS_C   "-Wall")
 224 endif()
 225
 226 if(WIN32)
 227
 228     if(MSVC)
 229         # turn off various warnings
 230         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 231         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 232         # endforeach(warning)
 233
 234         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS")
 235         if (${MSVC_VERSION} EQUAL 1600)
 236             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 237         endif (${MSVC_VERSION} EQUAL 1600)
 238     endif(MSVC)
 239
 240     set(NOMINMAX 1)
 241 endif(WIN32)
 242
 243 set (BOOST_CXX_FLAGS "-DBOOST_MULTI_INDEX_DISABLE_SERIALIZATION -DBOOST_BIMAP_DISABLE_SERIALIZATION")
 244
 245 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS} -D_REENTRANT")
 246 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} -D_REENTRANT ${BOOST_CXX_FLAGS}")
 247 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 248
 249 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 250     ${Boost_INCLUDE_DIRS}
 251     ${ZLIB_INCLUDE_DIR}
 252     ${ALUT_INCLUDE_DIR}
 253     ${OPENGL_INCLUDE_DIR}
 254     ${OPENAL_INCLUDE_DIR}
 255     ${SIMGEAR_INCLUDE_DIR}
 256     ${PLIB_INCLUDE_DIR} )
 257
 258 include_directories(${PROJECT_SOURCE_DIR}/src)
 259
 260 # following is needed, because config.h is include 'bare', whereas
 261 # version.h is included as <Include/version.h> - this should be cleaned up
 262 include_directories(${PROJECT_BINARY_DIR}/src)
 263 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 264
 265 add_definitions(-DHAVE_CONFIG_H)
 266
 267 check_function_exists(mkfifo HAVE_MKFIFO)
 268
 269 # configure a header file to pass some of the CMake settings
 270 # to the source code
 271 configure_file (
 272     "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 273     "${PROJECT_BINARY_DIR}/src/Include/config.h"
 274 )
 275
 276 #and the same for the version header
 277 configure_file (
 278     "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 279     "${PROJECT_BINARY_DIR}/src/Include/version.h"
 280 )
 281
 282 add_subdirectory(src)
 283 add_subdirectory(utils)
 284 add_subdirectory(man)
 285
 286 #-----------------------------------------------------------------------------
 287 ### uninstall target
 288 #-----------------------------------------------------------------------------
 289 CONFIGURE_FILE(
 290     "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 291     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 292     IMMEDIATE @ONLY)
 293 ADD_CUSTOM_TARGET(uninstall
 294     "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")