CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2
   3 if(COMMAND cmake_policy)
   4     if(${CMAKE_MAJOR_VERSION} GREATER 2) # version 3 or higher
   5         cmake_policy(SET CMP0054 NEW)
   6         cmake_policy(SET CMP0042 NEW)
   7     endif()
   8 endif()
   9
  10 include (CheckFunctionExists)
  11 include (CheckIncludeFile)
  12 include (CheckCXXSourceCompiles)
  13 include (CheckCXXCompilerFlag)
  14
  15 # set this before project()
  16 # using 10.7 because boost requires libc++ and 10.6 doesn't include it
  17 set(CMAKE_OSX_DEPLOYMENT_TARGET 10.7)
  18
  19 project(SimGear)
  20
  21 # read 'version' file into a variable (stripping any newlines or spaces)
  22 file(READ version versionFile)
  23 string(STRIP ${versionFile} SIMGEAR_VERSION)
  24
  25 set(FIND_LIBRARY_USE_LIB64_PATHS ON)
  26
  27 # use simgear version also as the SO version (if building SOs)
  28 SET(SIMGEAR_SOVERSION ${SIMGEAR_VERSION})
  29
  30 # Warning when build is not an out-of-source build.
  31 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  32 if(InSourceBuild)
  33     message(WARNING  "Avoid building inside the source tree!")
  34     message(WARNING  "Create a separate build directory instead (i.e. 'sgbuild') and call CMake from there: ")
  35     message(WARNING  "  mkdir ../sgbuild && cd ../sgbuild && cmake ${CMAKE_SOURCE_DIR}")
  36 endif(InSourceBuild)
  37
  38 #packaging
  39 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  40 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  41 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Simulation support libraries for FlightGear and related projects")
  42 SET(CPACK_PACKAGE_VENDOR "The FlightGear project")
  43 SET(CPACK_GENERATOR "TBZ2")
  44 SET(CPACK_INSTALL_CMAKE_PROJECTS  ${CMAKE_CURRENT_BINARY_DIR};SimGear;ALL;/)
  45
  46
  47 # split version string into components, note CMAKE_MATCH_0 is the entire regexp match
  48 string(REGEX MATCH "([0-9]+)\\.([0-9]+)\\.([0-9]+)" CPACK_PACKAGE_VERSION ${SIMGEAR_VERSION} )
  49 set(CPACK_PACKAGE_VERSION_MAJOR ${CMAKE_MATCH_1})
  50 set(CPACK_PACKAGE_VERSION_MINOR ${CMAKE_MATCH_2})
  51 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_3})
  52
  53 message(STATUS "version is ${CPACK_PACKAGE_VERSION_MAJOR} dot ${CPACK_PACKAGE_VERSION_MINOR} dot ${CPACK_PACKAGE_VERSION_PATCH}")
  54
  55 set(CPACK_SOURCE_GENERATOR TBZ2)
  56 set(CPACK_SOURCE_PACKAGE_FILE_NAME "simgear-${SIMGEAR_VERSION}" CACHE INTERNAL "tarball basename")
  57 set(CPACK_SOURCE_IGNORE_FILES
  58   "^${PROJECT_SOURCE_DIR}/.git;\\\\.gitignore;Makefile.am;~$;${CPACK_SOURCE_IGNORE_FILES}")
  59
  60 message(STATUS "ignoring: ${CPACK_SOURCE_IGNORE_FILES}")
  61
  62 include (CPack)
  63
  64 # We have some custom .cmake scripts not in the official distribution.
  65 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  66
  67 # Change the default build type to something fast
  68 if(NOT CMAKE_BUILD_TYPE)
  69   set(CMAKE_BUILD_TYPE Release CACHE STRING
  70       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  71       FORCE)
  72 endif(NOT CMAKE_BUILD_TYPE)
  73
  74 # Determine name of library installation directory, i.e. "lib" vs "lib64", which
  75 # differs between all Debian-based vs all other Linux distros.
  76 # See cmake bug #11964, http://cmake.org/gitweb?p=cmake.git;a=commit;h=126c993d
  77 # GNUInstallDirs requires CMake >= 2.8.5, use own file for older cmake
  78 if(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  79   include(GNUInstallDirs)
  80 else(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  81   include(OldGNUInstallDirs)
  82 endif(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  83 message(STATUS "Library installation directory: ${CMAKE_INSTALL_LIBDIR}")
  84
  85 #####################################################################################
  86 # Configure library search paths
  87 #####################################################################################
  88
  89 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  90     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  91     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  92     # add paths manually
  93     # see http://www.cmake.org/Bug/view.php?id=12049 and
  94     # http://www.cmake.org/Bug/view.php?id=12037
  95     list(APPEND ADDITIONAL_LIBRARY_PATHS
  96          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  97          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  98          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
  99     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
 100 endif()
 101
 102 #####################################################################################
 103
 104 if (NOT MSVC)
 105 option(SIMGEAR_SHARED   "Set to ON to build SimGear as a shared library/framework" OFF)
 106 option(SYSTEM_EXPAT     "Set to ON to build SimGear using the system libExpat" OFF)
 107 else()
 108 # Building SimGear DLLs is currently not supported for MSVC.
 109 set(SIMGEAR_SHARED OFF)
 110 # Using a system expat is currently not supported for MSVC - it would require shared simgear (DLL).
 111 set(SYSTEM_EXPAT OFF)
 112 endif()
 113
 114 option(SIMGEAR_HEADLESS "Set to ON to build SimGear without GUI/graphics support" OFF)
 115 option(ENABLE_RTI       "Set to ON to build SimGear with RTI support" OFF)
 116 option(ENABLE_TESTS     "Set to OFF to disable building SimGear's test applications" ON)
 117 option(ENABLE_SOUND     "Set to OFF to disable building SimGear's sound support" ON)
 118 option(ENABLE_PKGUTIL   "Set to ON to build the sg_pkgutil application (default)" ON)
 119
 120 if (MSVC)
 121   GET_FILENAME_COMPONENT(PARENT_DIR ${PROJECT_BINARY_DIR} PATH)
 122   if (CMAKE_CL_64)
 123     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty.x64")
 124   else (CMAKE_CL_64)
 125     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty")
 126   endif (CMAKE_CL_64)
 127   if (EXISTS ${TEST_3RDPARTY_DIR})
 128     set(MSVC_3RDPARTY_ROOT ${PARENT_DIR} CACHE PATH "Location where the third-party dependencies are extracted")
 129   else (EXISTS ${TEST_3RDPARTY_DIR})
 130     set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 131   endif (EXISTS ${TEST_3RDPARTY_DIR})
 132 else (MSVC)
 133   set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 134 endif (MSVC)
 135
 136 if (MSVC AND MSVC_3RDPARTY_ROOT)
 137   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_ROOT}")
 138   set( OSG_MSVC "msvc" )
 139   if (${MSVC_VERSION} EQUAL 1700)
 140       set( OSG_MSVC ${OSG_MSVC}110 )
 141   elseif (${MSVC_VERSION} EQUAL 1600)
 142       set( OSG_MSVC ${OSG_MSVC}100 )
 143   else (${MSVC_VERSION} EQUAL 1700)
 144       set( OSG_MSVC ${OSG_MSVC}90 )
 145   endif (${MSVC_VERSION} EQUAL 1700)
 146   if (CMAKE_CL_64)
 147       set( OSG_MSVC ${OSG_MSVC}-64 )
 148       set( MSVC_3RDPARTY_DIR 3rdParty.x64 )
 149   else (CMAKE_CL_64)
 150       set( MSVC_3RDPARTY_DIR 3rdParty )
 151   endif (CMAKE_CL_64)
 152
 153   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/lib )
 154   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/include)
 155   find_path(BOOST_ROOT boost/version.hpp
 156                         ${MSVC_3RDPARTY_ROOT}/boost
 157                         ${MSVC_3RDPARTY_ROOT}/boost_1_52_0
 158                         ${MSVC_3RDPARTY_ROOT}/boost_1_51_0
 159                         ${MSVC_3RDPARTY_ROOT}/boost_1_50_0
 160                         ${MSVC_3RDPARTY_ROOT}/boost_1_49_0
 161                         ${MSVC_3RDPARTY_ROOT}/boost_1_48_0
 162                         ${MSVC_3RDPARTY_ROOT}/boost_1_47_0
 163                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_1
 164                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_0
 165                         ${MSVC_3RDPARTY_ROOT}/boost_1_45_0
 166                         ${MSVC_3RDPARTY_ROOT}/boost_1_44_0
 167                         )
 168   # set (BOOST_ROOT ${MSVC_3RDPARTY_ROOT}/boost_1_44_0)
 169   message(STATUS "BOOST_ROOT is ${BOOST_ROOT}")
 170   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 171   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib)
 172 endif (MSVC AND MSVC_3RDPARTY_ROOT)
 173
 174 if(APPLE)
 175   find_library(COCOA_LIBRARY Cocoa)
 176 endif()
 177
 178 # Somehow this only works if included before searching for Boost...
 179 include(BoostTestTargets)
 180
 181 find_package(Boost REQUIRED)
 182 set (BOOST_CXX_FLAGS "-DBOOST_MULTI_INDEX_DISABLE_SERIALIZATION -DBOOST_BIMAP_DISABLE_SERIALIZATION")
 183
 184 if(SIMGEAR_HEADLESS)
 185     message(STATUS "SimGear mode: HEADLESS")
 186     set(ENABLE_SOUND 0)
 187 else()
 188     message(STATUS "SimGear mode: NORMAL")
 189     find_package(OpenGL REQUIRED)
 190
 191     if (ENABLE_SOUND)
 192         find_package(OpenAL REQUIRED)
 193         message(STATUS "Sound support: ENABLED")
 194     endif(ENABLE_SOUND)
 195
 196     find_package(OpenSceneGraph 3.2.0 REQUIRED osgText osgSim osgDB osgParticle osgGA osgViewer osgUtil)
 197 endif(SIMGEAR_HEADLESS)
 198
 199 find_package(ZLIB REQUIRED)
 200 find_package(Threads REQUIRED)
 201
 202 if (SYSTEM_EXPAT)
 203     message(STATUS "Requested to use system Expat library, forcing SIMGEAR_SHARED to true")
 204     set(SIMGEAR_SHARED ON)
 205     find_package(EXPAT REQUIRED)
 206
 207 else()
 208     message(STATUS "Using built-in expat code")
 209     # XML_STATIC is important to avoid sg_expat_external.h
 210     # declaring symbols as declspec(import)
 211     add_definitions(-DHAVE_EXPAT_CONFIG_H -DXML_STATIC)
 212     set(EXPAT_INCLUDE_DIRS
 213             ${PROJECT_SOURCE_DIR}/3rdparty/expat
 214             ${PROJECT_BINARY_DIR}/3rdparty/expat)
 215 endif(SYSTEM_EXPAT)
 216
 217 include_directories(${EXPAT_INCLUDE_DIRS})
 218
 219 check_include_file(inttypes.h HAVE_INTTYPES_H)
 220 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 221 check_include_file(sys/timeb.h HAVE_SYS_TIMEB_H)
 222 check_include_file(unistd.h HAVE_UNISTD_H)
 223 check_include_file(windows.h HAVE_WINDOWS_H)
 224
 225 if(HAVE_INTTYPES_H)
 226   # ShivaVG needs inttypes.h
 227   add_definitions(-DHAVE_INTTYPES_H)
 228 endif()
 229
 230 if(ENABLE_RTI)
 231     # See if we have any rti library variant installed
 232     message(STATUS "RTI: ENABLED")
 233     find_package(RTI)
 234 else()
 235     message(STATUS "RTI: DISABLED")
 236 endif(ENABLE_RTI)
 237
 238 check_function_exists(gettimeofday HAVE_GETTIMEOFDAY)
 239 check_function_exists(ftime HAVE_FTIME)
 240 check_function_exists(timegm HAVE_TIMEGM)
 241 check_function_exists(rint HAVE_RINT)
 242 check_function_exists(mkdtemp HAVE_MKDTEMP)
 243 check_function_exists(bcopy HAVE_BCOPY)
 244 check_function_exists(mmap HAVE_MMAP)
 245
 246 if(HAVE_UNISTD_H)
 247     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 248     check_cxx_source_compiles(
 249        "#include <unistd.h>
 250         #if !defined(_POSIX_TIMERS) || (0 >= _POSIX_TIMERS)
 251             #error clock_gettime is not supported
 252         #endif
 253
 254         int main() { return 0; }
 255         "
 256         HAVE_CLOCK_GETTIME)
 257 endif(HAVE_UNISTD_H)
 258
 259 set(RT_LIBRARY "")
 260 if(HAVE_CLOCK_GETTIME)
 261     check_library_exists(rt clock_gettime "" HAVE_RT)
 262     if(HAVE_RT)
 263         set(RT_LIBRARY rt)
 264     endif(HAVE_RT)
 265 endif(HAVE_CLOCK_GETTIME)
 266
 267 set(DL_LIBRARY "")
 268 check_cxx_source_compiles(
 269     "#include <dlfcn.h>
 270     int main(void) {
 271         return 0;
 272     }
 273     "
 274     HAVE_DLFCN_H)
 275
 276 if(HAVE_DLFCN_H)
 277     check_library_exists(dl dlerror "" HAVE_DL)
 278     if(HAVE_DL)
 279         set(DL_LIBRARY "dl")
 280     endif()
 281 endif()
 282
 283 SET(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "add a postfix, usually 'd' on windows")
 284 SET(CMAKE_RELEASE_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 285 SET(CMAKE_RELWITHDEBINFO_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 286 SET(CMAKE_MINSIZEREL_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 287
 288 # isnan might not be real symbol, so can't check using function_exists
 289 check_cxx_source_compiles(
 290     "#include <cmath>
 291     int main() { return isnan(0.0);} "
 292     HAVE_ISNAN)
 293
 294 check_cxx_source_compiles(
 295     "#include <cmath>
 296     int main() { return std::isnan(0.0);} "
 297     HAVE_STD_ISNAN)
 298
 299 if(CMAKE_COMPILER_IS_GNUCXX)
 300     set(WARNING_FLAGS_CXX "-Wall")
 301     set(WARNING_FLAGS_C   "-Wall")
 302
 303     # certain GCC versions don't provide the atomic builds, and hence
 304     # require is to provide them in SGAtomic.cxx
 305     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 306     check_cxx_source_compiles(
 307        "int main() { unsigned mValue; return __sync_add_and_fetch(&mValue, 1); }"
 308         GCC_ATOMIC_BUILTINS_FOUND)
 309 endif(CMAKE_COMPILER_IS_GNUCXX)
 310
 311 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 312    set(WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual")
 313    set(WARNING_FLAGS_C   "-Wall")
 314 endif()
 315
 316 if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 317 # boost goes haywire wrt static asserts
 318     check_cxx_compiler_flag(-Wno-unused-local-typedefs HAS_NOWARN_UNUSED_TYPEDEFS)
 319     if(HAS_NOWARN_UNUSED_TYPEDEFS)
 320         set(WARNING_FLAGS_CXX " ${WARNING_FLAGS_CXX} -Wno-unused-local-typedefs")
 321     endif()
 322 endif()
 323
 324 if(WIN32)
 325
 326     if(MINGW)
 327         add_definitions(-D_WIN32_WINNT=0x501)
 328     endif()
 329
 330     if(MSVC)
 331         # turn off various warnings
 332         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 333         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 334         # endforeach(warning)
 335
 336         set(MSVC_FLAGS "-DWIN32 -DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS /wd4996 /wd4250 -Dstrdup=_strdup")
 337         if (${MSVC_VERSION} GREATER 1599)
 338             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 339         endif (${MSVC_VERSION} GREATER 1599)
 340     endif(MSVC)
 341
 342     # assumed on Windows
 343     set(HAVE_GETLOCALTIME 1)
 344
 345     set( WINSOCK_LIBRARY "ws2_32.lib" )
 346     set( RT_LIBRARY "winmm" )
 347 endif(WIN32)
 348
 349 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS}")
 350 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} ${BOOST_CXX_FLAGS}")
 351 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 352
 353 # use BEFORE to ensure local directories are used first,
 354 # ahead of system-installed libs
 355 include_directories(BEFORE ${PROJECT_SOURCE_DIR})
 356 include_directories(BEFORE ${PROJECT_SOURCE_DIR}/simgear/canvas/ShivaVG/include)
 357 include_directories(BEFORE ${PROJECT_BINARY_DIR}/simgear)
 358
 359 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 360     ${Boost_INCLUDE_DIRS}
 361     ${ZLIB_INCLUDE_DIR}
 362     ${OPENAL_INCLUDE_DIR}
 363 )
 364
 365 add_definitions(-DHAVE_CONFIG_H)
 366
 367 # configure a header file to pass some of the CMake settings
 368 # to the source code
 369 configure_file (
 370   "${PROJECT_SOURCE_DIR}/simgear/simgear_config_cmake.h.in"
 371   "${PROJECT_BINARY_DIR}/simgear/simgear_config.h"
 372   )
 373
 374 if(ENABLE_TESTS)
 375     # enable CTest / make test target
 376     message(STATUS "Tests: ENABLED")
 377
 378     include (Dart)
 379     enable_testing()
 380 else()
 381     message(STATUS "Tests: DISABLED")
 382 endif(ENABLE_TESTS)
 383
 384 # always set TEST_LIBS as it is also used by other tools/applications
 385 set(TEST_LIBS_INTERNAL_CORE
 386     ${CMAKE_THREAD_LIBS_INIT}
 387     ${ZLIB_LIBRARY}
 388     ${WINSOCK_LIBRARY}
 389     ${RT_LIBRARY}
 390     ${DL_LIBRARY}
 391     ${COCOA_LIBRARY})
 392 set(TEST_LIBS SimGearCore ${TEST_LIBS_INTERNAL_CORE})
 393
 394 if(NOT SIMGEAR_HEADLESS)
 395     set(TEST_LIBS SimGearScene ${OPENGL_LIBRARIES} ${TEST_LIBS})
 396 endif()
 397
 398 install (FILES ${PROJECT_BINARY_DIR}/simgear/simgear_config.h  DESTINATION include/simgear/)
 399
 400 include_directories(3rdparty/utf8/source)
 401
 402 add_subdirectory(3rdparty)
 403 add_subdirectory(simgear)
 404
 405 #-----------------------------------------------------------------------------
 406 ### uninstall target
 407 #-----------------------------------------------------------------------------
 408 CONFIGURE_FILE(
 409   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 410   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 411   IMMEDIATE @ONLY)
 412 ADD_CUSTOM_TARGET(uninstall
 413   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
 414
 415