CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7
   8 project(FlightGear)
   9
  10 # We have some custom .cmake scripts not in the official distribution.
  11 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  12
  13 if(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  14     # use official include provided by latest CMake
  15     include(GNUInstallDirs)
  16 else(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  17     # backward compatibility: use our own module for older cmake versions
  18     include(OldGNUInstallDirs)
  19 endif(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  20
  21 # Warning when build is not an out-of-source build.
  22 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  23 if(InSourceBuild)
  24     message(WARNING  "Avoid building inside the source tree!")
  25     message(WARNING  "Create a separate build directory instead (i.e. 'fgbuild') and call CMake from there: ")
  26     message(WARNING  "  mkdir ../fgbuild && cd ../fgbuild && cmake ${CMAKE_SOURCE_DIR}")
  27 endif(InSourceBuild)
  28
  29 # System detection/default settings
  30 include( DetectDistro )
  31 include( DetectBrowser )
  32
  33 set(CMAKE_DEBUG_POSTFIX          "d" CACHE STRING "add a postfix, usually d on windows")
  34 set(CMAKE_RELEASE_POSTFIX        ""  CACHE STRING "add a postfix, usually empty on windows")
  35 set(CMAKE_RELWITHDEBINFO_POSTFIX ""  CACHE STRING "add a postfix, usually empty on windows")
  36 set(CMAKE_MINSIZEREL_POSTFIX     ""  CACHE STRING "add a postfix, usually empty on windows")
  37
  38 # read 'version' file into a variable (stripping any newlines or spaces)
  39 file(READ version versionFile)
  40 if (NOT versionFile)
  41     message(FATAL_ERROR "Unable to determine FlightGear version. Version file is missing.")
  42 endif()
  43 string(STRIP "${versionFile}" FLIGHTGEAR_VERSION)
  44
  45 # FlightGear packaging (to build a source tarball)
  46 include( ConfigureCPack )
  47
  48 # FlightGear base package path
  49 if (FG_DATA_DIR)
  50     message(STATUS "Using explicit data directory for base package: ${FG_DATA_DIR}")
  51 else()
  52     set(FG_DATA_DIR "${CMAKE_INSTALL_PREFIX}/lib/FlightGear" CACHE PATH "Default location where data files are located")
  53     message(STATUS "Using default data directory for base package:  ${FG_DATA_DIR}")
  54 endif()
  55
  56 # Change the default build type to something fast
  57 if(NOT CMAKE_BUILD_TYPE)
  58     set(CMAKE_BUILD_TYPE Release CACHE STRING
  59         "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  60         FORCE)
  61 endif(NOT CMAKE_BUILD_TYPE)
  62
  63 if(NOT "$ENV{BUILD_ID}" STREQUAL "")
  64     set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  65     set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  66     message(STATUS "running under Hudson/Jenkins, build-number is ${HUDSON_BUILD_NUMBER}")
  67 else()
  68     set(HUDSON_BUILD_NUMBER 0)
  69     set(HUDSON_BUILD_ID "none")
  70 endif()
  71
  72 #####################################################################################
  73 # Configure library search paths
  74 #####################################################################################
  75
  76 if(APPLE)
  77     # Custom library directories for Mac, which should have precedence over any other
  78     list(APPEND ADDITIONAL_LIBRARY_PATHS
  79          ~/Library/Frameworks
  80          /Library/Frameworks)
  81 endif(APPLE)
  82
  83 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  84     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  85     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  86     # add paths manually
  87     # see http://www.cmake.org/Bug/view.php?id=12049 and
  88     # http://www.cmake.org/Bug/view.php?id=12037
  89     list(APPEND ADDITIONAL_LIBRARY_PATHS
  90          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  91          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  92          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
  93     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
  94 endif()
  95
  96 if(NOT MSVC)
  97     # TBD: are these really necessary? Aren't they considered by cmake automatically?
  98     list(APPEND ADDITIONAL_LIBRARY_PATHS
  99          /opt/local
 100          /usr/local
 101          /usr)
 102 endif()
 103 #####################################################################################
 104
 105 IF(APPLE)
 106     set(EVENT_INPUT_DEFAULT 1)
 107
 108     find_library(CORESERVICES_LIBRARY CoreServices)
 109     find_library(COCOA_LIBRARY Cocoa)
 110     list(APPEND PLATFORM_LIBS ${COCOA_LIBRARY} ${CORESERVICES_LIBRARY})
 111
 112 elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 113     set(USE_DBUS_DEFAULT 1)
 114     find_package(UDev)
 115
 116     if(UDEV_FOUND)
 117         set(EVENT_INPUT_DEFAULT 1)
 118     endif(UDEV_FOUND)
 119
 120     find_package(Speex)
 121     find_package(Speexdsp)
 122     if(SPEEX_FOUND AND SPEEXDSP_FOUND)
 123         set(SYSTEM_SPEEX_DEFAULT 1)
 124     endif(SPEEX_FOUND AND SPEEXDSP_FOUND)
 125
 126     find_package(Gsm)
 127     if(GSM_FOUND)
 128         set(SYSTEM_GSM_DEFAULT 1)
 129     endif(GSM_FOUND)
 130 endif()
 131
 132 find_package(Git)
 133 if (GIT_FOUND)
 134     execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
 135         OUTPUT_VARIABLE REVISION
 136         OUTPUT_STRIP_TRAILING_WHITESPACE)
 137     message(STATUS "Git revision is ${REVISION}")
 138 else()
 139     set(REVISION "none")
 140 endif()
 141
 142 # FlightGear build options
 143 option(SIMGEAR_SHARED    "Set to ON when SimGear was built as a shared library" OFF)
 144 option(LOGGING           "Set to ON to build FlightGear with logging support (default)" ON)
 145 option(SP_FDMS           "Set to ON to build FlightGear with special-purpose FDMs" OFF)
 146 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" OFF)
 147 option(ENABLE_LARCSIM    "Set to ON to build FlightGear with LaRCsim FDM" OFF)
 148 option(ENABLE_YASIM      "Set to ON to build FlightGear with YASIM FDM (default)" ON)
 149 option(ENABLE_JSBSIM     "Set to ON to build FlightGear with JSBSim FDM (default)" ON)
 150 option(EVENT_INPUT       "Set to ON to build FlightGear with event-based Input support" ${EVENT_INPUT_DEFAULT})
 151 option(ENABLE_RTI        "Set to ON to build FlightGear with RTI support" OFF)
 152 option(ENABLE_PROFILE    "Set to ON to build FlightGear with gperftools profiling support" OFF)
 153 option(JPEG_FACTORY      "Set to ON to build FlightGear with JPEG-factory support" OFF)
 154 option(SYSTEM_SQLITE     "Set to ON to build FlightGear with the system's SQLite3 library" OFF)
 155 option(ENABLE_IAX        "Set to ON to build FlightGear with IAXClient/fgcom built-in (default)" ON)
 156 option(USE_DBUS          "Set to ON to build FlightGear with DBus screensaver interaction (default on Linux)" ${USE_DBUS_DEFAULT})
 157 option(SYSTEM_SPEEX      "Set to ON to build IAXClient with the system's speex and speexdsp library" ${SYSTEM_SPEEX_DEFAULT})
 158 option(SYSTEM_GSM        "Set to ON to build IAXClient with the system's GSM library" ${SYSTEM_GSM_DEFAULT})
 159
 160 # additional utilities
 161 option(ENABLE_FGADMIN    "Set to ON to build the FGADMIN application (default)" ON)
 162 option(ENABLE_FGELEV     "Set to ON to build the fgelev application (default)" ON)
 163 option(WITH_FGPANEL      "Set to ON to build the fgpanel application (default)" ON)
 164 option(ENABLE_FGVIEWER   "Set to ON to build the fgviewer application (default)" ON)
 165 option(ENABLE_GPSSMOOTH  "Set to ON to build the GPSsmooth application (default)" ON)
 166 option(ENABLE_TERRASYNC  "Set to ON to build the terrasync application (default)" ON)
 167 option(ENABLE_FGJS       "Set to ON to build the fgjs application (default)" ON)
 168 option(ENABLE_JS_DEMO    "Set to ON to build the js_demo application (default)" ON)
 169 option(ENABLE_METAR      "Set to ON to build the metar application (default)" ON)
 170 option(ENABLE_TESTS      "Set to ON to build test applications (default)" ON)
 171 option(ENABLE_FGCOM      "Set to ON to build the FGCom application (default)" ON)
 172
 173 if(LOGGING)
 174     # nothing
 175 else()
 176     set(FG_NDEBUG 1)
 177 endif()
 178
 179 if(SP_FDMS)
 180     set(ENABLE_SP_FDM 1)
 181 endif()
 182
 183 if(ENABLE_FGCOM)
 184   set(ENABLE_IAX 1)
 185 endif()
 186
 187 # Setup MSVC 3rd party directories
 188 include( ConfigureMsvc3rdParty )
 189
 190 if(EVENT_INPUT)
 191     if(APPLE)
 192     elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 193         if(NOT UDEV_FOUND)
 194             message(WARNING "UDev not found, event input is disabled!")
 195             set(EVENT_INPUT 0)
 196         else()
 197             add_definitions(-DWITH_EVENTINPUT)
 198             set(EVENT_INPUT_LIBRARIES ${UDEV_LIBRARIES})
 199             message(STATUS "event-based input enabled. Using ${UDEV_LIBRARIES}")
 200         endif()
 201     else()
 202         message(WARNING "event-based input is not supported on this platform yet")
 203     endif()
 204
 205     # Keep PLIB INPUT enabled as long as EventInput does not replace current joystick configurations.
 206     set(ENABLE_PLIB_JOYSTICK 1)
 207 else(EVENT_INPUT)
 208     set(ENABLE_PLIB_JOYSTICK 1)
 209 endif(EVENT_INPUT)
 210
 211 # check required dependencies
 212 find_package(Boost   REQUIRED)
 213 find_package(ZLIB    REQUIRED)
 214 find_package(Threads REQUIRED)
 215 find_package(OpenGL  REQUIRED)
 216 find_package(OpenAL  REQUIRED)
 217 find_package(OpenSceneGraph 3.0.0 REQUIRED osgText osgSim osgDB osgParticle osgFX osgUtil osgViewer osgGA)
 218
 219 if (MSVC)
 220         find_package(CrashRpt)
 221         if (CRASHRPT_FOUND)
 222                 set(HAVE_CRASHRPT 1)
 223                 message(STATUS "Using CrashRpt")
 224         include_directories( ${CRASHRPT_INCLUDE_DIR})
 225         endif()
 226 endif()
 227
 228 if(ENABLE_FGADMIN)
 229     find_package(FLTK)
 230
 231     if ( FLTK_FOUND )
 232         if ( X11_Xinerama_FOUND )
 233             message(STATUS "Found X11_Xinerama...")
 234             list(APPEND FLTK_LIBRARIES ${X11_Xinerama_LIB})
 235         endif()
 236
 237         if ( X11_Xft_FOUND )
 238             message(STATUS "Found X11_Xft...")
 239             list(APPEND FLTK_LIBRARIES ${X11_Xft_LIB})
 240         endif()
 241
 242         if ( CMAKE_DL_LIBS )
 243             list(APPEND FLTK_LIBRARIES ${CMAKE_DL_LIBS})
 244         endif()
 245
 246         message(STATUS "Using FLTK_LIBRARIES for fgadmin: ${FLTK_LIBRARIES}")
 247     endif ( FLTK_FOUND )
 248 endif(ENABLE_FGADMIN)
 249
 250 ##############################################################################
 251 ## Sqlite3 setup
 252
 253 if (SYSTEM_SQLITE)
 254     find_package(SQLite3 REQUIRED)
 255
 256     message(STATUS "Using system SQLite3 library")
 257 else()
 258     set(SQLITE3_INCLUDED_DIR "${CMAKE_SOURCE_DIR}/3rdparty/sqlite3")
 259     # this target is defined in src/Navaids/CMakeLists.txt
 260     list(APPEND SQLITE3_LIBRARY fgsqlite3)
 261 endif (SYSTEM_SQLITE)
 262
 263 # Sqlite always depends on the threading lib
 264 list(APPEND SQLITE3_LIBRARY ${CMAKE_THREAD_LIBS_INIT})
 265
 266 ##############################################################################
 267 ## DBus setup
 268
 269 if (USE_DBUS)
 270     include(FindPkgConfig)
 271     if (PKG_CONFIG_FOUND)
 272         pkg_check_modules(DBUS dbus-1)
 273     endif (PKG_CONFIG_FOUND) #if we don't have pkg-config, assume we don't have libdbus-1-dev either http://packages.debian.org/sid/libdbus-1-dev
 274     if (DBUS_FOUND)
 275         set(HAVE_DBUS 1)
 276         message(STATUS "Using DBus")
 277         include_directories( ${DBUS_INCLUDE_DIRS})
 278     else()
 279         message(STATUS "DBus not found, screensaver control disabled")
 280     endif (DBUS_FOUND)
 281 else()
 282 endif (USE_DBUS)
 283
 284 # Sqlite always depends on the threading lib
 285 list(APPEND SQLITE3_LIBRARY ${CMAKE_THREAD_LIBS_INIT})
 286
 287 ##############################################################################
 288
 289 find_package(PLIB REQUIRED puaux pu js fnt)
 290
 291 # FlightGear and SimGear versions need to match
 292 find_package(SimGear ${FLIGHTGEAR_VERSION} REQUIRED)
 293
 294 ##############################################################################
 295
 296 if (JPEG_FACTORY)
 297     # check simgear was built with JPEG-factory support
 298     find_package(JPEG REQUIRED)
 299     include_directories(${JPEG_INCLUDE_DIR})
 300
 301     set(CMAKE_REQUIRED_INCLUDES
 302         ${SIMGEAR_INCLUDE_DIR}
 303         ${JPEG_INCLUDE_DIR}
 304         ${OPENSCENEGRAPH_INCLUDE_DIRS})
 305
 306     check_cxx_source_compiles(
 307         "#include <simgear/screen/jpgfactory.hxx>
 308         int main()    { return 0; } "
 309         FG_JPEG_SERVER)
 310
 311     if (NOT FG_JPEG_SERVER)
 312         message(STATUS "JPEG server support requested, but SimGear was built without JPEG support")
 313     endif()
 314 endif()
 315
 316 check_include_file(unistd.h   HAVE_UNISTD_H)
 317 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 318 check_include_file(windows.h  HAVE_WINDOWS_H)
 319
 320 if(ENABLE_PROFILE)
 321     find_package(GooglePerfTools REQUIRED)
 322     set(FG_HAVE_GPERFTOOLS 1)
 323     message(STATUS "Built-in profiler using gperftools available")
 324 endif()
 325
 326 if(ENABLE_RTI)
 327     message(STATUS "RTI: ENABLED")
 328     find_package(RTI)
 329     if(RTI_FOUND)
 330         set(FG_HAVE_HLA 1)
 331     endif(RTI_FOUND)
 332 else()
 333     message(STATUS "RTI: DISABLED")
 334 endif(ENABLE_RTI)
 335
 336 if(CMAKE_COMPILER_IS_GNUCXX)
 337     set(WARNING_FLAGS_CXX "-Wall")
 338     set(WARNING_FLAGS_C   "-Wall")
 339 endif(CMAKE_COMPILER_IS_GNUCXX)
 340
 341 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 342    set (WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual")
 343    set (WARNING_FLAGS_C   "-Wall")
 344 endif()
 345
 346 if(WIN32)
 347
 348     if(MSVC)
 349         # turn off various warnings
 350         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 351         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 352         # endforeach(warning)
 353
 354         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS -Dstrdup=_strdup")
 355         if (${MSVC_VERSION} GREATER 1599)
 356             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 357         endif (${MSVC_VERSION} GREATER 1599)
 358     endif(MSVC)
 359
 360     set(NOMINMAX 1)
 361 endif(WIN32)
 362
 363 set (BOOST_CXX_FLAGS "-DBOOST_MULTI_INDEX_DISABLE_SERIALIZATION -DBOOST_BIMAP_DISABLE_SERIALIZATION")
 364
 365 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS} -D_REENTRANT")
 366 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} -D_REENTRANT ${BOOST_CXX_FLAGS}")
 367 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 368
 369 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 370     ${Boost_INCLUDE_DIRS}
 371     ${ZLIB_INCLUDE_DIR}
 372     ${OPENGL_INCLUDE_DIR}
 373     ${OPENAL_INCLUDE_DIR}
 374     ${SIMGEAR_INCLUDE_DIR}
 375     ${PLIB_INCLUDE_DIR}
 376     ${SQLITE3_INCLUDED_DIR} )
 377
 378 include_directories(${PROJECT_SOURCE_DIR})
 379 include_directories(${PROJECT_SOURCE_DIR}/src)
 380 include_directories(${PROJECT_SOURCE_DIR}/3rdparty/iaxclient/lib ) # for iaxclient.h
 381 # following is needed, because config.h is include 'bare', whereas
 382 # version.h is included as <Include/version.h> - this should be cleaned up
 383 include_directories(${PROJECT_BINARY_DIR}/src)
 384 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 385
 386 add_definitions(-DHAVE_CONFIG_H)
 387
 388 check_function_exists(mkfifo HAVE_MKFIFO)
 389
 390 # configure a header file to pass some of the CMake settings
 391 # to the source code
 392 configure_file (
 393     "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 394     "${PROJECT_BINARY_DIR}/src/Include/config.h"
 395 )
 396
 397 #and the same for the version header
 398 configure_file (
 399     "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 400     "${PROJECT_BINARY_DIR}/src/Include/version.h"
 401 )
 402
 403 add_subdirectory(3rdparty)
 404 add_subdirectory(utils)
 405 add_subdirectory(src)
 406 add_subdirectory(man)
 407
 408 #-----------------------------------------------------------------------------
 409 ### uninstall target
 410 #-----------------------------------------------------------------------------
 411 CONFIGURE_FILE(
 412     "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 413     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 414     IMMEDIATE @ONLY)
 415 ADD_CUSTOM_TARGET(uninstall
 416     "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")