CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8.11)
   2
   3 if(COMMAND cmake_policy)
   4    if(POLICY CMP0054)
   5        cmake_policy(SET CMP0054 NEW)
   6    endif()
   7    if(POLICY CMP0042)
   8        cmake_policy(SET CMP0042 NEW)
   9    endif()
  10 endif()
  11
  12 include (CheckFunctionExists)
  13 include (CheckIncludeFile)
  14 include (CheckLibraryExists)
  15 include (CheckCXXSourceCompiles)
  16 include (CheckCXXCompilerFlag)
  17
  18 # using 10.7 because boost requires libc++ and 10.6 doesn't include it
  19 set(CMAKE_OSX_DEPLOYMENT_TARGET 10.7)
  20
  21 # only relevant for building shared libs but let's set it regardless
  22 set(CMAKE_OSX_RPATH 1)
  23
  24 project(SimGear)
  25
  26 # read 'version' file into a variable (stripping any newlines or spaces)
  27 file(READ version versionFile)
  28 string(STRIP ${versionFile} SIMGEAR_VERSION)
  29
  30 set(FIND_LIBRARY_USE_LIB64_PATHS ON)
  31
  32 # use simgear version also as the SO version (if building SOs)
  33 SET(SIMGEAR_SOVERSION ${SIMGEAR_VERSION})
  34
  35 # Warning when build is not an out-of-source build.
  36 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  37 if(InSourceBuild)
  38     message(WARNING  "Avoid building inside the source tree!")
  39     message(WARNING  "Create a separate build directory instead (i.e. 'sgbuild') and call CMake from there: ")
  40     message(WARNING  "  mkdir ../sgbuild && cd ../sgbuild && cmake ${CMAKE_SOURCE_DIR}")
  41 endif(InSourceBuild)
  42
  43 #packaging
  44 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  45 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  46 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Simulation support libraries for FlightGear and related projects")
  47 SET(CPACK_PACKAGE_VENDOR "The FlightGear project")
  48 SET(CPACK_GENERATOR "TBZ2")
  49 SET(CPACK_INSTALL_CMAKE_PROJECTS  ${CMAKE_CURRENT_BINARY_DIR};SimGear;ALL;/)
  50
  51
  52 # split version string into components, note CMAKE_MATCH_0 is the entire regexp match
  53 string(REGEX MATCH "([0-9]+)\\.([0-9]+)\\.([0-9]+)" CPACK_PACKAGE_VERSION ${SIMGEAR_VERSION} )
  54 set(CPACK_PACKAGE_VERSION_MAJOR ${CMAKE_MATCH_1})
  55 set(CPACK_PACKAGE_VERSION_MINOR ${CMAKE_MATCH_2})
  56 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_3})
  57
  58 message(STATUS "version is ${CPACK_PACKAGE_VERSION_MAJOR} dot ${CPACK_PACKAGE_VERSION_MINOR} dot ${CPACK_PACKAGE_VERSION_PATCH}")
  59
  60 set(CPACK_SOURCE_GENERATOR TBZ2)
  61 set(CPACK_SOURCE_PACKAGE_FILE_NAME "simgear-${SIMGEAR_VERSION}" CACHE INTERNAL "tarball basename")
  62 set(CPACK_SOURCE_IGNORE_FILES
  63   "^${PROJECT_SOURCE_DIR}/.git;\\\\.gitignore;Makefile.am;~$;${CPACK_SOURCE_IGNORE_FILES}")
  64
  65 message(STATUS "ignoring: ${CPACK_SOURCE_IGNORE_FILES}")
  66
  67 include (CPack)
  68
  69 # We have some custom .cmake scripts not in the official distribution.
  70 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  71
  72 # Change the default build type to something fast
  73 if(NOT CMAKE_BUILD_TYPE)
  74   set(CMAKE_BUILD_TYPE Release CACHE STRING
  75       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  76       FORCE)
  77 endif(NOT CMAKE_BUILD_TYPE)
  78
  79 # Determine name of library installation directory, i.e. "lib" vs "lib64", which
  80 # differs between all Debian-based vs all other Linux distros.
  81 # See cmake bug #11964, http://cmake.org/gitweb?p=cmake.git;a=commit;h=126c993d
  82 include(GNUInstallDirs)
  83 message(STATUS "Library installation directory: ${CMAKE_INSTALL_LIBDIR}")
  84
  85 #####################################################################################
  86 # Configure library search paths
  87 #####################################################################################
  88
  89 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  90     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  91     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  92     # add paths manually
  93     # see http://www.cmake.org/Bug/view.php?id=12049 and
  94     # http://www.cmake.org/Bug/view.php?id=12037
  95     list(APPEND ADDITIONAL_LIBRARY_PATHS
  96          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  97          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  98          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
  99     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
 100 endif()
 101
 102 #####################################################################################
 103
 104 if (NOT MSVC)
 105 option(SIMGEAR_SHARED   "Set to ON to build SimGear as a shared library/framework" OFF)
 106 option(SYSTEM_EXPAT     "Set to ON to build SimGear using the system libExpat" OFF)
 107 else()
 108 # Building SimGear DLLs is currently not supported for MSVC.
 109 set(SIMGEAR_SHARED OFF)
 110 # Using a system expat is currently not supported for MSVC - it would require shared simgear (DLL).
 111 set(SYSTEM_EXPAT OFF)
 112 endif()
 113
 114 option(SIMGEAR_HEADLESS "Set to ON to build SimGear without GUI/graphics support" OFF)
 115 option(ENABLE_RTI       "Set to ON to build SimGear with RTI support" OFF)
 116 option(ENABLE_TESTS     "Set to OFF to disable building SimGear's test applications" ON)
 117 option(ENABLE_SOUND     "Set to OFF to disable building SimGear's sound support" ON)
 118 option(ENABLE_PKGUTIL   "Set to ON to build the sg_pkgutil application (default)" ON)
 119
 120 if (MSVC)
 121   GET_FILENAME_COMPONENT(PARENT_DIR ${PROJECT_BINARY_DIR} PATH)
 122   if (CMAKE_CL_64)
 123     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty.x64")
 124   else (CMAKE_CL_64)
 125     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty")
 126   endif (CMAKE_CL_64)
 127   if (EXISTS ${TEST_3RDPARTY_DIR})
 128     set(MSVC_3RDPARTY_ROOT ${PARENT_DIR} CACHE PATH "Location where the third-party dependencies are extracted")
 129   else (EXISTS ${TEST_3RDPARTY_DIR})
 130     set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 131   endif (EXISTS ${TEST_3RDPARTY_DIR})
 132 else (MSVC)
 133   set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 134 endif (MSVC)
 135
 136 if (MSVC AND MSVC_3RDPARTY_ROOT)
 137   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_ROOT}")
 138   set( OSG_MSVC "msvc" )
 139   if (${MSVC_VERSION} EQUAL 1700)
 140       set( OSG_MSVC ${OSG_MSVC}110 )
 141   elseif (${MSVC_VERSION} EQUAL 1600)
 142       set( OSG_MSVC ${OSG_MSVC}100 )
 143   else (${MSVC_VERSION} EQUAL 1700)
 144       set( OSG_MSVC ${OSG_MSVC}90 )
 145   endif (${MSVC_VERSION} EQUAL 1700)
 146   if (CMAKE_CL_64)
 147       set( OSG_MSVC ${OSG_MSVC}-64 )
 148       set( MSVC_3RDPARTY_DIR 3rdParty.x64 )
 149   else (CMAKE_CL_64)
 150       set( MSVC_3RDPARTY_DIR 3rdParty )
 151   endif (CMAKE_CL_64)
 152
 153   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/lib )
 154   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/include)
 155   find_path(BOOST_ROOT boost/version.hpp
 156                         ${MSVC_3RDPARTY_ROOT}/boost
 157                         ${MSVC_3RDPARTY_ROOT}/boost_1_52_0
 158                         ${MSVC_3RDPARTY_ROOT}/boost_1_51_0
 159                         ${MSVC_3RDPARTY_ROOT}/boost_1_50_0
 160                         ${MSVC_3RDPARTY_ROOT}/boost_1_49_0
 161                         ${MSVC_3RDPARTY_ROOT}/boost_1_48_0
 162                         ${MSVC_3RDPARTY_ROOT}/boost_1_47_0
 163                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_1
 164                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_0
 165                         ${MSVC_3RDPARTY_ROOT}/boost_1_45_0
 166                         ${MSVC_3RDPARTY_ROOT}/boost_1_44_0
 167                         )
 168   # set (BOOST_ROOT ${MSVC_3RDPARTY_ROOT}/boost_1_44_0)
 169   message(STATUS "BOOST_ROOT is ${BOOST_ROOT}")
 170   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 171   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib)
 172 endif (MSVC AND MSVC_3RDPARTY_ROOT)
 173
 174 if(APPLE)
 175   find_library(COCOA_LIBRARY Cocoa)
 176 endif()
 177
 178 if(${CMAKE_SYSTEM_NAME} MATCHES "Linux" OR
 179         ${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD")
 180     find_package(Threads REQUIRED)
 181 endif()
 182
 183 # Somehow this only works if included before searching for Boost...
 184 include(BoostTestTargets)
 185
 186 find_package(Boost REQUIRED)
 187 set (BOOST_CXX_FLAGS "-DBOOST_BIMAP_DISABLE_SERIALIZATION")
 188
 189 if(SIMGEAR_HEADLESS)
 190     message(STATUS "SimGear mode: HEADLESS")
 191     set(ENABLE_SOUND 0)
 192 else()
 193     message(STATUS "SimGear mode: NORMAL")
 194     find_package(OpenGL REQUIRED)
 195
 196     if (ENABLE_SOUND)
 197         find_package(OpenAL REQUIRED)
 198         message(STATUS "Sound support: ENABLED")
 199     endif(ENABLE_SOUND)
 200
 201     find_package(OpenSceneGraph 3.2.0 REQUIRED osgText osgSim osgDB osgParticle osgGA osgViewer osgUtil)
 202 endif(SIMGEAR_HEADLESS)
 203
 204 find_package(ZLIB REQUIRED)
 205
 206 if (SYSTEM_EXPAT)
 207     message(STATUS "Requested to use system Expat library, forcing SIMGEAR_SHARED to true")
 208     set(SIMGEAR_SHARED ON)
 209     find_package(EXPAT REQUIRED)
 210
 211 else()
 212     message(STATUS "Using built-in expat code")
 213     # XML_STATIC is important to avoid sg_expat_external.h
 214     # declaring symbols as declspec(import)
 215     add_definitions(-DHAVE_EXPAT_CONFIG_H -DXML_STATIC)
 216     set(EXPAT_INCLUDE_DIRS
 217             ${PROJECT_SOURCE_DIR}/3rdparty/expat
 218             ${PROJECT_BINARY_DIR}/3rdparty/expat)
 219 endif(SYSTEM_EXPAT)
 220
 221 include_directories(${EXPAT_INCLUDE_DIRS})
 222
 223 check_include_file(inttypes.h HAVE_INTTYPES_H)
 224 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 225 check_include_file(sys/timeb.h HAVE_SYS_TIMEB_H)
 226 check_include_file(unistd.h HAVE_UNISTD_H)
 227 check_include_file(windows.h HAVE_WINDOWS_H)
 228
 229 if(HAVE_INTTYPES_H)
 230   # ShivaVG needs inttypes.h
 231   add_definitions(-DHAVE_INTTYPES_H)
 232 endif()
 233
 234 if(ENABLE_RTI)
 235     # See if we have any rti library variant installed
 236     message(STATUS "RTI: ENABLED")
 237     find_package(RTI)
 238 else()
 239     message(STATUS "RTI: DISABLED")
 240 endif(ENABLE_RTI)
 241
 242 check_function_exists(gettimeofday HAVE_GETTIMEOFDAY)
 243 check_function_exists(ftime HAVE_FTIME)
 244 check_function_exists(timegm HAVE_TIMEGM)
 245 check_function_exists(rint HAVE_RINT)
 246 check_function_exists(mkdtemp HAVE_MKDTEMP)
 247 check_function_exists(bcopy HAVE_BCOPY)
 248 check_function_exists(mmap HAVE_MMAP)
 249
 250 if(HAVE_UNISTD_H)
 251     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 252     check_cxx_source_compiles(
 253        "#include <unistd.h>
 254         #if !defined(_POSIX_TIMERS) || (0 >= _POSIX_TIMERS)
 255             #error clock_gettime is not supported
 256         #endif
 257
 258         int main() { return 0; }
 259         "
 260         HAVE_CLOCK_GETTIME)
 261 endif(HAVE_UNISTD_H)
 262
 263 set(RT_LIBRARY "")
 264 if(HAVE_CLOCK_GETTIME)
 265     check_library_exists(rt clock_gettime "" HAVE_RT)
 266     if(HAVE_RT)
 267         set(RT_LIBRARY rt)
 268     endif(HAVE_RT)
 269 endif(HAVE_CLOCK_GETTIME)
 270
 271 set(DL_LIBRARY "")
 272 check_cxx_source_compiles(
 273     "#include <dlfcn.h>
 274     int main(void) {
 275         return 0;
 276     }
 277     "
 278     HAVE_DLFCN_H)
 279
 280 if(HAVE_DLFCN_H)
 281     check_library_exists(dl dlerror "" HAVE_DL)
 282     if(HAVE_DL)
 283         set(DL_LIBRARY "dl")
 284     endif()
 285 endif()
 286
 287 SET(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "add a postfix, usually 'd' on windows")
 288 SET(CMAKE_RELEASE_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 289 SET(CMAKE_RELWITHDEBINFO_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 290 SET(CMAKE_MINSIZEREL_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 291
 292 # isnan might not be real symbol, so can't check using function_exists
 293 check_cxx_source_compiles(
 294     "#include <cmath>
 295     int main() { return isnan(0.0);} "
 296     HAVE_ISNAN)
 297
 298 check_cxx_source_compiles(
 299     "#include <cmath>
 300     int main() { return std::isnan(0.0);} "
 301     HAVE_STD_ISNAN)
 302
 303 if(CMAKE_COMPILER_IS_GNUCXX)
 304     set(WARNING_FLAGS_CXX "-Wall")
 305     set(WARNING_FLAGS_C   "-Wall")
 306
 307     # certain GCC versions don't provide the atomic builds, and hence
 308     # require is to provide them in SGAtomic.cxx
 309     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 310     check_cxx_source_compiles(
 311        "int main() { unsigned mValue; return __sync_add_and_fetch(&mValue, 1); }"
 312         GCC_ATOMIC_BUILTINS_FOUND)
 313 endif(CMAKE_COMPILER_IS_GNUCXX)
 314
 315 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 316     # Boost redeclares class members
 317     set(WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual -Wno-redeclared-class-member")
 318     set(WARNING_FLAGS_C   "-Wall")
 319     set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LIBRARY "libc++")
 320     set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LANGUAGE_STANDARD "c++11")
 321     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -stdlib=libc++")
 322 endif()
 323
 324 if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 325 # boost goes haywire wrt static asserts
 326     check_cxx_compiler_flag(-Wno-unused-local-typedefs HAS_NOWARN_UNUSED_TYPEDEFS)
 327     if(HAS_NOWARN_UNUSED_TYPEDEFS)
 328         set(WARNING_FLAGS_CXX " ${WARNING_FLAGS_CXX} -Wno-unused-local-typedefs")
 329     endif()
 330 endif()
 331
 332 if(WIN32)
 333
 334     if(MINGW)
 335         add_definitions(-D_WIN32_WINNT=0x501)
 336     endif()
 337
 338     if(MSVC)
 339         # turn off various warnings
 340         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 341         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 342         # endforeach(warning)
 343
 344         set(MSVC_FLAGS "-DWIN32 -DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS /wd4996 /wd4250 -Dstrdup=_strdup")
 345         if (${MSVC_VERSION} GREATER 1599)
 346             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 347         endif (${MSVC_VERSION} GREATER 1599)
 348     endif(MSVC)
 349
 350     # assumed on Windows
 351     set(HAVE_GETLOCALTIME 1)
 352
 353     set( WINSOCK_LIBRARY "ws2_32.lib" )
 354     set( RT_LIBRARY "winmm" )
 355 endif(WIN32)
 356
 357 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS}")
 358 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} ${BOOST_CXX_FLAGS}")
 359 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 360
 361 # use BEFORE to ensure local directories are used first,
 362 # ahead of system-installed libs
 363 include_directories(BEFORE ${PROJECT_SOURCE_DIR})
 364 include_directories(BEFORE ${PROJECT_SOURCE_DIR}/simgear/canvas/ShivaVG/include)
 365 include_directories(BEFORE ${PROJECT_BINARY_DIR}/simgear)
 366
 367 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 368     ${Boost_INCLUDE_DIRS}
 369     ${ZLIB_INCLUDE_DIR}
 370     ${OPENAL_INCLUDE_DIR}
 371 )
 372
 373 add_definitions(-DHAVE_CONFIG_H)
 374
 375 # configure a header file to pass some of the CMake settings
 376 # to the source code
 377 configure_file (
 378   "${PROJECT_SOURCE_DIR}/simgear/simgear_config_cmake.h.in"
 379   "${PROJECT_BINARY_DIR}/simgear/simgear_config.h"
 380   )
 381
 382 if(ENABLE_TESTS)
 383     # enable CTest / make test target
 384     message(STATUS "Tests: ENABLED")
 385
 386     include (Dart)
 387     enable_testing()
 388 else()
 389     message(STATUS "Tests: DISABLED")
 390 endif(ENABLE_TESTS)
 391
 392 # always set TEST_LIBS as it is also used by other tools/applications
 393 set(TEST_LIBS_INTERNAL_CORE
 394     ${CMAKE_THREAD_LIBS_INIT}
 395     ${ZLIB_LIBRARY}
 396     ${WINSOCK_LIBRARY}
 397     ${RT_LIBRARY}
 398     ${DL_LIBRARY}
 399     ${COCOA_LIBRARY})
 400 set(TEST_LIBS SimGearCore ${TEST_LIBS_INTERNAL_CORE})
 401
 402 if(NOT SIMGEAR_HEADLESS)
 403     set(TEST_LIBS SimGearScene ${OPENGL_LIBRARIES} ${TEST_LIBS})
 404 endif()
 405
 406 install (FILES ${PROJECT_BINARY_DIR}/simgear/simgear_config.h  DESTINATION include/simgear/)
 407
 408 include_directories(3rdparty/utf8/source)
 409
 410 add_subdirectory(3rdparty)
 411 add_subdirectory(simgear)
 412
 413 #-----------------------------------------------------------------------------
 414 ### uninstall target
 415 #-----------------------------------------------------------------------------
 416 CONFIGURE_FILE(
 417   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 418   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 419   IMMEDIATE @ONLY)
 420 ADD_CUSTOM_TARGET(uninstall
 421   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")