CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7 include (CPack)
   8
   9 project(FlightGear)
  10
  11 # read 'version' file into a variable (stripping any newlines or spaces)
  12 file(READ version versionFile)
  13 string(STRIP ${versionFile} FLIGHTGEAR_VERSION)
  14
  15 #packaging
  16 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  17 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  18
  19 # We have some custom .cmake scripts not in the official distribution.
  20 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  21
  22 # autoconf compatibility
  23 set(PKGLIBDIR "foo")
  24
  25 if($ENV{BUILD_ID})
  26         set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  27         set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  28         message(STATUS "running under Hudson, build-number is ${HUDSON_BUILD_NUMBER}")
  29 else()
  30         set(HUDSON_BUILD_NUMBER 0)
  31         set(HUDSON_BUILD_ID "none")
  32 endif()
  33
  34 find_package(Git)
  35 if (GIT_FOUND)
  36         execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
  37                 OUTPUT_VARIABLE REVISION
  38                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  39         message(STATUS "Git revision is ${REVISION}")
  40 else()
  41         set(REVISION "none")
  42 endif()
  43
  44 option(LOGGING "Set to OFF to build FlightGear without logging" ON)
  45
  46 option(SP_FDMS "Set to ON to build FlightGear with special-purpose FDMs" OFF)
  47 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" ON)
  48 option(ENABLE_LARCSIM "Set to ON to build FlightGear with LaRCsim FDM" ON)
  49 option(ENABLE_YASIM "Set to ON to build FlightGear with YASIM FDM" ON)
  50 option(ENABLE_JSBSIM "Set to ON to build FlightGear with JSBSim FDM" ON)
  51 option(EVENT_INPUT "Set to ON to build FlightGear with event-based Input support" OFF)
  52 option(MSVC_3RDPARTY_DIR "Location where the third-party dependencies are extracted" NOT_FOUND)
  53
  54 if(LOGGING)
  55         # nothing
  56 else()
  57         set(FG_NDEBUG 1)
  58 endif()
  59
  60 if(${SP_FDMS})
  61         set(ENABLE_SP_FDM 1)
  62 endif()
  63
  64 if(EVENT_INPUT)
  65         message(STATUS "checking event-based Input")
  66         IF(APPLE)
  67
  68         elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
  69
  70         else()
  71                 message(WARNING "event input is not supported on this platform yet")
  72         endif()
  73 else(EVENT_INPUT)
  74         set(ENABLE_PLIB_JOYSTICK 1)
  75 endif(EVENT_INPUT)
  76
  77 if (MSVC_3RDPARTY_DIR)
  78   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_DIR}")
  79   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_DIR}/3rdParty/lib ${MSVC_3RDPARTY_DIR}/install/msvc90/OpenScenegraph/lib )
  80   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_DIR}/3rdParty/include ${MSVC_3RDPARTY_DIR}/install/msvc90/OpenScenegraph/include)
  81   set (BOOST_ROOT ${MSVC_3RDPARTY_DIR}/boost_1_44_0)
  82   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_DIR}/3rdParty/include)
  83   set (ALUT_INCLUDE_DIR ${MSVC_3RDPARTY_DIR}/3rdParty/include)
  84   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_DIR}/3rdParty/lib)
  85 endif (MSVC_3RDPARTY_DIR)
  86
  87
  88 # check required dependencies
  89 find_package(Boost REQUIRED)
  90 find_package(ZLIB REQUIRED)
  91 find_package(Threads REQUIRED)
  92 find_package(OpenGL REQUIRED)
  93 find_package(OpenAL REQUIRED)
  94 find_package(ALUT REQUIRED)
  95 find_package(OpenSceneGraph 2.8.2 REQUIRED osgText osgSim osgDB osgParticle osgFX osgUtil osgViewer osgGA)
  96
  97 find_package(PLIB REQUIRED puaux pu js fnt)
  98 find_package(SimGear 2.0.0 REQUIRED)
  99
 100 check_include_file(unistd.h HAVE_UNISTD_H)
 101 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 102
 103 # definition depends on OSG version
 104 set(CMAKE_REQUIRED_INCLUDES ${OPENSCENEGRAPH_INCLUDE_DIRS})
 105
 106 check_cxx_source_compiles(
 107     "#include <osg/CullSettings>
 108     int main()
 109     {
 110        osg::CullSettings::VariablesMask mask = osg::CullSettings::CLEAR_MASK;
 111        return 0;
 112     }
 113     "
 114     HAVE_CULLSETTINGS_CLEAR_MASK)
 115
 116 # library required by simgear
 117 # XXX This should go in a module and only run if simgear is not shared.
 118
 119 if(HAVE_UNISTD_H)
 120 set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 121 check_cxx_source_compiles(
 122    "#include <unistd.h>
 123     #if !defined(_POSIX_TIMERS) || (0 >= _POSIX_TIMERS)
 124     #error clock_gettime is not supported
 125     #endif
 126
 127     int main() { return 0; }
 128     "
 129     HAVE_CLOCK_GETTIME)
 130 endif(HAVE_UNISTD_H)
 131
 132 set(RT_LIBRARY "")
 133 if(HAVE_CLOCK_GETTIME)
 134 check_function_exists(clock_gettime CLOCK_GETTIME_IN_LIBC)
 135 if(NOT CLOCK_GETTIME_IN_LIBC)
 136 check_library_exists(rt clock_gettime "" HAVE_RT)
 137 if(HAVE_RT)
 138 set(RT_LIBRARY rt)
 139 endif(HAVE_RT)
 140 endif(NOT CLOCK_GETTIME_IN_LIBC)
 141 endif(HAVE_CLOCK_GETTIME)
 142
 143 if(CMAKE_COMPILER_IS_GNUCXX)
 144     set(WARNING_FLAGS -Wall)
 145 endif(CMAKE_COMPILER_IS_GNUCXX)
 146
 147 if(WIN32)
 148
 149     if(MSVC)
 150         # turn off various warnings
 151         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 152         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 153         # endforeach(warning)
 154
 155         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS")
 156     endif(MSVC)
 157
 158     set(NOMINMAX 1)
 159 endif(WIN32)
 160
 161 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS} -D_REENTRANT")
 162 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS} -D_REENTRANT")
 163
 164 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 165     ${Boost_INCLUDE_DIRS}
 166         ${ZLIB_INCLUDE_DIR}
 167     ${ALUT_INCLUDE_DIR}
 168         ${OPENAL_INCLUDE_DIR}
 169         ${SIMGEAR_INCLUDE_DIR}
 170         ${PLIB_INCLUDE_DIR} )
 171
 172 include_directories(${PROJECT_SOURCE_DIR}/src)
 173
 174 # following is needed, because config.h is include 'bare', whereas
 175 # version.h is included as <Include/version.h> - this should be cleaned up
 176 include_directories(${PROJECT_BINARY_DIR}/src)
 177 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 178
 179 add_definitions(-DHAVE_CONFIG_H)
 180
 181 # configure a header file to pass some of the CMake settings
 182 # to the source code
 183 configure_file (
 184   "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 185   "${PROJECT_BINARY_DIR}/src/Include/config.h"
 186   )
 187
 188 #and the same for the version header
 189 configure_file (
 190   "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 191   "${PROJECT_BINARY_DIR}/src/Include/version.h"
 192   )
 193
 194 add_subdirectory(src)
 195 add_subdirectory(utils)
 196
 197 #-----------------------------------------------------------------------------
 198 ### uninstall target
 199 #-----------------------------------------------------------------------------
 200 CONFIGURE_FILE(
 201   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 202   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 203   IMMEDIATE @ONLY)
 204 ADD_CUSTOM_TARGET(uninstall
 205   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
 206