CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8.11)
   2
   3 if(COMMAND cmake_policy)
   4    if(POLICY CMP0054)
   5        cmake_policy(SET CMP0054 NEW)
   6    endif()
   7    if(POLICY CMP0042)
   8        cmake_policy(SET CMP0042 NEW)
   9    endif()
  10 endif()
  11
  12 include (CheckFunctionExists)
  13 include (CheckIncludeFile)
  14 include (CheckLibraryExists)
  15 include (CheckCXXSourceCompiles)
  16 include (CheckCXXCompilerFlag)
  17 include (GenerateExportHeader)
  18
  19 # using 10.7 because boost requires libc++ and 10.6 doesn't include it
  20 set(CMAKE_OSX_DEPLOYMENT_TARGET 10.7)
  21
  22 # only relevant for building shared libs but let's set it regardless
  23 set(CMAKE_OSX_RPATH 1)
  24
  25 # Set the C++ standard to C++98 to avoid compilation errors on GCC 6 (which
  26 # defaults to C++14).
  27 if(CMAKE_VERSION VERSION_LESS "3.1")
  28   if(CMAKE_COMPILER_IS_GNUCXX)
  29     set (CMAKE_CXX_FLAGS "-std=gnu++98 ${CMAKE_CXX_FLAGS}")
  30   endif()
  31 else()
  32   set (CMAKE_CXX_STANDARD 98)
  33 endif()
  34
  35 project(SimGear)
  36
  37 # read 'version' file into a variable (stripping any newlines or spaces)
  38 file(READ version versionFile)
  39 string(STRIP ${versionFile} SIMGEAR_VERSION)
  40
  41 # add a dependency on the versino file
  42 set_property(DIRECTORY APPEND PROPERTY CMAKE_CONFIGURE_DEPENDS version)
  43
  44 set(FIND_LIBRARY_USE_LIB64_PATHS ON)
  45
  46 # use simgear version also as the SO version (if building SOs)
  47 SET(SIMGEAR_SOVERSION ${SIMGEAR_VERSION})
  48
  49 # Warning when build is not an out-of-source build.
  50 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  51 if(InSourceBuild)
  52     message(WARNING  "Avoid building inside the source tree!")
  53     message(WARNING  "Create a separate build directory instead (i.e. 'sgbuild') and call CMake from there: ")
  54     message(WARNING  "  mkdir ../sgbuild && cd ../sgbuild && cmake ${CMAKE_SOURCE_DIR}")
  55 endif(InSourceBuild)
  56
  57 #packaging
  58 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  59 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  60 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Simulation support libraries for FlightGear and related projects")
  61 SET(CPACK_PACKAGE_VENDOR "The FlightGear project")
  62 SET(CPACK_GENERATOR "TBZ2")
  63 SET(CPACK_INSTALL_CMAKE_PROJECTS  ${CMAKE_CURRENT_BINARY_DIR};SimGear;ALL;/)
  64
  65
  66 # split version string into components, note CMAKE_MATCH_0 is the entire regexp match
  67 string(REGEX MATCH "([0-9]+)\\.([0-9]+)\\.([0-9]+)" CPACK_PACKAGE_VERSION ${SIMGEAR_VERSION} )
  68 set(CPACK_PACKAGE_VERSION_MAJOR ${CMAKE_MATCH_1})
  69 set(CPACK_PACKAGE_VERSION_MINOR ${CMAKE_MATCH_2})
  70 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_3})
  71
  72 message(STATUS "version is ${CPACK_PACKAGE_VERSION_MAJOR} dot ${CPACK_PACKAGE_VERSION_MINOR} dot ${CPACK_PACKAGE_VERSION_PATCH}")
  73
  74 set(CPACK_SOURCE_GENERATOR TBZ2)
  75 set(CPACK_SOURCE_PACKAGE_FILE_NAME "simgear-${SIMGEAR_VERSION}" CACHE INTERNAL "tarball basename")
  76 set(CPACK_SOURCE_IGNORE_FILES
  77   "^${PROJECT_SOURCE_DIR}/.git;\\\\.gitignore;Makefile.am;~$;${CPACK_SOURCE_IGNORE_FILES}")
  78
  79 message(STATUS "ignoring: ${CPACK_SOURCE_IGNORE_FILES}")
  80
  81 include (CPack)
  82
  83 # We have some custom .cmake scripts not in the official distribution.
  84 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  85
  86 # Change the default build type to something fast
  87 if(NOT CMAKE_BUILD_TYPE)
  88   set(CMAKE_BUILD_TYPE Release CACHE STRING
  89       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  90       FORCE)
  91 endif(NOT CMAKE_BUILD_TYPE)
  92
  93 # Determine name of library installation directory, i.e. "lib" vs "lib64", which
  94 # differs between all Debian-based vs all other Linux distros.
  95 # See cmake bug #11964, http://cmake.org/gitweb?p=cmake.git;a=commit;h=126c993d
  96 include(GNUInstallDirs)
  97 message(STATUS "Library installation directory: ${CMAKE_INSTALL_LIBDIR}")
  98
  99 #####################################################################################
 100 # Configure library search paths
 101 #####################################################################################
 102
 103 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
 104     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
 105     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
 106     # add paths manually
 107     # see http://www.cmake.org/Bug/view.php?id=12049 and
 108     # http://www.cmake.org/Bug/view.php?id=12037
 109     list(APPEND ADDITIONAL_LIBRARY_PATHS
 110          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
 111          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
 112          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
 113     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
 114 endif()
 115
 116 #####################################################################################
 117
 118 if (NOT MSVC)
 119 option(SIMGEAR_SHARED   "Set to ON to build SimGear as a shared library/framework" OFF)
 120 option(SYSTEM_EXPAT     "Set to ON to build SimGear using the system expat library" OFF)
 121 option(SYSTEM_UDNS      "Set to ON to build SimGear using the system udns library" OFF)
 122 else()
 123 # Building SimGear DLLs is currently not supported for MSVC.
 124 set(SIMGEAR_SHARED OFF)
 125 # Using external 3rd party libraries is currently not supported for MSVC - it would require shared simgear (DLL).
 126 set(SYSTEM_EXPAT OFF)
 127 set(SYSTEM_UDNS OFF)
 128 endif()
 129
 130 option(SIMGEAR_HEADLESS "Set to ON to build SimGear without GUI/graphics support" OFF)
 131 option(ENABLE_RTI       "Set to ON to build SimGear with RTI support" OFF)
 132 option(ENABLE_TESTS     "Set to OFF to disable building SimGear's test applications" ON)
 133 option(ENABLE_SOUND     "Set to OFF to disable building SimGear's sound support" ON)
 134 option(ENABLE_PKGUTIL   "Set to ON to build the sg_pkgutil application (default)" ON)
 135 option(ENABLE_DNS       "Set to ON to use udns library and DNS service resolver" ON)
 136
 137 if (MSVC)
 138   GET_FILENAME_COMPONENT(PARENT_DIR ${PROJECT_BINARY_DIR} PATH)
 139   if (CMAKE_CL_64)
 140     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty.x64")
 141   else (CMAKE_CL_64)
 142     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty")
 143   endif (CMAKE_CL_64)
 144   if (EXISTS ${TEST_3RDPARTY_DIR})
 145     set(MSVC_3RDPARTY_ROOT ${PARENT_DIR} CACHE PATH "Location where the third-party dependencies are extracted")
 146   else (EXISTS ${TEST_3RDPARTY_DIR})
 147     set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 148   endif (EXISTS ${TEST_3RDPARTY_DIR})
 149 else (MSVC)
 150   set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 151 endif (MSVC)
 152
 153 if (MSVC AND MSVC_3RDPARTY_ROOT)
 154   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_ROOT}")
 155
 156   set( OSG_MSVC "msvc" )
 157   if (${MSVC_VERSION} EQUAL 1900)
 158       set( OSG_MSVC ${OSG_MSVC}140 )
 159   elseif (${MSVC_VERSION} EQUAL 1800)
 160       set( OSG_MSVC ${OSG_MSVC}120 )
 161   elseif (${MSVC_VERSION} EQUAL 1700)
 162       set( OSG_MSVC ${OSG_MSVC}110 )
 163   elseif (${MSVC_VERSION} EQUAL 1600)
 164       set( OSG_MSVC ${OSG_MSVC}100 )
 165   endif ()
 166   if (CMAKE_CL_64)
 167       set( OSG_MSVC ${OSG_MSVC}-64 )
 168       set( MSVC_3RDPARTY_DIR 3rdParty.x64 )
 169   else (CMAKE_CL_64)
 170       set( MSVC_3RDPARTY_DIR 3rdParty )
 171   endif (CMAKE_CL_64)
 172
 173   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/lib )
 174   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/include)
 175
 176   GET_FILENAME_COMPONENT(MSVC_ROOT_PARENT_DIR ${MSVC_3RDPARTY_ROOT} PATH)
 177   find_path(BOOST_ROOT boost/version.hpp
 178       PATHS
 179       ${MSVC_ROOT_PARENT_DIR}
 180                         ${MSVC_3RDPARTY_ROOT}/boost
 181                         ${MSVC_3RDPARTY_ROOT}/boost_1_52_0
 182                         ${MSVC_3RDPARTY_ROOT}/boost_1_51_0
 183                         ${MSVC_3RDPARTY_ROOT}/boost_1_50_0
 184                         ${MSVC_3RDPARTY_ROOT}/boost_1_49_0
 185                         ${MSVC_3RDPARTY_ROOT}/boost_1_48_0
 186                         ${MSVC_3RDPARTY_ROOT}/boost_1_47_0
 187                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_1
 188                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_0
 189                         ${MSVC_3RDPARTY_ROOT}/boost_1_45_0
 190                         ${MSVC_3RDPARTY_ROOT}/boost_1_44_0
 191                         )
 192   # set (BOOST_ROOT ${MSVC_3RDPARTY_ROOT}/boost_1_44_0)
 193   message(STATUS "BOOST_ROOT is ${BOOST_ROOT}")
 194   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 195   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib)
 196 endif (MSVC AND MSVC_3RDPARTY_ROOT)
 197
 198 if(APPLE)
 199   find_library(COCOA_LIBRARY Cocoa)
 200
 201   # using 10.7 because boost requires libc++ and 10.6 doesn't include it
 202   SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.7")
 203 endif()
 204
 205 if(${CMAKE_SYSTEM_NAME} MATCHES "Linux" OR
 206         ${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD")
 207     find_package(Threads REQUIRED)
 208 endif()
 209
 210 # Somehow this only works if included before searching for Boost...
 211 include(BoostTestTargets)
 212
 213 find_package(Boost REQUIRED)
 214 set (BOOST_CXX_FLAGS "-DBOOST_BIMAP_DISABLE_SERIALIZATION")
 215
 216 if(SIMGEAR_HEADLESS)
 217     message(STATUS "SimGear mode: HEADLESS")
 218     set(ENABLE_SOUND 0)
 219 else()
 220     message(STATUS "SimGear mode: NORMAL")
 221     find_package(OpenGL REQUIRED)
 222
 223     if (ENABLE_SOUND)
 224         find_package(OpenAL REQUIRED)
 225         message(STATUS "Sound support: ENABLED")
 226     endif(ENABLE_SOUND)
 227
 228     find_package(OpenSceneGraph 3.2.0 REQUIRED osgText osgSim osgDB osgParticle osgGA osgViewer osgUtil)
 229 endif(SIMGEAR_HEADLESS)
 230
 231 find_package(ZLIB REQUIRED)
 232 find_package(CURL REQUIRED)
 233
 234 if (SYSTEM_EXPAT)
 235     message(STATUS "Requested to use system Expat library, forcing SIMGEAR_SHARED to true")
 236     set(SIMGEAR_SHARED ON)
 237     find_package(EXPAT REQUIRED)
 238
 239 else()
 240     message(STATUS "Using built-in expat code")
 241     # XML_STATIC is important to avoid sg_expat_external.h
 242     # declaring symbols as declspec(import)
 243     add_definitions(-DHAVE_EXPAT_CONFIG_H -DXML_STATIC)
 244     set(EXPAT_INCLUDE_DIRS
 245             ${PROJECT_SOURCE_DIR}/3rdparty/expat
 246             ${PROJECT_BINARY_DIR}/3rdparty/expat)
 247 endif(SYSTEM_EXPAT)
 248
 249 include_directories(${EXPAT_INCLUDE_DIRS})
 250
 251 check_include_file(inttypes.h HAVE_INTTYPES_H)
 252 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 253 check_include_file(sys/timeb.h HAVE_SYS_TIMEB_H)
 254 check_include_file(unistd.h HAVE_UNISTD_H)
 255 check_include_file(windows.h HAVE_WINDOWS_H)
 256
 257 if(HAVE_INTTYPES_H)
 258   # ShivaVG needs inttypes.h
 259   add_definitions(-DHAVE_INTTYPES_H)
 260 endif()
 261
 262 if(ENABLE_RTI)
 263     # See if we have any rti library variant installed
 264     message(STATUS "RTI: ENABLED")
 265     find_package(RTI)
 266 else()
 267     message(STATUS "RTI: DISABLED")
 268 endif(ENABLE_RTI)
 269
 270 check_function_exists(gettimeofday HAVE_GETTIMEOFDAY)
 271 check_function_exists(ftime HAVE_FTIME)
 272 check_function_exists(timegm HAVE_TIMEGM)
 273 check_function_exists(rint HAVE_RINT)
 274 check_function_exists(mkdtemp HAVE_MKDTEMP)
 275 check_function_exists(bcopy HAVE_BCOPY)
 276 check_function_exists(mmap HAVE_MMAP)
 277
 278 if(HAVE_UNISTD_H)
 279     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 280     check_cxx_source_compiles(
 281        "#include <unistd.h>
 282         #if !defined(_POSIX_TIMERS) || (0 >= _POSIX_TIMERS)
 283             #error clock_gettime is not supported
 284         #endif
 285
 286         int main() { return 0; }
 287         "
 288         HAVE_CLOCK_GETTIME)
 289 endif(HAVE_UNISTD_H)
 290
 291 set(RT_LIBRARY "")
 292 if(HAVE_CLOCK_GETTIME)
 293     check_library_exists(rt clock_gettime "" HAVE_RT)
 294     if(HAVE_RT)
 295         set(RT_LIBRARY rt)
 296     endif(HAVE_RT)
 297 endif(HAVE_CLOCK_GETTIME)
 298
 299 set(DL_LIBRARY "")
 300 check_cxx_source_compiles(
 301     "#include <dlfcn.h>
 302     int main(void) {
 303         return 0;
 304     }
 305     "
 306     HAVE_DLFCN_H)
 307
 308 if(HAVE_DLFCN_H)
 309     check_library_exists(dl dlerror "" HAVE_DL)
 310     if(HAVE_DL)
 311         set(DL_LIBRARY "dl")
 312     endif()
 313 endif()
 314
 315 SET(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "add a postfix, usually 'd' on windows")
 316 SET(CMAKE_RELEASE_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 317 SET(CMAKE_RELWITHDEBINFO_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 318 SET(CMAKE_MINSIZEREL_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 319
 320 # isnan might not be real symbol, so can't check using function_exists
 321 check_cxx_source_compiles(
 322     "#include <cmath>
 323     int main() { return isnan(0.0);} "
 324     HAVE_ISNAN)
 325
 326 check_cxx_source_compiles(
 327     "#include <cmath>
 328     int main() { return std::isnan(0.0);} "
 329     HAVE_STD_ISNAN)
 330
 331 if(CMAKE_COMPILER_IS_GNUCXX)
 332     set(WARNING_FLAGS_CXX "-Wall")
 333     set(WARNING_FLAGS_C   "-Wall")
 334
 335     # certain GCC versions don't provide the atomic builds, and hence
 336     # require is to provide them in SGAtomic.cxx
 337     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 338     check_cxx_source_compiles(
 339        "int main() { unsigned mValue; return __sync_add_and_fetch(&mValue, 1); }"
 340         GCC_ATOMIC_BUILTINS_FOUND)
 341 endif(CMAKE_COMPILER_IS_GNUCXX)
 342
 343 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 344     # Boost redeclares class members
 345     set(WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual -Wno-redeclared-class-member")
 346     set(WARNING_FLAGS_C   "-Wall")
 347     set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LIBRARY "libc++")
 348     set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LANGUAGE_STANDARD "c++11")
 349     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -stdlib=libc++")
 350 endif()
 351
 352 if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 353 # boost goes haywire wrt static asserts
 354     check_cxx_compiler_flag(-Wno-unused-local-typedefs HAS_NOWARN_UNUSED_TYPEDEFS)
 355     if(HAS_NOWARN_UNUSED_TYPEDEFS)
 356         set(WARNING_FLAGS_CXX " ${WARNING_FLAGS_CXX} -Wno-unused-local-typedefs")
 357     endif()
 358 endif()
 359
 360 if(WIN32)
 361
 362     if(MINGW)
 363         add_definitions(-D_WIN32_WINNT=0x501)
 364     endif()
 365
 366     if(MSVC)
 367         set(MSVC_FLAGS "-DWIN32 -DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS /MP")
 368
 369         if (${MSVC_VERSION} GREATER 1599)
 370           # needed to avoid link errors on multiply-defined standard C++
 371           # symbols. Suspect this may be an OSG-DB export bug
 372             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 373         endif (${MSVC_VERSION} GREATER 1599)
 374
 375         if (${MSVC_VERSION} GREATER 1899)
 376             # needed for debug builds with VS2015
 377             set( MSVC_FLAGS "${MSVC_FLAGS} /bigobj" )
 378         endif()
 379     endif(MSVC)
 380
 381     # assumed on Windows
 382     set(HAVE_GETLOCALTIME 1)
 383
 384     set( WINSOCK_LIBRARY "ws2_32.lib" )
 385     set( RT_LIBRARY "winmm" )
 386 endif(WIN32)
 387
 388 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS}")
 389 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} ${BOOST_CXX_FLAGS}")
 390 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 391
 392 # use BEFORE to ensure local directories are used first,
 393 # ahead of system-installed libs
 394 include_directories(BEFORE ${PROJECT_SOURCE_DIR})
 395 include_directories(BEFORE ${PROJECT_SOURCE_DIR}/simgear/canvas/ShivaVG/include)
 396 include_directories(BEFORE ${PROJECT_BINARY_DIR}/simgear)
 397
 398 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 399     ${Boost_INCLUDE_DIRS}
 400     ${ZLIB_INCLUDE_DIR}
 401     ${OPENAL_INCLUDE_DIR}
 402     ${CURL_INCLUDE_DIRS}
 403 )
 404
 405 add_definitions(-DHAVE_CONFIG_H)
 406
 407 # configure a header file to pass some of the CMake settings
 408 # to the source code
 409 configure_file (
 410   "${PROJECT_SOURCE_DIR}/simgear/simgear_config_cmake.h.in"
 411   "${PROJECT_BINARY_DIR}/simgear/simgear_config.h"
 412   )
 413
 414 if(ENABLE_TESTS)
 415     # enable CTest / make test target
 416     message(STATUS "Tests: ENABLED")
 417
 418     include (Dart)
 419     enable_testing()
 420 else()
 421     message(STATUS "Tests: DISABLED")
 422 endif(ENABLE_TESTS)
 423
 424 # always set TEST_LIBS as it is also used by other tools/applications
 425 set(TEST_LIBS_INTERNAL_CORE
 426     ${CMAKE_THREAD_LIBS_INIT}
 427     ${ZLIB_LIBRARY}
 428     ${WINSOCK_LIBRARY}
 429     ${RT_LIBRARY}
 430     ${DL_LIBRARY}
 431     ${COCOA_LIBRARY}
 432     ${CURL_LIBRARIES})
 433 set(TEST_LIBS SimGearCore ${TEST_LIBS_INTERNAL_CORE})
 434
 435 if(NOT SIMGEAR_HEADLESS)
 436     set(TEST_LIBS SimGearScene ${OPENGL_LIBRARIES} ${TEST_LIBS})
 437 endif()
 438
 439 install (FILES ${PROJECT_BINARY_DIR}/simgear/simgear_config.h  DESTINATION include/simgear/)
 440
 441 include_directories(3rdparty/utf8/source)
 442
 443 if(ENABLE_DNS)
 444     if(SYSTEM_UDNS)
 445         message(STATUS "Requested to use system udns library, forcing SIMGEAR_SHARED to true")
 446         set(SIMGEAR_SHARED ON)
 447         find_package(Udns REQUIRED)
 448     else()
 449         message(STATUS "DNS resolver: ENABLED")
 450         include_directories(3rdparty/udns)
 451     endif()
 452 else()
 453     message(STATUS "DNS resolver: DISABLED")
 454 endif()
 455
 456
 457 add_subdirectory(3rdparty)
 458 add_subdirectory(simgear)
 459
 460 #-----------------------------------------------------------------------------
 461 ### Export stuff, see https://cmake.org/cmake/help/v3.2/manual/cmake-packages.7.html#creating-packages
 462 #-----------------------------------------------------------------------------
 463
 464 generate_export_header(SimGearCore)
 465 if(NOT SIMGEAR_HEADLESS)
 466   generate_export_header(SimGearScene)
 467 endif()
 468
 469 include(CMakePackageConfigHelpers)
 470
 471 write_basic_package_version_file(
 472   "${CMAKE_CURRENT_BINARY_DIR}/SimGear/SimGearConfigVersion.cmake"
 473   VERSION ${SIMGEAR_VERSION}
 474   COMPATIBILITY AnyNewerVersion
 475 )
 476
 477 configure_file(SimGearConfig.cmake.in
 478   "${CMAKE_CURRENT_BINARY_DIR}/SimGear/SimGearConfig.cmake"
 479   @ONLY
 480 )
 481
 482 set(ConfigPackageLocation lib/cmake/SimGear)
 483 install(EXPORT SimGearTargets
 484   DESTINATION ${ConfigPackageLocation}
 485 )
 486 install(
 487   FILES
 488     "${CMAKE_CURRENT_BINARY_DIR}/SimGear/SimGearConfig.cmake"
 489     "${CMAKE_CURRENT_BINARY_DIR}/SimGear/SimGearConfigVersion.cmake"
 490   DESTINATION ${ConfigPackageLocation}
 491   COMPONENT Devel
 492 )
 493
 494 #-----------------------------------------------------------------------------
 495 ### uninstall target
 496 #-----------------------------------------------------------------------------
 497 CONFIGURE_FILE(
 498   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 499   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 500   IMMEDIATE @ONLY)
 501 ADD_CUSTOM_TARGET(uninstall
 502   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")