CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2
   3 if(COMMAND cmake_policy)
   4    if(POLICY CMP0054)
   5        cmake_policy(SET CMP0054 NEW)
   6    endif()
   7    if(POLICY CMP0042)
   8        cmake_policy(SET CMP0042 NEW)
   9    endif()
  10 endif()
  11
  12 include (CheckFunctionExists)
  13 include (CheckIncludeFile)
  14 include (CheckCXXSourceCompiles)
  15 include (CheckCXXCompilerFlag)
  16
  17 project(SimGear)
  18
  19 # read 'version' file into a variable (stripping any newlines or spaces)
  20 file(READ version versionFile)
  21 string(STRIP ${versionFile} SIMGEAR_VERSION)
  22
  23 set(FIND_LIBRARY_USE_LIB64_PATHS ON)
  24
  25 # use simgear version also as the SO version (if building SOs)
  26 SET(SIMGEAR_SOVERSION ${SIMGEAR_VERSION})
  27
  28 # Warning when build is not an out-of-source build.
  29 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  30 if(InSourceBuild)
  31     message(WARNING  "Avoid building inside the source tree!")
  32     message(WARNING  "Create a separate build directory instead (i.e. 'sgbuild') and call CMake from there: ")
  33     message(WARNING  "  mkdir ../sgbuild && cd ../sgbuild && cmake ${CMAKE_SOURCE_DIR}")
  34 endif(InSourceBuild)
  35
  36 #packaging
  37 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  38 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  39 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Simulation support libraries for FlightGear and related projects")
  40 SET(CPACK_PACKAGE_VENDOR "The FlightGear project")
  41 SET(CPACK_GENERATOR "TBZ2")
  42 SET(CPACK_INSTALL_CMAKE_PROJECTS  ${CMAKE_CURRENT_BINARY_DIR};SimGear;ALL;/)
  43
  44
  45 # split version string into components, note CMAKE_MATCH_0 is the entire regexp match
  46 string(REGEX MATCH "([0-9]+)\\.([0-9]+)\\.([0-9]+)" CPACK_PACKAGE_VERSION ${SIMGEAR_VERSION} )
  47 set(CPACK_PACKAGE_VERSION_MAJOR ${CMAKE_MATCH_1})
  48 set(CPACK_PACKAGE_VERSION_MINOR ${CMAKE_MATCH_2})
  49 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_3})
  50
  51 message(STATUS "version is ${CPACK_PACKAGE_VERSION_MAJOR} dot ${CPACK_PACKAGE_VERSION_MINOR} dot ${CPACK_PACKAGE_VERSION_PATCH}")
  52
  53 set(CPACK_SOURCE_GENERATOR TBZ2)
  54 set(CPACK_SOURCE_PACKAGE_FILE_NAME "simgear-${SIMGEAR_VERSION}" CACHE INTERNAL "tarball basename")
  55 set(CPACK_SOURCE_IGNORE_FILES
  56   "^${PROJECT_SOURCE_DIR}/.git;\\\\.gitignore;Makefile.am;~$;${CPACK_SOURCE_IGNORE_FILES}")
  57
  58 message(STATUS "ignoring: ${CPACK_SOURCE_IGNORE_FILES}")
  59
  60 include (CPack)
  61
  62 # We have some custom .cmake scripts not in the official distribution.
  63 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  64
  65 # Change the default build type to something fast
  66 if(NOT CMAKE_BUILD_TYPE)
  67   set(CMAKE_BUILD_TYPE Release CACHE STRING
  68       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  69       FORCE)
  70 endif(NOT CMAKE_BUILD_TYPE)
  71
  72 # Determine name of library installation directory, i.e. "lib" vs "lib64", which
  73 # differs between all Debian-based vs all other Linux distros.
  74 # See cmake bug #11964, http://cmake.org/gitweb?p=cmake.git;a=commit;h=126c993d
  75 # GNUInstallDirs requires CMake >= 2.8.5, use own file for older cmake
  76 if(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  77   include(GNUInstallDirs)
  78 else(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  79   include(OldGNUInstallDirs)
  80 endif(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  81 message(STATUS "Library installation directory: ${CMAKE_INSTALL_LIBDIR}")
  82
  83 #####################################################################################
  84 # Configure library search paths
  85 #####################################################################################
  86
  87 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  88     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  89     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  90     # add paths manually
  91     # see http://www.cmake.org/Bug/view.php?id=12049 and
  92     # http://www.cmake.org/Bug/view.php?id=12037
  93     list(APPEND ADDITIONAL_LIBRARY_PATHS
  94          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  95          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  96          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
  97     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
  98 endif()
  99
 100 #####################################################################################
 101
 102 if (NOT MSVC)
 103 option(SIMGEAR_SHARED   "Set to ON to build SimGear as a shared library/framework" OFF)
 104 option(SYSTEM_EXPAT     "Set to ON to build SimGear using the system libExpat" OFF)
 105 else()
 106 # Building SimGear DLLs is currently not supported for MSVC.
 107 set(SIMGEAR_SHARED OFF)
 108 # Using a system expat is currently not supported for MSVC - it would require shared simgear (DLL).
 109 set(SYSTEM_EXPAT OFF)
 110 endif()
 111
 112 option(SIMGEAR_HEADLESS "Set to ON to build SimGear without GUI/graphics support" OFF)
 113 option(ENABLE_RTI       "Set to ON to build SimGear with RTI support" OFF)
 114 option(ENABLE_TESTS     "Set to OFF to disable building SimGear's test applications" ON)
 115 option(ENABLE_SOUND     "Set to OFF to disable building SimGear's sound support" ON)
 116 option(ENABLE_PKGUTIL   "Set to ON to build the sg_pkgutil application (default)" ON)
 117
 118 if (MSVC)
 119   GET_FILENAME_COMPONENT(PARENT_DIR ${PROJECT_BINARY_DIR} PATH)
 120   if (CMAKE_CL_64)
 121     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty.x64")
 122   else (CMAKE_CL_64)
 123     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty")
 124   endif (CMAKE_CL_64)
 125   if (EXISTS ${TEST_3RDPARTY_DIR})
 126     set(MSVC_3RDPARTY_ROOT ${PARENT_DIR} CACHE PATH "Location where the third-party dependencies are extracted")
 127   else (EXISTS ${TEST_3RDPARTY_DIR})
 128     set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 129   endif (EXISTS ${TEST_3RDPARTY_DIR})
 130 else (MSVC)
 131   set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 132 endif (MSVC)
 133
 134 if (MSVC AND MSVC_3RDPARTY_ROOT)
 135   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_ROOT}")
 136   set( OSG_MSVC "msvc" )
 137   if (${MSVC_VERSION} EQUAL 1700)
 138       set( OSG_MSVC ${OSG_MSVC}110 )
 139   elseif (${MSVC_VERSION} EQUAL 1600)
 140       set( OSG_MSVC ${OSG_MSVC}100 )
 141   else (${MSVC_VERSION} EQUAL 1700)
 142       set( OSG_MSVC ${OSG_MSVC}90 )
 143   endif (${MSVC_VERSION} EQUAL 1700)
 144   if (CMAKE_CL_64)
 145       set( OSG_MSVC ${OSG_MSVC}-64 )
 146       set( MSVC_3RDPARTY_DIR 3rdParty.x64 )
 147   else (CMAKE_CL_64)
 148       set( MSVC_3RDPARTY_DIR 3rdParty )
 149   endif (CMAKE_CL_64)
 150
 151   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/lib )
 152   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/include)
 153   find_path(BOOST_ROOT boost/version.hpp
 154                         ${MSVC_3RDPARTY_ROOT}/boost
 155                         ${MSVC_3RDPARTY_ROOT}/boost_1_52_0
 156                         ${MSVC_3RDPARTY_ROOT}/boost_1_51_0
 157                         ${MSVC_3RDPARTY_ROOT}/boost_1_50_0
 158                         ${MSVC_3RDPARTY_ROOT}/boost_1_49_0
 159                         ${MSVC_3RDPARTY_ROOT}/boost_1_48_0
 160                         ${MSVC_3RDPARTY_ROOT}/boost_1_47_0
 161                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_1
 162                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_0
 163                         ${MSVC_3RDPARTY_ROOT}/boost_1_45_0
 164                         ${MSVC_3RDPARTY_ROOT}/boost_1_44_0
 165                         )
 166   # set (BOOST_ROOT ${MSVC_3RDPARTY_ROOT}/boost_1_44_0)
 167   message(STATUS "BOOST_ROOT is ${BOOST_ROOT}")
 168   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 169   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib)
 170 endif (MSVC AND MSVC_3RDPARTY_ROOT)
 171
 172 if(APPLE)
 173   find_library(COCOA_LIBRARY Cocoa)
 174
 175   # using 10.7 because boost requires libc++ and 10.6 doesn't include it
 176   SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.7")
 177 endif()
 178
 179 # Somehow this only works if included before searching for Boost...
 180 include(BoostTestTargets)
 181
 182 find_package(Boost REQUIRED)
 183 set (BOOST_CXX_FLAGS "-DBOOST_BIMAP_DISABLE_SERIALIZATION")
 184
 185 if(SIMGEAR_HEADLESS)
 186     message(STATUS "SimGear mode: HEADLESS")
 187     set(ENABLE_SOUND 0)
 188 else()
 189     message(STATUS "SimGear mode: NORMAL")
 190     find_package(OpenGL REQUIRED)
 191
 192     if (ENABLE_SOUND)
 193         find_package(OpenAL REQUIRED)
 194         message(STATUS "Sound support: ENABLED")
 195     endif(ENABLE_SOUND)
 196
 197     find_package(OpenSceneGraph 3.2.0 REQUIRED osgText osgSim osgDB osgParticle osgGA osgViewer osgUtil)
 198 endif(SIMGEAR_HEADLESS)
 199
 200 find_package(ZLIB REQUIRED)
 201 find_package(Threads REQUIRED)
 202
 203 if (SYSTEM_EXPAT)
 204     message(STATUS "Requested to use system Expat library, forcing SIMGEAR_SHARED to true")
 205     set(SIMGEAR_SHARED ON)
 206     find_package(EXPAT REQUIRED)
 207
 208 else()
 209     message(STATUS "Using built-in expat code")
 210     # XML_STATIC is important to avoid sg_expat_external.h
 211     # declaring symbols as declspec(import)
 212     add_definitions(-DHAVE_EXPAT_CONFIG_H -DXML_STATIC)
 213     set(EXPAT_INCLUDE_DIRS
 214             ${PROJECT_SOURCE_DIR}/3rdparty/expat
 215             ${PROJECT_BINARY_DIR}/3rdparty/expat)
 216 endif(SYSTEM_EXPAT)
 217
 218 include_directories(${EXPAT_INCLUDE_DIRS})
 219
 220 check_include_file(inttypes.h HAVE_INTTYPES_H)
 221 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 222 check_include_file(sys/timeb.h HAVE_SYS_TIMEB_H)
 223 check_include_file(unistd.h HAVE_UNISTD_H)
 224 check_include_file(windows.h HAVE_WINDOWS_H)
 225
 226 if(HAVE_INTTYPES_H)
 227   # ShivaVG needs inttypes.h
 228   add_definitions(-DHAVE_INTTYPES_H)
 229 endif()
 230
 231 if(ENABLE_RTI)
 232     # See if we have any rti library variant installed
 233     message(STATUS "RTI: ENABLED")
 234     find_package(RTI)
 235 else()
 236     message(STATUS "RTI: DISABLED")
 237 endif(ENABLE_RTI)
 238
 239 check_function_exists(gettimeofday HAVE_GETTIMEOFDAY)
 240 check_function_exists(ftime HAVE_FTIME)
 241 check_function_exists(timegm HAVE_TIMEGM)
 242 check_function_exists(rint HAVE_RINT)
 243 check_function_exists(mkdtemp HAVE_MKDTEMP)
 244 check_function_exists(bcopy HAVE_BCOPY)
 245 check_function_exists(mmap HAVE_MMAP)
 246
 247 if(HAVE_UNISTD_H)
 248     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 249     check_cxx_source_compiles(
 250        "#include <unistd.h>
 251         #if !defined(_POSIX_TIMERS) || (0 >= _POSIX_TIMERS)
 252             #error clock_gettime is not supported
 253         #endif
 254
 255         int main() { return 0; }
 256         "
 257         HAVE_CLOCK_GETTIME)
 258 endif(HAVE_UNISTD_H)
 259
 260 set(RT_LIBRARY "")
 261 if(HAVE_CLOCK_GETTIME)
 262     check_library_exists(rt clock_gettime "" HAVE_RT)
 263     if(HAVE_RT)
 264         set(RT_LIBRARY rt)
 265     endif(HAVE_RT)
 266 endif(HAVE_CLOCK_GETTIME)
 267
 268 set(DL_LIBRARY "")
 269 check_cxx_source_compiles(
 270     "#include <dlfcn.h>
 271     int main(void) {
 272         return 0;
 273     }
 274     "
 275     HAVE_DLFCN_H)
 276
 277 if(HAVE_DLFCN_H)
 278     check_library_exists(dl dlerror "" HAVE_DL)
 279     if(HAVE_DL)
 280         set(DL_LIBRARY "dl")
 281     endif()
 282 endif()
 283
 284 SET(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "add a postfix, usually 'd' on windows")
 285 SET(CMAKE_RELEASE_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 286 SET(CMAKE_RELWITHDEBINFO_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 287 SET(CMAKE_MINSIZEREL_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 288
 289 # isnan might not be real symbol, so can't check using function_exists
 290 check_cxx_source_compiles(
 291     "#include <cmath>
 292     int main() { return isnan(0.0);} "
 293     HAVE_ISNAN)
 294
 295 check_cxx_source_compiles(
 296     "#include <cmath>
 297     int main() { return std::isnan(0.0);} "
 298     HAVE_STD_ISNAN)
 299
 300 if(CMAKE_COMPILER_IS_GNUCXX)
 301     set(WARNING_FLAGS_CXX "-Wall")
 302     set(WARNING_FLAGS_C   "-Wall")
 303
 304     # certain GCC versions don't provide the atomic builds, and hence
 305     # require is to provide them in SGAtomic.cxx
 306     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 307     check_cxx_source_compiles(
 308        "int main() { unsigned mValue; return __sync_add_and_fetch(&mValue, 1); }"
 309         GCC_ATOMIC_BUILTINS_FOUND)
 310 endif(CMAKE_COMPILER_IS_GNUCXX)
 311
 312 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 313     # Boost redeclares class members
 314     set(WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual -Wno-redeclared-class-member")
 315     set(WARNING_FLAGS_C   "-Wall")
 316     set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LIBRARY "libc++")
 317     set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LANGUAGE_STANDARD "c++11")
 318     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -stdlib=libc++")
 319 endif()
 320
 321 if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 322 # boost goes haywire wrt static asserts
 323     check_cxx_compiler_flag(-Wno-unused-local-typedefs HAS_NOWARN_UNUSED_TYPEDEFS)
 324     if(HAS_NOWARN_UNUSED_TYPEDEFS)
 325         set(WARNING_FLAGS_CXX " ${WARNING_FLAGS_CXX} -Wno-unused-local-typedefs")
 326     endif()
 327 endif()
 328
 329 if(WIN32)
 330
 331     if(MINGW)
 332         add_definitions(-D_WIN32_WINNT=0x501)
 333     endif()
 334
 335     if(MSVC)
 336         # turn off various warnings
 337         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 338         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 339         # endforeach(warning)
 340
 341         set(MSVC_FLAGS "-DWIN32 -DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS /wd4996 /wd4250 -Dstrdup=_strdup")
 342         if (${MSVC_VERSION} GREATER 1599)
 343             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 344         endif (${MSVC_VERSION} GREATER 1599)
 345     endif(MSVC)
 346
 347     # assumed on Windows
 348     set(HAVE_GETLOCALTIME 1)
 349
 350     set( WINSOCK_LIBRARY "ws2_32.lib" )
 351     set( RT_LIBRARY "winmm" )
 352 endif(WIN32)
 353
 354 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS}")
 355 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} ${BOOST_CXX_FLAGS}")
 356 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 357
 358 # use BEFORE to ensure local directories are used first,
 359 # ahead of system-installed libs
 360 include_directories(BEFORE ${PROJECT_SOURCE_DIR})
 361 include_directories(BEFORE ${PROJECT_SOURCE_DIR}/simgear/canvas/ShivaVG/include)
 362 include_directories(BEFORE ${PROJECT_BINARY_DIR}/simgear)
 363
 364 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 365     ${Boost_INCLUDE_DIRS}
 366     ${ZLIB_INCLUDE_DIR}
 367     ${OPENAL_INCLUDE_DIR}
 368 )
 369
 370 add_definitions(-DHAVE_CONFIG_H)
 371
 372 # configure a header file to pass some of the CMake settings
 373 # to the source code
 374 configure_file (
 375   "${PROJECT_SOURCE_DIR}/simgear/simgear_config_cmake.h.in"
 376   "${PROJECT_BINARY_DIR}/simgear/simgear_config.h"
 377   )
 378
 379 if(ENABLE_TESTS)
 380     # enable CTest / make test target
 381     message(STATUS "Tests: ENABLED")
 382
 383     include (Dart)
 384     enable_testing()
 385 else()
 386     message(STATUS "Tests: DISABLED")
 387 endif(ENABLE_TESTS)
 388
 389 # always set TEST_LIBS as it is also used by other tools/applications
 390 set(TEST_LIBS_INTERNAL_CORE
 391     ${CMAKE_THREAD_LIBS_INIT}
 392     ${ZLIB_LIBRARY}
 393     ${WINSOCK_LIBRARY}
 394     ${RT_LIBRARY}
 395     ${DL_LIBRARY}
 396     ${COCOA_LIBRARY})
 397 set(TEST_LIBS SimGearCore ${TEST_LIBS_INTERNAL_CORE})
 398
 399 if(NOT SIMGEAR_HEADLESS)
 400     set(TEST_LIBS SimGearScene ${OPENGL_LIBRARIES} ${TEST_LIBS})
 401 endif()
 402
 403 install (FILES ${PROJECT_BINARY_DIR}/simgear/simgear_config.h  DESTINATION include/simgear/)
 404
 405 include_directories(3rdparty/utf8/source)
 406
 407 add_subdirectory(3rdparty)
 408 add_subdirectory(simgear)
 409
 410 #-----------------------------------------------------------------------------
 411 ### uninstall target
 412 #-----------------------------------------------------------------------------
 413 CONFIGURE_FILE(
 414   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 415   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 416   IMMEDIATE @ONLY)
 417 ADD_CUSTOM_TARGET(uninstall
 418   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
 419
 420