CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7 include (CPack)
   8
   9 project(FlightGear)
  10
  11 set(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "add a postfix, usually d on windows")
  12 set(CMAKE_RELEASE_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
  13 set(CMAKE_RELWITHDEBINFO_POSTFIX "rd" CACHE STRING "add a postfix, usually empty on windows")
  14 set(CMAKE_MINSIZEREL_POSTFIX "s" CACHE STRING "add a postfix, usually empty on windows")
  15
  16 # read 'version' file into a variable (stripping any newlines or spaces)
  17 file(READ version versionFile)
  18 string(STRIP ${versionFile} FLIGHTGEAR_VERSION)
  19
  20 #packaging
  21 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  22 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  23
  24 # We have some custom .cmake scripts not in the official distribution.
  25 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  26
  27 # autoconf compatibility
  28 set(PKGLIBDIR "foo")
  29
  30 if($ENV{BUILD_ID})
  31         set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  32         set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  33         message(STATUS "running under Hudson, build-number is ${HUDSON_BUILD_NUMBER}")
  34 else()
  35         set(HUDSON_BUILD_NUMBER 0)
  36         set(HUDSON_BUILD_ID "none")
  37 endif()
  38
  39 find_package(Git)
  40 if (GIT_FOUND)
  41         execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
  42                 OUTPUT_VARIABLE REVISION
  43                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  44         message(STATUS "Git revision is ${REVISION}")
  45 else()
  46         set(REVISION "none")
  47 endif()
  48
  49 option(LOGGING "Set to OFF to build FlightGear without logging" ON)
  50
  51 option(SP_FDMS "Set to ON to build FlightGear with special-purpose FDMs" OFF)
  52 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" ON)
  53 option(ENABLE_LARCSIM "Set to ON to build FlightGear with LaRCsim FDM" ON)
  54 option(ENABLE_YASIM "Set to ON to build FlightGear with YASIM FDM" ON)
  55 option(ENABLE_JSBSIM "Set to ON to build FlightGear with JSBSim FDM" ON)
  56 option(ENABLE_FGADMIN "Set to ON to build FlightGear with FGADMIN" ON)
  57 option(EVENT_INPUT "Set to ON to build FlightGear with event-based Input support" OFF)
  58 option(ENABLE_LIBSVN "Set to ON to build terrasync with libsvnclient support" OFF)
  59
  60 set(MSVC_3RDPARTY_DIR NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
  61
  62 if(LOGGING)
  63         # nothing
  64 else()
  65         set(FG_NDEBUG 1)
  66 endif()
  67
  68 if(${SP_FDMS})
  69         set(ENABLE_SP_FDM 1)
  70 endif()
  71
  72 if(EVENT_INPUT)
  73         message(STATUS "checking event-based Input")
  74         IF(APPLE)
  75
  76         elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
  77
  78         else()
  79                 message(WARNING "event input is not supported on this platform yet")
  80         endif()
  81 else(EVENT_INPUT)
  82         set(ENABLE_PLIB_JOYSTICK 1)
  83
  84     message(STATUS "adding runtime JS dependencies")
  85     if(APPLE)
  86     # resolve frameworks to full paths
  87         find_library(IOKIT_LIBRARY IOKit)
  88         find_library(CF_LIBRARY CoreFoundation)
  89         set(JS_LIBS ${IOKIT_LIBRARY} ${CF_LIBRARY})
  90     elseif(WIN32)
  91         find_library(WINMM_LIBRARY winmm)
  92         set(JS_LIBS ${WINMM_LIBRARY})
  93     elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
  94         # anything needed here?
  95     elseif(CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
  96         find_library(USBHID_LIBRARY usbhid)
  97         # check_function_exists(hidinit)
  98         set(JS_LIBS ${USBHID_LIBRARY})
  99     else()
 100         message(WARNING "Unsupported platform for JS libs")
 101     endif()
 102 endif(EVENT_INPUT)
 103
 104 if (MSVC_3RDPARTY_DIR)
 105   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_DIR}")
 106   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_DIR}/3rdParty/lib ${MSVC_3RDPARTY_DIR}/install/msvc90/OpenScenegraph/lib ${MSVC_3RDPARTY_DIR}/install/msvc90/SimGear/lib )
 107   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_DIR}/3rdParty/include ${MSVC_3RDPARTY_DIR}/install/msvc90/OpenScenegraph/include ${MSVC_3RDPARTY_DIR}/install/msvc90/SimGear/include)
 108   set (BOOST_ROOT ${MSVC_3RDPARTY_DIR}/boost_1_44_0)
 109   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_DIR}/3rdParty/include)
 110   set (ALUT_INCLUDE_DIR ${MSVC_3RDPARTY_DIR}/3rdParty/include)
 111   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_DIR}/3rdParty/lib)
 112 endif (MSVC_3RDPARTY_DIR)
 113
 114
 115 # check required dependencies
 116 find_package(Boost REQUIRED)
 117 find_package(ZLIB REQUIRED)
 118 find_package(Threads REQUIRED)
 119 find_package(OpenGL REQUIRED)
 120 find_package(OpenAL REQUIRED)
 121 find_package(ALUT REQUIRED)
 122 find_package(OpenSceneGraph 2.8.1 REQUIRED osgText osgSim osgDB osgParticle osgFX osgUtil osgViewer osgGA)
 123
 124 if(ENABLE_FGADMIN)
 125   find_package(FLTK)
 126 endif(ENABLE_FGADMIN)
 127
 128 if(ENABLE_LIBSVN)
 129         find_package(SvnClient)
 130
 131         if(LIBSVN_FOUND)
 132                 message(STATUS "libsvn found, enabling in terrasync")
 133                 set(HAVE_SVN_CLIENT_H 1)
 134                 set(HAVE_LIBSVN_CLIENT_1 1)
 135         endif(LIBSVN_FOUND)
 136 endif(ENABLE_LIBSVN)
 137
 138 find_package(PLIB REQUIRED puaux pu fnt)
 139 find_package(SimGear 2.2.0 REQUIRED)
 140
 141 check_include_file(unistd.h HAVE_UNISTD_H)
 142 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 143 check_include_file(windows.h HAVE_WINDOWS_H)
 144
 145 # definition depends on OSG version
 146 set(CMAKE_REQUIRED_INCLUDES ${OPENSCENEGRAPH_INCLUDE_DIRS})
 147
 148 check_cxx_source_compiles(
 149     "#include <osg/CullSettings>
 150     int main()
 151     {
 152        osg::CullSettings::VariablesMask mask = osg::CullSettings::CLEAR_MASK;
 153        return 0;
 154     }
 155     "
 156     HAVE_CULLSETTINGS_CLEAR_MASK)
 157
 158 # library required by simgear
 159 # XXX This should go in a module and only run if simgear is not shared.
 160
 161 if(HAVE_UNISTD_H)
 162 set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 163 check_cxx_source_compiles(
 164    "#include <unistd.h>
 165     #if !defined(_POSIX_TIMERS) || (0 >= _POSIX_TIMERS)
 166     #error clock_gettime is not supported
 167     #endif
 168
 169     int main() { return 0; }
 170     "
 171     HAVE_CLOCK_GETTIME)
 172 endif(HAVE_UNISTD_H)
 173
 174 set(RT_LIBRARY "")
 175 if(HAVE_CLOCK_GETTIME)
 176 check_function_exists(clock_gettime CLOCK_GETTIME_IN_LIBC)
 177 if(NOT CLOCK_GETTIME_IN_LIBC)
 178 check_library_exists(rt clock_gettime "" HAVE_RT)
 179 if(HAVE_RT)
 180 set(RT_LIBRARY rt)
 181 endif(HAVE_RT)
 182 endif(NOT CLOCK_GETTIME_IN_LIBC)
 183 endif(HAVE_CLOCK_GETTIME)
 184
 185 if(CMAKE_COMPILER_IS_GNUCXX)
 186     set(WARNING_FLAGS -Wall)
 187 endif(CMAKE_COMPILER_IS_GNUCXX)
 188
 189 if(WIN32)
 190
 191     if(MSVC)
 192         # turn off various warnings
 193         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 194         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 195         # endforeach(warning)
 196
 197         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS")
 198     endif(MSVC)
 199
 200     set(NOMINMAX 1)
 201     set( WINSOCK_LIBRARY "ws2_32.lib" )
 202 endif(WIN32)
 203
 204 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS} -D_REENTRANT")
 205 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS} -D_REENTRANT")
 206
 207 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 208     ${Boost_INCLUDE_DIRS}
 209         ${ZLIB_INCLUDE_DIR}
 210     ${ALUT_INCLUDE_DIR}
 211         ${OPENAL_INCLUDE_DIR}
 212         ${SIMGEAR_INCLUDE_DIR}
 213         ${PLIB_INCLUDE_DIR} )
 214
 215 include_directories(${PROJECT_SOURCE_DIR}/src)
 216
 217 # following is needed, because config.h is include 'bare', whereas
 218 # version.h is included as <Include/version.h> - this should be cleaned up
 219 include_directories(${PROJECT_BINARY_DIR}/src)
 220 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 221
 222 add_definitions(-DHAVE_CONFIG_H)
 223
 224 # configure a header file to pass some of the CMake settings
 225 # to the source code
 226 configure_file (
 227   "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 228   "${PROJECT_BINARY_DIR}/src/Include/config.h"
 229   )
 230
 231 #and the same for the version header
 232 configure_file (
 233   "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 234   "${PROJECT_BINARY_DIR}/src/Include/version.h"
 235   )
 236
 237 add_subdirectory(src)
 238 add_subdirectory(utils)
 239
 240 #-----------------------------------------------------------------------------
 241 ### uninstall target
 242 #-----------------------------------------------------------------------------
 243 CONFIGURE_FILE(
 244   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 245   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 246   IMMEDIATE @ONLY)
 247 ADD_CUSTOM_TARGET(uninstall
 248   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
 249