CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7 include (CPack)
   8
   9 project(FlightGear)
  10
  11 # read 'version' file into a variable (stripping any newlines or spaces)
  12 file(READ version versionFile)
  13 string(STRIP ${versionFile} FLIGHTGEAR_VERSION)
  14
  15 #packaging
  16 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  17 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  18
  19 # We have some custom .cmake scripts not in the official distribution.
  20 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  21
  22 # autoconf compatibility
  23 set(PKGLIBDIR "foo")
  24
  25 if($ENV{BUILD_ID})
  26         set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  27         set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  28         message(STATUS "running under Hudson, build-number is ${HUDSON_BUILD_NUMBER}")
  29 else()
  30         set(HUDSON_BUILD_NUMBER 0)
  31         set(HUDSON_BUILD_ID "none")
  32 endif()
  33
  34 find_package(Git)
  35 if (GIT_FOUND)
  36         execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
  37                 OUTPUT_VARIABLE REVISION
  38                 OUTPUT_STRIP_TRAILING_WHITESPACE)
  39         message(STATUS "Git revision is ${REVISION}")
  40 else()
  41         set(REVISION "none")
  42 endif()
  43
  44 option(LOGGING "Set to OFF to build FlightGear without logging" ON)
  45
  46 option(SP_FDMS "Set to ON to build FlightGear with special-purpose FDMs" OFF)
  47 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" ON)
  48 option(ENABLE_LARCSIM "Set to ON to build FlightGear with LaRCsim FDM" ON)
  49 option(ENABLE_YASIM "Set to ON to build FlightGear with YASIM FDM" ON)
  50 option(ENABLE_JSBSIM "Set to ON to build FlightGear with JSBSim FDM" ON)
  51 option(EVENT_INPUT "Set to ON to build FlightGear with event-based Input support" OFF)
  52 set(MSVC_3RDPARTY_DIR NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
  53
  54 if(LOGGING)
  55         # nothing
  56 else()
  57         set(FG_NDEBUG 1)
  58 endif()
  59
  60 if(${SP_FDMS})
  61         set(ENABLE_SP_FDM 1)
  62 endif()
  63
  64 if(EVENT_INPUT)
  65         message(STATUS "checking event-based Input")
  66         IF(APPLE)
  67
  68         elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
  69
  70         else()
  71                 message(WARNING "event input is not supported on this platform yet")
  72         endif()
  73 else(EVENT_INPUT)
  74         set(ENABLE_PLIB_JOYSTICK 1)
  75 endif(EVENT_INPUT)
  76
  77 if (MSVC_3RDPARTY_DIR)
  78   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_DIR}")
  79   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_DIR}/3rdParty/lib ${MSVC_3RDPARTY_DIR}/install/msvc90/OpenScenegraph/lib ${MSVC_3RDPARTY_DIR}/install/msvc90/SimGear/lib )
  80   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_DIR}/3rdParty/include ${MSVC_3RDPARTY_DIR}/install/msvc90/OpenScenegraph/include ${MSVC_3RDPARTY_DIR}/install/msvc90/SimGear/include)
  81   set (BOOST_ROOT ${MSVC_3RDPARTY_DIR}/boost_1_44_0)
  82   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_DIR}/3rdParty/include)
  83   set (ALUT_INCLUDE_DIR ${MSVC_3RDPARTY_DIR}/3rdParty/include)
  84   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_DIR}/3rdParty/lib)
  85 endif (MSVC_3RDPARTY_DIR)
  86
  87
  88 # check required dependencies
  89 find_package(Boost REQUIRED)
  90 find_package(ZLIB REQUIRED)
  91 find_package(Threads REQUIRED)
  92 find_package(OpenGL REQUIRED)
  93 find_package(OpenAL REQUIRED)
  94 find_package(ALUT REQUIRED)
  95 find_package(OpenSceneGraph 2.8.2 REQUIRED osgText osgSim osgDB osgParticle osgFX osgUtil osgViewer osgGA)
  96
  97 find_package(PLIB REQUIRED puaux pu js fnt)
  98 find_package(SimGear 2.0.0 REQUIRED)
  99
 100 check_include_file(unistd.h HAVE_UNISTD_H)
 101 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 102 check_include_file(windows.h HAVE_WINDOWS_H)
 103
 104 # definition depends on OSG version
 105 set(CMAKE_REQUIRED_INCLUDES ${OPENSCENEGRAPH_INCLUDE_DIRS})
 106
 107 check_cxx_source_compiles(
 108     "#include <osg/CullSettings>
 109     int main()
 110     {
 111        osg::CullSettings::VariablesMask mask = osg::CullSettings::CLEAR_MASK;
 112        return 0;
 113     }
 114     "
 115     HAVE_CULLSETTINGS_CLEAR_MASK)
 116
 117 # library required by simgear
 118 # XXX This should go in a module and only run if simgear is not shared.
 119
 120 if(HAVE_UNISTD_H)
 121 set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 122 check_cxx_source_compiles(
 123    "#include <unistd.h>
 124     #if !defined(_POSIX_TIMERS) || (0 >= _POSIX_TIMERS)
 125     #error clock_gettime is not supported
 126     #endif
 127
 128     int main() { return 0; }
 129     "
 130     HAVE_CLOCK_GETTIME)
 131 endif(HAVE_UNISTD_H)
 132
 133 set(RT_LIBRARY "")
 134 if(HAVE_CLOCK_GETTIME)
 135 check_function_exists(clock_gettime CLOCK_GETTIME_IN_LIBC)
 136 if(NOT CLOCK_GETTIME_IN_LIBC)
 137 check_library_exists(rt clock_gettime "" HAVE_RT)
 138 if(HAVE_RT)
 139 set(RT_LIBRARY rt)
 140 endif(HAVE_RT)
 141 endif(NOT CLOCK_GETTIME_IN_LIBC)
 142 endif(HAVE_CLOCK_GETTIME)
 143
 144 if(CMAKE_COMPILER_IS_GNUCXX)
 145     set(WARNING_FLAGS -Wall)
 146 endif(CMAKE_COMPILER_IS_GNUCXX)
 147
 148 if(WIN32)
 149
 150     if(MSVC)
 151         # turn off various warnings
 152         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 153         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 154         # endforeach(warning)
 155
 156         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS")
 157     endif(MSVC)
 158
 159     set(NOMINMAX 1)
 160 endif(WIN32)
 161
 162 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS} -D_REENTRANT")
 163 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS} -D_REENTRANT")
 164
 165 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 166     ${Boost_INCLUDE_DIRS}
 167         ${ZLIB_INCLUDE_DIR}
 168     ${ALUT_INCLUDE_DIR}
 169         ${OPENAL_INCLUDE_DIR}
 170         ${SIMGEAR_INCLUDE_DIR}
 171         ${PLIB_INCLUDE_DIR} )
 172
 173 include_directories(${PROJECT_SOURCE_DIR}/src)
 174
 175 # following is needed, because config.h is include 'bare', whereas
 176 # version.h is included as <Include/version.h> - this should be cleaned up
 177 include_directories(${PROJECT_BINARY_DIR}/src)
 178 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 179
 180 add_definitions(-DHAVE_CONFIG_H)
 181
 182 # configure a header file to pass some of the CMake settings
 183 # to the source code
 184 configure_file (
 185   "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 186   "${PROJECT_BINARY_DIR}/src/Include/config.h"
 187   )
 188
 189 #and the same for the version header
 190 configure_file (
 191   "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 192   "${PROJECT_BINARY_DIR}/src/Include/version.h"
 193   )
 194
 195 add_subdirectory(src)
 196 add_subdirectory(utils)
 197
 198 #-----------------------------------------------------------------------------
 199 ### uninstall target
 200 #-----------------------------------------------------------------------------
 201 CONFIGURE_FILE(
 202   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 203   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 204   IMMEDIATE @ONLY)
 205 ADD_CUSTOM_TARGET(uninstall
 206   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
 207