CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8.11)
   2
   3 if(COMMAND cmake_policy)
   4    if(POLICY CMP0054)
   5        cmake_policy(SET CMP0054 NEW)
   6    endif()
   7    if(POLICY CMP0042)
   8        cmake_policy(SET CMP0042 NEW)
   9    endif()
  10 endif()
  11
  12 include (CheckFunctionExists)
  13 include (CheckIncludeFile)
  14 include (CheckLibraryExists)
  15 include (CheckCXXSourceCompiles)
  16 include (CheckCXXCompilerFlag)
  17 include (GenerateExportHeader)
  18
  19 # using 10.7 because boost requires libc++ and 10.6 doesn't include it
  20 set(CMAKE_OSX_DEPLOYMENT_TARGET 10.7)
  21
  22 # only relevant for building shared libs but let's set it regardless
  23 set(CMAKE_OSX_RPATH 1)
  24
  25 # Set the C++ standard to C++98 to avoid compilation errors on GCC 6 (which
  26 # defaults to C++14).
  27 if(CMAKE_VERSION VERSION_LESS "3.1")
  28   if(CMAKE_COMPILER_IS_GNUCXX)
  29     set (CMAKE_CXX_FLAGS "--std=gnu++98 ${CMAKE_CXX_FLAGS}")
  30   endif()
  31 else()
  32   set (CMAKE_CXX_STANDARD 98)
  33 endif()
  34
  35 project(SimGear)
  36
  37 # read 'version' file into a variable (stripping any newlines or spaces)
  38 file(READ version versionFile)
  39 string(STRIP ${versionFile} SIMGEAR_VERSION)
  40
  41 set(FIND_LIBRARY_USE_LIB64_PATHS ON)
  42
  43 # use simgear version also as the SO version (if building SOs)
  44 SET(SIMGEAR_SOVERSION ${SIMGEAR_VERSION})
  45
  46 # Warning when build is not an out-of-source build.
  47 string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}" InSourceBuild)
  48 if(InSourceBuild)
  49     message(WARNING  "Avoid building inside the source tree!")
  50     message(WARNING  "Create a separate build directory instead (i.e. 'sgbuild') and call CMake from there: ")
  51     message(WARNING  "  mkdir ../sgbuild && cd ../sgbuild && cmake ${CMAKE_SOURCE_DIR}")
  52 endif(InSourceBuild)
  53
  54 #packaging
  55 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  56 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  57 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Simulation support libraries for FlightGear and related projects")
  58 SET(CPACK_PACKAGE_VENDOR "The FlightGear project")
  59 SET(CPACK_GENERATOR "TBZ2")
  60 SET(CPACK_INSTALL_CMAKE_PROJECTS  ${CMAKE_CURRENT_BINARY_DIR};SimGear;ALL;/)
  61
  62
  63 # split version string into components, note CMAKE_MATCH_0 is the entire regexp match
  64 string(REGEX MATCH "([0-9]+)\\.([0-9]+)\\.([0-9]+)" CPACK_PACKAGE_VERSION ${SIMGEAR_VERSION} )
  65 set(CPACK_PACKAGE_VERSION_MAJOR ${CMAKE_MATCH_1})
  66 set(CPACK_PACKAGE_VERSION_MINOR ${CMAKE_MATCH_2})
  67 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_3})
  68
  69 message(STATUS "version is ${CPACK_PACKAGE_VERSION_MAJOR} dot ${CPACK_PACKAGE_VERSION_MINOR} dot ${CPACK_PACKAGE_VERSION_PATCH}")
  70
  71 set(CPACK_SOURCE_GENERATOR TBZ2)
  72 set(CPACK_SOURCE_PACKAGE_FILE_NAME "simgear-${SIMGEAR_VERSION}" CACHE INTERNAL "tarball basename")
  73 set(CPACK_SOURCE_IGNORE_FILES
  74   "^${PROJECT_SOURCE_DIR}/.git;\\\\.gitignore;Makefile.am;~$;${CPACK_SOURCE_IGNORE_FILES}")
  75
  76 message(STATUS "ignoring: ${CPACK_SOURCE_IGNORE_FILES}")
  77
  78 include (CPack)
  79
  80 # We have some custom .cmake scripts not in the official distribution.
  81 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  82
  83 # Change the default build type to something fast
  84 if(NOT CMAKE_BUILD_TYPE)
  85   set(CMAKE_BUILD_TYPE Release CACHE STRING
  86       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  87       FORCE)
  88 endif(NOT CMAKE_BUILD_TYPE)
  89
  90 # Determine name of library installation directory, i.e. "lib" vs "lib64", which
  91 # differs between all Debian-based vs all other Linux distros.
  92 # See cmake bug #11964, http://cmake.org/gitweb?p=cmake.git;a=commit;h=126c993d
  93 include(GNUInstallDirs)
  94 message(STATUS "Library installation directory: ${CMAKE_INSTALL_LIBDIR}")
  95
  96 #####################################################################################
  97 # Configure library search paths
  98 #####################################################################################
  99
 100 if(NOT "${CMAKE_LIBRARY_ARCHITECTURE}" STREQUAL "")
 101     # Workaround for Ubuntu/Debian which introduced the "multiarch" library
 102     # directory structure, which is unsupported by CMake < 2.8.10, so we need to
 103     # add paths manually
 104     # see http://www.cmake.org/Bug/view.php?id=12049 and
 105     # http://www.cmake.org/Bug/view.php?id=12037
 106     list(APPEND ADDITIONAL_LIBRARY_PATHS
 107          /usr/local/lib/${CMAKE_LIBRARY_ARCHITECTURE}
 108          /usr/lib/${CMAKE_LIBRARY_ARCHITECTURE}
 109          /lib/${CMAKE_LIBRARY_ARCHITECTURE})
 110     message(STATUS "additional library directories: ${ADDITIONAL_LIBRARY_PATHS}")
 111 endif()
 112
 113 #####################################################################################
 114
 115 if (NOT MSVC)
 116 option(SIMGEAR_SHARED   "Set to ON to build SimGear as a shared library/framework" OFF)
 117 option(SYSTEM_EXPAT     "Set to ON to build SimGear using the system libExpat" OFF)
 118 else()
 119 # Building SimGear DLLs is currently not supported for MSVC.
 120 set(SIMGEAR_SHARED OFF)
 121 # Using a system expat is currently not supported for MSVC - it would require shared simgear (DLL).
 122 set(SYSTEM_EXPAT OFF)
 123 endif()
 124
 125 option(SIMGEAR_HEADLESS "Set to ON to build SimGear without GUI/graphics support" OFF)
 126 option(ENABLE_RTI       "Set to ON to build SimGear with RTI support" OFF)
 127 option(ENABLE_TESTS     "Set to OFF to disable building SimGear's test applications" ON)
 128 option(ENABLE_SOUND     "Set to OFF to disable building SimGear's sound support" ON)
 129 option(ENABLE_PKGUTIL   "Set to ON to build the sg_pkgutil application (default)" ON)
 130 option(ENABLE_DNS       "Set to ON to use udns library and DNS service resolver" ON)
 131
 132 if (MSVC)
 133   GET_FILENAME_COMPONENT(PARENT_DIR ${PROJECT_BINARY_DIR} PATH)
 134   if (CMAKE_CL_64)
 135     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty.x64")
 136   else (CMAKE_CL_64)
 137     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty")
 138   endif (CMAKE_CL_64)
 139   if (EXISTS ${TEST_3RDPARTY_DIR})
 140     set(MSVC_3RDPARTY_ROOT ${PARENT_DIR} CACHE PATH "Location where the third-party dependencies are extracted")
 141   else (EXISTS ${TEST_3RDPARTY_DIR})
 142     set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 143   endif (EXISTS ${TEST_3RDPARTY_DIR})
 144 else (MSVC)
 145   set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
 146 endif (MSVC)
 147
 148 if (MSVC AND MSVC_3RDPARTY_ROOT)
 149   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_ROOT}")
 150   set( OSG_MSVC "msvc" )
 151   if (${MSVC_VERSION} EQUAL 1700)
 152       set( OSG_MSVC ${OSG_MSVC}110 )
 153   elseif (${MSVC_VERSION} EQUAL 1600)
 154       set( OSG_MSVC ${OSG_MSVC}100 )
 155   else (${MSVC_VERSION} EQUAL 1700)
 156       set( OSG_MSVC ${OSG_MSVC}90 )
 157   endif (${MSVC_VERSION} EQUAL 1700)
 158   if (CMAKE_CL_64)
 159       set( OSG_MSVC ${OSG_MSVC}-64 )
 160       set( MSVC_3RDPARTY_DIR 3rdParty.x64 )
 161   else (CMAKE_CL_64)
 162       set( MSVC_3RDPARTY_DIR 3rdParty )
 163   endif (CMAKE_CL_64)
 164
 165   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/lib )
 166   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenRTI/include)
 167   find_path(BOOST_ROOT boost/version.hpp
 168                         ${MSVC_3RDPARTY_ROOT}/boost
 169                         ${MSVC_3RDPARTY_ROOT}/boost_1_52_0
 170                         ${MSVC_3RDPARTY_ROOT}/boost_1_51_0
 171                         ${MSVC_3RDPARTY_ROOT}/boost_1_50_0
 172                         ${MSVC_3RDPARTY_ROOT}/boost_1_49_0
 173                         ${MSVC_3RDPARTY_ROOT}/boost_1_48_0
 174                         ${MSVC_3RDPARTY_ROOT}/boost_1_47_0
 175                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_1
 176                         ${MSVC_3RDPARTY_ROOT}/boost_1_46_0
 177                         ${MSVC_3RDPARTY_ROOT}/boost_1_45_0
 178                         ${MSVC_3RDPARTY_ROOT}/boost_1_44_0
 179                         )
 180   # set (BOOST_ROOT ${MSVC_3RDPARTY_ROOT}/boost_1_44_0)
 181   message(STATUS "BOOST_ROOT is ${BOOST_ROOT}")
 182   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
 183   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib)
 184 endif (MSVC AND MSVC_3RDPARTY_ROOT)
 185
 186 if(APPLE)
 187   find_library(COCOA_LIBRARY Cocoa)
 188
 189   # using 10.7 because boost requires libc++ and 10.6 doesn't include it
 190   SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mmacosx-version-min=10.7")
 191 endif()
 192
 193 if(${CMAKE_SYSTEM_NAME} MATCHES "Linux" OR
 194         ${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD")
 195     find_package(Threads REQUIRED)
 196 endif()
 197
 198 # Somehow this only works if included before searching for Boost...
 199 include(BoostTestTargets)
 200
 201 find_package(Boost REQUIRED)
 202 set (BOOST_CXX_FLAGS "-DBOOST_BIMAP_DISABLE_SERIALIZATION")
 203
 204 if(SIMGEAR_HEADLESS)
 205     message(STATUS "SimGear mode: HEADLESS")
 206     set(ENABLE_SOUND 0)
 207 else()
 208     message(STATUS "SimGear mode: NORMAL")
 209     find_package(OpenGL REQUIRED)
 210
 211     if (ENABLE_SOUND)
 212         find_package(OpenAL REQUIRED)
 213         message(STATUS "Sound support: ENABLED")
 214     endif(ENABLE_SOUND)
 215
 216     find_package(OpenSceneGraph 3.2.0 REQUIRED osgText osgSim osgDB osgParticle osgGA osgViewer osgUtil)
 217 endif(SIMGEAR_HEADLESS)
 218
 219 find_package(ZLIB REQUIRED)
 220 find_package(CURL REQUIRED)
 221
 222 if (SYSTEM_EXPAT)
 223     message(STATUS "Requested to use system Expat library, forcing SIMGEAR_SHARED to true")
 224     set(SIMGEAR_SHARED ON)
 225     find_package(EXPAT REQUIRED)
 226
 227 else()
 228     message(STATUS "Using built-in expat code")
 229     # XML_STATIC is important to avoid sg_expat_external.h
 230     # declaring symbols as declspec(import)
 231     add_definitions(-DHAVE_EXPAT_CONFIG_H -DXML_STATIC)
 232     set(EXPAT_INCLUDE_DIRS
 233             ${PROJECT_SOURCE_DIR}/3rdparty/expat
 234             ${PROJECT_BINARY_DIR}/3rdparty/expat)
 235 endif(SYSTEM_EXPAT)
 236
 237 include_directories(${EXPAT_INCLUDE_DIRS})
 238
 239 check_include_file(inttypes.h HAVE_INTTYPES_H)
 240 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 241 check_include_file(sys/timeb.h HAVE_SYS_TIMEB_H)
 242 check_include_file(unistd.h HAVE_UNISTD_H)
 243 check_include_file(windows.h HAVE_WINDOWS_H)
 244
 245 if(HAVE_INTTYPES_H)
 246   # ShivaVG needs inttypes.h
 247   add_definitions(-DHAVE_INTTYPES_H)
 248 endif()
 249
 250 if(ENABLE_RTI)
 251     # See if we have any rti library variant installed
 252     message(STATUS "RTI: ENABLED")
 253     find_package(RTI)
 254 else()
 255     message(STATUS "RTI: DISABLED")
 256 endif(ENABLE_RTI)
 257
 258 check_function_exists(gettimeofday HAVE_GETTIMEOFDAY)
 259 check_function_exists(ftime HAVE_FTIME)
 260 check_function_exists(timegm HAVE_TIMEGM)
 261 check_function_exists(rint HAVE_RINT)
 262 check_function_exists(mkdtemp HAVE_MKDTEMP)
 263 check_function_exists(bcopy HAVE_BCOPY)
 264 check_function_exists(mmap HAVE_MMAP)
 265
 266 if(HAVE_UNISTD_H)
 267     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 268     check_cxx_source_compiles(
 269        "#include <unistd.h>
 270         #if !defined(_POSIX_TIMERS) || (0 >= _POSIX_TIMERS)
 271             #error clock_gettime is not supported
 272         #endif
 273
 274         int main() { return 0; }
 275         "
 276         HAVE_CLOCK_GETTIME)
 277 endif(HAVE_UNISTD_H)
 278
 279 set(RT_LIBRARY "")
 280 if(HAVE_CLOCK_GETTIME)
 281     check_library_exists(rt clock_gettime "" HAVE_RT)
 282     if(HAVE_RT)
 283         set(RT_LIBRARY rt)
 284     endif(HAVE_RT)
 285 endif(HAVE_CLOCK_GETTIME)
 286
 287 set(DL_LIBRARY "")
 288 check_cxx_source_compiles(
 289     "#include <dlfcn.h>
 290     int main(void) {
 291         return 0;
 292     }
 293     "
 294     HAVE_DLFCN_H)
 295
 296 if(HAVE_DLFCN_H)
 297     check_library_exists(dl dlerror "" HAVE_DL)
 298     if(HAVE_DL)
 299         set(DL_LIBRARY "dl")
 300     endif()
 301 endif()
 302
 303 SET(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "add a postfix, usually 'd' on windows")
 304 SET(CMAKE_RELEASE_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 305 SET(CMAKE_RELWITHDEBINFO_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 306 SET(CMAKE_MINSIZEREL_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 307
 308 # isnan might not be real symbol, so can't check using function_exists
 309 check_cxx_source_compiles(
 310     "#include <cmath>
 311     int main() { return isnan(0.0);} "
 312     HAVE_ISNAN)
 313
 314 check_cxx_source_compiles(
 315     "#include <cmath>
 316     int main() { return std::isnan(0.0);} "
 317     HAVE_STD_ISNAN)
 318
 319 if(CMAKE_COMPILER_IS_GNUCXX)
 320     set(WARNING_FLAGS_CXX "-Wall")
 321     set(WARNING_FLAGS_C   "-Wall")
 322
 323     # certain GCC versions don't provide the atomic builds, and hence
 324     # require is to provide them in SGAtomic.cxx
 325     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 326     check_cxx_source_compiles(
 327        "int main() { unsigned mValue; return __sync_add_and_fetch(&mValue, 1); }"
 328         GCC_ATOMIC_BUILTINS_FOUND)
 329 endif(CMAKE_COMPILER_IS_GNUCXX)
 330
 331 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 332     # Boost redeclares class members
 333     set(WARNING_FLAGS_CXX "-Wall -Wno-overloaded-virtual -Wno-redeclared-class-member")
 334     set(WARNING_FLAGS_C   "-Wall")
 335     set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LIBRARY "libc++")
 336     set(CMAKE_XCODE_ATTRIBUTE_CLANG_CXX_LANGUAGE_STANDARD "c++11")
 337     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -stdlib=libc++")
 338 endif()
 339
 340 if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
 341 # boost goes haywire wrt static asserts
 342     check_cxx_compiler_flag(-Wno-unused-local-typedefs HAS_NOWARN_UNUSED_TYPEDEFS)
 343     if(HAS_NOWARN_UNUSED_TYPEDEFS)
 344         set(WARNING_FLAGS_CXX " ${WARNING_FLAGS_CXX} -Wno-unused-local-typedefs")
 345     endif()
 346 endif()
 347
 348 if(WIN32)
 349
 350     if(MINGW)
 351         add_definitions(-D_WIN32_WINNT=0x501)
 352     endif()
 353
 354     if(MSVC)
 355         # turn off various warnings
 356         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 357         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 358         # endforeach(warning)
 359
 360         set(MSVC_FLAGS "-DWIN32 -DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS /wd4996 /wd4250 -Dstrdup=_strdup")
 361         if (${MSVC_VERSION} GREATER 1599)
 362             set( MSVC_LD_FLAGS "/FORCE:MULTIPLE" )
 363         endif (${MSVC_VERSION} GREATER 1599)
 364     endif(MSVC)
 365
 366     # assumed on Windows
 367     set(HAVE_GETLOCALTIME 1)
 368
 369     set( WINSOCK_LIBRARY "ws2_32.lib" )
 370     set( RT_LIBRARY "winmm" )
 371 endif(WIN32)
 372
 373 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS_C} ${MSVC_FLAGS}")
 374 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS_CXX} ${MSVC_FLAGS} ${BOOST_CXX_FLAGS}")
 375 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${MSVC_LD_FLAGS}")
 376
 377 # use BEFORE to ensure local directories are used first,
 378 # ahead of system-installed libs
 379 include_directories(BEFORE ${PROJECT_SOURCE_DIR})
 380 include_directories(BEFORE ${PROJECT_SOURCE_DIR}/simgear/canvas/ShivaVG/include)
 381 include_directories(BEFORE ${PROJECT_BINARY_DIR}/simgear)
 382
 383 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 384     ${Boost_INCLUDE_DIRS}
 385     ${ZLIB_INCLUDE_DIR}
 386     ${OPENAL_INCLUDE_DIR}
 387     ${CURL_INCLUDE_DIRS}
 388 )
 389
 390 add_definitions(-DHAVE_CONFIG_H)
 391
 392 # configure a header file to pass some of the CMake settings
 393 # to the source code
 394 configure_file (
 395   "${PROJECT_SOURCE_DIR}/simgear/simgear_config_cmake.h.in"
 396   "${PROJECT_BINARY_DIR}/simgear/simgear_config.h"
 397   )
 398
 399 if(ENABLE_TESTS)
 400     # enable CTest / make test target
 401     message(STATUS "Tests: ENABLED")
 402
 403     include (Dart)
 404     enable_testing()
 405 else()
 406     message(STATUS "Tests: DISABLED")
 407 endif(ENABLE_TESTS)
 408
 409 # always set TEST_LIBS as it is also used by other tools/applications
 410 set(TEST_LIBS_INTERNAL_CORE
 411     ${CMAKE_THREAD_LIBS_INIT}
 412     ${ZLIB_LIBRARY}
 413     ${WINSOCK_LIBRARY}
 414     ${RT_LIBRARY}
 415     ${DL_LIBRARY}
 416     ${COCOA_LIBRARY}
 417     ${CURL_LIBRARIES})
 418 set(TEST_LIBS SimGearCore ${TEST_LIBS_INTERNAL_CORE})
 419
 420 if(NOT SIMGEAR_HEADLESS)
 421     set(TEST_LIBS SimGearScene ${OPENGL_LIBRARIES} ${TEST_LIBS})
 422 endif()
 423
 424 install (FILES ${PROJECT_BINARY_DIR}/simgear/simgear_config.h  DESTINATION include/simgear/)
 425
 426 include_directories(3rdparty/utf8/source)
 427 if (ENABLE_DNS)
 428     message(STATUS "DNS resolver: ENABLED")
 429     include_directories(3rdparty/udns)
 430 else()
 431     message(STATUS "DNS resolver: DISABLED")
 432 endif()
 433
 434
 435 add_subdirectory(3rdparty)
 436 add_subdirectory(simgear)
 437
 438 #-----------------------------------------------------------------------------
 439 ### Export stuff, see https://cmake.org/cmake/help/v3.2/manual/cmake-packages.7.html#creating-packages
 440 #-----------------------------------------------------------------------------
 441
 442 generate_export_header(SimGearCore)
 443 if(NOT SIMGEAR_HEADLESS)
 444   generate_export_header(SimGearScene)
 445 endif()
 446
 447 include(CMakePackageConfigHelpers)
 448
 449 write_basic_package_version_file(
 450   "${CMAKE_CURRENT_BINARY_DIR}/SimGear/SimGearConfigVersion.cmake"
 451   VERSION ${SIMGEAR_VERSION}
 452   COMPATIBILITY AnyNewerVersion
 453 )
 454
 455 configure_file(SimGearConfig.cmake.in
 456   "${CMAKE_CURRENT_BINARY_DIR}/SimGear/SimGearConfig.cmake"
 457   @ONLY
 458 )
 459
 460 set(ConfigPackageLocation lib/cmake/SimGear)
 461 install(EXPORT SimGearTargets
 462   DESTINATION ${ConfigPackageLocation}
 463 )
 464 install(
 465   FILES
 466     "${CMAKE_CURRENT_BINARY_DIR}/SimGear/SimGearConfig.cmake"
 467     "${CMAKE_CURRENT_BINARY_DIR}/SimGear/SimGearConfigVersion.cmake"
 468   DESTINATION ${ConfigPackageLocation}
 469   COMPONENT Devel
 470 )
 471
 472 #-----------------------------------------------------------------------------
 473 ### uninstall target
 474 #-----------------------------------------------------------------------------
 475 CONFIGURE_FILE(
 476   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 477   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 478   IMMEDIATE @ONLY)
 479 ADD_CUSTOM_TARGET(uninstall
 480   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")