CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6)
   2 include (CheckFunctionExists)
   3 include (CheckIncludeFile)
   4 include (CheckCXXSourceCompiles)
   5 include (CPack)
   6
   7 project(SimGear)
   8
   9 # read 'version' file into a variable (stripping any newlines or spaces)
  10 file(READ version versionFile)
  11 string(STRIP ${versionFile} SIMGEAR_VERSION)
  12
  13 #packaging
  14 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  15 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  16
  17 # We have some custom .cmake scripts not in the official distribution.
  18 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  19
  20 option(SIMGEAR_SHARED "Set to ON to build SimGear as a shared library/framework" OFF)
  21 option(SIMGEAR_HEADLESS "Set to ON to build SimGear with GUI/graphics support" OFF)
  22 option(JPEG_FACTORY "Enable JPEG-factory support" OFF)
  23 option(ENABLE_LIBSVN "Set to ON to build SimGear with libsvnclient support" ON)
  24
  25 set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
  26
  27 if (MSVC AND MSVC_3RDPARTY_ROOT)
  28   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_ROOT}")
  29   set( OSG_MSVC "msvc" )
  30   if (${MSVC_VERSION} EQUAL 1600)
  31       set( OSG_MSVC ${OSG_MSVC}100 )
  32   else (${MSVC_VERSION} EQUAL 1600)
  33       set( OSG_MSVC ${OSG_MSVC}90 )
  34   endif (${MSVC_VERSION} EQUAL 1600)
  35   if (CMAKE_CL_64)
  36       set( OSG_MSVC ${OSG_MSVC}-64 )
  37       set( MSVC_3RDPARTY_DIR 3rdParty.x64 )
  38   else (CMAKE_CL_64)
  39       set( MSVC_3RDPARTY_DIR 3rdParty )
  40   endif (CMAKE_CL_64)
  41
  42   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/lib )
  43   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/include)
  44   set (BOOST_ROOT ${MSVC_3RDPARTY_ROOT}/boost_1_44_0)
  45   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
  46   set (ALUT_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
  47   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib)
  48 endif (MSVC AND MSVC_3RDPARTY_ROOT)
  49
  50 find_package(Boost REQUIRED)
  51 set (BOOST_CXX_FLAGS "-DBOOST_MULTI_INDEX_DISABLE_SERIALIZATION -DBOOST_BIMAP_DISABLE_SERIALIZATION")
  52
  53 find_package(ZLIB REQUIRED)
  54 find_package(Threads REQUIRED)
  55
  56 if (${SIMGEAR_HEADLESS})
  57     message(STATUS "headlesss mode")
  58     set(NO_OPENSCENEGRAPH_INTERFACE 1)
  59 else()
  60     find_package(OpenGL REQUIRED)
  61     find_package(OpenAL REQUIRED)
  62     find_package(ALUT REQUIRED)
  63     find_package(OpenSceneGraph 2.8.1 REQUIRED osgText osgSim osgDB osgParticle osgUtil)
  64 endif()
  65
  66 if(JPEG_FACTORY)
  67     message(STATUS "JPEG-factory enabled")
  68     find_package(JPEG REQUIRED)
  69     include_directories(${JPEG_INCLUDE_DIR})
  70 endif()
  71
  72 if(ENABLE_LIBSVN)
  73         find_package(SvnClient)
  74
  75         if(LIBSVN_FOUND)
  76                 message(STATUS "libsvn found, enabling in SimGear")
  77                 set(HAVE_SVN_CLIENT_H 1)
  78                 set(HAVE_LIBSVN_CLIENT_1 1)
  79         else()
  80                 message(STATUS "Missing libsvn, unable to enable SVN in SimGear")
  81         endif(LIBSVN_FOUND)
  82 endif(ENABLE_LIBSVN)
  83
  84 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  85 check_include_file(sys/timeb.h HAVE_SYS_TIMEB_H)
  86 check_include_file(unistd.h HAVE_UNISTD_H)
  87 check_include_file(windows.h HAVE_WINDOWS_H)
  88
  89 # See if we have any rti library variant installed
  90 find_package(RTI)
  91
  92 check_function_exists(gettimeofday HAVE_GETTIMEOFDAY)
  93 check_function_exists(ftime HAVE_FTIME)
  94 check_function_exists(timegm HAVE_TIMEGM)
  95 check_function_exists(rint HAVE_RINT)
  96
  97
  98 if(HAVE_UNISTD_H)
  99     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 100     check_cxx_source_compiles(
 101        "#include <unistd.h>
 102         #if !defined(_POSIX_TIMERS) || (0 >= _POSIX_TIMERS)
 103             #error clock_gettime is not supported
 104         #endif
 105
 106         int main() { return 0; }
 107         "
 108         HAVE_CLOCK_GETTIME)
 109 endif(HAVE_UNISTD_H)
 110
 111 set(RT_LIBRARY "")
 112 if(HAVE_CLOCK_GETTIME)
 113     check_function_exists(clock_gettime CLOCK_GETTIME_IN_LIBC)
 114     if(NOT CLOCK_GETTIME_IN_LIBC)
 115         check_library_exists(rt clock_gettime "" HAVE_RT)
 116         if(HAVE_RT)
 117             set(RT_LIBRARY rt)
 118         endif(HAVE_RT)
 119         endif(NOT CLOCK_GETTIME_IN_LIBC)
 120 endif(HAVE_CLOCK_GETTIME)
 121
 122 SET(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "add a postfix, usually d on windows")
 123 SET(CMAKE_RELEASE_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 124 SET(CMAKE_RELWITHDEBINFO_POSTFIX "rd" CACHE STRING "add a postfix, usually empty on windows")
 125 SET(CMAKE_MINSIZEREL_POSTFIX "s" CACHE STRING "add a postfix, usually empty on windows")
 126
 127 # isnan might not be real symbol, so can't check using function_exists
 128 check_cxx_source_compiles(
 129     "#include <cmath>
 130     void f() { isnan(0.0);} "
 131     HAVE_ISNAN)
 132
 133 if(CMAKE_COMPILER_IS_GNUCXX)
 134     set(WARNING_FLAGS -Wall)
 135 endif(CMAKE_COMPILER_IS_GNUCXX)
 136
 137 if(WIN32)
 138
 139     if(MSVC)
 140         # turn off various warnings
 141         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 142         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 143         # endforeach(warning)
 144
 145         set(MSVC_FLAGS "-DWIN32 -DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS")
 146     endif(MSVC)
 147
 148     # assumed on Windows
 149     set(HAVE_GETLOCALTIME 1)
 150 endif(WIN32)
 151
 152 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS}")
 153 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS} ${BOOST_CXX_FLAGS}")
 154
 155 include_directories(${PROJECT_SOURCE_DIR})
 156 include_directories(${PROJECT_BINARY_DIR}/simgear)
 157
 158 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 159     ${Boost_INCLUDE_DIRS} ${ZLIB_INCLUDE_DIR}
 160     ${ALUT_INCLUDE_DIR} ${OPENAL_INCLUDE_DIR} )
 161
 162
 163 add_definitions(-DHAVE_CONFIG_H)
 164
 165 # configure a header file to pass some of the CMake settings
 166 # to the source code
 167 configure_file (
 168   "${PROJECT_SOURCE_DIR}/simgear/simgear_config_cmake.h.in"
 169   "${PROJECT_BINARY_DIR}/simgear/simgear_config.h"
 170   )
 171
 172 # enable CTest / make test target
 173
 174 include (Dart)
 175 enable_testing()
 176
 177 install (FILES ${PROJECT_BINARY_DIR}/simgear/simgear_config.h  DESTINATION include/simgear/)
 178 add_subdirectory(simgear)
 179
 180 #-----------------------------------------------------------------------------
 181 ### uninstall target
 182 #-----------------------------------------------------------------------------
 183 CONFIGURE_FILE(
 184   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 185   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 186   IMMEDIATE @ONLY)
 187 ADD_CUSTOM_TARGET(uninstall
 188   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
 189
 190
 191