CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8.11)
   2
   3 if(COMMAND cmake_policy)
   4    if(POLICY CMP0054)
   5        cmake_policy(SET CMP0054 NEW)
   6    endif()
   7    if(POLICY CMP0042)
   8        cmake_policy(SET CMP0042 NEW)
   9    endif()
  10 endif()
  11
  12 include (CheckFunctionExists)
  13 include (CheckIncludeFile)
  14 include (CheckLibraryExists)
  15 include (CheckCXXSourceCompiles)
  16 include (CheckCXXCompilerFlag)
  17 include (GenerateExportHeader)
  18
  19 # using 10.7 because boost requires libc++ and 10.6 doesn't include it
  20 set(CMAKE_OSX_DEPLOYMENT_TARGET 10.7)
  21
  22 # only relevant for building shared libs but let's set it regardless
  23 set(CMAKE_OSX_RPATH 1)
  24
  25 project(SimGear)
  26
  27 # read 'version' file into a variable (stripping any newlines or spaces)
  28 file(READ version versionFile)
  29 string(STRIP ${versionFile} SIMGEAR_VERSION)
  30
  31 set(FIND_LIBRARY_USE_LIB64_PATHS ON)
  32
  33 # use simgear version also as the SO version (if building SOs)
  34 SET(SIMGEAR_SOVERSION ${SIMGEAR_VERSION})
  35
  36 # Warning when build is not an out-of-source build.
  37 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  38 if(InSourceBuild)
  39     message(WARNING  "Avoid building inside the source tree!")
  40     message(WARNING  "Create a separate build directory instead (i.e. 'sgbuild') and call CMake from there: ")
  41     message(WARNING  "  mkdir ../sgbuild && cd ../sgbuild && cmake ${CMAKE_SOURCE_DIR}")
  42 endif(InSourceBuild)
  43
  44 #packaging
  45 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  46 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  47 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Simulation support libraries for FlightGear and related projects")
  48 SET(CPACK_PACKAGE_VENDOR "The FlightGear project")
  49 SET(CPACK_GENERATOR "TBZ2")
  50 SET(CPACK_INSTALL_CMAKE_PROJECTS  ${CMAKE_CURRENT_BINARY_DIR};SimGear;ALL;/)
  51
  52
  53 # split version string into components, note CMAKE_MATCH_0 is the entire regexp match
  54 string(REGEX MATCH "([0-9]+)\\.([0-9]+)\\.([0-9]+)" CPACK_PACKAGE_VERSION ${SIMGEAR_VERSION} )
  55 set(CPACK_PACKAGE_VERSION_MAJOR ${CMAKE_MATCH_1})
  56 set(CPACK_PACKAGE_VERSION_MINOR ${CMAKE_MATCH_2})
  57 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_3})
  58
  59 message(STATUS "version is ${CPACK_PACKAGE_VERSION_MAJOR} dot ${CPACK_PACKAGE_VERSION_MINOR} dot ${CPACK_PACKAGE_VERSION_PATCH}")
  60
  61 set(CPACK_SOURCE_GENERATOR TBZ2)
  62 set(CPACK_SOURCE_PACKAGE_FILE_NAME "simgear-${SIMGEAR_VERSION}" CACHE INTERNAL "tarball basename")
  63 set(CPACK_SOURCE_IGNORE_FILES
  64   "^${PROJECT_SOURCE_DIR}/.git;\\\\.gitignore;Makefile.am;~$;${CPACK_SOURCE_IGNORE_FILES}")
  65
  66 message(STATUS "ignoring: ${CPACK_SOURCE_IGNORE_FILES}")
  67
  68 include (CPack)
  69
  70 # We have some custom .cmake scripts not in the official distribution.
  71 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  72
  73 # Change the default build type to something fast
  74 if(NOT CMAKE_BUILD_TYPE)
  75   set(CMAKE_BUILD_TYPE Release CACHE STRING
  76       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  77       FORCE)
  78 endif(NOT CMAKE_BUILD_TYPE)
  79
  80 # Determine name of library installation directory, i.e. "lib" vs "lib64", which
  81 # differs between all Debian-based vs all other Linux distros.
  82 # See cmake bug #11964, http://cmake.org/gitweb?p=cmake.git;a=commit;h=126c993d
  83 include(GNUInstallDirs)
  84 message(STATUS "Library installation directory: ${CMAKE_INSTALL_LIBDIR}")
  85
  86 #####################################################################################
  87 # Configure library search paths
  88 #####################################################################################
  89
  90 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  91     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  92     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  93     # add paths manually
  94     # see http://www.cmake.org/Bug/view.php?id=12049 and
  95     # http://www.cmake.org/Bug/view.php?id=12037
  96     list(APPEND ADDITIONAL_LIBRARY_PATHS
  97          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  98          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  99          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
 100     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
 101 endif()
 102
 103 #####################################################################################
 104
 105 if (NOT MSVC)
 106 option(SIMGEAR_SHARED   "Set to ON to build SimGear as a shared library/framework" OFF)
 107 option(SYSTEM_EXPAT     "Set to ON to build SimGear using the system libExpat" OFF)
 108 else()
 109 # Building SimGear DLLs is currently not supported for MSVC.
 110 set(SIMGEAR_SHARED OFF)
 111 # Using a system expat is currently not supported for MSVC - it would require shared simgear (DLL).
 112 set(SYSTEM_EXPAT OFF)
 113 endif()
 114
 115 option(SIMGEAR_HEADLESS "Set to ON to build SimGear without GUI/graphics support" OFF)
 116 option(ENABLE_RTI       "Set to ON to build SimGear with RTI support" OFF)
 117 option(ENABLE_TESTS     "Set to OFF to disable building SimGear's test applications" ON)
 118 option(ENABLE_SOUND     "Set to OFF to disable building SimGear's sound support" ON)
 119 option(ENABLE_PKGUTIL   "Set to ON to build the sg_pkgutil application (default)" ON)
 120 option(ENABLE_CURL      "Set to ON to use libCurl as the HTTP client backend" OFF)
 121
 122 if (MSVC)
 123   GET_FILENAME_COMPONENT(PARENT_DIR ${PROJECT_BINARY_DIR} PATH)
 124   if (CMAKE_CL_64)
 125     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty.x64")
 126   else (CMAKE_CL_64)
 127     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty")
 128   endif (CMAKE_CL_64)
 129   if (EXISTS ${TEST_3RDPARTY_DIR})
 130     set(MSVC_3RDPARTY_ROOT ${PARENT_DIR} CACHE PATH "Location where the third-party dependencies are extracted")
 131   else (EXISTS ${TEST_3RDPARTY_DIR})
 132     set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 133   endif (EXISTS ${TEST_3RDPARTY_DIR})
 134 else (MSVC)
 135   set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 136 endif (MSVC)
 137
 138 if (MSVC AND MSVC_3RDPARTY_ROOT)
 139   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_ROOT}")
 140   set( OSG_MSVC "msvc" )
 141   if (${MSVC_VERSION} EQUAL 1700)
 142       set( OSG_MSVC ${OSG_MSVC}110 )
 143   elseif (${MSVC_VERSION} EQUAL 1600)
 144       set( OSG_MSVC ${OSG_MSVC}100 )
 145   else (${MSVC_VERSION} EQUAL 1700)
 146       set( OSG_MSVC ${OSG_MSVC}90 )
 147   endif (${MSVC_VERSION} EQUAL 1700)
 148   if (CMAKE_CL_64)
 149       set( OSG_MSVC ${OSG_MSVC}-64 )
 150       set( MSVC_3RDPARTY_DIR 3rdParty.x64 )
 151   else (CMAKE_CL_64)
 152       set( MSVC_3RDPARTY_DIR 3rdParty )
 153   endif (CMAKE_CL_64)
 154
 155   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/lib )
 156   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/include)
 157   find_path(BOOST_ROOT boost/version.hpp
 158                         ${MSVC_3RDPARTY_ROOT}/boost
 159                         ${MSVC_3RDPARTY_ROOT}/boost_1_52_0
 160                         ${MSVC_3RDPARTY_ROOT}/boost_1_51_0
 161                         ${MSVC_3RDPARTY_ROOT}/boost_1_50_0
 162                         ${MSVC_3RDPARTY_ROOT}/boost_1_49_0
 163                         ${MSVC_3RDPARTY_ROOT}/boost_1_48_0
 164                         ${MSVC_3RDPARTY_ROOT}/boost_1_47_0
 165                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_1
 166                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_0
 167                         ${MSVC_3RDPARTY_ROOT}/boost_1_45_0
 168                         ${MSVC_3RDPARTY_ROOT}/boost_1_44_0
 169                         )
 170   # set (BOOST_ROOT ${MSVC_3RDPARTY_ROOT}/boost_1_44_0)
 171   message(STATUS "BOOST_ROOT is ${BOOST_ROOT}")
 172   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 173   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib)
 174 endif (MSVC AND MSVC_3RDPARTY_ROOT)
 175
 176 if(APPLE)
 177   find_library(COCOA_LIBRARY Cocoa)
 178
 179 # this should be handled by setting CMAKE_OSX_DEPLOYMENT_TARGET
 180 # but it's not working reliably, so forcing it for now
 181   SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.7")
 182   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.7")
 183 endif()
 184
 185 if(${CMAKE_SYSTEM_NAME} MATCHES "Linux" OR
 186         ${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD")
 187     find_package(Threads REQUIRED)
 188 endif()
 189
 190 # Somehow this only works if included before searching for Boost...
 191 include(BoostTestTargets)
 192
 193 find_package(Boost REQUIRED)
 194 set (BOOST_CXX_FLAGS "-DBOOST_BIMAP_DISABLE_SERIALIZATION")
 195
 196 if(SIMGEAR_HEADLESS)
 197     message(STATUS "SimGear mode: HEADLESS")
 198     set(ENABLE_SOUND 0)
 199 else()
 200     message(STATUS "SimGear mode: NORMAL")
 201     find_package(OpenGL REQUIRED)
 202
 203     if (ENABLE_SOUND)
 204         find_package(OpenAL REQUIRED)
 205         message(STATUS "Sound support: ENABLED")
 206     endif(ENABLE_SOUND)
 207
 208     find_package(OpenSceneGraph 3.2.0 REQUIRED osgText osgSim osgDB osgParticle osgGA osgViewer osgUtil)
 209 endif(SIMGEAR_HEADLESS)
 210
 211 find_package(ZLIB REQUIRED)
 212
 213 if (ENABLE_CURL)
 214   find_package(CURL REQUIRED)
 215   message(STATUS "Curl HTTP client: ENABLED")
 216 endif()
 217
 218 if (SYSTEM_EXPAT)
 219     message(STATUS "Requested to use system Expat library, forcing SIMGEAR_SHARED to true")
 220     set(SIMGEAR_SHARED ON)
 221     find_package(EXPAT REQUIRED)
 222
 223 else()
 224     message(STATUS "Using built-in expat code")
 225     # XML_STATIC is important to avoid sg_expat_external.h
 226     # declaring symbols as declspec(import)
 227     add_definitions(-DHAVE_EXPAT_CONFIG_H -DXML_STATIC)
 228     set(EXPAT_INCLUDE_DIRS
 229             ${PROJECT_SOURCE_DIR}/3rdparty/expat
 230             ${PROJECT_BINARY_DIR}/3rdparty/expat)
 231 endif(SYSTEM_EXPAT)
 232
 233 include_directories(${EXPAT_INCLUDE_DIRS})
 234
 235 check_include_file(inttypes.h HAVE_INTTYPES_H)
 236 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 237 check_include_file(sys/timeb.h HAVE_SYS_TIMEB_H)
 238 check_include_file(unistd.h HAVE_UNISTD_H)
 239 check_include_file(windows.h HAVE_WINDOWS_H)
 240
 241 if(HAVE_INTTYPES_H)
 242   # ShivaVG needs inttypes.h
 243   add_definitions(-DHAVE_INTTYPES_H)
 244 endif()
 245
 246 if(ENABLE_RTI)
 247     # See if we have any rti library variant installed
 248     message(STATUS "RTI: ENABLED")
 249     find_package(RTI)
 250 else()
 251     message(STATUS "RTI: DISABLED")
 252 endif(ENABLE_RTI)
 253
 254 check_function_exists(gettimeofday HAVE_GETTIMEOFDAY)
 255 check_function_exists(ftime HAVE_FTIME)
 256 check_function_exists(timegm HAVE_TIMEGM)
 257 check_function_exists(rint HAVE_RINT)
 258 check_function_exists(mkdtemp HAVE_MKDTEMP)
 259 check_function_exists(bcopy HAVE_BCOPY)
 260 check_function_exists(mmap HAVE_MMAP)
 261
 262 if(HAVE_UNISTD_H)
 263     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 264     check_cxx_source_compiles(
 265        "#include <unistd.h>
 266         #if !defined(_POSIX_TIMERS) || (0 >= _POSIX_TIMERS)
 267             #error clock_gettime is not supported
 268         #endif
 269
 270         int main() { return 0; }
 271         "
 272         HAVE_CLOCK_GETTIME)
 273 endif(HAVE_UNISTD_H)
 274
 275 set(RT_LIBRARY "")
 276 if(HAVE_CLOCK_GETTIME)
 277     check_library_exists(rt clock_gettime "" HAVE_RT)
 278     if(HAVE_RT)
 279         set(RT_LIBRARY rt)
 280     endif(HAVE_RT)
 281 endif(HAVE_CLOCK_GETTIME)
 282
 283 set(DL_LIBRARY "")
 284 check_cxx_source_compiles(
 285     "#include <dlfcn.h>
 286     int main(void) {
 287         return 0;
 288     }
 289     "
 290     HAVE_DLFCN_H)
 291
 292 if(HAVE_DLFCN_H)
 293     check_library_exists(dl dlerror "" HAVE_DL)
 294     if(HAVE_DL)
 295         set(DL_LIBRARY "dl")
 296     endif()
 297 endif()
 298
 299 SET(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "add a postfix, usually 'd' on windows")
 300 SET(CMAKE_RELEASE_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 301 SET(CMAKE_RELWITHDEBINFO_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 302 SET(CMAKE_MINSIZEREL_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 303
 304 # isnan might not be real symbol, so can't check using function_exists
 305 check_cxx_source_compiles(
 306     "#include <cmath>
 307     int main() { return isnan(0.0);} "
 308     HAVE_ISNAN)
 309
 310 check_cxx_source_compiles(
 311     "#include <cmath>
 312     int main() { return std::isnan(0.0);} "
 313     HAVE_STD_ISNAN)
 314
 315 if(CMAKE_COMPILER_IS_GNUCXX)
 316     set(WARNING_FLAGS_CXX "-Wall")
 317     set(WARNING_FLAGS_C   "-Wall")
 318
 319     # certain GCC versions don't provide the atomic builds, and hence
 320     # require is to provide them in SGAtomic.cxx
 321     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 322     check_cxx_source_compiles(
 323        "int main() { unsigned mValue; return __sync_add_and_fetch(&mValue, 1); }"
 324         GCC_ATOMIC_BUILTINS_FOUND)
 325 endif(CMAKE_COMPILER_IS_GNUCXX)
 326
 327 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 328     # Boost redeclares class members
 329     set(WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual -Wno-redeclared-class-member")
 330     set(WARNING_FLAGS_C   "-Wall")
 331     set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LIBRARY "libc++")
 332     set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LANGUAGE_STANDARD "c++11")
 333     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -stdlib=libc++")
 334 endif()
 335
 336 if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 337 # boost goes haywire wrt static asserts
 338     check_cxx_compiler_flag(-Wno-unused-local-typedefs HAS_NOWARN_UNUSED_TYPEDEFS)
 339     if(HAS_NOWARN_UNUSED_TYPEDEFS)
 340         set(WARNING_FLAGS_CXX " ${WARNING_FLAGS_CXX} -Wno-unused-local-typedefs")
 341     endif()
 342 endif()
 343
 344 if(WIN32)
 345
 346     if(MINGW)
 347         add_definitions(-D_WIN32_WINNT=0x501)
 348     endif()
 349
 350     if(MSVC)
 351         # turn off various warnings
 352         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 353         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 354         # endforeach(warning)
 355
 356         set(MSVC_FLAGS "-DWIN32 -DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS /wd4996 /wd4250 -Dstrdup=_strdup")
 357         if (${MSVC_VERSION} GREATER 1599)
 358             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 359         endif (${MSVC_VERSION} GREATER 1599)
 360     endif(MSVC)
 361
 362     # assumed on Windows
 363     set(HAVE_GETLOCALTIME 1)
 364
 365     set( WINSOCK_LIBRARY "ws2_32.lib" )
 366     set( RT_LIBRARY "winmm" )
 367 endif(WIN32)
 368
 369 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS}")
 370 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} ${BOOST_CXX_FLAGS}")
 371 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 372
 373 # use BEFORE to ensure local directories are used first,
 374 # ahead of system-installed libs
 375 include_directories(BEFORE ${PROJECT_SOURCE_DIR})
 376 include_directories(BEFORE ${PROJECT_SOURCE_DIR}/simgear/canvas/ShivaVG/include)
 377 include_directories(BEFORE ${PROJECT_BINARY_DIR}/simgear)
 378
 379 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 380     ${Boost_INCLUDE_DIRS}
 381     ${ZLIB_INCLUDE_DIR}
 382     ${OPENAL_INCLUDE_DIR}
 383     ${CURL_INCLUDE_DIRS}
 384 )
 385
 386 add_definitions(-DHAVE_CONFIG_H)
 387
 388 # configure a header file to pass some of the CMake settings
 389 # to the source code
 390 configure_file (
 391   "${PROJECT_SOURCE_DIR}/simgear/simgear_config_cmake.h.in"
 392   "${PROJECT_BINARY_DIR}/simgear/simgear_config.h"
 393   )
 394
 395 if(ENABLE_TESTS)
 396     # enable CTest / make test target
 397     message(STATUS "Tests: ENABLED")
 398
 399     include (Dart)
 400     enable_testing()
 401 else()
 402     message(STATUS "Tests: DISABLED")
 403 endif(ENABLE_TESTS)
 404
 405 # always set TEST_LIBS as it is also used by other tools/applications
 406 set(TEST_LIBS_INTERNAL_CORE
 407     ${CMAKE_THREAD_LIBS_INIT}
 408     ${ZLIB_LIBRARY}
 409     ${WINSOCK_LIBRARY}
 410     ${RT_LIBRARY}
 411     ${DL_LIBRARY}
 412     ${COCOA_LIBRARY}
 413     ${CURL_LIBRARIES})
 414 set(TEST_LIBS SimGearCore ${TEST_LIBS_INTERNAL_CORE})
 415
 416 if(NOT SIMGEAR_HEADLESS)
 417     set(TEST_LIBS SimGearScene ${OPENGL_LIBRARIES} ${TEST_LIBS})
 418 endif()
 419
 420 install (FILES ${PROJECT_BINARY_DIR}/simgear/simgear_config.h  DESTINATION include/simgear/)
 421
 422 include_directories(3rdparty/utf8/source)
 423
 424 add_subdirectory(3rdparty)
 425 add_subdirectory(simgear)
 426
 427 #-----------------------------------------------------------------------------
 428 ### Export stuff, see https://cmake.org/cmake/help/v3.2/manual/cmake-packages.7.html#creating-packages
 429 #-----------------------------------------------------------------------------
 430
 431 generate_export_header(SimGearCore)
 432 if(NOT SIMGEAR_HEADLESS)
 433   generate_export_header(SimGearScene)
 434 endif()
 435
 436 include(CMakePackageConfigHelpers)
 437
 438 write_basic_package_version_file(
 439   "${CMAKE_CURRENT_BINARY_DIR}/SimGear/SimGearConfigVersion.cmake"
 440   VERSION ${SIMGEAR_VERSION}
 441   COMPATIBILITY AnyNewerVersion
 442 )
 443
 444 configure_file(SimGearConfig.cmake.in
 445   "${CMAKE_CURRENT_BINARY_DIR}/SimGear/SimGearConfig.cmake"
 446   @ONLY
 447 )
 448
 449 set(ConfigPackageLocation lib/cmake/SimGear)
 450 install(EXPORT SimGearTargets
 451   DESTINATION ${ConfigPackageLocation}
 452 )
 453 install(
 454   FILES
 455     "${CMAKE_CURRENT_BINARY_DIR}/SimGear/SimGearConfig.cmake"
 456     "${CMAKE_CURRENT_BINARY_DIR}/SimGear/SimGearConfigVersion.cmake"
 457   DESTINATION ${ConfigPackageLocation}
 458   COMPONENT Devel
 459 )
 460
 461 #-----------------------------------------------------------------------------
 462 ### uninstall target
 463 #-----------------------------------------------------------------------------
 464 CONFIGURE_FILE(
 465   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 466   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 467   IMMEDIATE @ONLY)
 468 ADD_CUSTOM_TARGET(uninstall
 469   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")