CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7
   8 project(FlightGear)
   9
  10 # We have some custom .cmake scripts not in the official distribution.
  11 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  12
  13 if(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  14     # use official include provided by latest CMake
  15     include(GNUInstallDirs)
  16 else(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  17     # backward compatibility: use our own module for older cmake versions
  18     include(OldGNUInstallDirs)
  19 endif(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  20
  21 # Warning when build is not an out-of-source build.
  22 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  23 if(InSourceBuild)
  24     message(WARNING  "Avoid building inside the source tree!")
  25     message(WARNING  "Create a separate build directory instead (i.e. 'fgbuild') and call CMake from there: ")
  26     message(WARNING  "  mkdir ../fgbuild && cd ../fgbuild && cmake ${CMAKE_SOURCE_DIR}")
  27 endif(InSourceBuild)
  28
  29 # System detection/default settings
  30 include( DetectDistro )
  31 include( DetectBrowser )
  32
  33 set(CMAKE_DEBUG_POSTFIX          "d" CACHE STRING "add a postfix, usually d on windows")
  34 set(CMAKE_RELEASE_POSTFIX        ""  CACHE STRING "add a postfix, usually empty on windows")
  35 set(CMAKE_RELWITHDEBINFO_POSTFIX ""  CACHE STRING "add a postfix, usually empty on windows")
  36 set(CMAKE_MINSIZEREL_POSTFIX     ""  CACHE STRING "add a postfix, usually empty on windows")
  37
  38 # read 'version' file into a variable (stripping any newlines or spaces)
  39 file(READ version versionFile)
  40 if (NOT versionFile)
  41     message(FATAL_ERROR "Unable to determine FlightGear version. Version file is missing.")
  42 endif()
  43 string(STRIP "${versionFile}" FLIGHTGEAR_VERSION)
  44
  45 # FlightGear packaging (to build a source tarball)
  46 include( ConfigureCPack )
  47
  48 # FlightGear base package path
  49 if (FG_DATA_DIR)
  50     message(STATUS "Using explicit data directory for base package: ${FG_DATA_DIR}")
  51 else()
  52     set(FG_DATA_DIR "${CMAKE_INSTALL_PREFIX}/lib/FlightGear" CACHE PATH "Default location where data files are located")
  53     message(STATUS "Using default data directory for base package:  ${FG_DATA_DIR}")
  54 endif()
  55
  56 # Change the default build type to something fast
  57 if(NOT CMAKE_BUILD_TYPE)
  58     set(CMAKE_BUILD_TYPE Release CACHE STRING
  59         "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  60         FORCE)
  61 endif(NOT CMAKE_BUILD_TYPE)
  62
  63 if(NOT "$ENV{BUILD_ID}" STREQUAL "")
  64     set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  65     set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  66     message(STATUS "running under Hudson/Jenkins, build-number is ${HUDSON_BUILD_NUMBER}")
  67 else()
  68     set(HUDSON_BUILD_NUMBER 0)
  69     set(HUDSON_BUILD_ID "none")
  70 endif()
  71
  72 #####################################################################################
  73 # Configure library search paths
  74 #####################################################################################
  75
  76 if(APPLE)
  77     # Custom library directories for Mac, which should have precedence over any other
  78     list(APPEND ADDITIONAL_LIBRARY_PATHS
  79          ~/Library/Frameworks
  80          /Library/Frameworks)
  81 endif(APPLE)
  82
  83 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  84     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  85     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  86     # add paths manually
  87     # see http://www.cmake.org/Bug/view.php?id=12049 and
  88     # http://www.cmake.org/Bug/view.php?id=12037
  89     list(APPEND ADDITIONAL_LIBRARY_PATHS
  90          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  91          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  92          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
  93     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
  94 endif()
  95
  96 if(NOT MSVC)
  97     # TBD: are these really necessary? Aren't they considered by cmake automatically?
  98     list(APPEND ADDITIONAL_LIBRARY_PATHS
  99          /opt/local
 100          /usr/local
 101          /usr)
 102 endif()
 103 #####################################################################################
 104
 105 IF(APPLE)
 106     set(EVENT_INPUT_DEFAULT 1)
 107
 108     find_library(CORESERVICES_LIBRARY CoreServices)
 109     find_library(COCOA_LIBRARY Cocoa)
 110     list(APPEND PLATFORM_LIBS ${COCOA_LIBRARY} ${CORESERVICES_LIBRARY})
 111
 112 elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 113     set(USE_DBUS_DEFAULT 1)
 114     find_package(UDev)
 115
 116     if(UDEV_FOUND)
 117         set(EVENT_INPUT_DEFAULT 1)
 118     endif(UDEV_FOUND)
 119 endif()
 120
 121 find_package(Git)
 122 if (GIT_FOUND)
 123     execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
 124         OUTPUT_VARIABLE REVISION
 125         OUTPUT_STRIP_TRAILING_WHITESPACE)
 126     message(STATUS "Git revision is ${REVISION}")
 127 else()
 128     set(REVISION "none")
 129 endif()
 130
 131 # FlightGear build options
 132 option(SIMGEAR_SHARED    "Set to ON when SimGear was built as a shared library" OFF)
 133 option(LOGGING           "Set to ON to build FlightGear with logging support (default)" ON)
 134 option(SP_FDMS           "Set to ON to build FlightGear with special-purpose FDMs" OFF)
 135 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" OFF)
 136 option(ENABLE_LARCSIM    "Set to ON to build FlightGear with LaRCsim FDM" OFF)
 137 option(ENABLE_YASIM      "Set to ON to build FlightGear with YASIM FDM (default)" ON)
 138 option(ENABLE_JSBSIM     "Set to ON to build FlightGear with JSBSim FDM (default)" ON)
 139 option(EVENT_INPUT       "Set to ON to build FlightGear with event-based Input support" ${EVENT_INPUT_DEFAULT})
 140 option(ENABLE_RTI        "Set to ON to build FlightGear with RTI support" OFF)
 141 option(ENABLE_PROFILE    "Set to ON to build FlightGear with gperftools profiling support" OFF)
 142 option(JPEG_FACTORY      "Set to ON to build FlightGear with JPEG-factory support" OFF)
 143 option(SYSTEM_SQLITE     "Set to ON to build FlightGear with the system's SQLite3 library" OFF)
 144 option(ENABLE_IAX        "Set to ON to build FlightGear with IAXClient/fgcom built-in (default)" ON)
 145 option(USE_DBUS          "Set to ON to build FlightGear with DBus screensaver interaction (default on Linux)" ${USE_DBUS_DEFAULT})
 146
 147 # additional utilities
 148 option(ENABLE_FGADMIN    "Set to ON to build the FGADMIN application (default)" ON)
 149 option(ENABLE_FGELEV     "Set to ON to build the fgelev application (default)" ON)
 150 option(WITH_FGPANEL      "Set to ON to build the fgpanel application (default)" ON)
 151 option(ENABLE_FGVIEWER   "Set to ON to build the fgviewer application (default)" ON)
 152 option(ENABLE_GPSSMOOTH  "Set to ON to build the GPSsmooth application (default)" ON)
 153 option(ENABLE_TERRASYNC  "Set to ON to build the terrasync application (default)" ON)
 154 option(ENABLE_FGJS       "Set to ON to build the fgjs application (default)" ON)
 155 option(ENABLE_JS_DEMO    "Set to ON to build the js_demo application (default)" ON)
 156 option(ENABLE_METAR      "Set to ON to build the metar application (default)" ON)
 157 option(ENABLE_TESTS      "Set to ON to build test applications (default)" ON)
 158 option(ENABLE_FGCOM      "Set to ON to build the FGCom application (default)" ON)
 159
 160 if(LOGGING)
 161     # nothing
 162 else()
 163     set(FG_NDEBUG 1)
 164 endif()
 165
 166 if(SP_FDMS)
 167     set(ENABLE_SP_FDM 1)
 168 endif()
 169
 170 if(ENABLE_FGCOM)
 171   set(ENABLE_IAX 1)
 172 endif()
 173
 174 # Setup MSVC 3rd party directories
 175 include( ConfigureMsvc3rdParty )
 176
 177 if(EVENT_INPUT)
 178     if(APPLE)
 179     elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 180         if(NOT UDEV_FOUND)
 181             message(WARNING "UDev not found, event input is disabled!")
 182             set(EVENT_INPUT 0)
 183         else()
 184             add_definitions(-DWITH_EVENTINPUT)
 185             set(EVENT_INPUT_LIBRARIES ${UDEV_LIBRARIES})
 186             message(STATUS "event-based input enabled. Using ${UDEV_LIBRARIES}")
 187         endif()
 188     else()
 189         message(WARNING "event-based input is not supported on this platform yet")
 190     endif()
 191
 192     # Keep PLIB INPUT enabled as long as EventInput does not replace current joystick configurations.
 193     set(ENABLE_PLIB_JOYSTICK 1)
 194 else(EVENT_INPUT)
 195     set(ENABLE_PLIB_JOYSTICK 1)
 196 endif(EVENT_INPUT)
 197
 198 # check required dependencies
 199 find_package(Boost   REQUIRED)
 200 find_package(ZLIB    REQUIRED)
 201 find_package(Threads REQUIRED)
 202 find_package(OpenGL  REQUIRED)
 203 find_package(OpenAL  REQUIRED)
 204 find_package(OpenSceneGraph 3.0.0 REQUIRED osgText osgSim osgDB osgParticle osgFX osgUtil osgViewer osgGA)
 205
 206 if(ENABLE_FGADMIN)
 207     find_package(FLTK)
 208
 209     if ( FLTK_FOUND )
 210         if ( X11_Xinerama_FOUND )
 211             message(STATUS "Found X11_Xinerama...")
 212             list(APPEND FLTK_LIBRARIES ${X11_Xinerama_LIB})
 213         endif()
 214
 215         if ( X11_Xft_FOUND )
 216             message(STATUS "Found X11_Xft...")
 217             list(APPEND FLTK_LIBRARIES ${X11_Xft_LIB})
 218         endif()
 219
 220         if ( CMAKE_DL_LIBS )
 221             list(APPEND FLTK_LIBRARIES ${CMAKE_DL_LIBS})
 222         endif()
 223
 224         message(STATUS "Using FLTK_LIBRARIES for fgadmin: ${FLTK_LIBRARIES}")
 225     endif ( FLTK_FOUND )
 226 endif(ENABLE_FGADMIN)
 227
 228 ##############################################################################
 229 ## Sqlite3 setup
 230
 231 if (SYSTEM_SQLITE)
 232     find_package(SQLite3 REQUIRED)
 233
 234     message(STATUS "Using system SQLite3 library")
 235 else()
 236     set(SQLITE3_INCLUDED_DIR "${CMAKE_SOURCE_DIR}/3rdparty/sqlite3")
 237     # this target is defined in src/Navaids/CMakeLists.txt
 238     list(APPEND SQLITE3_LIBRARY fgsqlite3)
 239 endif (SYSTEM_SQLITE)
 240
 241 # Sqlite always depends on the threading lib
 242 list(APPEND SQLITE3_LIBRARY ${CMAKE_THREAD_LIBS_INIT})
 243
 244 ##############################################################################
 245 ## DBus setup
 246
 247 if (USE_DBUS)
 248     include(FindPkgConfig)
 249     if (PKG_CONFIG_FOUND)
 250         pkg_check_modules(DBUS dbus-1)
 251     endif (PKG_CONFIG_FOUND) #if we don't have pkg-config, assume we don't have libdbus-1-dev either http://packages.debian.org/sid/libdbus-1-dev
 252     if (DBUS_FOUND)
 253         set(HAVE_DBUS 1)
 254         message(STATUS "Using DBus")
 255         include_directories( ${DBUS_INCLUDE_DIRS})
 256     else()
 257         message(STATUS "DBus not found, screensaver control disabled")
 258     endif (DBUS_FOUND)
 259 else()
 260 endif (USE_DBUS)
 261
 262 # Sqlite always depends on the threading lib
 263 list(APPEND SQLITE3_LIBRARY ${CMAKE_THREAD_LIBS_INIT})
 264
 265 ##############################################################################
 266
 267 find_package(PLIB REQUIRED puaux pu js fnt)
 268
 269 # FlightGear and SimGear versions need to match
 270 find_package(SimGear ${FLIGHTGEAR_VERSION} REQUIRED)
 271
 272 ##############################################################################
 273
 274 if (JPEG_FACTORY)
 275     # check simgear was built with JPEG-factory support
 276     find_package(JPEG REQUIRED)
 277     include_directories(${JPEG_INCLUDE_DIR})
 278
 279     set(CMAKE_REQUIRED_INCLUDES
 280         ${SIMGEAR_INCLUDE_DIR}
 281         ${JPEG_INCLUDE_DIR}
 282         ${OPENSCENEGRAPH_INCLUDE_DIRS})
 283
 284     check_cxx_source_compiles(
 285         "#include <simgear/screen/jpgfactory.hxx>
 286         int main()    { return 0; } "
 287         FG_JPEG_SERVER)
 288
 289     if (NOT FG_JPEG_SERVER)
 290         message(STATUS "JPEG server support requested, but SimGear was built without JPEG support")
 291     endif()
 292 endif()
 293
 294 check_include_file(unistd.h   HAVE_UNISTD_H)
 295 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 296 check_include_file(windows.h  HAVE_WINDOWS_H)
 297
 298 if(ENABLE_PROFILE)
 299     find_package(GooglePerfTools REQUIRED)
 300     set(FG_HAVE_GPERFTOOLS 1)
 301     message(STATUS "Built-in profiler using gperftools available")
 302 endif()
 303
 304 if(ENABLE_RTI)
 305     message(STATUS "RTI: ENABLED")
 306     find_package(RTI)
 307     if(RTI_FOUND)
 308         set(FG_HAVE_HLA 1)
 309     endif(RTI_FOUND)
 310 else()
 311     message(STATUS "RTI: DISABLED")
 312 endif(ENABLE_RTI)
 313
 314 if(CMAKE_COMPILER_IS_GNUCXX)
 315     set(WARNING_FLAGS_CXX "-Wall")
 316     set(WARNING_FLAGS_C   "-Wall")
 317 endif(CMAKE_COMPILER_IS_GNUCXX)
 318
 319 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 320    set (WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual")
 321    set (WARNING_FLAGS_C   "-Wall")
 322 endif()
 323
 324 if(WIN32)
 325
 326     if(MSVC)
 327         # turn off various warnings
 328         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 329         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 330         # endforeach(warning)
 331
 332         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS -Dstrdup=_strdup")
 333         if (${MSVC_VERSION} GREATER 1599)
 334             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 335         endif (${MSVC_VERSION} GREATER 1599)
 336     endif(MSVC)
 337
 338     set(NOMINMAX 1)
 339 endif(WIN32)
 340
 341 set (BOOST_CXX_FLAGS "-DBOOST_MULTI_INDEX_DISABLE_SERIALIZATION -DBOOST_BIMAP_DISABLE_SERIALIZATION")
 342
 343 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS} -D_REENTRANT")
 344 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} -D_REENTRANT ${BOOST_CXX_FLAGS}")
 345 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 346
 347 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 348     ${Boost_INCLUDE_DIRS}
 349     ${ZLIB_INCLUDE_DIR}
 350     ${OPENGL_INCLUDE_DIR}
 351     ${OPENAL_INCLUDE_DIR}
 352     ${SIMGEAR_INCLUDE_DIR}
 353     ${PLIB_INCLUDE_DIR}
 354     ${SQLITE3_INCLUDED_DIR} )
 355
 356 include_directories(${PROJECT_SOURCE_DIR})
 357 include_directories(${PROJECT_SOURCE_DIR}/src)
 358 include_directories(${PROJECT_SOURCE_DIR}/3rdparty/iaxclient/lib ) # for iaxclient.h
 359 # following is needed, because config.h is include 'bare', whereas
 360 # version.h is included as <Include/version.h> - this should be cleaned up
 361 include_directories(${PROJECT_BINARY_DIR}/src)
 362 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 363
 364 add_definitions(-DHAVE_CONFIG_H)
 365
 366 check_function_exists(mkfifo HAVE_MKFIFO)
 367
 368 # configure a header file to pass some of the CMake settings
 369 # to the source code
 370 configure_file (
 371     "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 372     "${PROJECT_BINARY_DIR}/src/Include/config.h"
 373 )
 374
 375 #and the same for the version header
 376 configure_file (
 377     "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 378     "${PROJECT_BINARY_DIR}/src/Include/version.h"
 379 )
 380
 381 add_subdirectory(3rdparty)
 382 add_subdirectory(utils)
 383 add_subdirectory(src)
 384 add_subdirectory(man)
 385
 386 #-----------------------------------------------------------------------------
 387 ### uninstall target
 388 #-----------------------------------------------------------------------------
 389 CONFIGURE_FILE(
 390     "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 391     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 392     IMMEDIATE @ONLY)
 393 ADD_CUSTOM_TARGET(uninstall
 394     "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")