CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7
   8 project(FlightGear)
   9
  10 # We have some custom .cmake scripts not in the official distribution.
  11 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  12
  13 if(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  14     # use official include provided by latest CMake
  15     include(GNUInstallDirs)
  16 else(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  17     # backward compatibility: use our own module for older cmake versions
  18     include(OldGNUInstallDirs)
  19 endif(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  20
  21 # Warning when build is not an out-of-source build.
  22 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  23 if(InSourceBuild)
  24     message(WARNING  "Avoid building inside the source tree!")
  25     message(WARNING  "Create a separate build directory instead (i.e. 'fgbuild') and call CMake from there: ")
  26     message(WARNING  "  mkdir ../fgbuild && cd ../fgbuild && cmake ${CMAKE_SOURCE_DIR}")
  27 endif(InSourceBuild)
  28
  29 # System detection/default settings
  30 include( DetectDistro )
  31 include( DetectBrowser )
  32
  33 set(CMAKE_DEBUG_POSTFIX          "d" CACHE STRING "add a postfix, usually d on windows")
  34 set(CMAKE_RELEASE_POSTFIX        ""  CACHE STRING "add a postfix, usually empty on windows")
  35 set(CMAKE_RELWITHDEBINFO_POSTFIX ""  CACHE STRING "add a postfix, usually empty on windows")
  36 set(CMAKE_MINSIZEREL_POSTFIX     ""  CACHE STRING "add a postfix, usually empty on windows")
  37
  38 # read 'version' file into a variable (stripping any newlines or spaces)
  39 file(READ version versionFile)
  40 if (NOT versionFile)
  41     message(FATAL_ERROR "Unable to determine FlightGear version. Version file is missing.")
  42 endif()
  43 string(STRIP "${versionFile}" FLIGHTGEAR_VERSION)
  44
  45 # FlightGear packaging (to build a source tarball)
  46 include( ConfigureCPack )
  47
  48 # FlightGear base package path
  49 if (FG_DATA_DIR)
  50     message(STATUS "Using explicit data directory for base package: ${FG_DATA_DIR}")
  51 else()
  52     set(FG_DATA_DIR "${CMAKE_INSTALL_PREFIX}/lib/FlightGear" CACHE PATH "Default location where data files are located")
  53     message(STATUS "Using default data directory for base package:  ${FG_DATA_DIR}")
  54 endif()
  55
  56 # Change the default build type to something fast
  57 if(NOT CMAKE_BUILD_TYPE)
  58     set(CMAKE_BUILD_TYPE Release CACHE STRING
  59         "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  60         FORCE)
  61 endif(NOT CMAKE_BUILD_TYPE)
  62
  63 if(NOT "$ENV{BUILD_ID}" STREQUAL "")
  64     set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  65     set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  66     message(STATUS "running under Hudson/Jenkins, build-number is ${HUDSON_BUILD_NUMBER}")
  67 else()
  68     set(HUDSON_BUILD_NUMBER 0)
  69     set(HUDSON_BUILD_ID "none")
  70 endif()
  71
  72 #####################################################################################
  73 # Configure library search paths
  74 #####################################################################################
  75
  76
  77 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  78     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  79     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  80     # add paths manually
  81     # see http://www.cmake.org/Bug/view.php?id=12049 and
  82     # http://www.cmake.org/Bug/view.php?id=12037
  83     list(APPEND ADDITIONAL_LIBRARY_PATHS
  84          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  85          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  86          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
  87     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
  88 endif()
  89
  90 #####################################################################################
  91
  92 IF(APPLE)
  93     set(EVENT_INPUT_DEFAULT 1)
  94
  95     find_library(CORESERVICES_LIBRARY CoreServices)
  96     find_library(COCOA_LIBRARY Cocoa)
  97     list(APPEND PLATFORM_LIBS ${COCOA_LIBRARY} ${CORESERVICES_LIBRARY})
  98
  99 elseif(${CMAKE_SYSTEM_NAME} MATCHES "Linux" OR
 100         ${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD")
 101     set(USE_DBUS_DEFAULT 1)
 102
 103     find_package(UDev)
 104     if(UDEV_FOUND)
 105         set(EVENT_INPUT_DEFAULT 1)
 106     endif(UDEV_FOUND)
 107
 108     find_package(Speex)
 109     find_package(Speexdsp)
 110     if(SPEEX_FOUND AND SPEEXDSP_FOUND)
 111         set(SYSTEM_SPEEX_DEFAULT 1)
 112     endif(SPEEX_FOUND AND SPEEXDSP_FOUND)
 113
 114     find_package(Gsm)
 115     if(GSM_FOUND)
 116         set(SYSTEM_GSM_DEFAULT 1)
 117     endif(GSM_FOUND)
 118
 119     find_package(Flite)
 120     if(FLITE_FOUND)
 121         set(SYSTEM_FLITE_DEFAULT 1)
 122     endif()
 123
 124     find_package(HtsEngine)
 125     if(HTS_ENGINE_FOUND)
 126         set(SYSTEM_HTS_ENGINE_DEFAULT 1)
 127     endif()
 128 endif()
 129
 130 find_package(Git)
 131 if (GIT_FOUND)
 132     execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
 133         OUTPUT_VARIABLE REVISION
 134         OUTPUT_STRIP_TRAILING_WHITESPACE)
 135     message(STATUS "Git revision is ${REVISION}")
 136 else()
 137     set(REVISION "none")
 138 endif()
 139
 140 # FlightGear build options
 141 option(SIMGEAR_SHARED    "Set to ON when SimGear was built as a shared library" OFF)
 142 option(LOGGING           "Set to ON to build FlightGear with logging support (default)" ON)
 143 option(JSBSIM_TERRAIN    "Set to ON to build FlightGear with JSBSim terrain handling code" ON)
 144 option(SP_FDMS           "Set to ON to build FlightGear with special-purpose FDMs" OFF)
 145 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" OFF)
 146 option(ENABLE_LARCSIM    "Set to ON to build FlightGear with LaRCsim FDM" OFF)
 147 option(ENABLE_YASIM      "Set to ON to build FlightGear with YASIM FDM (default)" ON)
 148 option(ENABLE_JSBSIM     "Set to ON to build FlightGear with JSBSim FDM (default)" ON)
 149 option(EVENT_INPUT       "Set to ON to build FlightGear with event-based Input support" ${EVENT_INPUT_DEFAULT})
 150 option(ENABLE_RTI        "Set to ON to build FlightGear with RTI support" OFF)
 151 option(ENABLE_PROFILE    "Set to ON to build FlightGear with gperftools profiling support" OFF)
 152 option(SYSTEM_SQLITE     "Set to ON to build FlightGear with the system's SQLite3 library" OFF)
 153 option(ENABLE_IAX        "Set to ON to build FlightGear with IAXClient/fgcom built-in (default)" ON)
 154 option(USE_DBUS          "Set to ON to build FlightGear with DBus screensaver interaction (default on Linux)" ${USE_DBUS_DEFAULT})
 155 option(SYSTEM_SPEEX      "Set to ON to build IAXClient with the system's speex and speexdsp library" ${SYSTEM_SPEEX_DEFAULT})
 156 option(SYSTEM_GSM        "Set to ON to build IAXClient with the system's GSM library" ${SYSTEM_GSM_DEFAULT})
 157 option(SYSTEM_FLITE      "Set to ON to build Flightgear with the system's Flite library" ${SYSTEM_FLITE_DEFAULT})
 158 option(SYSTEM_HTS_ENGINE "Set to ON to build Flightgear with the system's HTS Engine library" ${SYSTEM_HTS_ENGINE_DEFAULT})
 159
 160 # additional utilities
 161 option(ENABLE_FGADMIN    "Set to ON to build the FGADMIN application (default)" ON)
 162 option(ENABLE_FGELEV     "Set to ON to build the fgelev application (default)" ON)
 163 option(WITH_FGPANEL      "Set to ON to build the fgpanel application (default)" ON)
 164 option(ENABLE_FGVIEWER   "Set to ON to build the fgviewer application (default)" ON)
 165 option(ENABLE_GPSSMOOTH  "Set to ON to build the GPSsmooth application (default)" ON)
 166 option(ENABLE_TERRASYNC  "Set to ON to build the terrasync application (default)" ON)
 167 option(ENABLE_FGJS       "Set to ON to build the fgjs application (default)" ON)
 168 option(ENABLE_JS_DEMO    "Set to ON to build the js_demo application (default)" ON)
 169 option(ENABLE_METAR      "Set to ON to build the metar application (default)" ON)
 170 option(ENABLE_TESTS      "Set to ON to build test applications (default)" ON)
 171 option(ENABLE_FGCOM      "Set to ON to build the FGCom application (default)" ON)
 172 option(ENABLE_FLITE      "Set to ON to build the Flite text-to-speech module" ON)
 173
 174 if(LOGGING)
 175     # nothing
 176 else()
 177     set(FG_NDEBUG 1)
 178 endif()
 179
 180 if(JSBSIM_TERRAIN)
 181    set(JSBSIM_USE_GROUNDREACTIONS 1)
 182 endif()
 183
 184 if(SP_FDMS)
 185     set(ENABLE_SP_FDM 1)
 186 endif()
 187
 188 if(ENABLE_FGCOM)
 189   set(ENABLE_IAX 1)
 190   include_directories(${PROJECT_SOURCE_DIR}/3rdparty/iaxclient/lib ) # for iaxclient.h
 191 endif()
 192
 193 # Setup MSVC 3rd party directories
 194 include( ConfigureMsvc3rdParty )
 195
 196 if(EVENT_INPUT)
 197     if(APPLE)
 198     elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 199         if(NOT UDEV_FOUND)
 200             message(WARNING "UDev not found, event input is disabled!")
 201             set(EVENT_INPUT 0)
 202         else()
 203             add_definitions(-DWITH_EVENTINPUT)
 204             set(EVENT_INPUT_LIBRARIES ${UDEV_LIBRARIES})
 205             message(STATUS "event-based input enabled. Using ${UDEV_LIBRARIES}")
 206         endif()
 207     else()
 208         message(WARNING "event-based input is not supported on this platform yet")
 209     endif()
 210
 211     # Keep PLIB INPUT enabled as long as EventInput does not replace current joystick configurations.
 212     set(ENABLE_PLIB_JOYSTICK 1)
 213 else(EVENT_INPUT)
 214     set(ENABLE_PLIB_JOYSTICK 1)
 215 endif(EVENT_INPUT)
 216
 217 # check required dependencies
 218 find_package(Boost   REQUIRED)
 219 find_package(ZLIB    REQUIRED)
 220 find_package(Threads REQUIRED)
 221 find_package(OpenGL  REQUIRED)
 222 find_package(OpenAL  REQUIRED)
 223 find_package(OpenSceneGraph 3.2.0 REQUIRED
 224   osgText
 225   osgSim
 226   osgDB
 227   osgParticle
 228   osgFX
 229   osgUtil
 230   osgViewer
 231   osgGA
 232 )
 233
 234 if (MSVC)
 235         find_package(CrashRpt)
 236         if (CRASHRPT_FOUND)
 237                 set(HAVE_CRASHRPT 1)
 238                 message(STATUS "Using CrashRpt")
 239         include_directories( ${CRASHRPT_INCLUDE_DIR})
 240         endif()
 241 endif()
 242
 243 ##############################################################################
 244 ## Sqlite3 setup
 245
 246 if (SYSTEM_SQLITE)
 247     find_package(SQLite3 REQUIRED)
 248
 249     message(STATUS "Using system SQLite3 library")
 250 else()
 251     set(SQLITE3_INCLUDED_DIR "${CMAKE_SOURCE_DIR}/3rdparty/sqlite3")
 252     # this target is defined in src/Navaids/CMakeLists.txt
 253     list(APPEND SQLITE3_LIBRARY fgsqlite3)
 254 endif (SYSTEM_SQLITE)
 255
 256 # Sqlite always depends on the threading lib
 257 list(APPEND SQLITE3_LIBRARY ${CMAKE_THREAD_LIBS_INIT})
 258
 259 ##############################################################################
 260 ## DBus setup
 261
 262 if (USE_DBUS)
 263     include(FindPkgConfig)
 264     if (PKG_CONFIG_FOUND)
 265         pkg_check_modules(DBUS dbus-1)
 266     endif (PKG_CONFIG_FOUND) #if we don't have pkg-config, assume we don't have libdbus-1-dev either http://packages.debian.org/sid/libdbus-1-dev
 267     if (DBUS_FOUND)
 268         set(HAVE_DBUS 1)
 269         message(STATUS "Using DBus")
 270         include_directories( ${DBUS_INCLUDE_DIRS})
 271     else()
 272         message(STATUS "DBus not found, screensaver control disabled")
 273     endif (DBUS_FOUND)
 274 else()
 275 endif (USE_DBUS)
 276
 277 # Sqlite always depends on the threading lib
 278 list(APPEND SQLITE3_LIBRARY ${CMAKE_THREAD_LIBS_INIT})
 279
 280 ##############################################################################
 281
 282 find_package(PLIB REQUIRED puaux pu js fnt)
 283
 284 # FlightGear and SimGear versions need to match
 285 find_package(SimGear ${FLIGHTGEAR_VERSION} REQUIRED)
 286
 287 ##############################################################################
 288
 289 check_include_file(unistd.h   HAVE_UNISTD_H)
 290 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 291 check_include_file(windows.h  HAVE_WINDOWS_H)
 292
 293 if(ENABLE_PROFILE)
 294     find_package(GooglePerfTools REQUIRED)
 295     set(FG_HAVE_GPERFTOOLS 1)
 296     message(STATUS "Built-in profiler using gperftools available")
 297 endif()
 298
 299 if(ENABLE_RTI)
 300     message(STATUS "RTI: ENABLED")
 301     find_package(RTI)
 302     if(RTI_FOUND)
 303         set(FG_HAVE_HLA 1)
 304     endif(RTI_FOUND)
 305 else()
 306     message(STATUS "RTI: DISABLED")
 307 endif(ENABLE_RTI)
 308
 309 if(CMAKE_COMPILER_IS_GNUCXX)
 310     set(WARNING_FLAGS_CXX "-Wall")
 311     set(WARNING_FLAGS_C   "-Wall")
 312 endif(CMAKE_COMPILER_IS_GNUCXX)
 313
 314 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 315    set (WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual")
 316    set (WARNING_FLAGS_C   "-Wall")
 317 endif()
 318
 319 if(WIN32)
 320
 321     if(MSVC)
 322         # turn off various warnings
 323         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 324         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 325         # endforeach(warning)
 326
 327         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS -Dstrdup=_strdup")
 328         if (${MSVC_VERSION} GREATER 1599)
 329             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 330         endif (${MSVC_VERSION} GREATER 1599)
 331     endif(MSVC)
 332
 333     set(NOMINMAX 1)
 334 endif(WIN32)
 335
 336 set (BOOST_CXX_FLAGS "-DBOOST_MULTI_INDEX_DISABLE_SERIALIZATION -DBOOST_BIMAP_DISABLE_SERIALIZATION")
 337
 338 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS} -D_REENTRANT")
 339 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} -D_REENTRANT ${BOOST_CXX_FLAGS}")
 340 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 341
 342 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 343     ${Boost_INCLUDE_DIRS}
 344     ${ZLIB_INCLUDE_DIR}
 345     ${OPENGL_INCLUDE_DIR}
 346     ${OPENAL_INCLUDE_DIR}
 347     ${SIMGEAR_INCLUDE_DIRS}
 348     ${PLIB_INCLUDE_DIR}
 349     ${SQLITE3_INCLUDED_DIR} )
 350
 351 include_directories(${PROJECT_SOURCE_DIR})
 352 include_directories(${PROJECT_SOURCE_DIR}/src)
 353 # following is needed, because config.h is include 'bare', whereas
 354 # version.h is included as <Include/version.h> - this should be cleaned up
 355 include_directories(${PROJECT_BINARY_DIR}/src)
 356 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 357
 358 if (ENABLE_FLITE)
 359     include_directories(${PROJECT_SOURCE_DIR}/3rdparty/hts_engine_API/include )
 360     include_directories(${PROJECT_SOURCE_DIR}/3rdparty/flite_hts_engine/include )
 361 endif()
 362
 363 add_definitions(-DHAVE_CONFIG_H)
 364
 365 check_function_exists(mkfifo HAVE_MKFIFO)
 366
 367 # configure a header file to pass some of the CMake settings
 368 # to the source code
 369 configure_file (
 370     "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 371     "${PROJECT_BINARY_DIR}/src/Include/config.h"
 372 )
 373
 374 #and the same for the version header
 375 configure_file (
 376     "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 377     "${PROJECT_BINARY_DIR}/src/Include/version.h"
 378 )
 379
 380 add_subdirectory(3rdparty)
 381 add_subdirectory(utils)
 382 add_subdirectory(src)
 383 add_subdirectory(man)
 384
 385 #-----------------------------------------------------------------------------
 386 ### uninstall target
 387 #-----------------------------------------------------------------------------
 388 CONFIGURE_FILE(
 389     "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 390     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 391     IMMEDIATE @ONLY)
 392 ADD_CUSTOM_TARGET(uninstall
 393     "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")