CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7 include (CPack)
   8
   9 project(FlightGear)
  10
  11 # read 'version' file into a variable (stripping any newlines or spaces)
  12 file(READ version versionFile)
  13 string(STRIP ${versionFile} FLIGHTGEAR_VERSION)
  14
  15 #packaging
  16 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  17 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  18
  19 # We have some custom .cmake scripts not in the official distribution.
  20 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  21
  22 # autoconf compatibility
  23 set(PKGLIBDIR "foo")
  24
  25 if($ENV{BUILD_ID})
  26         set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  27         set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  28         message(STATUS "running under Hudson, build-number is ${HUDSON_BUILD_NUMBER}")
  29 else()
  30         set(HUDSON_BUILD_NUMBER 0)
  31         set(HUDSON_BUILD_ID "none")
  32 endif()
  33
  34 find_package(Git)
  35 if (GIT_FOUND)
  36         execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
  37                 OUTPUT_VARIABLE REVISION
  38                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  39         message(STATUS "Git revision is ${REVISION}")
  40 else()
  41         set(REVISION "none")
  42 endif()
  43
  44 option(LOGGING "Set to OFF to build FlightGear without logging" ON)
  45
  46 option(SP_FDMS "Set to ON to build FlightGear with special-purpose FDMs" OFF)
  47 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" ON)
  48 option(ENABLE_LARCSIM "Set to ON to build FlightGear with LaRCsim FDM" ON)
  49 option(ENABLE_YASIM "Set to ON to build FlightGear with YASIM FDM" ON)
  50 option(ENABLE_JSBSIM "Set to ON to build FlightGear with JSBSim FDM" ON)
  51 option(EVENT_INPUT "Set to ON to build FlightGear with event-based Input support" OFF)
  52 option(MSVC_3RDPARTY_DIR "Location where the third-party dependencies are extracted" NOT_FOUND)
  53
  54 if(LOGGING)
  55         # nothing
  56 else()
  57         set(FG_NDEBUG 1)
  58 endif()
  59
  60 if(${SP_FDMS})
  61         set(ENABLE_SP_FDM 1)
  62 endif()
  63
  64 if(EVENT_INPUT)
  65         message(STATUS "checking event-based Input")
  66         IF(APPLE)
  67
  68         elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
  69
  70         else()
  71                 message(WARNING "event input is not supported on this platform yet")
  72         endif()
  73 else(EVENT_INPUT)
  74         set(ENABLE_PLIB_JOYSTICK 1)
  75 endif(EVENT_INPUT)
  76
  77 if (MSVC_3RDPARTY_DIR)
  78   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_DIR}")
  79   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_DIR}/3rdParty/lib ${MSVC_3RDPARTY_DIR}/install/msvc90/OpenScenegraph/lib )
  80   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_DIR}/3rdParty/include ${MSVC_3RDPARTY_DIR}/install/msvc90/OpenScenegraph/include)
  81   set (BOOST_ROOT ${MSVC_3RDPARTY_DIR}/boost_1_44_0)
  82   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_DIR}/3rdParty/include)
  83   set (ALUT_INCLUDE_DIR ${MSVC_3RDPARTY_DIR}/3rdParty/include)
  84   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_DIR}/3rdParty/lib)
  85 endif (MSVC_3RDPARTY_DIR)
  86
  87
  88 # check required dependencies
  89 if (MSVC)
  90     # on MSVC, Olaf reports that the serialization library is required at
  91     # link time. No one has you explained why, unfortunately.
  92     set(Boost_USE_STATIC_LIBS        ON)
  93     set(Boost_USE_MULTITHREADED      ON)
  94     set(Boost_USE_STATIC_RUNTIME    OFF)
  95     find_package(Boost REQUIRED COMPONENTS serialization)
  96 else (MSVC)
  97     find_package(Boost REQUIRED)
  98 endif (MSVC)
  99
 100 find_package(ZLIB REQUIRED)
 101 find_package(Threads REQUIRED)
 102 find_package(OpenGL REQUIRED)
 103 find_package(OpenAL REQUIRED)
 104 find_package(ALUT REQUIRED)
 105 find_package(OpenSceneGraph 2.8.2 REQUIRED osgText osgSim osgDB osgParticle osgFX osgUtil osgViewer osgGA)
 106
 107 find_package(PLIB REQUIRED puaux pu js fnt)
 108 find_package(SimGear 2.0.0 REQUIRED)
 109
 110 check_include_file(unistd.h HAVE_UNISTD_H)
 111 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 112
 113 # definition depends on OSG version
 114 set(CMAKE_REQUIRED_INCLUDES ${OPENSCENEGRAPH_INCLUDE_DIRS})
 115
 116 check_cxx_source_compiles(
 117     "#include <osg/CullSettings>
 118     int main()
 119     {
 120        osg::CullSettings::VariablesMask mask = osg::CullSettings::CLEAR_MASK;
 121        return 0;
 122     }
 123     "
 124     HAVE_CULLSETTINGS_CLEAR_MASK)
 125
 126 # library required by simgear
 127 # XXX This should go in a module and only run if simgear is not shared.
 128
 129 if(HAVE_UNISTD_H)
 130 set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 131 check_cxx_source_compiles(
 132    "#include <unistd.h>
 133     #if !defined(_POSIX_TIMERS) || (0 >= _POSIX_TIMERS)
 134     #error clock_gettime is not supported
 135     #endif
 136
 137     int main() { return 0; }
 138     "
 139     HAVE_CLOCK_GETTIME)
 140 endif(HAVE_UNISTD_H)
 141
 142 set(RT_LIBRARY "")
 143 if(HAVE_CLOCK_GETTIME)
 144 check_function_exists(clock_gettime CLOCK_GETTIME_IN_LIBC)
 145 if(NOT CLOCK_GETTIME_IN_LIBC)
 146 check_library_exists(rt clock_gettime "" HAVE_RT)
 147 if(HAVE_RT)
 148 set(RT_LIBRARY rt)
 149 endif(HAVE_RT)
 150 endif(NOT CLOCK_GETTIME_IN_LIBC)
 151 endif(HAVE_CLOCK_GETTIME)
 152
 153 if(CMAKE_COMPILER_IS_GNUCXX)
 154     set(WARNING_FLAGS -Wall)
 155 endif(CMAKE_COMPILER_IS_GNUCXX)
 156
 157 if(WIN32)
 158
 159     if(MSVC)
 160         # turn off various warnings
 161         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 162         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 163         # endforeach(warning)
 164
 165         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS")
 166     endif(MSVC)
 167
 168     set(NOMINMAX 1)
 169 endif(WIN32)
 170
 171 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS} -D_REENTRANT")
 172 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS} -D_REENTRANT")
 173
 174 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 175     ${Boost_INCLUDE_DIRS}
 176         ${ZLIB_INCLUDE_DIR}
 177     ${ALUT_INCLUDE_DIR}
 178         ${OPENAL_INCLUDE_DIR}
 179         ${SIMGEAR_INCLUDE_DIR}
 180         ${PLIB_INCLUDE_DIR} )
 181
 182 include_directories(${PROJECT_SOURCE_DIR}/src)
 183
 184 # following is needed, because config.h is include 'bare', whereas
 185 # version.h is included as <Include/version.h> - this should be cleaned up
 186 include_directories(${PROJECT_BINARY_DIR}/src)
 187 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 188
 189 add_definitions(-DHAVE_CONFIG_H)
 190
 191 # configure a header file to pass some of the CMake settings
 192 # to the source code
 193 configure_file (
 194   "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 195   "${PROJECT_BINARY_DIR}/src/Include/config.h"
 196   )
 197
 198 #and the same for the version header
 199 configure_file (
 200   "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 201   "${PROJECT_BINARY_DIR}/src/Include/version.h"
 202   )
 203
 204 add_subdirectory(src)
 205 add_subdirectory(utils)
 206
 207 #-----------------------------------------------------------------------------
 208 ### uninstall target
 209 #-----------------------------------------------------------------------------
 210 CONFIGURE_FILE(
 211   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 212   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 213   IMMEDIATE @ONLY)
 214 ADD_CUSTOM_TARGET(uninstall
 215   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
 216