CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2 include (CheckFunctionExists)
   3 include (CheckIncludeFile)
   4 include (CheckCXXSourceCompiles)
   5 include (CheckCXXCompilerFlag)
   6
   7 project(SimGear)
   8
   9 # read 'version' file into a variable (stripping any newlines or spaces)
  10 file(READ version versionFile)
  11 string(STRIP ${versionFile} SIMGEAR_VERSION)
  12
  13 set(FIND_LIBRARY_USE_LIB64_PATHS ON)
  14
  15 # use simgear version also as the SO version (if building SOs)
  16 SET(SIMGEAR_SOVERSION ${SIMGEAR_VERSION})
  17
  18 # Warning when build is not an out-of-source build.
  19 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  20 if(InSourceBuild)
  21     message(WARNING  "Avoid building inside the source tree!")
  22     message(WARNING  "Create a separate build directory instead (i.e. 'sgbuild') and call CMake from there: ")
  23     message(WARNING  "  mkdir ../sgbuild && cd ../sgbuild && cmake ${CMAKE_SOURCE_DIR}")
  24 endif(InSourceBuild)
  25
  26 if (NOT EMBEDDED_SIMGEAR)
  27     #packaging
  28     SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  29     SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  30     SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Simulation support libraries for FlightGear and related projects")
  31     SET(CPACK_PACKAGE_VENDOR "The FlightGear project")
  32     SET(CPACK_GENERATOR "TBZ2")
  33     SET(CPACK_INSTALL_CMAKE_PROJECTS  ${CMAKE_CURRENT_BINARY_DIR};SimGear;ALL;/)
  34
  35
  36     # split version string into components, note CMAKE_MATCH_0 is the entire regexp match
  37     string(REGEX MATCH "([0-9]+)\\.([0-9]+)\\.([0-9]+)" CPACK_PACKAGE_VERSION ${SIMGEAR_VERSION} )
  38     set(CPACK_PACKAGE_VERSION_MAJOR ${CMAKE_MATCH_1})
  39     set(CPACK_PACKAGE_VERSION_MINOR ${CMAKE_MATCH_2})
  40     set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_3})
  41
  42     message(STATUS "version is ${CPACK_PACKAGE_VERSION_MAJOR} dot ${CPACK_PACKAGE_VERSION_MINOR} dot ${CPACK_PACKAGE_VERSION_PATCH}")
  43
  44     set(CPACK_SOURCE_GENERATOR TBZ2)
  45     set(CPACK_SOURCE_PACKAGE_FILE_NAME "simgear-${SIMGEAR_VERSION}" CACHE INTERNAL "tarball basename")
  46     set(CPACK_SOURCE_IGNORE_FILES
  47       "^${PROJECT_SOURCE_DIR}/.git;\\\\.gitignore;Makefile.am;~$;${CPACK_SOURCE_IGNORE_FILES}")
  48
  49     message(STATUS "ignoring: ${CPACK_SOURCE_IGNORE_FILES}")
  50
  51     include (CPack)
  52 endif()
  53
  54 # We have some custom .cmake scripts not in the official distribution.
  55 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  56
  57 # Change the default build type to something fast
  58 if(NOT CMAKE_BUILD_TYPE)
  59   set(CMAKE_BUILD_TYPE Release CACHE STRING
  60       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  61       FORCE)
  62 endif(NOT CMAKE_BUILD_TYPE)
  63
  64 # Determine name of library installation directory, i.e. "lib" vs "lib64", which
  65 # differs between all Debian-based vs all other Linux distros.
  66 # See cmake bug #11964, http://cmake.org/gitweb?p=cmake.git;a=commit;h=126c993d
  67 # GNUInstallDirs requires CMake >= 2.8.5, use own file for older cmake
  68 if(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  69   include(GNUInstallDirs)
  70 else(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  71   include(OldGNUInstallDirs)
  72 endif(${CMAKE_VERSION} VERSION_GREATER 2.8.4)
  73 message(STATUS "Library installation directory: ${CMAKE_INSTALL_LIBDIR}")
  74
  75 #####################################################################################
  76 # Configure library search paths
  77 #####################################################################################
  78
  79 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
  80     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
  81     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
  82     # add paths manually
  83     # see http://www.cmake.org/Bug/view.php?id=12049 and
  84     # http://www.cmake.org/Bug/view.php?id=12037
  85     list(APPEND ADDITIONAL_LIBRARY_PATHS
  86          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  87          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
  88          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
  89     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
  90 endif()
  91
  92 if(NOT MSVC)
  93     # TBD: are these really necessary? Aren't they considered by cmake automatically?
  94     list(APPEND ADDITIONAL_LIBRARY_PATHS
  95          /opt/local
  96          /usr/local
  97          /usr)
  98 endif()
  99 #####################################################################################
 100
 101 if (NOT MSVC)
 102 option(SIMGEAR_SHARED   "Set to ON to build SimGear as a shared library/framework" OFF)
 103 option(SYSTEM_EXPAT     "Set to ON to build SimGear using the system libExpat" OFF)
 104 else()
 105 # Building SimGear DLLs is currently not supported for MSVC.
 106 set(SIMGEAR_SHARED OFF)
 107 # Using a system expat is currently not supported for MSVC - it would require shared simgear (DLL).
 108 set(SYSTEM_EXPAT OFF)
 109 endif()
 110
 111 option(SIMGEAR_HEADLESS "Set to ON to build SimGear without GUI/graphics support" OFF)
 112 option(JPEG_FACTORY     "Enable JPEG-factory support" OFF)
 113 option(ENABLE_RTI       "Set to ON to build SimGear with RTI support" OFF)
 114 option(ENABLE_TESTS     "Set to OFF to disable building SimGear's test applications" ON)
 115 option(ENABLE_SOUND     "Set to OFF to disable building SimGear's sound support" ON)
 116 option(ENABLE_PKGUTIL   "Set to ON to build the sg_pkgutil application (default)" ON)
 117
 118 if (MSVC)
 119   GET_FILENAME_COMPONENT(PARENT_DIR ${PROJECT_BINARY_DIR} PATH)
 120   if (CMAKE_CL_64)
 121     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty.x64")
 122   else (CMAKE_CL_64)
 123     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty")
 124   endif (CMAKE_CL_64)
 125   if (EXISTS ${TEST_3RDPARTY_DIR})
 126     set(MSVC_3RDPARTY_ROOT ${PARENT_DIR} CACHE PATH "Location where the third-party dependencies are extracted")
 127   else (EXISTS ${TEST_3RDPARTY_DIR})
 128     set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 129   endif (EXISTS ${TEST_3RDPARTY_DIR})
 130 else (MSVC)
 131   set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 132 endif (MSVC)
 133
 134 if (MSVC AND MSVC_3RDPARTY_ROOT)
 135   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_ROOT}")
 136   set( OSG_MSVC "msvc" )
 137   if (${MSVC_VERSION} EQUAL 1700)
 138       set( OSG_MSVC ${OSG_MSVC}110 )
 139   elseif (${MSVC_VERSION} EQUAL 1600)
 140       set( OSG_MSVC ${OSG_MSVC}100 )
 141   else (${MSVC_VERSION} EQUAL 1700)
 142       set( OSG_MSVC ${OSG_MSVC}90 )
 143   endif (${MSVC_VERSION} EQUAL 1700)
 144   if (CMAKE_CL_64)
 145       set( OSG_MSVC ${OSG_MSVC}-64 )
 146       set( MSVC_3RDPARTY_DIR 3rdParty.x64 )
 147   else (CMAKE_CL_64)
 148       set( MSVC_3RDPARTY_DIR 3rdParty )
 149   endif (CMAKE_CL_64)
 150
 151   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/lib )
 152   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/include)
 153   find_path(BOOST_ROOT boost/version.hpp
 154                         ${MSVC_3RDPARTY_ROOT}/boost
 155                         ${MSVC_3RDPARTY_ROOT}/boost_1_52_0
 156                         ${MSVC_3RDPARTY_ROOT}/boost_1_51_0
 157                         ${MSVC_3RDPARTY_ROOT}/boost_1_50_0
 158                         ${MSVC_3RDPARTY_ROOT}/boost_1_49_0
 159                         ${MSVC_3RDPARTY_ROOT}/boost_1_48_0
 160                         ${MSVC_3RDPARTY_ROOT}/boost_1_47_0
 161                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_1
 162                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_0
 163                         ${MSVC_3RDPARTY_ROOT}/boost_1_45_0
 164                         ${MSVC_3RDPARTY_ROOT}/boost_1_44_0
 165                         )
 166   # set (BOOST_ROOT ${MSVC_3RDPARTY_ROOT}/boost_1_44_0)
 167   message(STATUS "BOOST_ROOT is ${BOOST_ROOT}")
 168   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 169   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib)
 170 endif (MSVC AND MSVC_3RDPARTY_ROOT)
 171
 172 if(APPLE)
 173   find_library(CORE_SERVICES_LIBRARY CoreServices)
 174 endif()
 175
 176 find_package(Boost REQUIRED)
 177 set (BOOST_CXX_FLAGS "-DBOOST_MULTI_INDEX_DISABLE_SERIALIZATION -DBOOST_BIMAP_DISABLE_SERIALIZATION")
 178
 179 if(SIMGEAR_HEADLESS)
 180     message(STATUS "SimGear mode: HEADLESS")
 181     set(ENABLE_SOUND 0)
 182 else()
 183     message(STATUS "SimGear mode: NORMAL")
 184     find_package(OpenGL REQUIRED)
 185
 186     if (ENABLE_SOUND)
 187         find_package(OpenAL REQUIRED)
 188         message(STATUS "Sound support: ENABLED")
 189     endif(ENABLE_SOUND)
 190
 191     find_package(OpenSceneGraph 3.0.0 REQUIRED osgText osgSim osgDB osgParticle osgGA osgUtil)
 192 endif(SIMGEAR_HEADLESS)
 193
 194 if(JPEG_FACTORY)
 195     message(STATUS "JPEG-factory: ENABLED")
 196     find_package(JPEG REQUIRED)
 197     include_directories(${JPEG_INCLUDE_DIR})
 198 else()
 199     message(STATUS "JPEG-factory: DISABLED")
 200 endif(JPEG_FACTORY)
 201
 202 find_package(ZLIB REQUIRED)
 203 find_package(Threads REQUIRED)
 204
 205 if (SYSTEM_EXPAT)
 206     message(STATUS "Requested to use system Expat library, forcing SIMGEAR_SHARED to true")
 207     set(SIMGEAR_SHARED ON)
 208     find_package(EXPAT REQUIRED)
 209
 210 else()
 211     message(STATUS "Using built-in expat code")
 212     # XML_STATIC is important to avoid sg_expat_external.h
 213     # declaring symbols as declspec(import)
 214     add_definitions(-DHAVE_EXPAT_CONFIG_H -DXML_STATIC)
 215     set(EXPAT_INCLUDE_DIRS
 216             ${PROJECT_SOURCE_DIR}/3rdparty/expat
 217             ${PROJECT_BINARY_DIR}/3rdparty/expat)
 218 endif(SYSTEM_EXPAT)
 219
 220 include_directories(${EXPAT_INCLUDE_DIRS})
 221
 222 check_include_file(inttypes.h HAVE_INTTYPES_H)
 223 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 224 check_include_file(sys/timeb.h HAVE_SYS_TIMEB_H)
 225 check_include_file(unistd.h HAVE_UNISTD_H)
 226 check_include_file(windows.h HAVE_WINDOWS_H)
 227
 228 if(HAVE_INTTYPES_H)
 229   # ShivaVG needs inttypes.h
 230   add_definitions(-DHAVE_INTTYPES_H)
 231 endif()
 232
 233 if(ENABLE_RTI)
 234     # See if we have any rti library variant installed
 235     message(STATUS "RTI: ENABLED")
 236     find_package(RTI)
 237 else()
 238     message(STATUS "RTI: DISABLED")
 239 endif(ENABLE_RTI)
 240
 241 check_function_exists(gettimeofday HAVE_GETTIMEOFDAY)
 242 check_function_exists(ftime HAVE_FTIME)
 243 check_function_exists(timegm HAVE_TIMEGM)
 244 check_function_exists(rint HAVE_RINT)
 245 check_function_exists(mkdtemp HAVE_MKDTEMP)
 246 check_function_exists(bcopy HAVE_BCOPY)
 247 check_function_exists(mmap HAVE_MMAP)
 248
 249 if(HAVE_UNISTD_H)
 250     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 251     check_cxx_source_compiles(
 252        "#include <unistd.h>
 253         #if !defined(_POSIX_TIMERS) || (0 >= _POSIX_TIMERS)
 254             #error clock_gettime is not supported
 255         #endif
 256
 257         int main() { return 0; }
 258         "
 259         HAVE_CLOCK_GETTIME)
 260 endif(HAVE_UNISTD_H)
 261
 262 set(RT_LIBRARY "")
 263 if(HAVE_CLOCK_GETTIME)
 264     check_library_exists(rt clock_gettime "" HAVE_RT)
 265     if(HAVE_RT)
 266         set(RT_LIBRARY rt)
 267     endif(HAVE_RT)
 268 endif(HAVE_CLOCK_GETTIME)
 269
 270 set(DL_LIBRARY "")
 271 check_cxx_source_compiles(
 272     "#include <dlfcn.h>
 273     int main(void) {
 274         return 0;
 275     }
 276     "
 277     HAVE_DLFCN_H)
 278
 279 if(HAVE_DLFCN_H)
 280     check_library_exists(dl dlerror "" HAVE_DL)
 281     set(DL_LIBRARY "dl")
 282 endif()
 283
 284 SET(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "add a postfix, usually 'd' on windows")
 285 SET(CMAKE_RELEASE_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 286 SET(CMAKE_RELWITHDEBINFO_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 287 SET(CMAKE_MINSIZEREL_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 288
 289 # isnan might not be real symbol, so can't check using function_exists
 290 check_cxx_source_compiles(
 291     "#include <cmath>
 292     void f() { isnan(0.0);} "
 293     HAVE_ISNAN)
 294
 295 check_cxx_source_compiles(
 296     "#include <cmath>
 297     void f() { std::isnan(0.0);} "
 298     HAVE_STD_ISNAN)
 299
 300 if(CMAKE_COMPILER_IS_GNUCXX)
 301     set(WARNING_FLAGS_CXX "-Wall")
 302     set(WARNING_FLAGS_C   "-Wall")
 303
 304     # certain GCC versions don't provide the atomic builds, and hence
 305     # require is to provide them in SGAtomic.cxx
 306     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 307     check_cxx_source_compiles(
 308        "int main() { unsigned mValue; return __sync_add_and_fetch(&mValue, 1); }"
 309         GCC_ATOMIC_BUILTINS_FOUND)
 310 endif(CMAKE_COMPILER_IS_GNUCXX)
 311
 312 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 313    set(WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual")
 314    set(WARNING_FLAGS_C   "-Wall")
 315 endif()
 316
 317 if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 318 # boost goes haywire wrt static asserts
 319     check_cxx_compiler_flag(-Wno-unused-local-typedefs HAS_NOWARN_UNUSED_TYPEDEFS)
 320     if(HAS_NOWARN_UNUSED_TYPEDEFS)
 321         set(WARNING_FLAGS_CXX " ${WARNING_FLAGS_CXX} -Wno-unused-local-typedefs")
 322     endif()
 323 endif()
 324
 325 if(WIN32)
 326
 327     if(MINGW)
 328         add_definitions(-D_WIN32_WINNT=0x501)
 329     endif()
 330
 331     if(MSVC)
 332         # turn off various warnings
 333         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 334         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 335         # endforeach(warning)
 336
 337         set(MSVC_FLAGS "-DWIN32 -DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS /wd4996 /wd4250 -Dstrdup=_strdup")
 338         if (${MSVC_VERSION} GREATER 1599)
 339             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 340         endif (${MSVC_VERSION} GREATER 1599)
 341     endif(MSVC)
 342
 343     # assumed on Windows
 344     set(HAVE_GETLOCALTIME 1)
 345
 346     set( WINSOCK_LIBRARY "ws2_32.lib" )
 347     set( RT_LIBRARY "winmm" )
 348 endif(WIN32)
 349
 350 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS}")
 351 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} ${BOOST_CXX_FLAGS}")
 352 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 353
 354 include_directories(${PROJECT_SOURCE_DIR})
 355 include_directories(${PROJECT_SOURCE_DIR}/simgear/canvas/ShivaVG/include)
 356 include_directories(${PROJECT_BINARY_DIR}/simgear)
 357
 358 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 359     ${Boost_INCLUDE_DIRS}
 360     ${ZLIB_INCLUDE_DIR}
 361     ${OPENAL_INCLUDE_DIR}
 362     ${LibArchive_INCLUDE_DIRS}
 363 )
 364
 365 add_definitions(-DHAVE_CONFIG_H)
 366
 367 # configure a header file to pass some of the CMake settings
 368 # to the source code
 369 configure_file (
 370   "${PROJECT_SOURCE_DIR}/simgear/simgear_config_cmake.h.in"
 371   "${PROJECT_BINARY_DIR}/simgear/simgear_config.h"
 372   )
 373
 374 if(ENABLE_TESTS)
 375     # enable CTest / make test target
 376     message(STATUS "Tests: ENABLED")
 377
 378     include (Dart)
 379     enable_testing()
 380 else()
 381     message(STATUS "Tests: DISABLED")
 382 endif(ENABLE_TESTS)
 383
 384 # always set TEST_LIBS as it is also used by other tools/applications
 385 set(TEST_LIBS_INTERNAL_CORE
 386     ${CMAKE_THREAD_LIBS_INIT}
 387     ${ZLIB_LIBRARY}
 388     ${WINSOCK_LIBRARY}
 389     ${RT_LIBRARY}
 390     ${DL_LIBRARY}
 391     ${CORE_SERVICES_LIBRARY})
 392 set(TEST_LIBS SimGearCore ${TEST_LIBS_INTERNAL_CORE})
 393
 394 if(NOT SIMGEAR_HEADLESS)
 395     set(TEST_LIBS SimGearScene ${OPENGL_LIBRARIES} ${TEST_LIBS})
 396 endif()
 397
 398 install (FILES ${PROJECT_BINARY_DIR}/simgear/simgear_config.h  DESTINATION include/simgear/)
 399
 400 add_subdirectory(3rdparty)
 401 add_subdirectory(simgear)
 402
 403 if (NOT EMBEDDED_SIMGEAR)
 404 #-----------------------------------------------------------------------------
 405 ### uninstall target
 406 #-----------------------------------------------------------------------------
 407 CONFIGURE_FILE(
 408   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 409   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 410   IMMEDIATE @ONLY)
 411 ADD_CUSTOM_TARGET(uninstall
 412   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
 413
 414 endif()
 415