CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7
   8 project(FlightGear)
   9
  10 # We have some custom .cmake scripts not in the official distribution.
  11 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  12
  13 if(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  14     # use official include provided by latest CMake
  15     include(GNUInstallDirs)
  16 else(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  17     # backward compatibility: use our own module for older cmake versions
  18     include(OldGNUInstallDirs)
  19 endif(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  20
  21 # Warning when build is not an out-of-source build.
  22 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  23 if(InSourceBuild)
  24     message(WARNING  "Avoid building inside the source tree!")
  25     message(WARNING  "Create a separate build directory instead (i.e. 'fgbuild') and call CMake from there: ")
  26     message(WARNING  "  mkdir ../fgbuild && cd ../fgbuild && cmake ${CMAKE_SOURCE_DIR}")
  27 endif(InSourceBuild)
  28
  29 # System detection/default settings
  30 include( DetectDistro )
  31 include( DetectBrowser )
  32
  33 set(CMAKE_DEBUG_POSTFIX          "d" CACHE STRING "add a postfix, usually d on windows")
  34 set(CMAKE_RELEASE_POSTFIX        ""  CACHE STRING "add a postfix, usually empty on windows")
  35 set(CMAKE_RELWITHDEBINFO_POSTFIX ""  CACHE STRING "add a postfix, usually empty on windows")
  36 set(CMAKE_MINSIZEREL_POSTFIX     ""  CACHE STRING "add a postfix, usually empty on windows")
  37
  38 # read 'version' file into a variable (stripping any newlines or spaces)
  39 file(READ version versionFile)
  40 if (NOT versionFile)
  41     message(FATAL_ERROR "Unable to determine FlightGear version. Version file is missing.")
  42 endif()
  43 string(STRIP "${versionFile}" FLIGHTGEAR_VERSION)
  44
  45 # FlightGear packaging (to build a source tarball)
  46 include( ConfigureCPack )
  47
  48 # FlightGear base package path
  49 if (FG_DATA_DIR)
  50     message(STATUS "Using explicit data directory for base package: ${FG_DATA_DIR}")
  51 else()
  52     set(FG_DATA_DIR "${CMAKE_INSTALL_PREFIX}/lib/FlightGear" CACHE PATH "Default location where data files are located")
  53     message(STATUS "Using default data directory for base package:  ${FG_DATA_DIR}")
  54 endif()
  55
  56 # Change the default build type to something fast
  57 if(NOT CMAKE_BUILD_TYPE)
  58     set(CMAKE_BUILD_TYPE Release CACHE STRING
  59         "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  60         FORCE)
  61 endif(NOT CMAKE_BUILD_TYPE)
  62
  63 if(NOT "$ENV{BUILD_ID}" STREQUAL "")
  64     set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  65     set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  66     message(STATUS "running under Hudson/Jenkins, build-number is ${HUDSON_BUILD_NUMBER}")
  67 else()
  68     set(HUDSON_BUILD_NUMBER 0)
  69     set(HUDSON_BUILD_ID "none")
  70 endif()
  71
  72 #####################################################################################
  73 # Configure library search paths
  74 #####################################################################################
  75
  76
  77 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  78     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  79     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  80     # add paths manually
  81     # see http://www.cmake.org/Bug/view.php?id=12049 and
  82     # http://www.cmake.org/Bug/view.php?id=12037
  83     list(APPEND ADDITIONAL_LIBRARY_PATHS
  84          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  85          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  86          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
  87     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
  88 endif()
  89
  90 #####################################################################################
  91
  92 IF(APPLE)
  93     set(EVENT_INPUT_DEFAULT 1)
  94
  95     find_library(CORESERVICES_LIBRARY CoreServices)
  96     find_library(COCOA_LIBRARY Cocoa)
  97     list(APPEND PLATFORM_LIBS ${COCOA_LIBRARY} ${CORESERVICES_LIBRARY})
  98
  99 elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 100     set(USE_DBUS_DEFAULT 1)
 101     find_package(UDev)
 102
 103     if(UDEV_FOUND)
 104         set(EVENT_INPUT_DEFAULT 1)
 105     endif(UDEV_FOUND)
 106
 107     find_package(Speex)
 108     find_package(Speexdsp)
 109     if(SPEEX_FOUND AND SPEEXDSP_FOUND)
 110         set(SYSTEM_SPEEX_DEFAULT 1)
 111     endif(SPEEX_FOUND AND SPEEXDSP_FOUND)
 112
 113     find_package(Gsm)
 114     if(GSM_FOUND)
 115         set(SYSTEM_GSM_DEFAULT 1)
 116     endif(GSM_FOUND)
 117 endif()
 118
 119 find_package(Git)
 120 if (GIT_FOUND)
 121     execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
 122         OUTPUT_VARIABLE REVISION
 123         OUTPUT_STRIP_TRAILING_WHITESPACE)
 124     message(STATUS "Git revision is ${REVISION}")
 125 else()
 126     set(REVISION "none")
 127 endif()
 128
 129 # FlightGear build options
 130 option(SIMGEAR_SHARED    "Set to ON when SimGear was built as a shared library" OFF)
 131 option(LOGGING           "Set to ON to build FlightGear with logging support (default)" ON)
 132 option(JSBSIM_TERRAIN    "Set to ON to build FlightGear with JSBSim terrain handling code" ON)
 133 option(SP_FDMS           "Set to ON to build FlightGear with special-purpose FDMs" OFF)
 134 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" OFF)
 135 option(ENABLE_LARCSIM    "Set to ON to build FlightGear with LaRCsim FDM" OFF)
 136 option(ENABLE_YASIM      "Set to ON to build FlightGear with YASIM FDM (default)" ON)
 137 option(ENABLE_JSBSIM     "Set to ON to build FlightGear with JSBSim FDM (default)" ON)
 138 option(EVENT_INPUT       "Set to ON to build FlightGear with event-based Input support" ${EVENT_INPUT_DEFAULT})
 139 option(ENABLE_RTI        "Set to ON to build FlightGear with RTI support" OFF)
 140 option(ENABLE_PROFILE    "Set to ON to build FlightGear with gperftools profiling support" OFF)
 141 option(SYSTEM_SQLITE     "Set to ON to build FlightGear with the system's SQLite3 library" OFF)
 142 option(ENABLE_IAX        "Set to ON to build FlightGear with IAXClient/fgcom built-in (default)" ON)
 143 option(USE_DBUS          "Set to ON to build FlightGear with DBus screensaver interaction (default on Linux)" ${USE_DBUS_DEFAULT})
 144 option(SYSTEM_SPEEX      "Set to ON to build IAXClient with the system's speex and speexdsp library" ${SYSTEM_SPEEX_DEFAULT})
 145 option(SYSTEM_GSM        "Set to ON to build IAXClient with the system's GSM library" ${SYSTEM_GSM_DEFAULT})
 146
 147 # additional utilities
 148 option(ENABLE_FGADMIN    "Set to ON to build the FGADMIN application (default)" ON)
 149 option(ENABLE_FGELEV     "Set to ON to build the fgelev application (default)" ON)
 150 option(WITH_FGPANEL      "Set to ON to build the fgpanel application (default)" ON)
 151 option(ENABLE_FGVIEWER   "Set to ON to build the fgviewer application (default)" ON)
 152 option(ENABLE_GPSSMOOTH  "Set to ON to build the GPSsmooth application (default)" ON)
 153 option(ENABLE_TERRASYNC  "Set to ON to build the terrasync application (default)" ON)
 154 option(ENABLE_FGJS       "Set to ON to build the fgjs application (default)" ON)
 155 option(ENABLE_JS_DEMO    "Set to ON to build the js_demo application (default)" ON)
 156 option(ENABLE_METAR      "Set to ON to build the metar application (default)" ON)
 157 option(ENABLE_TESTS      "Set to ON to build test applications (default)" ON)
 158 option(ENABLE_FGCOM      "Set to ON to build the FGCom application (default)" ON)
 159
 160 if(LOGGING)
 161     # nothing
 162 else()
 163     set(FG_NDEBUG 1)
 164 endif()
 165
 166 if(JSBSIM_TERRAIN)
 167    set(JSBSIM_USE_GROUNDREACTIONS 1)
 168 endif()
 169
 170 if(SP_FDMS)
 171     set(ENABLE_SP_FDM 1)
 172 endif()
 173
 174 if(ENABLE_FGCOM)
 175   set(ENABLE_IAX 1)
 176 endif()
 177
 178 # Setup MSVC 3rd party directories
 179 include( ConfigureMsvc3rdParty )
 180
 181 if(EVENT_INPUT)
 182     if(APPLE)
 183     elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 184         if(NOT UDEV_FOUND)
 185             message(WARNING "UDev not found, event input is disabled!")
 186             set(EVENT_INPUT 0)
 187         else()
 188             add_definitions(-DWITH_EVENTINPUT)
 189             set(EVENT_INPUT_LIBRARIES ${UDEV_LIBRARIES})
 190             message(STATUS "event-based input enabled. Using ${UDEV_LIBRARIES}")
 191         endif()
 192     else()
 193         message(WARNING "event-based input is not supported on this platform yet")
 194     endif()
 195
 196     # Keep PLIB INPUT enabled as long as EventInput does not replace current joystick configurations.
 197     set(ENABLE_PLIB_JOYSTICK 1)
 198 else(EVENT_INPUT)
 199     set(ENABLE_PLIB_JOYSTICK 1)
 200 endif(EVENT_INPUT)
 201
 202 # check required dependencies
 203 find_package(Boost   REQUIRED)
 204 find_package(ZLIB    REQUIRED)
 205 find_package(Threads REQUIRED)
 206 find_package(OpenGL  REQUIRED)
 207 find_package(OpenAL  REQUIRED)
 208 find_package(OpenSceneGraph 3.2.0 REQUIRED osgText osgSim osgDB osgParticle osgFX osgUtil osgViewer osgGA)
 209
 210 if (MSVC)
 211         find_package(CrashRpt)
 212         if (CRASHRPT_FOUND)
 213                 set(HAVE_CRASHRPT 1)
 214                 message(STATUS "Using CrashRpt")
 215         include_directories( ${CRASHRPT_INCLUDE_DIR})
 216         endif()
 217 endif()
 218
 219 if(ENABLE_FGADMIN)
 220     find_package(FLTK)
 221
 222     if ( FLTK_FOUND )
 223         if ( X11_Xinerama_FOUND )
 224             message(STATUS "Found X11_Xinerama...")
 225             list(APPEND FLTK_LIBRARIES ${X11_Xinerama_LIB})
 226         endif()
 227
 228         if ( X11_Xft_FOUND )
 229             message(STATUS "Found X11_Xft...")
 230             list(APPEND FLTK_LIBRARIES ${X11_Xft_LIB})
 231         endif()
 232
 233         if ( CMAKE_DL_LIBS )
 234             list(APPEND FLTK_LIBRARIES ${CMAKE_DL_LIBS})
 235         endif()
 236
 237         message(STATUS "Using FLTK_LIBRARIES for fgadmin: ${FLTK_LIBRARIES}")
 238     endif ( FLTK_FOUND )
 239 endif(ENABLE_FGADMIN)
 240
 241 ##############################################################################
 242 ## Sqlite3 setup
 243
 244 if (SYSTEM_SQLITE)
 245     find_package(SQLite3 REQUIRED)
 246
 247     message(STATUS "Using system SQLite3 library")
 248 else()
 249     set(SQLITE3_INCLUDED_DIR "${CMAKE_SOURCE_DIR}/3rdparty/sqlite3")
 250     # this target is defined in src/Navaids/CMakeLists.txt
 251     list(APPEND SQLITE3_LIBRARY fgsqlite3)
 252 endif (SYSTEM_SQLITE)
 253
 254 # Sqlite always depends on the threading lib
 255 list(APPEND SQLITE3_LIBRARY ${CMAKE_THREAD_LIBS_INIT})
 256
 257 ##############################################################################
 258 ## DBus setup
 259
 260 if (USE_DBUS)
 261     include(FindPkgConfig)
 262     if (PKG_CONFIG_FOUND)
 263         pkg_check_modules(DBUS dbus-1)
 264     endif (PKG_CONFIG_FOUND) #if we don't have pkg-config, assume we don't have libdbus-1-dev either http://packages.debian.org/sid/libdbus-1-dev
 265     if (DBUS_FOUND)
 266         set(HAVE_DBUS 1)
 267         message(STATUS "Using DBus")
 268         include_directories( ${DBUS_INCLUDE_DIRS})
 269     else()
 270         message(STATUS "DBus not found, screensaver control disabled")
 271     endif (DBUS_FOUND)
 272 else()
 273 endif (USE_DBUS)
 274
 275 # Sqlite always depends on the threading lib
 276 list(APPEND SQLITE3_LIBRARY ${CMAKE_THREAD_LIBS_INIT})
 277
 278 ##############################################################################
 279
 280 find_package(PLIB REQUIRED puaux pu js fnt)
 281
 282 # FlightGear and SimGear versions need to match
 283 find_package(SimGear ${FLIGHTGEAR_VERSION} REQUIRED)
 284
 285 ##############################################################################
 286
 287 check_include_file(unistd.h   HAVE_UNISTD_H)
 288 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 289 check_include_file(windows.h  HAVE_WINDOWS_H)
 290
 291 if(ENABLE_PROFILE)
 292     find_package(GooglePerfTools REQUIRED)
 293     set(FG_HAVE_GPERFTOOLS 1)
 294     message(STATUS "Built-in profiler using gperftools available")
 295 endif()
 296
 297 if(ENABLE_RTI)
 298     message(STATUS "RTI: ENABLED")
 299     find_package(RTI)
 300     if(RTI_FOUND)
 301         set(FG_HAVE_HLA 1)
 302     endif(RTI_FOUND)
 303 else()
 304     message(STATUS "RTI: DISABLED")
 305 endif(ENABLE_RTI)
 306
 307 if(CMAKE_COMPILER_IS_GNUCXX)
 308     set(WARNING_FLAGS_CXX "-Wall")
 309     set(WARNING_FLAGS_C   "-Wall")
 310 endif(CMAKE_COMPILER_IS_GNUCXX)
 311
 312 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 313    set (WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual")
 314    set (WARNING_FLAGS_C   "-Wall")
 315 endif()
 316
 317 if(WIN32)
 318
 319     if(MSVC)
 320         # turn off various warnings
 321         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 322         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 323         # endforeach(warning)
 324
 325         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS -Dstrdup=_strdup")
 326         if (${MSVC_VERSION} GREATER 1599)
 327             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 328         endif (${MSVC_VERSION} GREATER 1599)
 329     endif(MSVC)
 330
 331     set(NOMINMAX 1)
 332 endif(WIN32)
 333
 334 set (BOOST_CXX_FLAGS "-DBOOST_MULTI_INDEX_DISABLE_SERIALIZATION -DBOOST_BIMAP_DISABLE_SERIALIZATION")
 335
 336 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS} -D_REENTRANT")
 337 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} -D_REENTRANT ${BOOST_CXX_FLAGS}")
 338 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 339
 340 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 341     ${Boost_INCLUDE_DIRS}
 342     ${ZLIB_INCLUDE_DIR}
 343     ${OPENGL_INCLUDE_DIR}
 344     ${OPENAL_INCLUDE_DIR}
 345     ${SIMGEAR_INCLUDE_DIR}
 346     ${PLIB_INCLUDE_DIR}
 347     ${SQLITE3_INCLUDED_DIR} )
 348
 349 include_directories(${PROJECT_SOURCE_DIR})
 350 include_directories(${PROJECT_SOURCE_DIR}/src)
 351 include_directories(${PROJECT_SOURCE_DIR}/3rdparty/iaxclient/lib ) # for iaxclient.h
 352 # following is needed, because config.h is include 'bare', whereas
 353 # version.h is included as <Include/version.h> - this should be cleaned up
 354 include_directories(${PROJECT_BINARY_DIR}/src)
 355 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 356
 357 add_definitions(-DHAVE_CONFIG_H)
 358
 359 check_function_exists(mkfifo HAVE_MKFIFO)
 360
 361 # configure a header file to pass some of the CMake settings
 362 # to the source code
 363 configure_file (
 364     "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 365     "${PROJECT_BINARY_DIR}/src/Include/config.h"
 366 )
 367
 368 #and the same for the version header
 369 configure_file (
 370     "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 371     "${PROJECT_BINARY_DIR}/src/Include/version.h"
 372 )
 373
 374 add_subdirectory(3rdparty)
 375 add_subdirectory(utils)
 376 add_subdirectory(src)
 377 add_subdirectory(man)
 378
 379 #-----------------------------------------------------------------------------
 380 ### uninstall target
 381 #-----------------------------------------------------------------------------
 382 CONFIGURE_FILE(
 383     "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 384     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 385     IMMEDIATE @ONLY)
 386 ADD_CUSTOM_TARGET(uninstall
 387     "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")