CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8.11)
   2
   3 if(COMMAND cmake_policy)
   4    if(POLICY CMP0054)
   5        cmake_policy(SET CMP0054 NEW)
   6    endif()
   7    if(POLICY CMP0042)
   8        cmake_policy(SET CMP0042 NEW)
   9    endif()
  10 endif()
  11
  12 include (CheckFunctionExists)
  13 include (CheckIncludeFile)
  14 include (CheckLibraryExists)
  15 include (CheckCXXSourceCompiles)
  16 include (CheckCXXCompilerFlag)
  17
  18 # using 10.7 because boost requires libc++ and 10.6 doesn't include it
  19 set(CMAKE_OSX_DEPLOYMENT_TARGET 10.7)
  20
  21 # only relevant for building shared libs but let's set it regardless
  22 set(CMAKE_OSX_RPATH 1)
  23
  24 project(SimGear)
  25
  26 # read 'version' file into a variable (stripping any newlines or spaces)
  27 file(READ version versionFile)
  28 string(STRIP ${versionFile} SIMGEAR_VERSION)
  29
  30 set(FIND_LIBRARY_USE_LIB64_PATHS ON)
  31
  32 # use simgear version also as the SO version (if building SOs)
  33 SET(SIMGEAR_SOVERSION ${SIMGEAR_VERSION})
  34
  35 # Warning when build is not an out-of-source build.
  36 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  37 if(InSourceBuild)
  38     message(WARNING  "Avoid building inside the source tree!")
  39     message(WARNING  "Create a separate build directory instead (i.e. 'sgbuild') and call CMake from there: ")
  40     message(WARNING  "  mkdir ../sgbuild && cd ../sgbuild && cmake ${CMAKE_SOURCE_DIR}")
  41 endif(InSourceBuild)
  42
  43 #packaging
  44 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  45 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  46 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Simulation support libraries for FlightGear and related projects")
  47 SET(CPACK_PACKAGE_VENDOR "The FlightGear project")
  48 SET(CPACK_GENERATOR "TBZ2")
  49 SET(CPACK_INSTALL_CMAKE_PROJECTS  ${CMAKE_CURRENT_BINARY_DIR};SimGear;ALL;/)
  50
  51
  52 # split version string into components, note CMAKE_MATCH_0 is the entire regexp match
  53 string(REGEX MATCH "([0-9]+)\\.([0-9]+)\\.([0-9]+)" CPACK_PACKAGE_VERSION ${SIMGEAR_VERSION} )
  54 set(CPACK_PACKAGE_VERSION_MAJOR ${CMAKE_MATCH_1})
  55 set(CPACK_PACKAGE_VERSION_MINOR ${CMAKE_MATCH_2})
  56 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_3})
  57
  58 message(STATUS "version is ${CPACK_PACKAGE_VERSION_MAJOR} dot ${CPACK_PACKAGE_VERSION_MINOR} dot ${CPACK_PACKAGE_VERSION_PATCH}")
  59
  60 set(CPACK_SOURCE_GENERATOR TBZ2)
  61 set(CPACK_SOURCE_PACKAGE_FILE_NAME "simgear-${SIMGEAR_VERSION}" CACHE INTERNAL "tarball basename")
  62 set(CPACK_SOURCE_IGNORE_FILES
  63   "^${PROJECT_SOURCE_DIR}/.git;\\\\.gitignore;Makefile.am;~$;${CPACK_SOURCE_IGNORE_FILES}")
  64
  65 message(STATUS "ignoring: ${CPACK_SOURCE_IGNORE_FILES}")
  66
  67 include (CPack)
  68
  69 # We have some custom .cmake scripts not in the official distribution.
  70 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  71
  72 # Change the default build type to something fast
  73 if(NOT CMAKE_BUILD_TYPE)
  74   set(CMAKE_BUILD_TYPE Release CACHE STRING
  75       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  76       FORCE)
  77 endif(NOT CMAKE_BUILD_TYPE)
  78
  79 # Determine name of library installation directory, i.e. "lib" vs "lib64", which
  80 # differs between all Debian-based vs all other Linux distros.
  81 # See cmake bug #11964, http://cmake.org/gitweb?p=cmake.git;a=commit;h=126c993d
  82 include(GNUInstallDirs)
  83 message(STATUS "Library installation directory: ${CMAKE_INSTALL_LIBDIR}")
  84
  85 #####################################################################################
  86 # Configure library search paths
  87 #####################################################################################
  88
  89 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  90     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  91     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  92     # add paths manually
  93     # see http://www.cmake.org/Bug/view.php?id=12049 and
  94     # http://www.cmake.org/Bug/view.php?id=12037
  95     list(APPEND ADDITIONAL_LIBRARY_PATHS
  96          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  97          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  98          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
  99     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
 100 endif()
 101
 102 #####################################################################################
 103
 104 if (NOT MSVC)
 105 option(SIMGEAR_SHARED   "Set to ON to build SimGear as a shared library/framework" OFF)
 106 option(SYSTEM_EXPAT     "Set to ON to build SimGear using the system libExpat" OFF)
 107 else()
 108 # Building SimGear DLLs is currently not supported for MSVC.
 109 set(SIMGEAR_SHARED OFF)
 110 # Using a system expat is currently not supported for MSVC - it would require shared simgear (DLL).
 111 set(SYSTEM_EXPAT OFF)
 112 endif()
 113
 114 option(SIMGEAR_HEADLESS "Set to ON to build SimGear without GUI/graphics support" OFF)
 115 option(ENABLE_RTI       "Set to ON to build SimGear with RTI support" OFF)
 116 option(ENABLE_TESTS     "Set to OFF to disable building SimGear's test applications" ON)
 117 option(ENABLE_SOUND     "Set to OFF to disable building SimGear's sound support" ON)
 118 option(ENABLE_PKGUTIL   "Set to ON to build the sg_pkgutil application (default)" ON)
 119 option(ENABLE_CURL      "Set to ON to use libCurl as the HTTP client backend" OFF)
 120
 121 if (MSVC)
 122   GET_FILENAME_COMPONENT(PARENT_DIR ${PROJECT_BINARY_DIR} PATH)
 123   if (CMAKE_CL_64)
 124     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty.x64")
 125   else (CMAKE_CL_64)
 126     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty")
 127   endif (CMAKE_CL_64)
 128   if (EXISTS ${TEST_3RDPARTY_DIR})
 129     set(MSVC_3RDPARTY_ROOT ${PARENT_DIR} CACHE PATH "Location where the third-party dependencies are extracted")
 130   else (EXISTS ${TEST_3RDPARTY_DIR})
 131     set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 132   endif (EXISTS ${TEST_3RDPARTY_DIR})
 133 else (MSVC)
 134   set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 135 endif (MSVC)
 136
 137 if (MSVC AND MSVC_3RDPARTY_ROOT)
 138   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_ROOT}")
 139   set( OSG_MSVC "msvc" )
 140   if (${MSVC_VERSION} EQUAL 1700)
 141       set( OSG_MSVC ${OSG_MSVC}110 )
 142   elseif (${MSVC_VERSION} EQUAL 1600)
 143       set( OSG_MSVC ${OSG_MSVC}100 )
 144   else (${MSVC_VERSION} EQUAL 1700)
 145       set( OSG_MSVC ${OSG_MSVC}90 )
 146   endif (${MSVC_VERSION} EQUAL 1700)
 147   if (CMAKE_CL_64)
 148       set( OSG_MSVC ${OSG_MSVC}-64 )
 149       set( MSVC_3RDPARTY_DIR 3rdParty.x64 )
 150   else (CMAKE_CL_64)
 151       set( MSVC_3RDPARTY_DIR 3rdParty )
 152   endif (CMAKE_CL_64)
 153
 154   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/lib )
 155   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/include)
 156   find_path(BOOST_ROOT boost/version.hpp
 157                         ${MSVC_3RDPARTY_ROOT}/boost
 158                         ${MSVC_3RDPARTY_ROOT}/boost_1_52_0
 159                         ${MSVC_3RDPARTY_ROOT}/boost_1_51_0
 160                         ${MSVC_3RDPARTY_ROOT}/boost_1_50_0
 161                         ${MSVC_3RDPARTY_ROOT}/boost_1_49_0
 162                         ${MSVC_3RDPARTY_ROOT}/boost_1_48_0
 163                         ${MSVC_3RDPARTY_ROOT}/boost_1_47_0
 164                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_1
 165                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_0
 166                         ${MSVC_3RDPARTY_ROOT}/boost_1_45_0
 167                         ${MSVC_3RDPARTY_ROOT}/boost_1_44_0
 168                         )
 169   # set (BOOST_ROOT ${MSVC_3RDPARTY_ROOT}/boost_1_44_0)
 170   message(STATUS "BOOST_ROOT is ${BOOST_ROOT}")
 171   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 172   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib)
 173 endif (MSVC AND MSVC_3RDPARTY_ROOT)
 174
 175 if(APPLE)
 176   find_library(COCOA_LIBRARY Cocoa)
 177
 178 # this should be handled by setting CMAKE_OSX_DEPLOYMENT_TARGET
 179 # but it's not working reliably, so forcing it for now
 180   SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.7")
 181   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.7")
 182 endif()
 183
 184 if(${CMAKE_SYSTEM_NAME} MATCHES "Linux" OR
 185         ${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD")
 186     find_package(Threads REQUIRED)
 187 endif()
 188
 189 # Somehow this only works if included before searching for Boost...
 190 include(BoostTestTargets)
 191
 192 find_package(Boost REQUIRED)
 193 set (BOOST_CXX_FLAGS "-DBOOST_BIMAP_DISABLE_SERIALIZATION")
 194
 195 if(SIMGEAR_HEADLESS)
 196     message(STATUS "SimGear mode: HEADLESS")
 197     set(ENABLE_SOUND 0)
 198 else()
 199     message(STATUS "SimGear mode: NORMAL")
 200     find_package(OpenGL REQUIRED)
 201
 202     if (ENABLE_SOUND)
 203         find_package(OpenAL REQUIRED)
 204         message(STATUS "Sound support: ENABLED")
 205     endif(ENABLE_SOUND)
 206
 207     find_package(OpenSceneGraph 3.2.0 REQUIRED osgText osgSim osgDB osgParticle osgGA osgViewer osgUtil)
 208 endif(SIMGEAR_HEADLESS)
 209
 210 find_package(ZLIB REQUIRED)
 211
 212 if (ENABLE_CURL)
 213   find_package(CURL REQUIRED)
 214   message(STATUS "Curl HTTP client: ENABLED")
 215 endif()
 216
 217 if (SYSTEM_EXPAT)
 218     message(STATUS "Requested to use system Expat library, forcing SIMGEAR_SHARED to true")
 219     set(SIMGEAR_SHARED ON)
 220     find_package(EXPAT REQUIRED)
 221
 222 else()
 223     message(STATUS "Using built-in expat code")
 224     # XML_STATIC is important to avoid sg_expat_external.h
 225     # declaring symbols as declspec(import)
 226     add_definitions(-DHAVE_EXPAT_CONFIG_H -DXML_STATIC)
 227     set(EXPAT_INCLUDE_DIRS
 228             ${PROJECT_SOURCE_DIR}/3rdparty/expat
 229             ${PROJECT_BINARY_DIR}/3rdparty/expat)
 230 endif(SYSTEM_EXPAT)
 231
 232 include_directories(${EXPAT_INCLUDE_DIRS})
 233
 234 check_include_file(inttypes.h HAVE_INTTYPES_H)
 235 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 236 check_include_file(sys/timeb.h HAVE_SYS_TIMEB_H)
 237 check_include_file(unistd.h HAVE_UNISTD_H)
 238 check_include_file(windows.h HAVE_WINDOWS_H)
 239
 240 if(HAVE_INTTYPES_H)
 241   # ShivaVG needs inttypes.h
 242   add_definitions(-DHAVE_INTTYPES_H)
 243 endif()
 244
 245 if(ENABLE_RTI)
 246     # See if we have any rti library variant installed
 247     message(STATUS "RTI: ENABLED")
 248     find_package(RTI)
 249 else()
 250     message(STATUS "RTI: DISABLED")
 251 endif(ENABLE_RTI)
 252
 253 check_function_exists(gettimeofday HAVE_GETTIMEOFDAY)
 254 check_function_exists(ftime HAVE_FTIME)
 255 check_function_exists(timegm HAVE_TIMEGM)
 256 check_function_exists(rint HAVE_RINT)
 257 check_function_exists(mkdtemp HAVE_MKDTEMP)
 258 check_function_exists(bcopy HAVE_BCOPY)
 259 check_function_exists(mmap HAVE_MMAP)
 260
 261 if(HAVE_UNISTD_H)
 262     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 263     check_cxx_source_compiles(
 264        "#include <unistd.h>
 265         #if !defined(_POSIX_TIMERS) || (0 >= _POSIX_TIMERS)
 266             #error clock_gettime is not supported
 267         #endif
 268
 269         int main() { return 0; }
 270         "
 271         HAVE_CLOCK_GETTIME)
 272 endif(HAVE_UNISTD_H)
 273
 274 set(RT_LIBRARY "")
 275 if(HAVE_CLOCK_GETTIME)
 276     check_library_exists(rt clock_gettime "" HAVE_RT)
 277     if(HAVE_RT)
 278         set(RT_LIBRARY rt)
 279     endif(HAVE_RT)
 280 endif(HAVE_CLOCK_GETTIME)
 281
 282 set(DL_LIBRARY "")
 283 check_cxx_source_compiles(
 284     "#include <dlfcn.h>
 285     int main(void) {
 286         return 0;
 287     }
 288     "
 289     HAVE_DLFCN_H)
 290
 291 if(HAVE_DLFCN_H)
 292     check_library_exists(dl dlerror "" HAVE_DL)
 293     if(HAVE_DL)
 294         set(DL_LIBRARY "dl")
 295     endif()
 296 endif()
 297
 298 SET(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "add a postfix, usually 'd' on windows")
 299 SET(CMAKE_RELEASE_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 300 SET(CMAKE_RELWITHDEBINFO_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 301 SET(CMAKE_MINSIZEREL_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 302
 303 # isnan might not be real symbol, so can't check using function_exists
 304 check_cxx_source_compiles(
 305     "#include <cmath>
 306     int main() { return isnan(0.0);} "
 307     HAVE_ISNAN)
 308
 309 check_cxx_source_compiles(
 310     "#include <cmath>
 311     int main() { return std::isnan(0.0);} "
 312     HAVE_STD_ISNAN)
 313
 314 if(CMAKE_COMPILER_IS_GNUCXX)
 315     set(WARNING_FLAGS_CXX "-Wall")
 316     set(WARNING_FLAGS_C   "-Wall")
 317
 318     # certain GCC versions don't provide the atomic builds, and hence
 319     # require is to provide them in SGAtomic.cxx
 320     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 321     check_cxx_source_compiles(
 322        "int main() { unsigned mValue; return __sync_add_and_fetch(&mValue, 1); }"
 323         GCC_ATOMIC_BUILTINS_FOUND)
 324 endif(CMAKE_COMPILER_IS_GNUCXX)
 325
 326 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 327     # Boost redeclares class members
 328     set(WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual -Wno-redeclared-class-member")
 329     set(WARNING_FLAGS_C   "-Wall")
 330     set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LIBRARY "libc++")
 331     set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LANGUAGE_STANDARD "c++11")
 332     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -stdlib=libc++")
 333 endif()
 334
 335 if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 336 # boost goes haywire wrt static asserts
 337     check_cxx_compiler_flag(-Wno-unused-local-typedefs HAS_NOWARN_UNUSED_TYPEDEFS)
 338     if(HAS_NOWARN_UNUSED_TYPEDEFS)
 339         set(WARNING_FLAGS_CXX " ${WARNING_FLAGS_CXX} -Wno-unused-local-typedefs")
 340     endif()
 341 endif()
 342
 343 if(WIN32)
 344
 345     if(MINGW)
 346         add_definitions(-D_WIN32_WINNT=0x501)
 347     endif()
 348
 349     if(MSVC)
 350         # turn off various warnings
 351         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 352         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 353         # endforeach(warning)
 354
 355         set(MSVC_FLAGS "-DWIN32 -DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS /wd4996 /wd4250 -Dstrdup=_strdup")
 356         if (${MSVC_VERSION} GREATER 1599)
 357             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 358         endif (${MSVC_VERSION} GREATER 1599)
 359     endif(MSVC)
 360
 361     # assumed on Windows
 362     set(HAVE_GETLOCALTIME 1)
 363
 364     set( WINSOCK_LIBRARY "ws2_32.lib" )
 365     set( RT_LIBRARY "winmm" )
 366 endif(WIN32)
 367
 368 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS}")
 369 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} ${BOOST_CXX_FLAGS}")
 370 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 371
 372 # use BEFORE to ensure local directories are used first,
 373 # ahead of system-installed libs
 374 include_directories(BEFORE ${PROJECT_SOURCE_DIR})
 375 include_directories(BEFORE ${PROJECT_SOURCE_DIR}/simgear/canvas/ShivaVG/include)
 376 include_directories(BEFORE ${PROJECT_BINARY_DIR}/simgear)
 377
 378 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 379     ${Boost_INCLUDE_DIRS}
 380     ${ZLIB_INCLUDE_DIR}
 381     ${OPENAL_INCLUDE_DIR}
 382     ${CURL_INCLUDE_DIRS}
 383 )
 384
 385 add_definitions(-DHAVE_CONFIG_H)
 386
 387 # configure a header file to pass some of the CMake settings
 388 # to the source code
 389 configure_file (
 390   "${PROJECT_SOURCE_DIR}/simgear/simgear_config_cmake.h.in"
 391   "${PROJECT_BINARY_DIR}/simgear/simgear_config.h"
 392   )
 393
 394 if(ENABLE_TESTS)
 395     # enable CTest / make test target
 396     message(STATUS "Tests: ENABLED")
 397
 398     include (Dart)
 399     enable_testing()
 400 else()
 401     message(STATUS "Tests: DISABLED")
 402 endif(ENABLE_TESTS)
 403
 404 # always set TEST_LIBS as it is also used by other tools/applications
 405 set(TEST_LIBS_INTERNAL_CORE
 406     ${CMAKE_THREAD_LIBS_INIT}
 407     ${ZLIB_LIBRARY}
 408     ${WINSOCK_LIBRARY}
 409     ${RT_LIBRARY}
 410     ${DL_LIBRARY}
 411     ${COCOA_LIBRARY}
 412     ${CURL_LIBRARIES})
 413 set(TEST_LIBS SimGearCore ${TEST_LIBS_INTERNAL_CORE})
 414
 415 if(NOT SIMGEAR_HEADLESS)
 416     set(TEST_LIBS SimGearScene ${OPENGL_LIBRARIES} ${TEST_LIBS})
 417 endif()
 418
 419 install (FILES ${PROJECT_BINARY_DIR}/simgear/simgear_config.h  DESTINATION include/simgear/)
 420
 421 include_directories(3rdparty/utf8/source)
 422
 423 add_subdirectory(3rdparty)
 424 add_subdirectory(simgear)
 425
 426 #-----------------------------------------------------------------------------
 427 ### uninstall target
 428 #-----------------------------------------------------------------------------
 429 CONFIGURE_FILE(
 430   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 431   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 432   IMMEDIATE @ONLY)
 433 ADD_CUSTOM_TARGET(uninstall
 434   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")