CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2
   3 include (CheckFunctionExists)
   4 include (CheckCSourceCompiles)
   5 include (CheckCXXSourceCompiles)
   6 include (CheckIncludeFile)
   7
   8 project(FlightGear)
   9
  10 # We have some custom .cmake scripts not in the official distribution.
  11 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  12
  13 if(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  14     # use official include provided by latest CMake
  15     include(GNUInstallDirs)
  16 else(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  17     # backward compatibility: use our own module for older cmake versions
  18     include(OldGNUInstallDirs)
  19 endif(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  20
  21 # Warning when build is not an out-of-source build.
  22 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  23 if(InSourceBuild)
  24     message(WARNING  "Avoid building inside the source tree!")
  25     message(WARNING  "Create a separate build directory instead (i.e. 'fgbuild') and call CMake from there: ")
  26     message(WARNING  "  mkdir ../fgbuild && cd ../fgbuild && cmake ${CMAKE_SOURCE_DIR}")
  27 endif(InSourceBuild)
  28
  29 # System detection/default settings
  30 include( DetectDistro )
  31 include( DetectBrowser )
  32
  33 set(CMAKE_DEBUG_POSTFIX          "d" CACHE STRING "add a postfix, usually d on windows")
  34 set(CMAKE_RELEASE_POSTFIX        ""  CACHE STRING "add a postfix, usually empty on windows")
  35 set(CMAKE_RELWITHDEBINFO_POSTFIX ""  CACHE STRING "add a postfix, usually empty on windows")
  36 set(CMAKE_MINSIZEREL_POSTFIX     ""  CACHE STRING "add a postfix, usually empty on windows")
  37
  38 # read 'version' file into a variable (stripping any newlines or spaces)
  39 file(READ version versionFile)
  40 if (NOT versionFile)
  41     message(FATAL_ERROR "Unable to determine FlightGear version. Version file is missing.")
  42 endif()
  43 string(STRIP "${versionFile}" FLIGHTGEAR_VERSION)
  44
  45 # FlightGear packaging (to build a source tarball)
  46 include( ConfigureCPack )
  47
  48 # FlightGear base package path
  49 if (FG_DATA_DIR)
  50     message(STATUS "Using explicit data directory for base package: ${FG_DATA_DIR}")
  51 else()
  52     set(FG_DATA_DIR "${CMAKE_INSTALL_PREFIX}/lib/FlightGear" CACHE PATH "Default location where data files are located")
  53     message(STATUS "Using default data directory for base package:  ${FG_DATA_DIR}")
  54 endif()
  55
  56 # Change the default build type to something fast
  57 if(NOT CMAKE_BUILD_TYPE)
  58     set(CMAKE_BUILD_TYPE Release CACHE STRING
  59         "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  60         FORCE)
  61 endif(NOT CMAKE_BUILD_TYPE)
  62
  63 if(NOT "$ENV{BUILD_ID}" STREQUAL "")
  64     set(HUDSON_BUILD_ID $ENV{BUILD_ID})
  65     set(HUDSON_BUILD_NUMBER $ENV{BUILD_NUMBER})
  66     message(STATUS "running under Hudson/Jenkins, build-number is ${HUDSON_BUILD_NUMBER}")
  67 else()
  68     set(HUDSON_BUILD_NUMBER 0)
  69     set(HUDSON_BUILD_ID "none")
  70 endif()
  71
  72 IF(APPLE)
  73     set(EVENT_INPUT_DEFAULT 1)
  74
  75     find_library(CORESERVICES_LIBRARY CoreServices)
  76     find_library(COCOA_LIBRARY Cocoa)
  77     list(APPEND PLATFORM_LIBS ${COCOA_LIBRARY} ${CORESERVICES_LIBRARY})
  78
  79 elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
  80     find_package(UDev)
  81
  82     if(UDEV_FOUND)
  83         set(EVENT_INPUT_DEFAULT 1)
  84     endif(UDEV_FOUND)
  85 endif()
  86
  87 find_package(Git)
  88 if (GIT_FOUND)
  89     execute_process(COMMAND git --git-dir ${PROJECT_SOURCE_DIR}/.git rev-parse  HEAD
  90         OUTPUT_VARIABLE REVISION
  91         OUTPUT_STRIP_TRAILING_WHITESPACE)
  92     message(STATUS "Git revision is ${REVISION}")
  93 else()
  94     set(REVISION "none")
  95 endif()
  96
  97 # FlightGear build options
  98 option(SIMGEAR_SHARED    "Set to ON when SimGear was built as a shared library" OFF)
  99 option(LOGGING           "Set to ON to build FlightGear with logging support (default)" ON)
 100 option(SP_FDMS           "Set to ON to build FlightGear with special-purpose FDMs" OFF)
 101 option(ENABLE_UIUC_MODEL "Set to ON to build FlightGear with UIUCModel FDM" OFF)
 102 option(ENABLE_LARCSIM    "Set to ON to build FlightGear with LaRCsim FDM" OFF)
 103 option(ENABLE_YASIM      "Set to ON to build FlightGear with YASIM FDM (default)" ON)
 104 option(ENABLE_JSBSIM     "Set to ON to build FlightGear with JSBSim FDM (default)" ON)
 105 option(EVENT_INPUT       "Set to ON to build FlightGear with event-based Input support" ${EVENT_INPUT_DEFAULT})
 106 option(ENABLE_LIBSVN     "Set to ON to build FlightGear/terrasync with libsvnclient support (default)" ON)
 107 option(ENABLE_RTI        "Set to ON to build FlightGear with RTI support" OFF)
 108 option(JPEG_FACTORY      "Set to ON to build FlightGear with JPEG-factory support" OFF)
 109 option(SYSTEM_SQLITE     "Set to ON to build FlightGear with the system's SQLite3 library" OFF)
 110
 111 # additional utilities
 112 option(ENABLE_FGADMIN    "Set to ON to build the FGADMIN application (default)" ON)
 113 option(WITH_FGPANEL      "Set to ON to build the fgpanel application (default)" ON)
 114 option(ENABLE_TESTS      "Set to ON to build test applications (default)" ON)
 115
 116 if(LOGGING)
 117     # nothing
 118 else()
 119     set(FG_NDEBUG 1)
 120 endif()
 121
 122 if(SP_FDMS)
 123     set(ENABLE_SP_FDM 1)
 124 endif()
 125
 126 # Setup MSVC 3rd party directories
 127 include( ConfigureMsvc3rdParty )
 128
 129 if(EVENT_INPUT)
 130     if(APPLE)
 131     elseif(CMAKE_SYSTEM_NAME MATCHES "Linux")
 132         if(NOT UDEV_FOUND)
 133             message(WARNING "UDev not found, event input is disabled!")
 134             set(EVENT_INPUT 0)
 135         else()
 136             add_definitions(-DWITH_EVENTINPUT)
 137             set(EVENT_INPUT_LIBRARIES ${UDEV_LIBRARIES})
 138             message(STATUS "event-based input enabled. Using ${UDEV_LIBRARIES}")
 139         endif()
 140     else()
 141         message(WARNING "event-based input is not supported on this platform yet")
 142     endif()
 143
 144     # Keep PLIB INPUT enabled as long as EventInput does not replace current joystick configurations.
 145     set(ENABLE_PLIB_JOYSTICK 1)
 146 else(EVENT_INPUT)
 147     set(ENABLE_PLIB_JOYSTICK 1)
 148 endif(EVENT_INPUT)
 149
 150 # check required dependencies
 151 find_package(Boost   REQUIRED)
 152 find_package(ZLIB    REQUIRED)
 153 find_package(Threads REQUIRED)
 154 find_package(OpenGL  REQUIRED)
 155 find_package(OpenAL  REQUIRED)
 156 find_package(OpenSceneGraph 3.0.0 REQUIRED osgText osgSim osgDB osgParticle osgFX osgUtil osgViewer osgGA)
 157
 158 if(ENABLE_FGADMIN)
 159     find_package(FLTK)
 160
 161     if ( FLTK_FOUND )
 162         if ( X11_Xinerama_FOUND )
 163             message(STATUS "Found X11_Xinerama...")
 164             list(APPEND FLTK_LIBRARIES ${X11_Xinerama_LIB})
 165         endif()
 166
 167         if ( X11_Xft_FOUND )
 168             message(STATUS "Found X11_Xft...")
 169             list(APPEND FLTK_LIBRARIES ${X11_Xft_LIB})
 170         endif()
 171
 172         message(STATUS "Using FLTK_LIBRARIES for fgadmin: ${FLTK_LIBRARIES}")
 173     endif ( FLTK_FOUND )
 174 endif(ENABLE_FGADMIN)
 175
 176 if(ENABLE_LIBSVN)
 177     find_package(SvnClient)
 178
 179     if(LIBSVN_FOUND)
 180         message(STATUS "libsvn found, enabling in terrasync")
 181         set(HAVE_SVN_CLIENT_H 1)
 182         set(HAVE_LIBSVN_CLIENT_1 1)
 183     else()
 184         message(STATUS "libsvn missing. Disabling...")
 185     endif(LIBSVN_FOUND)
 186 endif(ENABLE_LIBSVN)
 187
 188 if (SYSTEM_SQLITE)
 189     find_package(SQLite3 REQUIRED)
 190     set(CMAKE_REQUIRED_INCLUDES ${SQLITE3_INCLUDED_DIR})
 191     message(STATUS "Using system SQLite3 library")
 192 endif (SYSTEM_SQLITE)
 193
 194 # Sqlite always depends on the threading lib
 195 list(APPEND SQLITE3_LIBRARY ${CMAKE_THREAD_LIBS_INIT})
 196
 197 find_package(PLIB REQUIRED puaux pu js fnt)
 198
 199 # FlightGear and SimGear versions need to match
 200 find_package(SimGear ${FLIGHTGEAR_VERSION} REQUIRED)
 201
 202 if (JPEG_FACTORY)
 203     # check simgear was built with JPEG-factory support
 204     find_package(JPEG REQUIRED)
 205     include_directories(${JPEG_INCLUDE_DIR})
 206
 207     set(CMAKE_REQUIRED_INCLUDES
 208         ${SIMGEAR_INCLUDE_DIR}
 209         ${JPEG_INCLUDE_DIR}
 210         ${OPENSCENEGRAPH_INCLUDE_DIRS})
 211
 212     check_cxx_source_compiles(
 213         "#include <simgear/screen/jpgfactory.hxx>
 214         int main()    { return 0; } "
 215         FG_JPEG_SERVER)
 216
 217     if (NOT FG_JPEG_SERVER)
 218         message(STATUS "JPEG server support requested, but SimGear was built without JPEG support")
 219     endif()
 220 endif()
 221
 222 check_include_file(unistd.h   HAVE_UNISTD_H)
 223 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 224 check_include_file(windows.h  HAVE_WINDOWS_H)
 225
 226 # check optionally supported dependencies
 227 find_package(GooglePerfTools)
 228
 229 if(ENABLE_RTI)
 230     find_package(RTI)
 231     if(RTI_FOUND)
 232         set(FG_HAVE_HLA 1)
 233     endif(RTI_FOUND)
 234 endif(ENABLE_RTI)
 235
 236 if(CMAKE_COMPILER_IS_GNUCXX)
 237     set(WARNING_FLAGS_CXX "-Wall")
 238     set(WARNING_FLAGS_C   "-Wall")
 239 endif(CMAKE_COMPILER_IS_GNUCXX)
 240
 241 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 242    set (WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual")
 243    set (WARNING_FLAGS_C   "-Wall")
 244 endif()
 245
 246 if(WIN32)
 247
 248     if(MSVC)
 249         # turn off various warnings
 250         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 251         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 252         # endforeach(warning)
 253
 254         set(MSVC_FLAGS "-DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS")
 255         if (${MSVC_VERSION} GREATER 1599)
 256             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 257         endif (${MSVC_VERSION} GREATER 1599)
 258     endif(MSVC)
 259
 260     set(NOMINMAX 1)
 261 endif(WIN32)
 262
 263 set (BOOST_CXX_FLAGS "-DBOOST_MULTI_INDEX_DISABLE_SERIALIZATION -DBOOST_BIMAP_DISABLE_SERIALIZATION")
 264
 265 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS} -D_REENTRANT")
 266 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} -D_REENTRANT ${BOOST_CXX_FLAGS}")
 267 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 268
 269 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 270     ${Boost_INCLUDE_DIRS}
 271     ${ZLIB_INCLUDE_DIR}
 272     ${OPENGL_INCLUDE_DIR}
 273     ${OPENAL_INCLUDE_DIR}
 274     ${SIMGEAR_INCLUDE_DIR}
 275     ${PLIB_INCLUDE_DIR} )
 276
 277 include_directories(${PROJECT_SOURCE_DIR}/src)
 278
 279 # following is needed, because config.h is include 'bare', whereas
 280 # version.h is included as <Include/version.h> - this should be cleaned up
 281 include_directories(${PROJECT_BINARY_DIR}/src)
 282 include_directories(${PROJECT_BINARY_DIR}/src/Include)
 283
 284 add_definitions(-DHAVE_CONFIG_H)
 285
 286 check_function_exists(mkfifo HAVE_MKFIFO)
 287
 288 # configure a header file to pass some of the CMake settings
 289 # to the source code
 290 configure_file (
 291     "${PROJECT_SOURCE_DIR}/src/Include/config_cmake.h.in"
 292     "${PROJECT_BINARY_DIR}/src/Include/config.h"
 293 )
 294
 295 #and the same for the version header
 296 configure_file (
 297     "${PROJECT_SOURCE_DIR}/src/Include/version.h.cmake-in"
 298     "${PROJECT_BINARY_DIR}/src/Include/version.h"
 299 )
 300
 301 add_subdirectory(src)
 302 add_subdirectory(utils)
 303 add_subdirectory(man)
 304
 305 #-----------------------------------------------------------------------------
 306 ### uninstall target
 307 #-----------------------------------------------------------------------------
 308 CONFIGURE_FILE(
 309     "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 310     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 311     IMMEDIATE @ONLY)
 312 ADD_CUSTOM_TARGET(uninstall
 313     "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")