CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7
   8 project(FlightGear)
   9
  10 # We have some custom .cmake scripts not in the official distribution.
  11 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  12
  13 if(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  14     # use official include provided by latest CMake
  15     include(GNUInstallDirs)
  16 else(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  17     # backward compatibility: use our own module for older cmake versions
  18     include(OldGNUInstallDirs)
  19 endif(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  20
  21 # Warning when build is not an out-of-source build.
  22 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  23 if(InSourceBuild)
  24     message(WARNING  "Avoid building inside the source tree!")
  25     message(WARNING  "Create a separate build directory instead (i.e. 'fgbuild') and call CMake from there: ")
  26     message(WARNING  "  mkdir ../fgbuild && cd ../fgbuild && cmake ${CMAKE_SOURCE_DIR}")
  27 endif(InSourceBuild)
  28
  29 # System detection/default settings
  30 include( DetectDistro )
  31 include( DetectBrowser )
  32
  33 set(CMAKE_DEBUG_POSTFIX          "d" CACHE STRING "add a postfix, usually d on windows")
  34 set(CMAKE_RELEASE_POSTFIX        ""  CACHE STRING "add a postfix, usually empty on windows")
  35 set(CMAKE_RELWITHDEBINFO_POSTFIX ""  CACHE STRING "add a postfix, usually empty on windows")
  36 set(CMAKE_MINSIZEREL_POSTFIX     ""  CACHE STRING "add a postfix, usually empty on windows")
  37
  38 # read 'version' file into a variable (stripping any newlines or spaces)
  39 file(READ version versionFile)
  40 if (NOT versionFile)
  41     message(FATAL_ERROR "Unable to determine FlightGear version. Version file is missing.")
  42 endif()
  43 string(STRIP "${versionFile}" FLIGHTGEAR_VERSION)
  44
  45 # FlightGear packaging (to build a source tarball)
  46 include( ConfigureCPack )
  47
  48 # FlightGear base package path
  49 if (FG_DATA_DIR)
  50     message(STATUS "Using explicit data directory for base package: ${FG_DATA_DIR}")
  51 else()
  52     set(FG_DATA_DIR "${CMAKE_INSTALL_PREFIX}/lib/FlightGear" CACHE PATH "Default location where data files are located")
  53     message(STATUS "Using default data directory for base package:  ${FG_DATA_DIR}")
  54 endif()
  55
  56 # Change the default build type to something fast
  57 if(NOT CMAKE_BUILD_TYPE)
  58     set(CMAKE_BUILD_TYPE Release CACHE STRING
  59         "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  60         FORCE)
  61 endif(NOT CMAKE_BUILD_TYPE)
  62
  63 if(NOT "$ENV{BUILD_ID}" STREQUAL "")
  64     set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  65     set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  66     message(STATUS "running under Hudson/Jenkins, build-number is ${HUDSON_BUILD_NUMBER}")
  67 else()
  68     set(HUDSON_BUILD_NUMBER 0)
  69     set(HUDSON_BUILD_ID "none")
  70 endif()
  71
  72 IF(APPLE)
  73     set(EVENT_INPUT_DEFAULT 1)
  74
  75     find_library(CORESERVICES_LIBRARY CoreServices)
  76     find_library(COCOA_LIBRARY Cocoa)
  77     list(APPEND PLATFORM_LIBS ${COCOA_LIBRARY} ${CORESERVICES_LIBRARY})
  78
  79 elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
  80     find_package(UDev)
  81
  82     if(UDEV_FOUND)
  83         set(EVENT_INPUT_DEFAULT 1)
  84     endif(UDEV_FOUND)
  85 endif()
  86
  87 find_package(Git)
  88 if (GIT_FOUND)
  89     execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
  90         OUTPUT_VARIABLE REVISION
  91         OUTPUT_STRIP_TRAILING_WHITESPACE)
  92     message(STATUS "Git revision is ${REVISION}")
  93 else()
  94     set(REVISION "none")
  95 endif()
  96
  97 # FlightGear build options
  98 option(LOGGING           "Set to ON to build FlightGear with logging support (default)" ON)
  99 option(SP_FDMS           "Set to ON to build FlightGear with special-purpose FDMs" OFF)
 100 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" OFF)
 101 option(ENABLE_LARCSIM    "Set to ON to build FlightGear with LaRCsim FDM" OFF)
 102 option(ENABLE_YASIM      "Set to ON to build FlightGear with YASIM FDM (default)" ON)
 103 option(ENABLE_JSBSIM     "Set to ON to build FlightGear with JSBSim FDM (default)" ON)
 104 option(EVENT_INPUT       "Set to ON to build FlightGear with event-based Input support" ${EVENT_INPUT_DEFAULT})
 105 option(ENABLE_LIBSVN     "Set to ON to build FlightGear/terrasync with libsvnclient support (default)" ON)
 106 option(ENABLE_RTI        "Set to ON to build FlightGear with RTI support" OFF)
 107 option(JPEG_FACTORY      "Set to ON to build FlightGear with JPEG-factory support" OFF)
 108
 109 # additional utilities
 110 option(ENABLE_FGADMIN    "Set to ON to build the FGADMIN application (default)" ON)
 111 option(WITH_FGPANEL      "Set to ON to build the fgpanel application (default)" ON)
 112 option(ENABLE_TESTS      "Set to ON to build test applications (default)" ON)
 113
 114 if(LOGGING)
 115     # nothing
 116 else()
 117     set(FG_NDEBUG 1)
 118 endif()
 119
 120 if(SP_FDMS)
 121     set(ENABLE_SP_FDM 1)
 122 endif()
 123
 124 # Setup MSVC 3rd party directories
 125 include( ConfigureMsvc3rdParty )
 126
 127 if(EVENT_INPUT)
 128     if(APPLE)
 129     elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 130         if(NOT UDEV_FOUND)
 131             message(WARNING "UDev not found, event input is disabled!")
 132             set(EVENT_INPUT 0)
 133         else()
 134             set(EVENT_INPUT_LIBRARIES ${UDEV_LIBRARIES})
 135             message(STATUS "event-based input enabled. Using ${UDEV_LIBRARIES}")
 136         endif()
 137     else()
 138         message(WARNING "event-based input is not supported on this platform yet")
 139     endif()
 140
 141     # Keep PLIB INPUT enabled as long as EventInput does not replace current joystick configurations.
 142     set(ENABLE_PLIB_JOYSTICK 1)
 143 else(EVENT_INPUT)
 144     set(ENABLE_PLIB_JOYSTICK 1)
 145 endif(EVENT_INPUT)
 146
 147 # check required dependencies
 148 find_package(Boost   REQUIRED)
 149 find_package(ZLIB    REQUIRED)
 150 find_package(Threads REQUIRED)
 151 find_package(OpenGL  REQUIRED)
 152 find_package(OpenAL  REQUIRED)
 153 find_package(OpenSceneGraph 3.0.0 REQUIRED osgText osgSim osgDB osgParticle osgFX osgUtil osgViewer osgGA)
 154
 155 if(ENABLE_FGADMIN)
 156     find_package(FLTK)
 157
 158     if ( FLTK_FOUND )
 159         if ( X11_Xinerama_FOUND )
 160             message(STATUS "Found X11_Xinerama...")
 161             list(APPEND FLTK_LIBRARIES ${X11_Xinerama_LIB})
 162         endif()
 163
 164         if ( X11_Xft_FOUND )
 165             message(STATUS "Found X11_Xft...")
 166             list(APPEND FLTK_LIBRARIES ${X11_Xft_LIB})
 167         endif()
 168
 169         message(STATUS "Using FLTK_LIBRARIES for fgadmin: ${FLTK_LIBRARIES}")
 170     endif ( FLTK_FOUND )
 171 endif(ENABLE_FGADMIN)
 172
 173 if(ENABLE_LIBSVN)
 174     find_package(SvnClient)
 175
 176     if(LIBSVN_FOUND)
 177         message(STATUS "libsvn found, enabling in terrasync")
 178         set(HAVE_SVN_CLIENT_H 1)
 179         set(HAVE_LIBSVN_CLIENT_1 1)
 180     else()
 181         message(STATUS "libsvn missing. Disabling...")
 182     endif(LIBSVN_FOUND)
 183 endif(ENABLE_LIBSVN)
 184
 185 find_package(PLIB REQUIRED puaux pu js fnt)
 186
 187 # FlightGear and SimGear versions need to match
 188 find_package(SimGear ${FLIGHTGEAR_VERSION} REQUIRED)
 189
 190 if (JPEG_FACTORY)
 191     # check simgear was built with JPEG-factory support
 192     find_package(JPEG REQUIRED)
 193     include_directories(${JPEG_INCLUDE_DIR})
 194
 195     set(CMAKE_REQUIRED_INCLUDES
 196         ${SIMGEAR_INCLUDE_DIR}
 197         ${JPEG_INCLUDE_DIR}
 198         ${OPENSCENEGRAPH_INCLUDE_DIRS})
 199
 200     check_cxx_source_compiles(
 201         "#include <simgear/screen/jpgfactory.hxx>
 202         int main()    { return 0; } "
 203         FG_JPEG_SERVER)
 204
 205     if (NOT FG_JPEG_SERVER)
 206         message(STATUS "JPEG server support requested, but SimGear was built without JPEG support")
 207     endif()
 208 endif()
 209
 210 check_include_file(unistd.h   HAVE_UNISTD_H)
 211 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 212 check_include_file(windows.h  HAVE_WINDOWS_H)
 213
 214 if(ENABLE_RTI)
 215     find_package(RTI)
 216     if(RTI_FOUND)
 217         set(FG_HAVE_HLA 1)
 218     endif(RTI_FOUND)
 219 endif(ENABLE_RTI)
 220
 221 if(CMAKE_COMPILER_IS_GNUCXX)
 222     set(WARNING_FLAGS_CXX "-Wall")
 223     set(WARNING_FLAGS_C   "-Wall")
 224 endif(CMAKE_COMPILER_IS_GNUCXX)
 225
 226 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 227    set (WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual")
 228    set (WARNING_FLAGS_C   "-Wall")
 229 endif()
 230
 231 if(WIN32)
 232
 233     if(MSVC)
 234         # turn off various warnings
 235         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 236         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 237         # endforeach(warning)
 238
 239         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS")
 240         if (${MSVC_VERSION} EQUAL 1600)
 241             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 242         endif (${MSVC_VERSION} EQUAL 1600)
 243     endif(MSVC)
 244
 245     set(NOMINMAX 1)
 246 endif(WIN32)
 247
 248 set (BOOST_CXX_FLAGS "-DBOOST_MULTI_INDEX_DISABLE_SERIALIZATION -DBOOST_BIMAP_DISABLE_SERIALIZATION")
 249
 250 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS} -D_REENTRANT")
 251 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} -D_REENTRANT ${BOOST_CXX_FLAGS}")
 252 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 253
 254 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 255     ${Boost_INCLUDE_DIRS}
 256     ${ZLIB_INCLUDE_DIR}
 257     ${OPENGL_INCLUDE_DIR}
 258     ${OPENAL_INCLUDE_DIR}
 259     ${SIMGEAR_INCLUDE_DIR}
 260     ${PLIB_INCLUDE_DIR} )
 261
 262 include_directories(${PROJECT_SOURCE_DIR}/src)
 263
 264 # following is needed, because config.h is include 'bare', whereas
 265 # version.h is included as <Include/version.h> - this should be cleaned up
 266 include_directories(${PROJECT_BINARY_DIR}/src)
 267 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 268
 269 add_definitions(-DHAVE_CONFIG_H)
 270
 271 check_function_exists(mkfifo HAVE_MKFIFO)
 272
 273 # configure a header file to pass some of the CMake settings
 274 # to the source code
 275 configure_file (
 276     "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 277     "${PROJECT_BINARY_DIR}/src/Include/config.h"
 278 )
 279
 280 #and the same for the version header
 281 configure_file (
 282     "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 283     "${PROJECT_BINARY_DIR}/src/Include/version.h"
 284 )
 285
 286 add_subdirectory(src)
 287 add_subdirectory(utils)
 288 add_subdirectory(man)
 289
 290 #-----------------------------------------------------------------------------
 291 ### uninstall target
 292 #-----------------------------------------------------------------------------
 293 CONFIGURE_FILE(
 294     "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 295     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 296     IMMEDIATE @ONLY)
 297 ADD_CUSTOM_TARGET(uninstall
 298     "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")