CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6)
   2 include (CheckFunctionExists)
   3 include (CheckIncludeFile)
   4 include (CheckCXXSourceCompiles)
   5 include (CPack)
   6
   7 project(SimGear)
   8
   9 set(SIMGEAR_VERSION "2.2.0")
  10
  11 #packaging
  12 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  13 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  14
  15 # We have some custom .cmake scripts not in the official distribution.
  16 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  17
  18 option(SIMGEAR_SHARED "Set to ON to build SimGear as a shared library/framework" OFF)
  19 option(SIMGEAR_HEADLESS "Set to ON to build SimGear with GUI/graphics support" OFF)
  20 option(JPEG_FACTORY "Enable JPEG-factory support" OFF)
  21 set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
  22
  23 if (MSVC_3RDPARTY_ROOT)
  24   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_ROOT}")
  25   set( OSG_MSVC "msvc" )
  26   if (${MSVC_VERSION} EQUAL 1600)
  27       set( OSG_MSVC ${OSG_MSVC}100 )
  28   else (${MSVC_VERSION} EQUAL 1600)
  29       set( OSG_MSVC ${OSG_MSVC}90 )
  30   endif (${MSVC_VERSION} EQUAL 1600)
  31   if (CMAKE_CL_64)
  32       set( OSG_MSVC ${OSG_MSVC}-64 )
  33       set( MSVC_3RDPARTY_DIR 3rdParty.x64 )
  34   else (CMAKE_CL_64)
  35       set( MSVC_3RDPARTY_DIR 3rdParty )
  36   endif (CMAKE_CL_64)
  37
  38   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/lib )
  39   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/include)
  40   set (BOOST_ROOT ${MSVC_3RDPARTY_ROOT}/boost_1_44_0)
  41   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
  42   set (ALUT_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
  43   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib)
  44 endif (MSVC_3RDPARTY_ROOT)
  45
  46 find_package(Boost REQUIRED)
  47 set (BOOST_CXX_FLAGS "-DBOOST_MULTI_INDEX_DISABLE_SERIALIZATION -DBOOST_BIMAP_DISABLE_SERIALIZATION")
  48
  49 find_package(ZLIB REQUIRED)
  50 find_package(Threads REQUIRED)
  51
  52 if (${SIMGEAR_HEADLESS})
  53     message(STATUS "headlesss mode")
  54     set(NO_OPENSCENEGRAPH_INTERFACE 1)
  55 else()
  56     find_package(OpenGL REQUIRED)
  57     find_package(OpenAL REQUIRED)
  58     find_package(ALUT REQUIRED)
  59     find_package(OpenSceneGraph 2.8.1 REQUIRED osgText osgSim osgDB osgParticle osgUtil)
  60 endif()
  61
  62 if(JPEG_FACTORY)
  63     message(STATUS "JPEG-factory enabled")
  64     find_package(JPEG REQUIRED)
  65     include_directories(${JPEG_INCLUDE_DIR})
  66 endif()
  67
  68 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  69 check_include_file(sys/timeb.h HAVE_SYS_TIMEB_H)
  70 check_include_file(unistd.h HAVE_UNISTD_H)
  71 check_include_file(windows.h HAVE_WINDOWS_H)
  72
  73 # See if we have any rti library variant installed
  74 find_package(RTI)
  75
  76 check_function_exists(gettimeofday HAVE_GETTIMEOFDAY)
  77 check_function_exists(ftime HAVE_FTIME)
  78 check_function_exists(timegm HAVE_TIMEGM)
  79 check_function_exists(rint HAVE_RINT)
  80
  81 SET(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "add a postfix, usually d on windows")
  82 SET(CMAKE_RELEASE_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
  83 SET(CMAKE_RELWITHDEBINFO_POSTFIX "rd" CACHE STRING "add a postfix, usually empty on windows")
  84 SET(CMAKE_MINSIZEREL_POSTFIX "s" CACHE STRING "add a postfix, usually empty on windows")
  85
  86 # isnan might not be real symbol, so can't check using function_exists
  87 check_cxx_source_compiles(
  88     "#include <cmath>
  89     void f() { isnan(0.0);} "
  90     HAVE_ISNAN)
  91
  92 if(CMAKE_COMPILER_IS_GNUCXX)
  93     set(WARNING_FLAGS -Wall)
  94 endif(CMAKE_COMPILER_IS_GNUCXX)
  95
  96 if(WIN32)
  97
  98     if(MSVC)
  99         # turn off various warnings
 100         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 101         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 102         # endforeach(warning)
 103
 104         set(MSVC_FLAGS "-DWIN32 -DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS")
 105     endif(MSVC)
 106
 107     # assumed on Windows
 108     set(HAVE_GETLOCALTIME 1)
 109 endif(WIN32)
 110
 111 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS}")
 112 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS} ${BOOST_CXX_FLAGS}")
 113
 114 include_directories(${PROJECT_SOURCE_DIR})
 115 include_directories(${PROJECT_BINARY_DIR}/simgear)
 116
 117 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 118     ${Boost_INCLUDE_DIRS} ${ZLIB_INCLUDE_DIR}
 119     ${ALUT_INCLUDE_DIR} ${OPENAL_INCLUDE_DIR} )
 120
 121
 122 add_definitions(-DHAVE_CONFIG_H)
 123
 124 # configure a header file to pass some of the CMake settings
 125 # to the source code
 126 configure_file (
 127   "${PROJECT_SOURCE_DIR}/simgear/simgear_config_cmake.h.in"
 128   "${PROJECT_BINARY_DIR}/simgear/simgear_config.h"
 129   )
 130
 131 install (FILES ${PROJECT_BINARY_DIR}/simgear/simgear_config.h  DESTINATION include/simgear/)
 132 add_subdirectory(simgear)
 133
 134 #-----------------------------------------------------------------------------
 135 ### uninstall target
 136 #-----------------------------------------------------------------------------
 137 CONFIGURE_FILE(
 138   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 139   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 140   IMMEDIATE @ONLY)
 141 ADD_CUSTOM_TARGET(uninstall
 142   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
 143
 144