CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2 include (CheckFunctionExists)
   3 include (CheckIncludeFile)
   4 include (CheckCXXSourceCompiles)
   5
   6
   7 project(SimGear)
   8
   9 # read 'version' file into a variable (stripping any newlines or spaces)
  10 file(READ version versionFile)
  11 string(STRIP ${versionFile} SIMGEAR_VERSION)
  12
  13 set(FIND_LIBRARY_USE_LIB64_PATHS ON)
  14
  15 # use simgear version also as the SO version (if building SOs)
  16 SET(SIMGEAR_SOVERSION ${SIMGEAR_VERSION})
  17
  18 # Warning when build is not an out-of-source build.
  19 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  20 if(InSourceBuild)
  21     message(WARNING  "Avoid building inside the source tree!")
  22     message(WARNING  "Create a separate build directory instead (i.e. 'sgbuild') and call CMake from there: ")
  23     message(WARNING  "  mkdir ../sgbuild && cd ../sgbuild && cmake ${CMAKE_SOURCE_DIR}")
  24 endif(InSourceBuild)
  25
  26 if (NOT EMBEDDED_SIMGEAR)
  27     #packaging
  28     SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  29     SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  30     SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Simulation support libraries for FlightGear and related projects")
  31     SET(CPACK_PACKAGE_VENDOR "The FlightGear project")
  32     SET(CPACK_GENERATOR "TBZ2")
  33     SET(CPACK_INSTALL_CMAKE_PROJECTS  ${CMAKE_CURRENT_BINARY_DIR};SimGear;ALL;/)
  34
  35
  36     # split version string into components, note CMAKE_MATCH_0 is the entire regexp match
  37     string(REGEX MATCH "([0-9]+)\\.([0-9]+)\\.([0-9]+)" CPACK_PACKAGE_VERSION ${SIMGEAR_VERSION} )
  38     set(CPACK_PACKAGE_VERSION_MAJOR ${CMAKE_MATCH_1})
  39     set(CPACK_PACKAGE_VERSION_MINOR ${CMAKE_MATCH_2})
  40     set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_3})
  41
  42     message(STATUS "version is ${CPACK_PACKAGE_VERSION_MAJOR} dot ${CPACK_PACKAGE_VERSION_MINOR} dot ${CPACK_PACKAGE_VERSION_PATCH}")
  43
  44     set(CPACK_SOURCE_GENERATOR TBZ2)
  45     set(CPACK_SOURCE_PACKAGE_FILE_NAME "simgear-${SIMGEAR_VERSION}" CACHE INTERNAL "tarball basename")
  46     set(CPACK_SOURCE_IGNORE_FILES
  47       "^${PROJECT_SOURCE_DIR}/.git;\\\\.gitignore;Makefile.am;~$;${CPACK_SOURCE_IGNORE_FILES}")
  48
  49     message(STATUS "ignoring: ${CPACK_SOURCE_IGNORE_FILES}")
  50
  51     include (CPack)
  52 endif()
  53
  54 # We have some custom .cmake scripts not in the official distribution.
  55 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  56
  57 # Change the default build type to something fast
  58 if(NOT CMAKE_BUILD_TYPE)
  59   set(CMAKE_BUILD_TYPE Release CACHE STRING
  60       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  61       FORCE)
  62 endif(NOT CMAKE_BUILD_TYPE)
  63
  64 # Determine name of library installation directory, i.e. "lib" vs "lib64", which
  65 # differs between all Debian-based vs all other Linux distros.
  66 # See cmake bug #11964, http://cmake.org/gitweb?p=cmake.git;a=commit;h=126c993d
  67 # GNUInstallDirs requires CMake >= 2.8.5, use own file for older cmake
  68 if(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  69   include(GNUInstallDirs)
  70 else(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  71   include(OldGNUInstallDirs)
  72 endif(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  73 message(STATUS "Library installation directory: ${CMAKE_INSTALL_LIBDIR}")
  74
  75 #####################################################################################
  76 # Configure library search paths
  77 #####################################################################################
  78
  79 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  80     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  81     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  82     # add paths manually
  83     # see http://www.cmake.org/Bug/view.php?id=12049 and
  84     # http://www.cmake.org/Bug/view.php?id=12037
  85     list(APPEND ADDITIONAL_LIBRARY_PATHS
  86          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  87          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  88          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
  89     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
  90 endif()
  91
  92 if(NOT MSVC)
  93     # TBD: are these really necessary? Aren't they considered by cmake automatically?
  94     list(APPEND ADDITIONAL_LIBRARY_PATHS
  95          /opt/local
  96          /usr/local
  97          /usr)
  98 endif()
  99 #####################################################################################
 100
 101 if (NOT MSVC)
 102 option(SIMGEAR_SHARED   "Set to ON to build SimGear as a shared library/framework" OFF)
 103 option(SYSTEM_EXPAT     "Set to ON to build SimGear using the system libExpat" OFF)
 104 else()
 105 # Building SimGear DLLs is currently not supported for MSVC.
 106 set(SIMGEAR_SHARED OFF)
 107 # Using a system expat is currently not supported for MSVC - it would require shared simgear (DLL).
 108 set(SYSTEM_EXPAT OFF)
 109 endif()
 110
 111 option(SIMGEAR_HEADLESS "Set to ON to build SimGear without GUI/graphics support" OFF)
 112 option(JPEG_FACTORY     "Enable JPEG-factory support" OFF)
 113 option(SG_SVN_CLIENT    "Set to ON to build SimGear with built-in SVN support" OFF)
 114 option(ENABLE_LIBSVN    "Set to ON to build SimGear with libsvnclient support" ON)
 115 option(ENABLE_RTI       "Set to ON to build SimGear with RTI support" OFF)
 116 option(ENABLE_TESTS     "Set to OFF to disable building SimGear's test applications" ON)
 117 option(ENABLE_SOUND     "Set to OFF to disable building SimGear's sound support" ON)
 118 option(ENABLE_PKGUTIL   "Set to ON to build the sg_pkgutil application (default)" ON)
 119
 120 if (MSVC)
 121   GET_FILENAME_COMPONENT(PARENT_DIR ${PROJECT_BINARY_DIR} PATH)
 122   if (CMAKE_CL_64)
 123     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty.x64")
 124   else (CMAKE_CL_64)
 125     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty")
 126   endif (CMAKE_CL_64)
 127   if (EXISTS ${TEST_3RDPARTY_DIR})
 128     set(MSVC_3RDPARTY_ROOT ${PARENT_DIR} CACHE PATH "Location where the third-party dependencies are extracted")
 129   else (EXISTS ${TEST_3RDPARTY_DIR})
 130     set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 131   endif (EXISTS ${TEST_3RDPARTY_DIR})
 132 else (MSVC)
 133   set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 134 endif (MSVC)
 135
 136 if (MSVC AND MSVC_3RDPARTY_ROOT)
 137   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_ROOT}")
 138   set( OSG_MSVC "msvc" )
 139   if (${MSVC_VERSION} EQUAL 1700)
 140       set( OSG_MSVC ${OSG_MSVC}110 )
 141   elseif (${MSVC_VERSION} EQUAL 1600)
 142       set( OSG_MSVC ${OSG_MSVC}100 )
 143   else (${MSVC_VERSION} EQUAL 1700)
 144       set( OSG_MSVC ${OSG_MSVC}90 )
 145   endif (${MSVC_VERSION} EQUAL 1700)
 146   if (CMAKE_CL_64)
 147       set( OSG_MSVC ${OSG_MSVC}-64 )
 148       set( MSVC_3RDPARTY_DIR 3rdParty.x64 )
 149   else (CMAKE_CL_64)
 150       set( MSVC_3RDPARTY_DIR 3rdParty )
 151   endif (CMAKE_CL_64)
 152
 153   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/lib )
 154   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/include)
 155   find_path(BOOST_ROOT boost/version.hpp
 156                         ${MSVC_3RDPARTY_ROOT}/boost
 157                         ${MSVC_3RDPARTY_ROOT}/boost_1_52_0
 158                         ${MSVC_3RDPARTY_ROOT}/boost_1_51_0
 159                         ${MSVC_3RDPARTY_ROOT}/boost_1_50_0
 160                         ${MSVC_3RDPARTY_ROOT}/boost_1_49_0
 161                         ${MSVC_3RDPARTY_ROOT}/boost_1_48_0
 162                         ${MSVC_3RDPARTY_ROOT}/boost_1_47_0
 163                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_1
 164                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_0
 165                         ${MSVC_3RDPARTY_ROOT}/boost_1_45_0
 166                         ${MSVC_3RDPARTY_ROOT}/boost_1_44_0
 167                         )
 168   # set (BOOST_ROOT ${MSVC_3RDPARTY_ROOT}/boost_1_44_0)
 169   message(STATUS "BOOST_ROOT is ${BOOST_ROOT}")
 170   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 171   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib)
 172 endif (MSVC AND MSVC_3RDPARTY_ROOT)
 173
 174 if(APPLE)
 175   find_library(CORE_SERVICES_LIBRARY CoreServices)
 176 endif()
 177
 178 find_package(Boost REQUIRED)
 179 set (BOOST_CXX_FLAGS "-DBOOST_MULTI_INDEX_DISABLE_SERIALIZATION -DBOOST_BIMAP_DISABLE_SERIALIZATION")
 180
 181 if(SIMGEAR_HEADLESS)
 182     message(STATUS "SimGear mode: HEADLESS")
 183     set(ENABLE_SOUND 0)
 184 else()
 185     message(STATUS "SimGear mode: NORMAL")
 186     find_package(OpenGL REQUIRED)
 187
 188     if (ENABLE_SOUND)
 189         find_package(OpenAL REQUIRED)
 190         message(STATUS "Sound support: ENABLED")
 191     endif(ENABLE_SOUND)
 192
 193     find_package(OpenSceneGraph 3.0.0 REQUIRED osgText osgSim osgDB osgParticle osgGA osgUtil)
 194 endif(SIMGEAR_HEADLESS)
 195
 196 if(JPEG_FACTORY)
 197     message(STATUS "JPEG-factory: ENABLED")
 198     find_package(JPEG REQUIRED)
 199     include_directories(${JPEG_INCLUDE_DIR})
 200 else()
 201     message(STATUS "JPEG-factory: DISABLED")
 202 endif(JPEG_FACTORY)
 203
 204 if (SG_SVN_CLIENT)
 205     message(STATUS "Using built-in subversion client code")
 206 elseif(ENABLE_LIBSVN)
 207     find_package(SvnClient)
 208
 209     if(LIBSVN_FOUND)
 210         message(STATUS "Subversion client support: ENABLED")
 211         set(HAVE_SVN_CLIENT_H 1)
 212         set(HAVE_LIBSVN_CLIENT_1 1)
 213     else()
 214         # Oops. ENABLE_LIBSVN is ON, but svn is still missing.
 215         # Provide clearly visible warning/hint, so builders know what else they should install (or disable).
 216         message(WARNING "Failed to enable subversion client support. Unable to find required subversion client library. Some features may not be available (scenery download).")
 217         message(WARNING "Install 'libsvn' library/DLL (libsvn-devel/libsvnclient/...). Otherwise disable subversion support (set 'ENABLE_LIBSVN' to 'OFF').")
 218     endif(LIBSVN_FOUND)
 219 else()
 220     message(STATUS "Subversion client support: DISABLED")
 221 endif(SG_SVN_CLIENT)
 222
 223 find_package(ZLIB REQUIRED)
 224 find_package(Threads REQUIRED)
 225
 226 if (SYSTEM_EXPAT)
 227     message(STATUS "Requested to use system Expat library, forcing SIMGEAR_SHARED to true")
 228     set(SIMGEAR_SHARED ON)
 229     find_package(EXPAT REQUIRED)
 230     include_directories(${EXPAT_INCLUDE_DIRS})
 231 else()
 232     message(STATUS "Using built-in expat code")
 233     add_definitions(-DHAVE_EXPAT_CONFIG_H)
 234 endif(SYSTEM_EXPAT)
 235
 236 check_include_file(inttypes.h HAVE_INTTYPES_H)
 237 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 238 check_include_file(sys/timeb.h HAVE_SYS_TIMEB_H)
 239 check_include_file(unistd.h HAVE_UNISTD_H)
 240 check_include_file(windows.h HAVE_WINDOWS_H)
 241
 242 if(HAVE_INTTYPES_H)
 243   # ShivaVG needs inttypes.h
 244   add_definitions(-DHAVE_INTTYPES_H)
 245 endif()
 246
 247 if(ENABLE_RTI)
 248     # See if we have any rti library variant installed
 249     message(STATUS "RTI: ENABLED")
 250     find_package(RTI)
 251 else()
 252     message(STATUS "RTI: DISABLED")
 253 endif(ENABLE_RTI)
 254
 255 check_function_exists(gettimeofday HAVE_GETTIMEOFDAY)
 256 check_function_exists(ftime HAVE_FTIME)
 257 check_function_exists(timegm HAVE_TIMEGM)
 258 check_function_exists(rint HAVE_RINT)
 259 check_function_exists(mkdtemp HAVE_MKDTEMP)
 260 check_function_exists(bcopy HAVE_BCOPY)
 261 check_function_exists(mmap HAVE_MMAP)
 262
 263 if(HAVE_UNISTD_H)
 264     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 265     check_cxx_source_compiles(
 266        "#include <unistd.h>
 267         #if !defined(_POSIX_TIMERS) || (0 >= _POSIX_TIMERS)
 268             #error clock_gettime is not supported
 269         #endif
 270
 271         int main() { return 0; }
 272         "
 273         HAVE_CLOCK_GETTIME)
 274 endif(HAVE_UNISTD_H)
 275
 276 set(RT_LIBRARY "")
 277 if(HAVE_CLOCK_GETTIME)
 278     check_library_exists(rt clock_gettime "" HAVE_RT)
 279     if(HAVE_RT)
 280         set(RT_LIBRARY rt)
 281     endif(HAVE_RT)
 282 endif(HAVE_CLOCK_GETTIME)
 283
 284 SET(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "add a postfix, usually 'd' on windows")
 285 SET(CMAKE_RELEASE_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 286 SET(CMAKE_RELWITHDEBINFO_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 287 SET(CMAKE_MINSIZEREL_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 288
 289 # isnan might not be real symbol, so can't check using function_exists
 290 check_cxx_source_compiles(
 291     "#include <cmath>
 292     void f() { isnan(0.0);} "
 293     HAVE_ISNAN)
 294
 295 check_cxx_source_compiles(
 296     "#include <cmath>
 297     void f() { std::isnan(0.0);} "
 298     HAVE_STD_ISNAN)
 299
 300 if(CMAKE_COMPILER_IS_GNUCXX)
 301     set(WARNING_FLAGS_CXX "-Wall")
 302     set(WARNING_FLAGS_C   "-Wall")
 303
 304     # certain GCC versions don't provide the atomic builds, and hence
 305     # require is to provide them in SGAtomic.cxx
 306     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 307     check_cxx_source_compiles(
 308        "int main() { unsigned mValue; return __sync_add_and_fetch(&mValue, 1); }"
 309         GCC_ATOMIC_BUILTINS_FOUND)
 310 endif(CMAKE_COMPILER_IS_GNUCXX)
 311
 312 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 313    set(WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual")
 314    set(WARNING_FLAGS_C   "-Wall")
 315 endif()
 316
 317 if(WIN32)
 318
 319     if(MINGW)
 320         add_definitions(-D_WIN32_WINNT=0x501)
 321     endif()
 322
 323     if(MSVC)
 324         # turn off various warnings
 325         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 326         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 327         # endforeach(warning)
 328
 329         set(MSVC_FLAGS "-DWIN32 -DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS /wd4996 /wd4250 -Dstrdup=_strdup")
 330         if (${MSVC_VERSION} GREATER 1599)
 331             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 332         endif (${MSVC_VERSION} GREATER 1599)
 333     endif(MSVC)
 334
 335     # assumed on Windows
 336     set(HAVE_GETLOCALTIME 1)
 337
 338     set( WINSOCK_LIBRARY "ws2_32.lib" )
 339     set( RT_LIBRARY "winmm" )
 340 endif(WIN32)
 341
 342 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS}")
 343 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} ${BOOST_CXX_FLAGS}")
 344 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 345
 346 include_directories(${PROJECT_SOURCE_DIR})
 347 include_directories(${PROJECT_SOURCE_DIR}/simgear/canvas/ShivaVG/include)
 348 include_directories(${PROJECT_BINARY_DIR}/simgear)
 349 include_directories(${PROJECT_BINARY_DIR}/simgear/xml)
 350
 351 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 352     ${Boost_INCLUDE_DIRS}
 353     ${ZLIB_INCLUDE_DIR}
 354     ${OPENAL_INCLUDE_DIR}
 355     ${LibArchive_INCLUDE_DIRS}
 356 )
 357
 358 add_definitions(-DHAVE_CONFIG_H)
 359
 360 # configure a header file to pass some of the CMake settings
 361 # to the source code
 362 configure_file (
 363   "${PROJECT_SOURCE_DIR}/simgear/simgear_config_cmake.h.in"
 364   "${PROJECT_BINARY_DIR}/simgear/simgear_config.h"
 365   )
 366
 367 configure_file (
 368     "${PROJECT_SOURCE_DIR}/simgear/xml/expat_config_cmake.in"
 369     "${PROJECT_BINARY_DIR}/simgear/xml/expat_config.h"
 370 )
 371
 372 if(ENABLE_TESTS)
 373     # enable CTest / make test target
 374     message(STATUS "Tests: ENABLED")
 375
 376     include (Dart)
 377     enable_testing()
 378 else()
 379     message(STATUS "Tests: DISABLED")
 380 endif(ENABLE_TESTS)
 381
 382 # always set TEST_LIBS as it is also used by other tools/applications
 383 # TODO maybe better rename?
 384 if(SIMGEAR_SHARED)
 385     set( TEST_LIBS
 386         SimGearCore)
 387 else()
 388     set( TEST_LIBS
 389         SimGearCore
 390         ${CMAKE_THREAD_LIBS_INIT}
 391         ${ZLIB_LIBRARY}
 392         ${WINSOCK_LIBRARY}
 393         ${RT_LIBRARY}
 394         ${CORE_SERVICES_LIBRARY})
 395 endif()
 396
 397 if(NOT SIMGEAR_HEADLESS)
 398     set( TEST_LIBS
 399         SimGearScene
 400         ${TEST_LIBS}
 401         ${OPENGL_LIBRARIES})
 402 endif()
 403
 404 install (FILES ${PROJECT_BINARY_DIR}/simgear/simgear_config.h  DESTINATION include/simgear/)
 405 add_subdirectory(simgear)
 406
 407 if (NOT EMBEDDED_SIMGEAR)
 408 #-----------------------------------------------------------------------------
 409 ### uninstall target
 410 #-----------------------------------------------------------------------------
 411 CONFIGURE_FILE(
 412   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 413   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 414   IMMEDIATE @ONLY)
 415 ADD_CUSTOM_TARGET(uninstall
 416   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
 417
 418 endif()
 419