CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8.11)
   2
   3 if(COMMAND cmake_policy)
   4    if(POLICY CMP0054)
   5        cmake_policy(SET CMP0054 NEW)
   6    endif()
   7    if(POLICY CMP0042)
   8        cmake_policy(SET CMP0042 NEW)
   9    endif()
  10 endif()
  11
  12 include (CheckFunctionExists)
  13 include (CheckIncludeFile)
  14 include (CheckLibraryExists)
  15 include (CheckCXXSourceCompiles)
  16 include (CheckCXXCompilerFlag)
  17
  18 # using 10.7 because boost requires libc++ and 10.6 doesn't include it
  19 set(CMAKE_OSX_DEPLOYMENT_TARGET 10.7)
  20
  21 # only relevant for building shared libs but let's set it regardless
  22 set(CMAKE_OSX_RPATH 1)
  23
  24 project(SimGear)
  25
  26 # read 'version' file into a variable (stripping any newlines or spaces)
  27 file(READ version versionFile)
  28 string(STRIP ${versionFile} SIMGEAR_VERSION)
  29
  30 set(FIND_LIBRARY_USE_LIB64_PATHS ON)
  31
  32 # use simgear version also as the SO version (if building SOs)
  33 SET(SIMGEAR_SOVERSION ${SIMGEAR_VERSION})
  34
  35 # Warning when build is not an out-of-source build.
  36 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  37 if(InSourceBuild)
  38     message(WARNING  "Avoid building inside the source tree!")
  39     message(WARNING  "Create a separate build directory instead (i.e. 'sgbuild') and call CMake from there: ")
  40     message(WARNING  "  mkdir ../sgbuild && cd ../sgbuild && cmake ${CMAKE_SOURCE_DIR}")
  41 endif(InSourceBuild)
  42
  43 #packaging
  44 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  45 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  46 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Simulation support libraries for FlightGear and related projects")
  47 SET(CPACK_PACKAGE_VENDOR "The FlightGear project")
  48 SET(CPACK_GENERATOR "TBZ2")
  49 SET(CPACK_INSTALL_CMAKE_PROJECTS  ${CMAKE_CURRENT_BINARY_DIR};SimGear;ALL;/)
  50
  51
  52 # split version string into components, note CMAKE_MATCH_0 is the entire regexp match
  53 string(REGEX MATCH "([0-9]+)\\.([0-9]+)\\.([0-9]+)" CPACK_PACKAGE_VERSION ${SIMGEAR_VERSION} )
  54 set(CPACK_PACKAGE_VERSION_MAJOR ${CMAKE_MATCH_1})
  55 set(CPACK_PACKAGE_VERSION_MINOR ${CMAKE_MATCH_2})
  56 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_3})
  57
  58 message(STATUS "version is ${CPACK_PACKAGE_VERSION_MAJOR} dot ${CPACK_PACKAGE_VERSION_MINOR} dot ${CPACK_PACKAGE_VERSION_PATCH}")
  59
  60 set(CPACK_SOURCE_GENERATOR TBZ2)
  61 set(CPACK_SOURCE_PACKAGE_FILE_NAME "simgear-${SIMGEAR_VERSION}" CACHE INTERNAL "tarball basename")
  62 set(CPACK_SOURCE_IGNORE_FILES
  63   "^${PROJECT_SOURCE_DIR}/.git;\\\\.gitignore;Makefile.am;~$;${CPACK_SOURCE_IGNORE_FILES}")
  64
  65 message(STATUS "ignoring: ${CPACK_SOURCE_IGNORE_FILES}")
  66
  67 include (CPack)
  68
  69 # We have some custom .cmake scripts not in the official distribution.
  70 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  71
  72 # Change the default build type to something fast
  73 if(NOT CMAKE_BUILD_TYPE)
  74   set(CMAKE_BUILD_TYPE Release CACHE STRING
  75       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  76       FORCE)
  77 endif(NOT CMAKE_BUILD_TYPE)
  78
  79 # Determine name of library installation directory, i.e. "lib" vs "lib64", which
  80 # differs between all Debian-based vs all other Linux distros.
  81 # See cmake bug #11964, http://cmake.org/gitweb?p=cmake.git;a=commit;h=126c993d
  82 include(GNUInstallDirs)
  83 message(STATUS "Library installation directory: ${CMAKE_INSTALL_LIBDIR}")
  84
  85 #####################################################################################
  86 # Configure library search paths
  87 #####################################################################################
  88
  89 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  90     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  91     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  92     # add paths manually
  93     # see http://www.cmake.org/Bug/view.php?id=12049 and
  94     # http://www.cmake.org/Bug/view.php?id=12037
  95     list(APPEND ADDITIONAL_LIBRARY_PATHS
  96          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  97          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  98          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
  99     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
 100 endif()
 101
 102 #####################################################################################
 103
 104 if (NOT MSVC)
 105 option(SIMGEAR_SHARED   "Set to ON to build SimGear as a shared library/framework" OFF)
 106 option(SYSTEM_EXPAT     "Set to ON to build SimGear using the system libExpat" OFF)
 107 else()
 108 # Building SimGear DLLs is currently not supported for MSVC.
 109 set(SIMGEAR_SHARED OFF)
 110 # Using a system expat is currently not supported for MSVC - it would require shared simgear (DLL).
 111 set(SYSTEM_EXPAT OFF)
 112 endif()
 113
 114 option(SIMGEAR_HEADLESS "Set to ON to build SimGear without GUI/graphics support" OFF)
 115 option(ENABLE_RTI       "Set to ON to build SimGear with RTI support" OFF)
 116 option(ENABLE_TESTS     "Set to OFF to disable building SimGear's test applications" ON)
 117 option(ENABLE_SOUND     "Set to OFF to disable building SimGear's sound support" ON)
 118 option(ENABLE_PKGUTIL   "Set to ON to build the sg_pkgutil application (default)" ON)
 119 option(ENABLE_CURL      "Set to ON to use libCurl as the HTTP client backend" OFF)
 120
 121 if (MSVC)
 122   GET_FILENAME_COMPONENT(PARENT_DIR ${PROJECT_BINARY_DIR} PATH)
 123   if (CMAKE_CL_64)
 124     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty.x64")
 125   else (CMAKE_CL_64)
 126     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty")
 127   endif (CMAKE_CL_64)
 128   if (EXISTS ${TEST_3RDPARTY_DIR})
 129     set(MSVC_3RDPARTY_ROOT ${PARENT_DIR} CACHE PATH "Location where the third-party dependencies are extracted")
 130   else (EXISTS ${TEST_3RDPARTY_DIR})
 131     set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 132   endif (EXISTS ${TEST_3RDPARTY_DIR})
 133 else (MSVC)
 134   set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 135 endif (MSVC)
 136
 137 if (MSVC AND MSVC_3RDPARTY_ROOT)
 138   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_ROOT}")
 139   set( OSG_MSVC "msvc" )
 140   if (${MSVC_VERSION} EQUAL 1700)
 141       set( OSG_MSVC ${OSG_MSVC}110 )
 142   elseif (${MSVC_VERSION} EQUAL 1600)
 143       set( OSG_MSVC ${OSG_MSVC}100 )
 144   else (${MSVC_VERSION} EQUAL 1700)
 145       set( OSG_MSVC ${OSG_MSVC}90 )
 146   endif (${MSVC_VERSION} EQUAL 1700)
 147   if (CMAKE_CL_64)
 148       set( OSG_MSVC ${OSG_MSVC}-64 )
 149       set( MSVC_3RDPARTY_DIR 3rdParty.x64 )
 150   else (CMAKE_CL_64)
 151       set( MSVC_3RDPARTY_DIR 3rdParty )
 152   endif (CMAKE_CL_64)
 153
 154   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/lib )
 155   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/include)
 156   find_path(BOOST_ROOT boost/version.hpp
 157                         ${MSVC_3RDPARTY_ROOT}/boost
 158                         ${MSVC_3RDPARTY_ROOT}/boost_1_52_0
 159                         ${MSVC_3RDPARTY_ROOT}/boost_1_51_0
 160                         ${MSVC_3RDPARTY_ROOT}/boost_1_50_0
 161                         ${MSVC_3RDPARTY_ROOT}/boost_1_49_0
 162                         ${MSVC_3RDPARTY_ROOT}/boost_1_48_0
 163                         ${MSVC_3RDPARTY_ROOT}/boost_1_47_0
 164                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_1
 165                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_0
 166                         ${MSVC_3RDPARTY_ROOT}/boost_1_45_0
 167                         ${MSVC_3RDPARTY_ROOT}/boost_1_44_0
 168                         )
 169   # set (BOOST_ROOT ${MSVC_3RDPARTY_ROOT}/boost_1_44_0)
 170   message(STATUS "BOOST_ROOT is ${BOOST_ROOT}")
 171   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 172   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib)
 173 endif (MSVC AND MSVC_3RDPARTY_ROOT)
 174
 175 if(APPLE)
 176   find_library(COCOA_LIBRARY Cocoa)
 177 endif()
 178
 179 if(${CMAKE_SYSTEM_NAME} MATCHES "Linux" OR
 180         ${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD")
 181     find_package(Threads REQUIRED)
 182 endif()
 183
 184 # Somehow this only works if included before searching for Boost...
 185 include(BoostTestTargets)
 186
 187 find_package(Boost REQUIRED)
 188 set (BOOST_CXX_FLAGS "-DBOOST_BIMAP_DISABLE_SERIALIZATION")
 189
 190 if(SIMGEAR_HEADLESS)
 191     message(STATUS "SimGear mode: HEADLESS")
 192     set(ENABLE_SOUND 0)
 193 else()
 194     message(STATUS "SimGear mode: NORMAL")
 195     find_package(OpenGL REQUIRED)
 196
 197     if (ENABLE_SOUND)
 198         find_package(OpenAL REQUIRED)
 199         message(STATUS "Sound support: ENABLED")
 200     endif(ENABLE_SOUND)
 201
 202     find_package(OpenSceneGraph 3.2.0 REQUIRED osgText osgSim osgDB osgParticle osgGA osgViewer osgUtil)
 203 endif(SIMGEAR_HEADLESS)
 204
 205 find_package(ZLIB REQUIRED)
 206
 207 if (ENABLE_CURL)
 208   find_package(CURL REQUIRED)
 209   message(STATUS "Curl HTTP client: ENABLED")
 210 endif()
 211
 212 if (SYSTEM_EXPAT)
 213     message(STATUS "Requested to use system Expat library, forcing SIMGEAR_SHARED to true")
 214     set(SIMGEAR_SHARED ON)
 215     find_package(EXPAT REQUIRED)
 216
 217 else()
 218     message(STATUS "Using built-in expat code")
 219     # XML_STATIC is important to avoid sg_expat_external.h
 220     # declaring symbols as declspec(import)
 221     add_definitions(-DHAVE_EXPAT_CONFIG_H -DXML_STATIC)
 222     set(EXPAT_INCLUDE_DIRS
 223             ${PROJECT_SOURCE_DIR}/3rdparty/expat
 224             ${PROJECT_BINARY_DIR}/3rdparty/expat)
 225 endif(SYSTEM_EXPAT)
 226
 227 include_directories(${EXPAT_INCLUDE_DIRS})
 228
 229 check_include_file(inttypes.h HAVE_INTTYPES_H)
 230 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 231 check_include_file(sys/timeb.h HAVE_SYS_TIMEB_H)
 232 check_include_file(unistd.h HAVE_UNISTD_H)
 233 check_include_file(windows.h HAVE_WINDOWS_H)
 234
 235 if(HAVE_INTTYPES_H)
 236   # ShivaVG needs inttypes.h
 237   add_definitions(-DHAVE_INTTYPES_H)
 238 endif()
 239
 240 if(ENABLE_RTI)
 241     # See if we have any rti library variant installed
 242     message(STATUS "RTI: ENABLED")
 243     find_package(RTI)
 244 else()
 245     message(STATUS "RTI: DISABLED")
 246 endif(ENABLE_RTI)
 247
 248 check_function_exists(gettimeofday HAVE_GETTIMEOFDAY)
 249 check_function_exists(ftime HAVE_FTIME)
 250 check_function_exists(timegm HAVE_TIMEGM)
 251 check_function_exists(rint HAVE_RINT)
 252 check_function_exists(mkdtemp HAVE_MKDTEMP)
 253 check_function_exists(bcopy HAVE_BCOPY)
 254 check_function_exists(mmap HAVE_MMAP)
 255
 256 if(HAVE_UNISTD_H)
 257     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 258     check_cxx_source_compiles(
 259        "#include <unistd.h>
 260         #if !defined(_POSIX_TIMERS) || (0 >= _POSIX_TIMERS)
 261             #error clock_gettime is not supported
 262         #endif
 263
 264         int main() { return 0; }
 265         "
 266         HAVE_CLOCK_GETTIME)
 267 endif(HAVE_UNISTD_H)
 268
 269 set(RT_LIBRARY "")
 270 if(HAVE_CLOCK_GETTIME)
 271     check_library_exists(rt clock_gettime "" HAVE_RT)
 272     if(HAVE_RT)
 273         set(RT_LIBRARY rt)
 274     endif(HAVE_RT)
 275 endif(HAVE_CLOCK_GETTIME)
 276
 277 set(DL_LIBRARY "")
 278 check_cxx_source_compiles(
 279     "#include <dlfcn.h>
 280     int main(void) {
 281         return 0;
 282     }
 283     "
 284     HAVE_DLFCN_H)
 285
 286 if(HAVE_DLFCN_H)
 287     check_library_exists(dl dlerror "" HAVE_DL)
 288     if(HAVE_DL)
 289         set(DL_LIBRARY "dl")
 290     endif()
 291 endif()
 292
 293 SET(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "add a postfix, usually 'd' on windows")
 294 SET(CMAKE_RELEASE_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 295 SET(CMAKE_RELWITHDEBINFO_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 296 SET(CMAKE_MINSIZEREL_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 297
 298 # isnan might not be real symbol, so can't check using function_exists
 299 check_cxx_source_compiles(
 300     "#include <cmath>
 301     int main() { return isnan(0.0);} "
 302     HAVE_ISNAN)
 303
 304 check_cxx_source_compiles(
 305     "#include <cmath>
 306     int main() { return std::isnan(0.0);} "
 307     HAVE_STD_ISNAN)
 308
 309 if(CMAKE_COMPILER_IS_GNUCXX)
 310     set(WARNING_FLAGS_CXX "-Wall")
 311     set(WARNING_FLAGS_C   "-Wall")
 312
 313     # certain GCC versions don't provide the atomic builds, and hence
 314     # require is to provide them in SGAtomic.cxx
 315     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 316     check_cxx_source_compiles(
 317        "int main() { unsigned mValue; return __sync_add_and_fetch(&mValue, 1); }"
 318         GCC_ATOMIC_BUILTINS_FOUND)
 319 endif(CMAKE_COMPILER_IS_GNUCXX)
 320
 321 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 322     # Boost redeclares class members
 323     set(WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual -Wno-redeclared-class-member")
 324     set(WARNING_FLAGS_C   "-Wall")
 325     set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LIBRARY "libc++")
 326     set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LANGUAGE_STANDARD "c++11")
 327     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -stdlib=libc++")
 328 endif()
 329
 330 if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 331 # boost goes haywire wrt static asserts
 332     check_cxx_compiler_flag(-Wno-unused-local-typedefs HAS_NOWARN_UNUSED_TYPEDEFS)
 333     if(HAS_NOWARN_UNUSED_TYPEDEFS)
 334         set(WARNING_FLAGS_CXX " ${WARNING_FLAGS_CXX} -Wno-unused-local-typedefs")
 335     endif()
 336 endif()
 337
 338 if(WIN32)
 339
 340     if(MINGW)
 341         add_definitions(-D_WIN32_WINNT=0x501)
 342     endif()
 343
 344     if(MSVC)
 345         # turn off various warnings
 346         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 347         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 348         # endforeach(warning)
 349
 350         set(MSVC_FLAGS "-DWIN32 -DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS /wd4996 /wd4250 -Dstrdup=_strdup")
 351         if (${MSVC_VERSION} GREATER 1599)
 352             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 353         endif (${MSVC_VERSION} GREATER 1599)
 354     endif(MSVC)
 355
 356     # assumed on Windows
 357     set(HAVE_GETLOCALTIME 1)
 358
 359     set( WINSOCK_LIBRARY "ws2_32.lib" )
 360     set( RT_LIBRARY "winmm" )
 361 endif(WIN32)
 362
 363 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS}")
 364 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} ${BOOST_CXX_FLAGS}")
 365 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 366
 367 # use BEFORE to ensure local directories are used first,
 368 # ahead of system-installed libs
 369 include_directories(BEFORE ${PROJECT_SOURCE_DIR})
 370 include_directories(BEFORE ${PROJECT_SOURCE_DIR}/simgear/canvas/ShivaVG/include)
 371 include_directories(BEFORE ${PROJECT_BINARY_DIR}/simgear)
 372
 373 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 374     ${Boost_INCLUDE_DIRS}
 375     ${ZLIB_INCLUDE_DIR}
 376     ${OPENAL_INCLUDE_DIR}
 377     ${CURL_INCLUDE_DIRS}
 378 )
 379
 380 add_definitions(-DHAVE_CONFIG_H)
 381
 382 # configure a header file to pass some of the CMake settings
 383 # to the source code
 384 configure_file (
 385   "${PROJECT_SOURCE_DIR}/simgear/simgear_config_cmake.h.in"
 386   "${PROJECT_BINARY_DIR}/simgear/simgear_config.h"
 387   )
 388
 389 if(ENABLE_TESTS)
 390     # enable CTest / make test target
 391     message(STATUS "Tests: ENABLED")
 392
 393     include (Dart)
 394     enable_testing()
 395 else()
 396     message(STATUS "Tests: DISABLED")
 397 endif(ENABLE_TESTS)
 398
 399 # always set TEST_LIBS as it is also used by other tools/applications
 400 set(TEST_LIBS_INTERNAL_CORE
 401     ${CMAKE_THREAD_LIBS_INIT}
 402     ${ZLIB_LIBRARY}
 403     ${WINSOCK_LIBRARY}
 404     ${RT_LIBRARY}
 405     ${DL_LIBRARY}
 406     ${COCOA_LIBRARY}
 407     ${CURL_LIBRARIES})
 408 set(TEST_LIBS SimGearCore ${TEST_LIBS_INTERNAL_CORE})
 409
 410 if(NOT SIMGEAR_HEADLESS)
 411     set(TEST_LIBS SimGearScene ${OPENGL_LIBRARIES} ${TEST_LIBS})
 412 endif()
 413
 414 install (FILES ${PROJECT_BINARY_DIR}/simgear/simgear_config.h  DESTINATION include/simgear/)
 415
 416 include_directories(3rdparty/utf8/source)
 417
 418 add_subdirectory(3rdparty)
 419 add_subdirectory(simgear)
 420
 421 #-----------------------------------------------------------------------------
 422 ### uninstall target
 423 #-----------------------------------------------------------------------------
 424 CONFIGURE_FILE(
 425   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 426   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 427   IMMEDIATE @ONLY)
 428 ADD_CUSTOM_TARGET(uninstall
 429   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")