CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2
   3 if(COMMAND cmake_policy)
   4    if(POLICY CMP0054)
   5        cmake_policy(SET CMP0054 NEW)
   6    endif()
   7    if(POLICY CMP0042)
   8        cmake_policy(SET CMP0042 NEW)
   9    endif()
  10 endif()
  11
  12 include (CheckFunctionExists)
  13 include (CheckIncludeFile)
  14 include (CheckLibraryExists)
  15 include (CheckCXXSourceCompiles)
  16 include (CheckCXXCompilerFlag)
  17
  18 # using 10.7 because boost requires libc++ and 10.6 doesn't include it
  19 set(CMAKE_OSX_DEPLOYMENT_TARGET 10.7)
  20 set(CMAKE_OSX_SYSROOT /Applications/Xcode.app/Contents/Developer/Platforms/MacOSX.platform/Developer/SDKs/MacOSX10.9.sdk)
  21
  22 project(SimGear)
  23
  24 # read 'version' file into a variable (stripping any newlines or spaces)
  25 file(READ version versionFile)
  26 string(STRIP ${versionFile} SIMGEAR_VERSION)
  27
  28 set(FIND_LIBRARY_USE_LIB64_PATHS ON)
  29
  30 # use simgear version also as the SO version (if building SOs)
  31 SET(SIMGEAR_SOVERSION ${SIMGEAR_VERSION})
  32
  33 # Warning when build is not an out-of-source build.
  34 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  35 if(InSourceBuild)
  36     message(WARNING  "Avoid building inside the source tree!")
  37     message(WARNING  "Create a separate build directory instead (i.e. 'sgbuild') and call CMake from there: ")
  38     message(WARNING  "  mkdir ../sgbuild && cd ../sgbuild && cmake ${CMAKE_SOURCE_DIR}")
  39 endif(InSourceBuild)
  40
  41 #packaging
  42 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  43 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  44 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Simulation support libraries for FlightGear and related projects")
  45 SET(CPACK_PACKAGE_VENDOR "The FlightGear project")
  46 SET(CPACK_GENERATOR "TBZ2")
  47 SET(CPACK_INSTALL_CMAKE_PROJECTS  ${CMAKE_CURRENT_BINARY_DIR};SimGear;ALL;/)
  48
  49
  50 # split version string into components, note CMAKE_MATCH_0 is the entire regexp match
  51 string(REGEX MATCH "([0-9]+)\\.([0-9]+)\\.([0-9]+)" CPACK_PACKAGE_VERSION ${SIMGEAR_VERSION} )
  52 set(CPACK_PACKAGE_VERSION_MAJOR ${CMAKE_MATCH_1})
  53 set(CPACK_PACKAGE_VERSION_MINOR ${CMAKE_MATCH_2})
  54 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_3})
  55
  56 message(STATUS "version is ${CPACK_PACKAGE_VERSION_MAJOR} dot ${CPACK_PACKAGE_VERSION_MINOR} dot ${CPACK_PACKAGE_VERSION_PATCH}")
  57
  58 set(CPACK_SOURCE_GENERATOR TBZ2)
  59 set(CPACK_SOURCE_PACKAGE_FILE_NAME "simgear-${SIMGEAR_VERSION}" CACHE INTERNAL "tarball basename")
  60 set(CPACK_SOURCE_IGNORE_FILES
  61   "^${PROJECT_SOURCE_DIR}/.git;\\\\.gitignore;Makefile.am;~$;${CPACK_SOURCE_IGNORE_FILES}")
  62
  63 message(STATUS "ignoring: ${CPACK_SOURCE_IGNORE_FILES}")
  64
  65 include (CPack)
  66
  67 # We have some custom .cmake scripts not in the official distribution.
  68 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  69
  70 # Change the default build type to something fast
  71 if(NOT CMAKE_BUILD_TYPE)
  72   set(CMAKE_BUILD_TYPE Release CACHE STRING
  73       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  74       FORCE)
  75 endif(NOT CMAKE_BUILD_TYPE)
  76
  77 # Determine name of library installation directory, i.e. "lib" vs "lib64", which
  78 # differs between all Debian-based vs all other Linux distros.
  79 # See cmake bug #11964, http://cmake.org/gitweb?p=cmake.git;a=commit;h=126c993d
  80 # GNUInstallDirs requires CMake >= 2.8.5, use own file for older cmake
  81 if(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  82   include(GNUInstallDirs)
  83 else(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  84   include(OldGNUInstallDirs)
  85 endif(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  86 message(STATUS "Library installation directory: ${CMAKE_INSTALL_LIBDIR}")
  87
  88 #####################################################################################
  89 # Configure library search paths
  90 #####################################################################################
  91
  92 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  93     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  94     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  95     # add paths manually
  96     # see http://www.cmake.org/Bug/view.php?id=12049 and
  97     # http://www.cmake.org/Bug/view.php?id=12037
  98     list(APPEND ADDITIONAL_LIBRARY_PATHS
  99          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
 100          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
 101          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
 102     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
 103 endif()
 104
 105 #####################################################################################
 106
 107 if (NOT MSVC)
 108 option(SIMGEAR_SHARED   "Set to ON to build SimGear as a shared library/framework" OFF)
 109 option(SYSTEM_EXPAT     "Set to ON to build SimGear using the system libExpat" OFF)
 110 else()
 111 # Building SimGear DLLs is currently not supported for MSVC.
 112 set(SIMGEAR_SHARED OFF)
 113 # Using a system expat is currently not supported for MSVC - it would require shared simgear (DLL).
 114 set(SYSTEM_EXPAT OFF)
 115 endif()
 116
 117 option(SIMGEAR_HEADLESS "Set to ON to build SimGear without GUI/graphics support" OFF)
 118 option(ENABLE_RTI       "Set to ON to build SimGear with RTI support" OFF)
 119 option(ENABLE_TESTS     "Set to OFF to disable building SimGear's test applications" ON)
 120 option(ENABLE_SOUND     "Set to OFF to disable building SimGear's sound support" ON)
 121 option(ENABLE_PKGUTIL   "Set to ON to build the sg_pkgutil application (default)" ON)
 122
 123 if (MSVC)
 124   GET_FILENAME_COMPONENT(PARENT_DIR ${PROJECT_BINARY_DIR} PATH)
 125   if (CMAKE_CL_64)
 126     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty.x64")
 127   else (CMAKE_CL_64)
 128     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty")
 129   endif (CMAKE_CL_64)
 130   if (EXISTS ${TEST_3RDPARTY_DIR})
 131     set(MSVC_3RDPARTY_ROOT ${PARENT_DIR} CACHE PATH "Location where the third-party dependencies are extracted")
 132   else (EXISTS ${TEST_3RDPARTY_DIR})
 133     set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 134   endif (EXISTS ${TEST_3RDPARTY_DIR})
 135 else (MSVC)
 136   set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 137 endif (MSVC)
 138
 139 if (MSVC AND MSVC_3RDPARTY_ROOT)
 140   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_ROOT}")
 141   set( OSG_MSVC "msvc" )
 142   if (${MSVC_VERSION} EQUAL 1700)
 143       set( OSG_MSVC ${OSG_MSVC}110 )
 144   elseif (${MSVC_VERSION} EQUAL 1600)
 145       set( OSG_MSVC ${OSG_MSVC}100 )
 146   else (${MSVC_VERSION} EQUAL 1700)
 147       set( OSG_MSVC ${OSG_MSVC}90 )
 148   endif (${MSVC_VERSION} EQUAL 1700)
 149   if (CMAKE_CL_64)
 150       set( OSG_MSVC ${OSG_MSVC}-64 )
 151       set( MSVC_3RDPARTY_DIR 3rdParty.x64 )
 152   else (CMAKE_CL_64)
 153       set( MSVC_3RDPARTY_DIR 3rdParty )
 154   endif (CMAKE_CL_64)
 155
 156   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/lib )
 157   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/include)
 158   find_path(BOOST_ROOT boost/version.hpp
 159                         ${MSVC_3RDPARTY_ROOT}/boost
 160                         ${MSVC_3RDPARTY_ROOT}/boost_1_52_0
 161                         ${MSVC_3RDPARTY_ROOT}/boost_1_51_0
 162                         ${MSVC_3RDPARTY_ROOT}/boost_1_50_0
 163                         ${MSVC_3RDPARTY_ROOT}/boost_1_49_0
 164                         ${MSVC_3RDPARTY_ROOT}/boost_1_48_0
 165                         ${MSVC_3RDPARTY_ROOT}/boost_1_47_0
 166                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_1
 167                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_0
 168                         ${MSVC_3RDPARTY_ROOT}/boost_1_45_0
 169                         ${MSVC_3RDPARTY_ROOT}/boost_1_44_0
 170                         )
 171   # set (BOOST_ROOT ${MSVC_3RDPARTY_ROOT}/boost_1_44_0)
 172   message(STATUS "BOOST_ROOT is ${BOOST_ROOT}")
 173   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 174   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib)
 175 endif (MSVC AND MSVC_3RDPARTY_ROOT)
 176
 177 if(APPLE)
 178   find_library(COCOA_LIBRARY Cocoa)
 179 endif()
 180
 181 if(${CMAKE_SYSTEM_NAME} MATCHES "Linux" OR
 182         ${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD")
 183     find_package(Threads REQUIRED)
 184 endif()
 185
 186 # Somehow this only works if included before searching for Boost...
 187 include(BoostTestTargets)
 188
 189 find_package(Boost REQUIRED)
 190 set (BOOST_CXX_FLAGS "-DBOOST_BIMAP_DISABLE_SERIALIZATION")
 191
 192 if(SIMGEAR_HEADLESS)
 193     message(STATUS "SimGear mode: HEADLESS")
 194     set(ENABLE_SOUND 0)
 195 else()
 196     message(STATUS "SimGear mode: NORMAL")
 197     find_package(OpenGL REQUIRED)
 198
 199     if (ENABLE_SOUND)
 200         find_package(OpenAL REQUIRED)
 201         message(STATUS "Sound support: ENABLED")
 202     endif(ENABLE_SOUND)
 203
 204     find_package(OpenSceneGraph 3.2.0 REQUIRED osgText osgSim osgDB osgParticle osgGA osgViewer osgUtil)
 205 endif(SIMGEAR_HEADLESS)
 206
 207 find_package(ZLIB REQUIRED)
 208
 209 if (SYSTEM_EXPAT)
 210     message(STATUS "Requested to use system Expat library, forcing SIMGEAR_SHARED to true")
 211     set(SIMGEAR_SHARED ON)
 212     find_package(EXPAT REQUIRED)
 213
 214 else()
 215     message(STATUS "Using built-in expat code")
 216     # XML_STATIC is important to avoid sg_expat_external.h
 217     # declaring symbols as declspec(import)
 218     add_definitions(-DHAVE_EXPAT_CONFIG_H -DXML_STATIC)
 219     set(EXPAT_INCLUDE_DIRS
 220             ${PROJECT_SOURCE_DIR}/3rdparty/expat
 221             ${PROJECT_BINARY_DIR}/3rdparty/expat)
 222 endif(SYSTEM_EXPAT)
 223
 224 include_directories(${EXPAT_INCLUDE_DIRS})
 225
 226 check_include_file(inttypes.h HAVE_INTTYPES_H)
 227 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 228 check_include_file(sys/timeb.h HAVE_SYS_TIMEB_H)
 229 check_include_file(unistd.h HAVE_UNISTD_H)
 230 check_include_file(windows.h HAVE_WINDOWS_H)
 231
 232 if(HAVE_INTTYPES_H)
 233   # ShivaVG needs inttypes.h
 234   add_definitions(-DHAVE_INTTYPES_H)
 235 endif()
 236
 237 if(ENABLE_RTI)
 238     # See if we have any rti library variant installed
 239     message(STATUS "RTI: ENABLED")
 240     find_package(RTI)
 241 else()
 242     message(STATUS "RTI: DISABLED")
 243 endif(ENABLE_RTI)
 244
 245 check_function_exists(gettimeofday HAVE_GETTIMEOFDAY)
 246 check_function_exists(ftime HAVE_FTIME)
 247 check_function_exists(timegm HAVE_TIMEGM)
 248 check_function_exists(rint HAVE_RINT)
 249 check_function_exists(mkdtemp HAVE_MKDTEMP)
 250 check_function_exists(bcopy HAVE_BCOPY)
 251 check_function_exists(mmap HAVE_MMAP)
 252
 253 if(HAVE_UNISTD_H)
 254     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 255     check_cxx_source_compiles(
 256        "#include <unistd.h>
 257         #if !defined(_POSIX_TIMERS) || (0 >= _POSIX_TIMERS)
 258             #error clock_gettime is not supported
 259         #endif
 260
 261         int main() { return 0; }
 262         "
 263         HAVE_CLOCK_GETTIME)
 264 endif(HAVE_UNISTD_H)
 265
 266 set(RT_LIBRARY "")
 267 if(HAVE_CLOCK_GETTIME)
 268     check_library_exists(rt clock_gettime "" HAVE_RT)
 269     if(HAVE_RT)
 270         set(RT_LIBRARY rt)
 271     endif(HAVE_RT)
 272 endif(HAVE_CLOCK_GETTIME)
 273
 274 set(DL_LIBRARY "")
 275 check_cxx_source_compiles(
 276     "#include <dlfcn.h>
 277     int main(void) {
 278         return 0;
 279     }
 280     "
 281     HAVE_DLFCN_H)
 282
 283 if(HAVE_DLFCN_H)
 284     check_library_exists(dl dlerror "" HAVE_DL)
 285     if(HAVE_DL)
 286         set(DL_LIBRARY "dl")
 287     endif()
 288 endif()
 289
 290 SET(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "add a postfix, usually 'd' on windows")
 291 SET(CMAKE_RELEASE_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 292 SET(CMAKE_RELWITHDEBINFO_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 293 SET(CMAKE_MINSIZEREL_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 294
 295 # isnan might not be real symbol, so can't check using function_exists
 296 check_cxx_source_compiles(
 297     "#include <cmath>
 298     int main() { return isnan(0.0);} "
 299     HAVE_ISNAN)
 300
 301 check_cxx_source_compiles(
 302     "#include <cmath>
 303     int main() { return std::isnan(0.0);} "
 304     HAVE_STD_ISNAN)
 305
 306 if(CMAKE_COMPILER_IS_GNUCXX)
 307     set(WARNING_FLAGS_CXX "-Wall")
 308     set(WARNING_FLAGS_C   "-Wall")
 309
 310     # certain GCC versions don't provide the atomic builds, and hence
 311     # require is to provide them in SGAtomic.cxx
 312     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 313     check_cxx_source_compiles(
 314        "int main() { unsigned mValue; return __sync_add_and_fetch(&mValue, 1); }"
 315         GCC_ATOMIC_BUILTINS_FOUND)
 316 endif(CMAKE_COMPILER_IS_GNUCXX)
 317
 318 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 319     # Boost redeclares class members
 320     set(WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual -Wno-redeclared-class-member")
 321     set(WARNING_FLAGS_C   "-Wall")
 322     set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LIBRARY "libc++")
 323     set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LANGUAGE_STANDARD "c++11")
 324     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -stdlib=libc++")
 325 endif()
 326
 327 if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 328 # boost goes haywire wrt static asserts
 329     check_cxx_compiler_flag(-Wno-unused-local-typedefs HAS_NOWARN_UNUSED_TYPEDEFS)
 330     if(HAS_NOWARN_UNUSED_TYPEDEFS)
 331         set(WARNING_FLAGS_CXX " ${WARNING_FLAGS_CXX} -Wno-unused-local-typedefs")
 332     endif()
 333 endif()
 334
 335 if(WIN32)
 336
 337     if(MINGW)
 338         add_definitions(-D_WIN32_WINNT=0x501)
 339     endif()
 340
 341     if(MSVC)
 342         # turn off various warnings
 343         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 344         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 345         # endforeach(warning)
 346
 347         set(MSVC_FLAGS "-DWIN32 -DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS /wd4996 /wd4250 -Dstrdup=_strdup")
 348         if (${MSVC_VERSION} GREATER 1599)
 349             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 350         endif (${MSVC_VERSION} GREATER 1599)
 351     endif(MSVC)
 352
 353     # assumed on Windows
 354     set(HAVE_GETLOCALTIME 1)
 355
 356     set( WINSOCK_LIBRARY "ws2_32.lib" )
 357     set( RT_LIBRARY "winmm" )
 358 endif(WIN32)
 359
 360 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS}")
 361 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} ${BOOST_CXX_FLAGS}")
 362 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 363
 364 # use BEFORE to ensure local directories are used first,
 365 # ahead of system-installed libs
 366 include_directories(BEFORE ${PROJECT_SOURCE_DIR})
 367 include_directories(BEFORE ${PROJECT_SOURCE_DIR}/simgear/canvas/ShivaVG/include)
 368 include_directories(BEFORE ${PROJECT_BINARY_DIR}/simgear)
 369
 370 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 371     ${Boost_INCLUDE_DIRS}
 372     ${ZLIB_INCLUDE_DIR}
 373     ${OPENAL_INCLUDE_DIR}
 374 )
 375
 376 add_definitions(-DHAVE_CONFIG_H)
 377
 378 # configure a header file to pass some of the CMake settings
 379 # to the source code
 380 configure_file (
 381   "${PROJECT_SOURCE_DIR}/simgear/simgear_config_cmake.h.in"
 382   "${PROJECT_BINARY_DIR}/simgear/simgear_config.h"
 383   )
 384
 385 if(ENABLE_TESTS)
 386     # enable CTest / make test target
 387     message(STATUS "Tests: ENABLED")
 388
 389     include (Dart)
 390     enable_testing()
 391 else()
 392     message(STATUS "Tests: DISABLED")
 393 endif(ENABLE_TESTS)
 394
 395 # always set TEST_LIBS as it is also used by other tools/applications
 396 set(TEST_LIBS_INTERNAL_CORE
 397     ${CMAKE_THREAD_LIBS_INIT}
 398     ${ZLIB_LIBRARY}
 399     ${WINSOCK_LIBRARY}
 400     ${RT_LIBRARY}
 401     ${DL_LIBRARY}
 402     ${COCOA_LIBRARY})
 403 set(TEST_LIBS SimGearCore ${TEST_LIBS_INTERNAL_CORE})
 404
 405 if(NOT SIMGEAR_HEADLESS)
 406     set(TEST_LIBS SimGearScene ${OPENGL_LIBRARIES} ${TEST_LIBS})
 407 endif()
 408
 409 install (FILES ${PROJECT_BINARY_DIR}/simgear/simgear_config.h  DESTINATION include/simgear/)
 410
 411 include_directories(3rdparty/utf8/source)
 412
 413 add_subdirectory(3rdparty)
 414 add_subdirectory(simgear)
 415
 416 #-----------------------------------------------------------------------------
 417 ### uninstall target
 418 #-----------------------------------------------------------------------------
 419 CONFIGURE_FILE(
 420   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 421   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 422   IMMEDIATE @ONLY)
 423 ADD_CUSTOM_TARGET(uninstall
 424   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
 425
 426